Nautilisia by Ryan Veeder

Nautilisia

Played 13,038 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Nautilisia" by Ryan Veeder

Volume 1 - Boring Stuff

The story headline is "A bizarre and whimsical dream-world steeped in pseudo-Jungian symbolism,".

The release number is 2.

[Include Basic Screen Effects by Emily Short.

Include Plurality by Emily Short.

Include Basic Help Menu by Emily Short.

When play begins:
	choose row 1 in Table of Basic Help Options;
	now description entry is "Okay, let me step out of the narrator-character's voice for a second.[paragraph break]Thank you very much for playing Nautilisia. This game started out as a parody of dream-logic oriented IF, but now that it's done I feel like maybe it's turned into more of an homage. Or maybe that's not up to me to decide. (The paradigm example of the Dream-Logic Game is Sara Dee's [italic type]Madam Spider's Web,[roman type] a really wonderful piece which I highly recommend.)[paragraph break]I'd love to know what you think of Nautilisia. If you have any kind of feedback or questions or that kind of thing, please send them in the direction of rcveeder@me.com[paragraph break]This game would be a lot less interesting if it weren't for my awesome beta testers: Heidi Poe, Amanda Lange, Emily Boegheim, and Zach S. They are the best.[paragraph break]Post-beta help came from Melvin and Andrew and Matthew and probably someone else. I feel like I'm forgetting someone. Shoot.[paragraph break]Sorry.[paragraph break]Anyway thanks again for playing! I'll get back into character now...";]

Use no scoring.

When play begins:
	now the right hand status line is "";
	say "I know, I know I know, we're gonna be late. But here's the thing: I'm in a coma. Yeah.[paragraph break]And my brain has put together this bizarre fantasy world, to try and keep me sane, or protect my fragile psyche from the trauma ofâ€¦ whatever the coma is about, and I can't wake up until I escape from the dream-world. And that's gonna take a while, because I am really comfortable. I mean in the dream-world and also in the real world, right here.[paragraph break]So I don't have a lot of incentive. To wake up, I mean.[paragraph break][open bracket]press any key[close bracket][paragraph break]";
	wait for any key;
	say "Well, if you're gonna be so stubborn about it, you can come in the dream-world and solve all the extremely symbolic puzzles and 'rescue' me from my delusions. I guess it's only fair to let you try.[paragraph break]";
	wait for any key;
	say "But hold on. I said hold on! Let me think of a name. For the dream-world. It has to be sufficiently fantasy-sounding, but it also has to be obviously symbolic of something. Hmm.[paragraph break]";
	wait for any key;
	say "Okay, I've got it.[paragraph break]";
	wait for any key;
	
After printing the banner text:
	say "[line break]Yeah, it's a stupid name, but it's the best I can come up with.";
	wait for any key.
	
Attempting to communicate is an action applying to one thing. Understand "talk [something]" or "talk to [something]" or "speak [something]" or "speak to [something]" or "speak with [something]" or "talk with [something]" or "call [something]" or "greet [something]" or "say [something]" or "beg [something]" as attempting to communicate.

Attempting to talk is an action applying to nothing. Understand "talk" or "speak" as attempting to talk.

Carry out attempting to communicate:
	if the noun is the Siren:
		say "The Siren smiles and says hello. She is extremely helpful and would love to tell you about anything you want to ask her about.";
	otherwise if the noun is the comatose body:
		say "But you've been talking to me this whole time!";
	otherwise if the noun is the goat-fish:
		say "You gurgle some baby talk at the baby goat-fish, and it bleats back at you.";
	otherwise:
		say "That's not something you can talk to."

Carry out attempting to talk:
	say "Who are you talking to, and what are you talking to them about?"

Expressing displeasure is an action applying to nothing. Understand "dangit" or "dang" or "darn" or "drat" or "shut up" or "aw" or "aww" or "awww" or "agh" or "arg" or "argh" as expressing displeasure.

Carry out expressing displeasure:
	say "I'm very sorry."
	
Thanking is an action applying to nothing. Understand "awesome" or "great" or "nice" or "yay" or "hooray" or "good" or "thanks" or "thx" or "thank you" as thanking.

Carry out thanking:
	say "You're welcome."

Instead of attacking something, say "Don't start with that stuff. Nautilisia is a safe place, a peaceful place. Play along a little."

Rule for printing a parser error when the latest parser error is the I beg your pardon error:
	say "You wanna say something? Or are you thinking?" instead.

Instead of sleeping, say "No, I'm already asleep. A person in a coma is always asleep basically."

Understand "dream" as a mistake ("What the heck are you trying to do?! You can't dream inside the dream! You'll start an infinite loop!").

The description of the player is "You look like yourself. Don't overthink it."

Instead of smelling something, say "I read somewhere that you can't smell in dreams. But I seem to remember smelling something in a dream once? Anyway, let's keep things simple: In [italic type]this[roman type] dream, you can't smell anything."

Instead of smelling, say "I read somewhere that you can't smell in dreams. But I seem to remember smelling something in a dream once? Anyway, let's keep things simple: In [italic type]this[roman type] dream, you can't smell anything."

Understand "fly" as jumping. Instead of jumping, say "You hop up in the air, but are unable to stay aloft. I've never been able to fly in a dream, so I'm deciding you can't fly either."

Instead of singing, say "[italic type]Danke Schoen, darling, Danke Schoen,[line break]
Thank you for all the joy and pain[roman type]..."

Dancing is an action applying to nothing. Understand "dance" and "dance around" and "do a dance" as dancing.

Instead of dancing, say "Your dancing is abominable! Quit ruining my dream-world!"

Instead of thinking:
	if the player is in caves:
		say "Your thoughts reverberate against the walls, bouncing around and multiplying and colliding and eventually canceling each other out.";
	otherwise:
		say "If you think, that'll help."
		


Understand "use [something] with [something]" as unlocking it with (with nouns reversed).

Understand "use [something] on [something]" as unlocking it with (with nouns reversed).

Understand the command "put" as something new.

Understand "put [something] on [something]" as unlocking it with (with nouns reversed).

Understand "put [something] in [something]" as unlocking it with (with nouns reversed).

Understand "put [something] into [something]" as unlocking it with (with nouns reversed).

Understand "put [something] in [an open container]" as inserting it into.

Understand "put [something] into [an open container]" as inserting it into.


Xyzzing is an action applying to nothing. Understand "xyzzy" and "say xyzzy" and "cast xyzzy" as xyzzing.

Instead of xyzzing:
	say "A hollow voice puts its hand over your mouth and says 'Shush!'"

Understand "sit" and "sit down" and "sit on floor" and "sit on ground" as sitting down.

Sitting down is an action applying to nothing.

Check sitting down:
	if the location is Enchanted Gulf:
		try entering the white sand instead;
	otherwise:
		say "You sit down. See? Doesn't that feel nice?" instead.

Volume 2 - The First Half (Outside Caves)

Book 1 - Stately Mansion

Stately Mansion is a room. "[if unvisited]Okay, so you start out in this stately mansion. [end if]It's like stately Wayne Manor, in that it's on top of a hill, and it's very expansive and full of expensive things, but there's no labyrinthine cave system underneath it.[if caves4 is unvisited] [otherwise] Well okay, I guess actually there turned out to be a labyrinthine cave system underneath it, [italic type]sorry to disappoint you.[roman type][paragraph break][otherwise]It symbolizes the trappings of society that are so [italic type]precious[roman type] to you, like being [italic type]on time[roman type] for things.[paragraph break][end if]There's even a big grandfather clock in here, that symbolizes punctuality, but it doesn't tell the time. Because it's a dream![paragraph break]You can go outside by going south[if unvisited]. Just because it's a dream doesn't mean there aren't still compass directions. Work with me[end if]."

Stately Mansion is north of Hill.

Before exiting in stately mansion:
	try going south instead.

Before going outside in stately mansion:
	try going south instead.

Instead of going nowhere in stately mansion, say "No, you can't go running around the stately manor. I don't have the creative energy to decide what's in there. Just pretend there's a curse or something on the rest of the manor, and the curse is keeping you from going to any rooms other than the one you're in. If you want to leave, you can go south."

The expensive things are scenery in stately mansion. Understand "thing" or "expensive thing" as the expensive things. Instead of doing something with the expensive things, say "You better not screw around with those expensive things too much. They're pretty expensive."

The big grandfather clock is scenery in stately mansion. Understand "chamber" as the big grandfather clock. The big grandfather clock is a closed transparent openable container. The description of the big grandfather clock is "There aren't even any hands! Or numbers! The face of the clock is just a spinning, spiraling shape, and when you look at it you realize that time is meaningless.[paragraph break]There's also that chamber underneath the face, where they keep the pendulums."

Instead of taking the big grandfather clock, say "No, you don't get it. This clock is huge."

The spinning spiraling shape is part of the big grandfather clock. Understand "face" or "face of the clock" or "clock face" as the shape. The description of the shape is "Yeah, so now you realize that time is meaningless. Time is just a giant hole, and our lives fall into the hole. And nothing means anything, forever[one of]. I'm bored. Do something other than just looking at the clock[or][stopping]."

After opening the big grandfather clock, say "[if the clock contains the pendulums]Okay so you open up the clock and there are these two pendulums inside. I don't know how they work[otherwise]You open up the clock and this time you see [a list of things contained by the clock][end if]."

Understand "clock" or "grandfather clock" or "grandfather" or "spinning spiraling shape" or "spiralling shape" or "shape" as "[the big grandfather clock]".

The big grandfather clock contains some zig-zaggy pendulums. Understand "weights" or "pendulum" or "weight" or "aquarius" or "zigzags" or "zigzag" or "zig zag" or "zig zags" or "zig-zag" or "zig-zags" as the pendulums. The description of the pendulums is "There's two of them, and they're made out of this white iridescent substance. And they're in a weird shape, like, a zig-zag shape. They're basically two long white zig-zags[if the clock contains the pendulums].[paragraph break]They're just hanging there inside the clock[end if]."

Check pulling the pendulums:
	if the clock contains the pendulums:
		now the player carries the pendulums;
		say "You pull on the pendulums and they detach, almost as if you were meant to carry them around with you." instead;
	otherwise:
		say "You pull on the pendulums but not a whole lot happens." instead.

Rule for printing room description details: stop.

Understand "weights" or "pendulum" or "pendulums" or "weight" or "aquarius" or "zigzags" or "zigzag" or "zig zag" or "zig zags" or "zig-zag" or "zig-zags" as "[the pendulums]".

After taking the pendulums, say "You pick up the zig-zaggy pendulums."

Instead of listening to stately mansion, say "Your brain is filled with the sound of the ticking clock. TICK. TICK. TICK. TICK. 'Let's get going!' it seems to say. TICK. 'We're gonna be late!'[paragraph break]TICK."

Book 2 - Hill

Hill is a room. "[if unvisited]As you exit the manor and symbolically shed the shackles of civilization, the sweet summer wind blows like a piccolo song across your weathered brow.[paragraph break][end if]So, from up here in front of the stately manor, you can see all the rest of the island[if unvisited], which I don't know if I've mentioned this yet but my dream world has taken the form of an island[end if]. [if caves4 is mapped west of hill]An entrance has opened into the caves beneath the jungle to the west of you[otherwise]To your right, which is west of you if you're facing south, is a thick jungle, with leaves that are deep greens and purples in their colors. It symbolizes the terror and the wonderment of the unknown. But it is impenetrable to you from where you're standing[end if].[paragraph break]Down the hill to the southwest is a white sandy beach[if enchanted gulf is unvisited]. I'll tell you what it symbolizes when you get there[end if]." Hill is northeast of Enchanted Gulf.

The cliffs are scenery in hill. The description of the cliffs is "They are deadly-looking, and symbolize the ultimate boundaries of human experience, in all their finality."

Instead of going inside in hill, try going north instead. Instead of going down in hill, try going west instead.

Instead of going nowhere in hill, say "Stop trying to make me think of more areas for my dream world! Either go north, into the manor, or southwest, to the beach[if caves4 is mapped west of hill], or west, into the caves[end if]."

The jungle is a backdrop. The jungle is in hill and enchanted gulf and jungler and clearing. The description of the jungle is "The jungle is thick, and leafy. It represents... what did I say it represented? Maybe danger?"

Instead of listening to hill, say "The sweet summer wind is still blowing like a piccolo song."

Book 3 - Enchanted Gulf

Enchanted Gulf is a room. "The gulf that this enchanted beach envelops is itself enchanted, or [italic type]ensorcelled,[roman type] with a magical [italic type]glamour[roman type] which makes everyone who sees it want to just sit around and take a break for once in their lives. It symbolizes taking a break for once in your life. Only you are able to resist this enchantment, because you alone are so incredibly uptight about getting stuff done all the time and being on time for things.[paragraph break]Back to the northeast is the hill, and over to the west is that dark, scary jungle.[paragraph break]A little ways out into the water is a white ship, pitching and yawing on the restless sea."

The restless sea is scenery in enchanted gulf. Understand "gulf" or "ocean" or "water" or "seawater" as the restless sea. The description of the restless sea is "Yeah, the sea. Let's not worry about what the sea symbolizes. Let's just look at it for a little bit.[paragraph break]Yeah."

Instead of drinking the restless sea, say "You cup your hands and lift some of the seawater to your lips, but it is incredibly salty so you spit it out."

The magical glamour is scenery in enchanted gulf. Understand "enchantment" or "magic" as the glamour. Instead of doing something with the glamour, say "The magical glamour evades your glance, like a bright, elusive butterfly; or else like one of those dots on your eyeball that moves when you try to look at it."

The white sand is a backdrop. Understand "beach" or "sands" or "sandy beach" as the white sand. The white sand is in hill and enchanted gulf. The description of the white sand is "[if the location is hill]You can't examine the sand from way up here[otherwise]The sand is white, and powdery; it must have been imported from Australia[end if]." Instead of taking the white sand, say "You don't need the sand. It's not part of any puzzle. It doesn't symbolize anything."

Instead of entering the white sand, say "[if the location is hill]You can't sit on it from way over here[otherwise]You sit on the beach, and stare at the sea; a feeling of calm washes over you."

The white ship is a backdrop. The white ship is in enchanted gulf and pearl. Understand "pearl" or "boat" or "ship of pearl" or "pearl ship" or "shipwreck" or "wreck" as the white ship. Instead of entering the white ship, try going inside. Instead of going south in enchanted gulf, try going inside. The description of the white ship is "Apparently wrecked here on the shallow reef. It's white, and shiny, like something out of a dream. I mean, it literally is in this dream that I'm describing to you right now. It symbolizes[if pearl is unvisited]... Actually, go in there first; give me a second to think about this[otherwise] the inescapable loneliness that all artists must learn to deal with[end if]."

The bare coral reef is scenery in enchanted gulf. The description of the bare coral reef is "Coral is super scratchy, you know that? It cuts you open and then the saltwater gets in there and it stings like a mother. This dream coral symbolizes the fundamental painfulness of existence.[paragraph break]I guess I don't know why the Siren is sitting on it then."

Instead of entering the reef, say "When you sit on the reef, it scratches your butt. I'm trying not to be sadistic, but you make it so easy sometimes."

Instead of going nowhere in Enchanted Gulf, say "You can't go that way! You can either go northeast, to the hill, or you can go west, into the terrifying jungle. Or you can go inside the ship over there."

Understand "go in [something]" and "go inside [something]" and "go to [something]" as entering. Understand "swim to [something]" as entering.

Understand "swim" and "go swimming" and "swim in sea" and "swim in water" and "swim in pool" and "swim in ocean" as swimming. Swimming is an action applying to nothing.

Check swimming:
	If the location is caves6:
		say "The pool is too small for you to swim in, so you shrink down to the size of a frog and swim around in it for a while. Then you return to your normal size." instead;
	otherwise if the location is enchanted gulf:
		say "You paddle out toward the white ship.";
		try going south instead;
	otherwise if the location is Pearl:
		say "You leave the ship and swim back toward the shore.";
		try going north instead;
	otherwise:
		say "There's nothing to swim in where you currently are." instead.

Part 1 - The Siren

The Siren is here. "A Siren is here, sitting and singing on a coral reef." The Siren is a woman. Understand "sea-maid" or "sea maid" or "maid" or "mermaid" or "woman" as the Siren. The description of the Siren is "A Siren is actually supposed to be a bird-woman, I guess, but I want this sea-maid to be more like a mermaid. From the hips down she is one hundred percent fish, but from the fish up she is one hundred percent woman, with long, streaming hair.[paragraph break]And she's singing a song, but it's not like she's gonna hypnotize you or anything. She's not evil. She symbolizes the beauty that can be found in life if you don't take everything so seriously all the time[if the Siren wears the girdle][paragraph break]She's wearing a girdle, which is kind of a curvy belt kind of thing[end if]."

The Siren's song is scenery in enchanted gulf. Understand "music" or "singing" or "siren's singing" or "siren singing" as the Siren's song.

Instead of examining the Siren's song:
	try listening to the location.
	
Instead of listening to the Siren's song:
	try listening to the location.
	
Instead of taking the Siren's song:
	say "You succeed in stealing the Siren's song for yourself, but, overcome with guilt, you quickly return it to her."

The long streaming hair is part of the Siren. The description of the streaming hair is "Her hair is black. Long and black and wet. It's all the more black for its being wet.[if the Siren carries the venus comb]At intervals, she runs that spiny comb through it[otherwise]The strands are all tangled up after a long day of swimming around, though, and she seems a bit frustrated at this.[paragraph break]But I can't decide whether her hair should cover up her boobs or not. I mean, maybe it's not very important, but I'm getting hung up on it anyway. For now I'm gonna say it covers up... [one of]both boobs[or]just the left boob[or]just the right boob[or]neither boob[at random]."

Some shimmering scales are part of the Siren. Understand "scale" or "shimmering scale" as the shimmering scales. The description of the shimmering scales is "They shimmer with a sparkling iridescence. Jeez, almost everything on this dream island is iridescent, huh?"

Some boobs are part of the Siren. Understand "boob" or "chest" or "booby" or "boobie" or "boobies" as the boobs. The description of the boobs is "As you gaze upon the Siren's boobs, which apparently the Siren does not mind you doing, I am going to decide whether they're covered up by her hair or not. It's not a completely arbitrary question, you know. This kind of detail does a lot to determine the overall tone of my dream world.[paragraph break]I'm gonna say... [one of]both boobs are covered up[or]just the left boob is exposed[or]just the left boob is covered up[or]both boobs are exposed[at random]."

After reading a command:
	if the player's command includes "[breasts]":
		say "Oh, come on. Let's be mature, okay? Just say 'boobs.'";
		reject the player's command.

Understand "breasts" or "breast" or "gazonga" or "gazongas" or "mammary" or "mammaries" or "tit" or "happy pillow" or "tits" or "happy pillows" or "melon" or "melons" or "funbag" or "funbags" or "rack" or "titties" or "cans" or "jugs" or "knockers" or "hooter" or "hooters" or "bazoom" or "bazooms" or "bust" or "chests" as "[breasts]".

The Siren wears a Siren's girdle. Understand "belt" or "corset" or "corselet" or "pisces" as the girdle. The description of the girdle is "[if the siren wears the girdle]The Siren's girdle is a pale, opalescent belt thing, pulled snug around her waist. It is the only thing she's wearing[otherwise]Now that she's not wearing it, the Siren's girdle has turned into more of a two-dimensional curvy H shape, like a crude drawing of a girdle being worn around an hourglass waist. It's still pale and opalescent, though[end if]."

Instead of wearing the Siren's girdle, say "I'm not saying you don't have the figure for it, but that's not how you're supposed to use the girdle."

Check taking the girdle:
	if the siren wears the girdle:
		say "You can't just yank it off her body! That's not how we do things in Nautilisia." instead.

Instead of listening to enchanted gulf:
	choose a random row in the table of singing;
	say "The Siren sings [intro entry] [italic type]'[song entry]'[roman type][paragraph break]"
	
Table of Singing
intro	song
"in a strange and untranslateable dream-language:"	"Deireadh an turas mÃ³r, tÃ¡im brÃ³nach, buartha [apostrophe]s briste..."
"in a strange and untranslateable dream-language:"	"Aoibhneas a bhÃ, ach d'imigh sin..."
"in a strange and untranslateable dream-language:"	"An ghealach, an ghrian, an ghaoth, moladh duit, a Dhia..."
"in what might be a Romance language, or might be random dream-syllables:"	"SerÃ© una ola. SerÃ© la luna. He sido todo, soy yo."
"in a strange and untranslateable dream-language:"	"MÃ¡ shiÃºlaim Ã³ na laethe beo, an ghrian [apostrophe]s an ghealach ar mo chÃºl..."
"in a strange and untranslateable dream-language:"	"SiÃºil liom trÃd an rÃ©alta dearg. Deireadh, deireadh an turas."
"in a strange and untranslateable dream-language:"	"Dan y dwr, tawelwch sydd. Dan y dwr, galwaf i. Nid yw'r swn gyda fi..."
"in plain English this time:"	"Dark skies fall on black earth and ivory; far from your sun, clouds now close over me."
"in plain English this time:"	"Let me sail, let me sail, let me crash upon your shore..."

Instead of listening to the siren, try listening.

After asking the Siren about a topic listed in the Table of Siren, say "[answer entry][paragraph break]".

After telling the Siren about a topic listed in the Table of Siren, say "[answer entry][paragraph break]".

Understand "drew" or "fran" or "rat" or "rats" or "zeke" or "rat king" as "[rats]".

Understand "roach" or "cockroach" or "roaches" or "cockroaches" or "miko" as "[miko]".

Understand "Ryan" or "Veeder" or "Ryan Veeder" or "the author" or "author" as "[ryan veeder]".

Understand "stately" or "manor" or "stately manor" or "mansion" as "[the stately manor]".

Understand "me" or "myself" or "I" or "player" or "the player" as "[the player]".

Understand "girdle" or "her girdle" or "siren's girdle" as "[the siren's girdle]".

Understand "herself" or "siren" or "marin" as "[the siren]".

Table of Siren
Topic	Answer
"life"	"The Siren tells you that life is better down where it's wetter. She means underwater."
"[the goat-fish]"	"[if the siren carries the goat-fish]The Siren thanks you again for your help[otherwise]The Siren tells you she is extremely worried about the well-being of her little goat-fish Tarin, who got lost in a cave[end if]."
"[the jungle]"	"She says that she is a fan of the jungle, but can't hang out there as much as she'd like, because her legs are a fish."
"[the player]"	"She says she likes you just fine, although you could stand to loosen up once in a while."
"[the Siren]"	"She smiles. She says she's doing just fine, thanks for asking."
"you"	"She says that I am a wonderful friend, and that you should go ahead and take your time waking me up from this coma that I'm in, because it's not about the destination [italic type]it's about the journey.[roman type]"
"singing"	"She says she practices literally all the time. She loves singing so much. Her singing is symbolic of beauty in general. That's me, I said that, not her."
"Enya"	"[one of]She says she has never heard of Enya. She looks mad. You better not pursue the subject[or]I really think you oughta let it go[stopping]."
"music"	"She says she loves music the most. She says it hath charms to soothe her savage breast. You blush."
"[rats]"	"[one of]The Siren expounds for a brief period on the vagaries of rat culture, which she finds fascinating, but I don't, so I'm gonna cut her off here[or]Nope! We're done talking about rats[stopping]."
"[miko]"	"The Siren tells you she doesn't care much for roaches, because they're disgusting and horrible."
"stew"	"The Siren says she loves stew, and cooking stew, and having friends over to cook stew together. All of these things are so much fun for her."
"[ryan veeder]"	"The Siren says something on that subject that I'm gonna quote directly so I don't screw it up: 'It is important to distinguish here between Ryan Veeder, the real-world author of this game, and the in-universe narrator of the game, who has not been given a name. One is real, and one is fictional. Although their authorial voices may be similar, they are two different people.'"
"[the stately manor]"	"The Siren says she's never been to the manor, but from down here it looks pretty boring."
"hill"	"The Siren is not big on hills. You can guess why."
"[the big grandfather clock]"	"The Siren knows all about clocks. They're great. And grandfather clocks in particular are great because they have that compartment in the bottom that you can open up."
"[the streaming hair]"	"She's so glad you noticed. [if the Siren carries the venus comb]She says the comb is just what she needed[otherwise]She says she's up here on the reef to sun her streaming hair, but she's been missing a certain accessory, which got lost on the island here somewhere[end if]."
"[the shimmering scales]"	"[one of]At first, the Siren is only too happy to talk about her scales. She begins to describe them in loving detail; then, she trails off. 'They're not really that interesting,' she mumbles[or]She seems to be kind of sensitive about the fish thing. Probably you should pick something else to talk about[stopping]."
"[the boobs]"	"The Siren winks, and flips her hair over her shoulder."
"[the venus comb]"	"[if the Siren carries the venus comb]'Thanks again for finding it,' she says[otherwise]'Yeah, it was a venus comb, and I lost it. I think it ended up on the island somehow. Could you go look for it?' she asks[end if]."
"[the Siren's girdle]"	"[if the Siren wears the Siren's girdle]'Do you like it?' she asks. 'I got it on Etsy for like sixteen bucks.'[otherwise]'I hope you put it to good use,' she says."
"[the white sand]"	"The Siren says she isn't crazy about sand. You can't blame her, really. Sand is annoying sometime."
"[the white ship]"	"The Siren doesn't want to say anything about the shipwreck, but she seems suspiciously proud of herself."
"[the bare coral reef]"	"The Siren slaps her tail on the reef. Then she says 'Ow.'"
"[the restless sea]"	"The Siren looks out to the sea and sighs. 'This island symbolizes a lot of things,' she says. 'A lot of things.' She sighs again."
"[the wreathed horn]"	"When you bring up the wreathÃ¨d horn, the Siren's eyes go wide. 'That horn is an artifact of tremendous psychic potential!' she whispers. 'Either that, or it symbolizes psychic potential.'"
"[the mysterious initials]"	"The Siren doesn't know what the deal is with the initials. That stuff is outside of her range of expertise."
"[the pendulums]"	"The Siren says those pendulums are subject to dream-logical duality, and probably they also function as something other than clock pendulums."
"[the large leather trunk]"	"The Siren wants to give you a hint about that trunk: She says the shape of the holes in the lock is similar to the shape of something in the Stately Manor. How she came by this knowledge is unclear."
"[the rock wall]"	"[if the rock wall is in clearing]The Siren says you definitely want to get behind that rock wall, but that won't happen unless you fully comprehend the sacred mystery of its curious design.[otherwise]'You're welcome,' says the Siren."
"[the curious design]"	"[if the rock wall is in clearing]The Siren takes a moment to compare the curvy H on the wall to the curvy curves of her human half.[otherwise]'You're welcome,' says the Siren."
"[the caves of thought]"	"The Siren says she's never been to the Caves of Thought, but her little goat-fish Tarin has been known to crawl down there once in a while."
"[the arch]"	"The Siren whispers that you should [italic type]steal with soft step your shining archway through,[roman type] which sounds like just the kind of ungrammatical nonsense you'd expect to hear in a dream."
"[the idle door]"	"[if the idle door is in shining archway]The idle door, according to the Siren, is sealed with a type of psychic lock that you have seen before; it requires the use of a related symbol to break the subconscious spell. I realize this is getting really hokey and puzzle-ish instead of being coma-dream-logic-ish, but I'm doing the best I can.[otherwise]The Siren nods smugly."
"[the irised ceiling]"	"CEILING"
"[the sunless crypt]"	"CRYPT"
"[nautilisia]"	"[one of]'You have to understand,' explains the Siren, 'After you solve all the puzzles, the dream will be over. It's in the nature of dreams, to end. And when the sleeper awakens, Nautilisia will be gone... only the memory of this dream land will exist in the waking world.[paragraph break]'But someday, you might recall this island... That memory must be the real Nautilisia.'[paragraph break]She smiles. 'I stole that speech from a video game.'[or]'You [italic type]did[roman type] play Link's Awakening, right? This whole concept is basically a ripoff of that game.'[stopping]"
"capricorn symbol"	"'It's the symbol for Capricorn, right? It looks like a dumb-looking V. That's all there is to say, I guess. Sorry.'"
"[goats]"	"The Siren says she's actually never seen a goat that didn't have a fish-tail for a lower half. She has no idea what kind of alien world exists away from the sea, a world where many things are mammalian at both ends."
"fish"	"The Siren has entirely too much to say about fish. She literally has too much to say."
"[puzzles]"	"'Well, the puzzles here aren't very tough,' says the Siren. 'You've basically got a bunch of locks, and you just have to look around for the keys. It's supposed to be complicated a little bit by the fact that the keys don't initially appear to be keys; that's the dream-logic duality working. So, think about the objects that you are able to find, and think about what kinds of locks they would fit.'"
"love"	"Are you trying to come on to the Siren? I'm not sure whether she's too naÃ¯ve and innocent to really understand [italic type]love[roman type] the way us grown-ups do, or if she's a sexy-dangerous makeout monster. I guess I'm falling into the maiden/whore dichotomy there, huh. Well. Let's think about something else."
"[songs]"	"She says that all the songs she sings are her own compositions. She is a little too insistent about this."
"[zodiac]"	"The Siren gives you some vital information about zodiac-themed puzzle solving. Here you go:[paragraph break]The symbol for Aries looks like a curly V.[line break]The symbol for Taurus looks like a circle with horns.[line break]The symbol for Gemini looks like a Roman numeral 2.[line break]The symbol for Cancer looks like the number 69 sideways.[line break]The symbol for Leo looks like someone was trying to draw a circle but they got distracted.[line break]The symbol for Virgo is one of those symbols that's basically a cursive capital M.[line break]The symbol for Libra is... shoot, what is it? Oh, it's like an equals-sign, but the top line has this circular bump in the middle of it, like a wart basically.[line break]The symbol for Scorpio is the other one that looks like a cursive M. I can't remember the exact difference between this one and Virgo.[line break]The symbol for Sagittarius is basically a diagonal arrow with a line through it.[line break]The symbol for Capricorn is a dumb-looking V with a curly thing hanging off the right side.[line break]The symbol for Aquarius is just two zig-zag lines, one on top of the other.[line break]The symbol for Pisces is like an H, but the sides curve in at the middle in a vaguely hourglassesque manner.[paragraph break]And that's all!"
"[koholint]"	"[one of]'Oh, let me see if I can remember one of those sayings,' says the Siren 'Here's one:[or]'Oh, let's see. Here's another one:[stopping] [one of]The Wind Fish slumbers long, the hero's life gone...[or]The Wind Fish in name only, for it is neither. Whatever that means.[or]Music, the fish stirs in the egg, you are there...[or]Sea bears foam, sleep bears dreams. Both end in the same way: CRASSSHHH![at random]'"
"zuleika"	"Who the heck is Zuleika? That's not the Siren saying that. I'm asking you. Who is Zuleika."
"time"	"'Man, time, huh?. I've always thought of time as, just like, a giant hole, you know? And our lives just, they fall into the hole. But that's just me.'"
"[taking breaks]"	"The Siren takes a mmoment to impress upon you that taking a break once in a while is a very good idea, because otherwise you'll stress yourself all the way out and die."
"[hints]"	"'Well, besides the main puzzles, which involve putting keys into locks, there's not a whole lot of stuff to hint at,' explains the Siren. 'The main other thing is, to get some of the keys, you'll have to deliver stuff from across the island to various NPCS.'[paragraph break]She sighs. 'I know I said [apostrophe]various NPCs,[apostrophe] but I meant me. I'm basically the only NPC on this island.'"

Check asking the siren about "fish":
	if the goat-fish is handled:
		try asking the siren about "[the goat-fish]" instead.

Understand "hint" or "hints" or "a hint" as "[hints]".

Understand "taking breaks" or "taking a break" or "breaks" as "[taking breaks]"

Understand "ceiling" or "irised ceiling" as "[the irised ceiling]".

Understand "door" or "idle door" as "[the idle door]".

Understand "arch" or "shining arch" or "shining archway" or "archway" as "[the arch]".

Understand "crypt" or "sunless crypt" or "dais" or "nacreous dais" as "[the sunless crypt]".

Understand "horoscope" or "zodiac" or "astrology" or "astrological signs" or "symbol" or "astrological symbol" or "symbols" or "astrological symbols" or "constellation" or "constellations" or "stars" as "[zodiac]".

Understand "song" or "songs" as "[songs]".

The white ship is a backdrop. The white ship is in enchanted gulf and pearl. Understand "pearl" or "boat" or "ship of pearl" or "pearl ship" or "shipwreck" or "ship" or "wreck" as "[the white ship]". 

Understand "puzzle" or "puzzles" as "[puzzles]".

Understand "goat" or "goats" as "[goats]".

Understand "Nautilisia" or "dream world" or "Koholint" or "dreamworld" or "dream-world" or "dream" or "island" or "world" as "[nautilisia]".

Understand "koholint" or "link's awakening" or "link" or "zelda" or "owl" or "video game" or "wind fish" as "[koholint]".

Understand "cave" or "caves" or "caves of thought" or "deep caves of thought" or "deep caves" or "deeper caves" or "deeper caves of thought" as "[the caves of thought]".

After asking the Siren about something, say "The Siren doesn't have anything interesting to say about that."

After telling the Siren about something, say "The Siren is not super interested in what you have to say on that subject."

Before giving an item listed in the Table of Show to the Siren:
	say "[speak entry][paragraph break]";
	if the noun is the venus comb:
		if the player encloses the venus comb:
			now the Siren carries the venus comb;
			now the player carries the Siren's girdle;
	if the noun is the goat-fish:
		if the player carries the goat-fish:
			now the Siren carries the goat-fish;
			now the player carries the Capricorn symbol;
			now the goat-fish is energetic;
	stop the action.

Before showing an item listed in the Table of Show to the Siren:
	say "[speak entry][paragraph break]";
	if the noun is the venus comb:
		if the player encloses the venus comb:
			now the Siren carries the venus comb;
			now the player carries the Siren's girdle;
	if the noun is the goat-fish:
		if the player carries the goat-fish:
			now the Siren carries the goat-fish;
			now the player carries the Capricorn symbol;
			now the goat-fish is energetic;
	stop the action.

Table of Show
item	speak
pendulums	"The Siren says those pendulums are subject to dream-logical duality, and probably they also function as something other than clock pendulums." 
goat-fish	"[one of]Her jaw drops. 'Oh my gosh! Oh my gosh. You brought Tarin!'[paragraph break]The goat-fish leaps into the Siren's arms with a triumphant bleat and she immediately begins cooing over it.[paragraph break]'You know, I actually have the perfect reward for you. Check this out:' She produces a piece of pearlescent material from an invisible drawer or something.[paragraph break]'Do you recognize this? It's the symbol for Capricorn. It's thematically appropriate, because Tarin here is a goat-fish, right? Anyway, I want you to have it.' She hands it to you[or]'Isn't he adorable?' She giggles, as the goat-fish tries to eat her hair[stopping]."
girdle	"The Siren nods as if to say: Yeah. I know."
wreathed horn	"When you display the wreathÃ¨d horn, the Siren's eyes go wide. 'That horn is an artifact of tremendous psychic potential!' she whispers. 'Either that, or it symbolizes psychic potential.'"
venus comb	"[one of]'Is this what I think it is? Where on earth did you find this? Well, anyway, thank you.'[paragraph break]She takes the comb from you and immediately starts brushing her hair.[paragraph break]'I suppose it's customary to repay you somehow, right? Well, here.'[paragraph break]She takes off her girdle, which dream-logically turns into... something else, I guess, and hands it to you.[or]'Yeah, it's pretty great, I know.' She continues combing herself.[stopping]"
symbol	"She regards the symbol impassively. 'It's the symbol for Capricorn, right? It looks like a dumb-looking V. That's all there is to say, I guess. Sorry.'"

Check showing the spines to the Siren:
	try showing the venus comb to the siren instead.

Check giving the spines to the Siren:
	try showing the venus comb to the siren instead.

Before kissing the Siren:
	say "[one of]The Siren isn't the type to get all sexy on you unprovoked, but since you decided to initiate things, the Siren goes ahead and [italic type]rocks your world[roman type][or]When you move in for some more action, the Siren does that thing where she pulls her head away at the last moment. So annoying[stopping]." instead.

Before singing:
	if the location is enchanted gulf:
		say "When you start singing, the Siren glares at you and starts singing louder. So you stop singing." instead.

Book 4 - Ship of Pearl

Pearl is a room. "When you are inside the ship, you realize that it symbolizes loneliness. Specifically, loneliness brought on by being an artist, which all artists suffer from deep inside their souls[if unvisited]. This is the ship of pearl, which painters sail into the seas of paint, and which sculptors sail across seas of clay, and of marble, searching for the distant moorages of inspiration. I could keep going, but you don't seem to be as into this as I am so I guess I'll stop[end if].[paragraph break]The interior of the ship is lit by a pale, eerie luminescence."

Pearl is inside of Enchanted Gulf. The printed name of Pearl is "Ship of Pearl".

The pale eerie luminescence is scenery in pearl. Instead of doing anything with the luminescence, say "Since this is a bizarre and mystical dream-world, you are able to pick up and mess around with the luminescence, but since I don't know how that would actually work, I'm gonna have to ask you to stop doing that."

The large leather trunk is a locked closed openable container in pearl. The initial appearance of the trunk is "It looks like whatever painter or poet who piloted this craft last left their leather trunk in here." The description of the large leather trunk is "A large leather trunk, scratched and pitted by the slings and arrows of being lugged all over the place for years and years. It symbolizes mystery. The mysterious initials OWH are inscribed on top.[paragraph break][if locked]It has a big lock thing on it, but no keyhole: Instead, there's just two depressions in the front, in the shape of the astrological symbol for Aquarius. See? Symbolism[otherwise]The Aquarius symbol has been unlocked by those pendulums I tricked you into carrying around[end if]."

Understand "chest" or "scratch" or "scratches" or "pit" or "pits" as the trunk.

Understand "trunk" or "leather trunk" or "large leather trunk" or "chest" as "[the large leather trunk]".

Instead of taking the trunk, say "It's too big for you to lug back across the water. That must be why its owner left it here.[paragraph break]Or maybe the owner is [italic type]dead[roman type] and never got a chance!"

Some depressions are part of the trunk. Understand "symbol" or "keyhole" or "lock" or "lock thing" as the depressions. The description of the depressions is "[if the trunk is locked]It has a big lock thing on it, but no keyhole: Instead, there's just two depressions in the front, in the shape of the astrological symbol for Aquarius. See? Symbolism[otherwise]The Aquarius symbol has been unlocked by those pendulums I tricked you into carrying around[end if]."

The mysterious initials are part of the trunk. Understand "O" or "W" or "H" or "OWH" as the initials. Understand "initials" or "mysterious initials" or "O" or "W" or "H" or "OWH" as "[the mysterious initials]". The description of the initials is "The letters OWH. They presumably stand for something. Maybe somebody's name. Maybe [italic type]more than one person's name[roman type]."

Instead of inserting the pendulums into the trunk:
	try unlocking the trunk with the pendulums.
	
Instead of inserting the pendulums into the depressions:
	try unlocking the trunk with the pendulums.
	
Instead of unlocking the depressions with the pendulums:
	try unlocking the trunk with the pendulums.

The pendulums unlock the large leather trunk.

After unlocking the trunk with the pendulums:
	now the pendulums are part of the trunk;
	now the description of the pendulums is "The pendulums are stuck in the lock pretty good now.";
	say "You insert the pendulums into the depressions, and they click into place. The pendulums were the symbol for Aquarius all along, and the symbol was the key to the trunk! You solved the mystery![paragraph break]The trunk opens, revealing a wreathÃ¨d horn.";
	now the trunk is open.

Check taking the pendulums:
	if the pendulums are part of the trunk:
		say "The pendulums are stuck in the lock, which is where they belong. You have to learn how to let go."

The trunk contains a wreathed horn. Understand "shell" or "conch" as the wreathed horn. Understand "wreathed" or "horn" or "hole" or "wreathed horn" or "conch" as "[the wreathed horn]". The printed name of the wreathed horn is "wreathÃ¨d horn". The description of the wreathed horn is "It's a huge conical, spiral shell of the type you often find on islands, like in[one of] that book, [italic type]Animal Farm.[roman type] Wait, that's not it. That wasn't even on an island. What book am I thinking of?[or] that book I can't remember. Shoot, what was it?[or]... Oh! [italic type]Lord of the Flies.[roman type] I knew I'd remember it eventually.[or] [italic type]Lord of the Flies,[roman type] by Sir William Gerald Golding.[stopping][paragraph break]It looks like somebody has already drilled a hole in it for you to blow into."

After taking the wreathed horn the first time:
	say "You pick up the horn from the trunk; it has a strange weight to it."

Before listening to the wreathed horn:
	say "You put your ear up to the wreathÃ¨d horn, and as if by magic you hear the soft sighing of a person in a coma, waiting to be awoken. Or maybe you're just hearing the noise of your own blood vessels, multiplied in the conical natural echo chamber. Since this is a magical dream world, it could be either one." instead.

Instead of going nowhere in pearl, say "Sorry, I can't let you run all over the boat. My coma-brain can only come up with so many interesting locations. If you want to leave, just go outside."

Instead of going north in pearl, try going outside.

Understand "exit [something]" as getting off.

Before getting off:
	If the location is Pearl:
		try going outside instead.

Book 5 - Junglina

Jungler is a room. "I keep forgetting what this jungle is supposed to symbolize. I think it was [one of]the unknown[or]danger[or]intrigue[or]sexual intrigue[or]the subconscious mind[or]the unconscious mind[or]confusion[or]my deepest fears[or]ignorance[or]secrecy[at random]. The branches, heavy with purple leaves, lean down toward you in a vaguely threatening way. It's a scary experience, but it's also kind of exciting. That's the fun of being in a coma-induced dream world.[paragraph break]A rough path through the vegetation leads from the gulf to the east to a clearing in the northwest." 

The printed name of Jungler is "Jungle". Jungler is west of Enchanted Gulf.

Instead of going nowhere in jungler, say "I already said: You can go northwest to the clearing, or east to the enchanted gulf. If you go deeper into the jungle, you'll... you'll get eaten by [one of]a grue[or]the Wumpus[or]a T-rex[or]monsters from the id[or]deceptively sexy mermaids[at random] or something. And if you get eaten in the dream, [italic type]you get eaten for real[roman type]."

Instead of listening to jungler, say "Above the chirping and creaking of the jungle, you can just barely make out the sound of the waves crashing in that gulf enchanted, where the Siren sings, and coral reefs lay bare, for that cold sea-maid to sun her streaming hair."

Some branches are a backdrop. The branches are in jungler and clearing. Understand "tree" or "vegetation" or "branch" or "trees" as the branches. The description of the branches is "The branches of the trees sway with magnificent slowness in the ocean breeze."

Some purple leaves are part of the branches. Understand "leaf" or "purple leaf" as the leaves. The description of the leaves is "The biggest of the purple leaves coil up on themselves in intricate spirals; they represent the beauty and calm we can all seek in introspective contemplation." Instead of taking the purple leaves, say "[one of]Oh, that would make a good dream logic puzzle! The leaf could start out as a leaf, but then it could turn into...[paragraph break]I can't think of anything. Better just leave it alone[or]Yeah, maybe you should just leave the leaves where they are, if that's okay with you[stopping]."

The long vine is here. Understand "snake" or "risk" or "risks" as the long vine. "A long vine hangs from the trees, swaying like a snake in front of your face." The description of the long vine is "It dances hypnotically before your vision. It's a symbol of risk. You have to take risks, see? Otherwise you can't get anywhere in life."

Instead of pulling the long vine, try taking the noun.

Instead of climbing the long vine, try taking the noun.

Understand "swing from [something]" as pulling.

Instead of taking the long vine:
	say "After giving a little resistance, the vine falls to the ground, dislodging something from the branches in the process.[paragraph break]When the entire length of the vine has fallen, it turns into a giant green snake, which slithers off into the jungle. That snake symbolizes the horrible things that can happen when you take risks.[paragraph break]The thing you dislodged finally hits the ground. It's a shell, a venus comb. That thing could have killed you![paragraph break]You see what happens when you take risks?";
	remove the long vine from play;
	now the venus comb is in jungler.

Book 6 - Clearing

Clearing is a room. The printed name of clearing is "Clearing". "This is an open area in the jungle, symbolizing the [italic type]eye of the storm[roman type]. It isn't the center of the jungle, but it's the center of your experience at this point in time. It's like the guy says: Wherever you go, there you are.[paragraph break]The path leading back into the jungle is southeast of here, but to your north is [if the rock wall is in clearing]a rock wall, carved with a curious design[otherwise]the mouth of an awesome-looking cave[end if]." 

Clearing is northwest of Jungler.

Instead of listening to clearing, say "The air here is very still, except for all those jungle sounds."

Check going north in clearing:
	if the rock wall is in clearing:
		say "You can't go straight through the rock wall. Nonsense." instead.
		
Understand "wall" or "rock wall" as "[the rock wall]".

The rock wall is scenery in clearing. The description of the rock wall is "This rock wall symbolizes writer's block. I mean, artist's block in general. It symbolizes a block.[paragraph break]The curious design I alluded to is a depression in the shape of the astrological symbol for Pisces."

The curious design is part of the rock wall. Understand "carving" or "pisces" or "slot" or "symbol" or "depression" as the curious design. The description of the design is "It's a carving, a depression kind of thing, in the shape of the astrological symbol for Pisces."

Understand "carving" or "pisces" or "slot" or "depression" or "design" or "curious design" as "[the curious design]".

Instead of unlocking the rock wall with the Siren's girdle:
	say "The girdle, which was all along the symbol for Pisces, fits perfectly into the slot on the wall. Both of them dissolve into a silver mist. You overcame the dream logic and defeated the puzzle![paragraph break]This is my favorite one, by the way. Because I'm a Pisces. Anyway, good job.[paragraph break]It turns out that behind the rock is a huge cave.";
	remove the Siren's girdle from play;
	remove the rock wall from play;
	now the fakecave is in the location.
	
Instead of inserting the Siren's girdle into the rock wall:
	say "The girdle, which was all along the symbol for Pisces, fits perfectly into the slot on the wall. Both of them dissolve into a silver mist. You overcame the dream logic and defeated the puzzle![paragraph break]This is my favorite one, by the way. Because I'm a Pisces. Anyway, good job.[paragraph break]It turns out that behind the rock is a huge cave.";
	remove the Siren's girdle from play;
	remove the rock wall from play;
	now the fakecave is in the location.

Instead of inserting the Siren's girdle into the curious design:
	say "The girdle, which was all along the symbol for Pisces, fits perfectly into the slot on the wall. Both of them dissolve into a silver mist. You overcame the dream logic and defeated the puzzle![paragraph break]This is my favorite one, by the way. Because I'm a Pisces. Anyway, good job.[paragraph break]It turns out that behind the rock is a huge cave.";
	remove the Siren's girdle from play;
	remove the rock wall from play;
	now the fakecave is in the location.
	
Instead of unlocking the curious design with the Siren's girdle:
	say "The girdle, which was all along the symbol for Pisces, fits perfectly into the slot on the wall. Both of them dissolve into a silver mist. You overcame the dream logic and defeated the puzzle![paragraph break]This is my favorite one, by the way. Because I'm a Pisces. Anyway, good job.[paragraph break]It turns out that behind the rock is a huge cave.";
	remove the Siren's girdle from play;
	remove the rock wall from play;
	now the fakecave is in the location.

Instead of entering the fakecave, try going north.

Instead of going inside in clearing, try going north. Instead of going down in clearing, try going north.

Instead of going nowhere in clearing, say "You're gonna have to trust me when I say that running around in the jungle won't do you any good. You can go back down the path to the southeast[if the rock wall is in clearing][otherwise], or north into the caves[end if]."

Volume 3 - The Second Half (Inside Caves)

Caves is a region. Caves1, Caves2, Caves3, Caves4, Caves5, Caves6, Shining Archway and Sunless Crypt are in Caves.

Instead of listening to caves, say "You hear a kind of empty echo."

The walls are a backdrop. Understand "wall" as the walls. The walls are in caves. Instead of doing something with the walls, say "The walls recede from your influence."

The stalagmites are a backdrop. The stalagmites are in caves. Understand "stalactites" or "stalactites and stalagmites" or "stalagmites and stalactites" or "stalactite" or "stalagmite" or "formations" as the stalagmites. The description of the stalagmites is "I actually don't remember the difference. Stalagmites might... They might something. Man, this is gonna keep me up all night. Or it would, if I wasn't in a coma." Instead of doing something other than examining with the stalagmites, say "Don't be distracted by the beautiful cave formations!"

Understand "reach the ceiling" or "from the ceiling" or "to the ceiling" as "[clue]".
		
After reading a command:
	if the player's command includes "[clue]":
		say "No, that doesn't sound right.";
		reject the player's command.

Book 1 - Caves of Thought

Caves1 is a room. "[if unvisited]You have finally found your way to the Caves of Thought. [end if]This cave represents thought, and thinking. There are stalactites and stalagmites and that kind of thing, but the area has been kept mostly empty, so as not to distract from your meditations as you approach the center of the island.[paragraph break]The tunnel continues to the northeast, but if you want you can return to the light and air of the clearing to the south." The printed name of caves1 is "Caves of Thought". Caves1 is north of Clearing.

Instead of going up in caves1, try going south. Instead of going outside in caves1, try going south.

Instead of going nowhere in caves1, say "Well, these caves are more like a tunnel than a maze. You can only go south or northeast."

Book 2 - Deep Caves of Thought

Caves2 is a room. "This cave represents deep thought. See, there are always deeper levels of thought. Getting really deep in thought is a necessary step on the path to self-attainment. So, keep going.[paragraph break]The way out is southwest, but the deeper caves are to the east."

The printed name of caves2 is "Deep Caves of Thought". Caves2 is northeast of Caves1.

Instead of going nowhere in caves2, say "Well, these caves are more like a tunnel than a maze. You can only go southwest or east."

Book 3 - Deeper Caves of Thought

Caves3 is a room. "I know, it probably seems like there are too many sections in this cave. I totally understand why you would feel that way. But having a bunch of caves like this is a [italic type]necessity.[roman type] It's called 'pacing.' Just trust me.[paragraph break]Even deeper caves are to the south; the less deep caves are west of here."

The printed name of caves3 is "Deeper Caves of Thought". Caves3 is east of Caves2.

Instead of going nowhere in caves3, say "Well, these caves are more like a tunnel than a maze. You can only go west or south."

Book 4 - Very Deep Caves of Thought

Caves4 is a room. "[if unvisited]Okay, okay, here for once is something more interesting than just more caves.[paragraph break][end if][if caves4 is mapped west of hill]Here's the place in the tunnel where there's an exit to the surface instead of an east wall[otherwise]At this curve in the tunnel, the east wall is made up of a bunch of rocks. I mean, the whole place is made out of rocks, but these rocks are smaller and... rubblier[end if].[paragraph break]The cave continues to the north and southwest[if shining archway is visited], and there's that tiny shortcut to the shining archway to the west[end if]."

The printed name of caves4 is "Very Deep Caves of Thought". Caves4 is south of Caves3.

The wall of rocks is scenery in caves4. Understand "rock" or "east wall" or "east" or "part of it" or "part" or "part of wall" as the wall of rocks. The description of the wall of rocks is "It looks like this wall of rocks is in a state of very low entropy. It looks like something drastic could very easily happen to this wall, if somebody were to yank on part of it. This wall of rocks represents [italic type]potential[roman type]."

Understand "yank on [something]" or "yank [something]" as pulling.

Instead of pushing the wall of rocks:
	say "Apparently pushing on [the wall of rocks] doesn't do anything."

Instead of pulling the wall of rocks the first time:
	say "You pull out one of the rocks from the wall. The rest of the rocks immediately fall down in a big pile.[paragraph break]But then: a rush of air! A shaft of light! You've uncovered a path to the surface. Nice job![paragraph break]Let's say this symbolizes an act of mutual recognition between your conscious and unconscious minds. I mean, my conscious and unconscious minds. Either way, good going.";
	now caves4 is mapped west of hill;
	now hill is mapped east of caves4;
	now the printed name of the wall of rocks is "pile of rocks";
	now the description of the wall of rocks is "This pile of rocks represents [italic type]spent potential[roman type]."
	
Instead of pulling the wall of rocks:
	say "There's not much more you can accomplish by pulling anything here."

Check taking the wall of rocks:
	if caves4 is mapped west of hill:
		say "You don't need a rock. Any given rock, considered on its own, doesn't symbolize anything in particular." instead;
	otherwise:
		try pulling the wall of rocks instead.

Instead of going outside in caves4, try going east. Instead of going up in caves4, try going east. 

Instead of going nowhere in caves4, say "Well, these caves are more like a tunnel than a maze. You can only go north or southwest[if caves4 is mapped west of hill], or east (to the surface)[end if][if shining archway is visited], or west (to that shining archway)[end if]."

Book 5 - Incredibly Deep Caves of Thought

Caves5 is a room. "Sorry, this is another room where there isn't really anything going on. I swear I'm not doing this just to frustrate you[if unvisited].[paragraph break]I know sometimes it seems like I'm doing stuff just to be annoying, but I always have a good reason. I mean, I always [italic type]think[roman type] I have a good reason. Sometimes it turns out later that I didn't actually have a good reason, but I never start out with the intention of doing nothing but screwing with you[end if].[paragraph break]The caves go northeast and northwest from here."

The printed name of caves5 is "Incredibly Deep Caves of Thought". Caves5 is southwest of Caves4.

Instead of going nowhere in caves5, say "These caves are more like a big long tunnel than a maze. You can only go northwest or northeast from here."

Book 6 - Uttermost Depths of Caves of Thought

Caves6 is a room. The description of caves6 is "This is it. You have reached the deepest part of the caves.[if unvisited] From here on out, you've still got underground rooms, but it's more like an ancient underground shrine than a plain old cave.[end if][paragraph break]From here you can go back southeast, or you can go northeast, in which direction you can discern an unearthly glow[if the goat-fish is not handled].[paragraph break]But first, gaze into that pool of still water, and see the face of your destiny[end if]."

The pool of still water is scenery in caves6. The printed name of the pool of still water is "pool". The pool of still water contains a goat-fish. Instead of taking the pool of still water, say "You try to pick up some of the water, but it falls through your fingers like sand. Maybe this represents futility, or maybe this is just how you should expect water to operate. We can make it symbolic, if you want."

Understand "gaze into [something]" as examining.

After inserting something into the pool of still water, say "You deposit [the noun] into the pool. [The noun] gets wet."

Instead of drinking the pool of still water, say "You cup your hands and lift some of the water to your lips. It is very cold."

The unearthly glow is scenery in caves6. Instead of taking the unearthly glow, say "[one of]You pick up the glow, but its unearthliness quickly becomes a nuisance. Your love affair with the glow has ended. You drop the glow[or]Don't put yourself through all that all over again[stopping]." The description of the unearthly glow is "It glimmers, or glistens, or maybe even [italic type]glisters[roman type]--no, I'd better stick with glistens--with a radiance you find very slightly unnerving."

The printed name of caves6 is "Uttermost Depths of Caves of Thought". Caves6 is northwest of Caves5.

Instead of going nowhere in caves6, say "These caves are more like a big long tunnel than a maze. You can only go northeast or southeast from here."

Part 1 - The Goat-fish

Understand "baby" or "baby goat-fish" or "Tarin" or "goat" or "fish" or "goat fish" or "goatfish" or "capricorn" or "kid-fish" or "kid" as the goat-fish.

Understand "baby" or "baby goat-fish" or "Tarin" or "goat fish" or "goatfish" or "capricorn" or "goat-fish" as "[the goat-fish]".

The description of the goat-fish is "It's a baby goat-fish. Maybe more of a kid-fish. It only has little nubby horns, and the fish end of it wriggles around energetically. This baby goat-fish represents youthful idealism, or youthful ignorance. I guess those are kind of the same thing."

After taking the goat-fish the first time, say "It takes a couple tries, but eventually you scoop the baby goat-fish up out of the pool. It emits a few high-pitched bleats and then it calms down in your comforting grasp."

Instead of eating the goat-fish, say "What is wrong with you? You can't [italic type]eat[roman type] it! What kind of sick freak would [italic type]eat[roman type] an adorable baby goat-fish?"

Instead of dropping the goat-fish, say "No, no! You can't leave it here alone! It can't fend for itself!"

Instead of inserting the goat-fish into something:
	if the second noun is the pool of still water:
		say "No! Don't just leave him here!";
	otherwise:
		say "That's no place for a baby goat-fish."

The goat-fish is either energetic or tired. The goat-fish is energetic.

Every turn:
	if the player carries the goat-fish:
		if the goat-fish is energetic:
			if the number of filled rows in the table of goatfish things is 0:
				say "All of a sudden, the baby goat-fish yawns and falls asleep.";
				now the goat-fish is tired;
				rule succeeds;
			otherwise:
				say "[cute][paragraph break]";
				rule succeeds;
		otherwise:
			if a random chance of 1 in 8 succeeds:
				say "[one of]The baby goat-fish snores a little bleating snore[or]The baby goat-fish wriggles a little; it must be dreaming about eating tin cans[or]The goat-fish burps in its sleep[or]The kid-fish seems to wake up for a second, but apparently it's just sleep-wriggling[at random].";
				rule succeeds.
				
To say cute:
	choose a random row in the table of goatfish things;
	say "[goof entry]";
	blank out the whole row.
	
Table of goatfish things
goof
"The baby goat-fish wriggles its way up your arm."
"The goat-fish bleats a little bleating song."
"The kid-fish crawls up to your shoulder and tries to headbutt you in the neck."
"The baby goat-fish almost falls to the ground, but you catch it."
"The goat-fish nibbles on your finger."

Before kissing the goat-fish, say "You peck the goat-fish on its adorable little forehead, and it purrs." instead.

Book 7 - Shining Archway

Shining Archway is a room. "This room is awash in light: In the south wall, an archway towers over you, glowing as if reflecting the brightness of a distant galaxy.[paragraph break][if the arch is in shining archway][otherwise]The way south is open. [end if]The room with the pool is back to the southwest, and it looks like there's a shortcut to the east. I put that shortcut there just for you."

The arch is scenery in shining archway. Understand "shining arch" or "archway" or "shining archway" or "shining" or "arch way" or "shining arch way" as the arch. The printed name of the arch is "shining arch". The description of the arch is "This archway is a symbol of the [if unvisited]ultimate, I mean the [end if]penultimate barrier between my comatose mind and the outside world. It literally is that, but it's also symbolically that. [italic type]The lines are beginning to blur.[roman type][paragraph break][if the idle door is in shining archway]The path through the arch is blocked by a big door[otherwise]The way south is open[end if]."

The idle door is scenery in shining archway. Understand "big door" as the idle door. The description of the idle door is "This idle door is actually the barrier you have to worry about. I guess if the arch is the symbolic barrier, then this door is the literal barrier. By 'literal' here I mean 'literal-within-the-dream-world.'[paragraph break]In the door is another keyhole-depression, this one in the shape of, like, a V with a ridiculous curly thing attached to it."

The keyhole-depression is part of the idle door. Understand "keyhole" or "capricorn" or "depression" or "keyhole depression" as the keyhole-depression. The description of the keyhole-depression is "It's basically like the Pisces one you saw earlier, but the shape is way dumber. It's a V with a curlicue on the side. It's a V with a ponytail."

Shining Archway is northeast of Caves6. Shining Archway is west of caves4.

Check going south in Shining Archway:
	if the idle door is in Shining Archway:
		say "You can't get through the door without solving its pseudo-Jungian dream-puzzle." instead.
		
Instead of opening the idle door, say "There's no handle in the door, just that goofy-looking depression."

Instead of going nowhere in Shining Archway, say "The only ways out are southwest, into the caves, east, to a different part of the caves, and south, through the archway to your ultimate destiny."

Instead of unlocking the idle door with the Capricorn symbol:
	remove the capricorn symbol from play;
	remove the idle door from play;
	say "The Capricorn symbol slides into place with a click. The door dematerializes, its constituent dream-atoms disappearing into the dream-aether.[paragraph break]Nice job! The path to the final challenge is now open."

Instead of inserting the Capricorn symbol into the idle door:
	remove the capricorn symbol from play;
	remove the idle door from play;
	say "The Capricorn symbol slides into place with a click. The door dematerializes, its constituent dream-atoms disappearing into the dream-aether.[paragraph break]Nice job! The path to the final challenge is now open."
	
Instead of unlocking the keyhole-depression with the Capricorn symbol:
	remove the capricorn symbol from play;
	remove the idle door from play;
	say "The Capricorn symbol slides into place with a click. The door dematerializes, its constituent dream-atoms disappearing into the dream-aether.[paragraph break]Nice job! The path to the final challenge is now open."

Instead of inserting the Capricorn symbol into the keyhole-depression:
	remove the capricorn symbol from play;
	remove the idle door from play;
	say "The Capricorn symbol slides into place with a click. The door dematerializes, its constituent dream-atoms disappearing into the dream-aether.[paragraph break]Nice job! The path to the final challenge is now open."
	
Instead of inserting the goat-fish into the keyhole-depression:
	say "See, that would make sense, but the goat-fish is a literal (dream-)goat-fish, not a Capricorn [italic type]symbol.[roman type] You've got a classic confusion between signifier and signified on your hands."
	
Instead of unlocking the keyhole-depression with the goat-fish:
	say "See, that would make sense, but the goat-fish is a literal (dream-)goat-fish, not a Capricorn [italic type]symbol.[roman type] You've got a classic confusion between signifier and signified on your hands."
	
Instead of unlocking the idle door with the goat-fish:
	say "See, that would make sense, but the goat-fish is a literal (dream-)goat-fish, not a Capricorn [italic type]symbol.[roman type] You've got a classic confusion between signifier and signified on your hands."
	
Instead of inserting the goat-fish into the keyhole-depression:
	say "See, that would make sense, but the goat-fish is a literal (dream-)goat-fish, not a Capricorn [italic type]symbol.[roman type] You've got a classic confusion between signifier and signified on your hands."

Book 8 - Sunless Crypt

Sunless Crypt is a room. "You have reached the end of your quest. Here, at the center of Nautilisia, is the sunless crypt that symbolizes the spiritual and psychological profundity of the coma that I've been in all this time.[paragraph break]The ceiling above roils with irisdescent turmoil, symbolizing the conflux of emotions that are going on in my brain. A spiral design on the floor leads your gaze toward the center of the room, which is the center of the center of Nautilisia:"

The comatose body is a neuter person in Sunless Crypt. Understand "you" as the body. "Lying prostrate on a dais of nacreous stone and wrapped in webs of gauze is my own comatose body." The indefinite article of the comatose body is "my". The description of the body is "That's definitely me. You'd know my face anywhere. And I'm definitely, definitely in a coma. This symbolizes the fact that I'm in a coma right now.[paragraph break]So, this is the final puzzle! How can you possibly wake me up, and release my mind from this nice nap? I mean, this coma?" Instead of taking the comatose body, say "You can't just schlep me around. That would ruin the whole tableau." Instead of pushing the comatose body, say "Ow! Cut that out!" Instead of attacking the comatose body, say "Ow! Ow! Stop! STOP. Seriously, stop."

The comatose body wears some webs of gauze. Understand "web" as the webs of gauze. The description of the gauze is "The gauze is... how do I put this? It's diaphanous, but it's not [italic type]too[roman type] diaphanous." Instead of taking the webs of gauze, say "No no no no! I'm not wearing anything under those webs." 

Sunless Crypt is south of Shining Archway. 

The spiral design on the floor is scenery in sunless crypt. The description of the spiral design on the floor is "You're gonna have to take my word for it, but the spiral on the floor is a logarithmic spiral with a growth factor of about 1.6180339887. This symbolizes [italic type]the mathematical perfection of pure thought[roman type]."

The irised ceiling is scenery in sunless crypt. Understand "iridescent" or "turmoil" or "iridescent turmoil" as the irised ceiling. The description of the irised ceiling is "The irised ceiling of the crypt casts all kinds of weird colored lights across the room, symbolizing the blurring of self, shadow, anima, and animus. It also symbolizes emotional turmoil. It symbolizes both things at the same time. That's part of the blurring."

The dais of nacreous stone is scenery in sunless crypt. Understand "pearl" or "mother-of-pearl" as the dais. The description of the dais of nacreous stone is "The word 'nacreous' looks like it means 'gross,' but it actually refers to the texture of nacre, i.e. mother-of-pearl. So you can imagine this dais as like a great big pearl growing out of the floor.[paragraph break]I guess when I put it that way it sounds kind of gross anyway."

After reading a command:
	if the player's command includes "my comatose body":
		say "No, [italic type]my[roman type] comatose body. You're not the one who's comatose.";
		reject the player's command.

Understand "waken [something]" and "awaken [something]" and "rouse [something]" and "stir [something]" and "shake [something]" as waking.

Before waking up:
	try waking the player instead.

Before waking:
	if the noun is the player:
		say "No, see, I'm the one who's in a coma. You're just fine. You don't need to wake up." instead;
	otherwise if the noun is the comatose body:
		say "Oh, no you don't. It's not gonna be that easy." instead;
	otherwise if the noun is the siren:
		say "The Siren is already awake. She's looking straight at you." instead;
	otherwise if the noun is the goat-fish:
		if the goat-fish is energetic:
			say "The goat-fish is clearly awake. It's got all kinds of energy." instead;
		otherwise:
			say "Aw, but it's so cute when it's sleeping! Just let it rest." instead;
	otherwise:
		say "[The noun] is not something that you can wake up. It's not asleep." instead;
	stop the action.
	
Understand the command "kiss [something]" as something new. Understand "kiss [something]" as kissing.

Before kissing the comatose body:
	say "Oh! Oh, that's adorable! That wasn't the solution I had in mind, but maybe it should work. Do you think that should be what wakes me up?[paragraph break]";
	if the player consents:
		say "All right, then. When you kiss me, it'll break the psychic spell, and Nautilisia will disappear, but I'll finally wake up from this coma and we can get going to whatever it is you think is so important.";
		end the story finally saying "So, go ahead.";
	otherwise:
		say "Okay, that's fine. Let's say you kiss me, but nothing happens. Go ahead and try to figure out the 'real' solution." instead.
		
After kissing something: Say "That's not something you need to kiss. Go ahead and don't kiss it."

Instead of asking the comatose body about something, say "There is no response. The body is in a coma."

Instead of telling the body about something, say "There's no response. The body is in a coma."



Blowing is an action applying to one thing. Understand "blow [something]" and "blow into [something]" and "blow in [something]" and "blow on [something]" and "play [something]" as blowing.

A shell is a kind of thing. The wreathed horn is a shell. The venus comb is a shell.

Check blowing:
	if the noun is a shell:
		continue the action;
	otherwise:
		say "That's not something you can blow into. Or, at any rate, you don't need to blow into it. Let's do something else." instead.

Virple is a number that varies. Virple is 1.

After blowing the wreathed horn:
	if the location is sunless crypt:
		If virple is 1:
			say "When you put your lips to the wreathÃ¨d horn, it emits a huge, deep moan like a mob of whales singing in unison. The ceiling rumbles. The sleeper stirs.[paragraph break]I'm trying to decide how many times you should have to blow the horn to make me wake up. How about nine?";
			now virple is 2;
			rule succeeds;
		otherwise if virple is 2:
			say "The conch blasts again, like waves crashing on a glass beach. The vibrations shake the irised ceiling.[paragraph break]Yeah, nine is probably too many. How about seven?[paragraph break]Fine. Because I like you: three times. Just one more time.";
			now virple is 3;
			rule succeeds;
		otherwise if virple is 3:
			say "You blow into the wreathÃ¨d horn again, with a tone like a hurricane inside a crystal bell.[paragraph break]Then the ceiling cracks, and shatters, and the light of the sun, symbolizing [italic type]the clarity of conscious thought,[roman type] shines into the previously sunless crypt, which symbolizes [italic type]the stagnancy of absolute introspection,[roman type] right onto my unconscious body, which symbolizes me.";
			wait for any key;
			say "[paragraph break]And then everything goes white.";
			wait for any key;
			now the left hand status line is "";
			clear the screen;
			wait for any key;
			say "And now I'm awake. Look, see? I'm awake. We can get going now.";
			wait for any key;
			say "[paragraph break]Anyway, thanks for putting up with all that nonsense. I know I probably goof off too much, and it gets to be a pain some of the time. I really do want both of us to have fun, even if some of the time the only one having any fun is me. So I really appreciate your tolerance. I guess 'tolerance' isn't the right word. You know what I mean.";
		end the story finally saying "No, seriously. Thank you.";
	otherwise:
		say "You start to blow into the horn, but the tremendous sound that emerges is too much for you to handle. It symbolizes the conclusion of the individuation process, which, if attained prematurely, would result in a psychological short-circuit. What I'm saying is, this is not the time or place for unleashing the power of the horn."
		
understand "nah" as saying no. Understand "yeah" as saying yes.

before saying yes:
	if virple is 2:
		say "[one of]Wait, seriously? You don't think that's kind of a lot?[or]We can't spend the rest of our lives discussing this![stopping][paragraph break]" instead;
	otherwise:
		say "Yeah! Yeah, exactly." instead.
		
before saying no:
	if virple is 2:
		say "[one of]Okay, if you say so. Less than nine.[or]We can't spend the rest of our lives discussing this![stopping][paragraph break]" instead;
	otherwise:
		say "No?" instead.

After blowing the venus comb:
	say "Are you sure you want to blow into the venus comb?[paragraph break]";
	if the player consents:
		say "[paragraph break]Well, okay: You put your mouth on the short end of the comb, and one of the spines pokes you in the lip. Nice going.";
	otherwise:
		say "[paragraph break]Good call."


Volume 8 - Barracks

Barracks is a room.

The fakecave is in barracks. The fakecave is scenery. Understand "caves" or "cavern" or "caverns" or "cave" as the fakecave. The description of the fakecave is "It's a pretty rad-looking cave. You should go in there and check it out." 

The Capricorn symbol is in Barracks. The description of the Capricorn symbol is "Here's the thing. This isn't literally [italic type]the symbol for Capricorn.[roman type] It's a pearly-white object [italic type]in the shape of[roman type] the symbol for Capricorn. That's what they call the type-token distinction. Anyway, all this means is, the thing looks like a V with a curly thing hanging off the side, or maybe a lowercase n with a kink in its right leg. I don't know what it's supposed to be."


The venus comb is in barracks. The initial appearance of the venus comb is "A venus comb is lying on the ground here."

Understand "accessory" or "brush" or "hairbrush" or "hair brush" or "murex pecten" or "venus comb murex" or "seashell" or "sea shell" or "shell" as the venus comb.

Understand "comb" or "venus comb" or "accessory" or "brush" or "hairbrush" or "hair brush" or "murex pecten" or "venus comb murex" or "seashell" or "sea shell" or "shell" as "[the venus comb]"

The description of the venus comb is "It's a seashell, spiral in shape and conical in form, but it's covered in dozens of long, skinny spines, like a hairbrush designed by H.R. Giger[if handled]. Holding it is an exercise in manual delicacy[end if]. It symbolizes beauty as a desirable but fundamentally dangerous aspect of experience."

The long skinny spines are part of the venus comb. Understand "spine" or "spike" or "spikes" as the long skinny spines. The description of the spines is "They stick out like gorgeous, deadly knitting needles."

The venus comb is wearable. After wearing the venus comb, say "You couldn't be blamed for expecting the comb to poke at you painfully, since you're sticking those sharp spines up against your scalp, but it actually feels just fine and makes you look very fetching."

Before listening to the venus comb, say "You put the comb up to your ear, but one of the spines almost stabs you in the face. So you decide not to listen to it."

After reading a command:
	if the player's command includes "[the secret]":
		say "Shhhh! I mean, good job figuring out the 'secret of the game,' but don't ruin it by saying it out loud!";
		reject the player's command.
		
Understand "Oliver Wendell Holmes" or "Chambered Nautilus" as "[the secret]".

Rule for amusing a victorious player:
	say "Have you tried...[paragraph break]...listening to a shell?[line break]...listening to the Siren's songs?[line break]...anything you wouldn't be able to get away with in the real world?[line break]...manipulating something intangible?[line break]...thinking? Jumping? All that nonsense?[line break]...drawing a map?[line break]...swimming? Swimming in different bodies of water?[line break]...feeling a bunch of different things?[line break]...tasting a bunch of different things?[line break]...sitting on a reef?[line break]...looking for an [italic type]alternate win condition?[roman type][paragraph break]"
	
After reading a command:
	if the player's command includes "the":
		cut the matched text.

A thing has some text called feel. Instead of touching something, say "[the feel of the noun][paragraph break]".

Instead of entering the dais of nacreous stone, say "Hey, get off! There's only room for one on this dais."

The feel of the pool of still water is "The water is cold. Cold like a broken promise."
The feel of the comatose body is "I feel like a sleeping person, I think. I guess?"
The feel of the goat-fish is "Alternately scaly and furry. That symbolizes duality."
The feel of the webs of gauze is "The webs flow between your fingers like a dream. Yes, I'm going with 'like a dream.' It's almost the end; I'm running out of flowery descriptions."
The feel of the spines is "You poke yourself and say [italic type]ouch![roman type] That's what happens when you mess with the fundamental danger of beauty." 
The feel of the venus comb is "You poke yourself and say [italic type]ouch![roman type] That's what happens when you mess with the fundamental danger of beauty."
The feel of the boobs is "Okay fine, you touched a boob. Congratulations." 
The feel of the wall of rocks is "The rocks feel like a lightweight foam. They're not real rocks!"
The feel of the arch is "It even [italic type]feels[roman type] like a distant galaxy."
The feel of the idle door is "The door is smooth and oppressive to the touch."
The feel of the keyhole-depression is "The depression's curves and divots play coquettishly beneath your fingers."
The feel of the spiral design on the floor is "Your fingers follow the subtle ridges of the spiral design for a few feet until I get bored. Um, I mean, until [italic type]you[roman type] get bored."
The feel of the irised ceiling is "Since this is a dream, you can tell that the ceiling feels like a very thick soap bubble."
The feel of the dais of nacreous stone is "Nacre is naturally smooth, and yet this dais is unnaturally smooth."
The feel of the clock is "It thrums and pulses beneath your fingers with each tick."
The feel of the shape is "As you reach up to feel it, the shape tries to suck your hand into its vortex (symbolism), so you pull your hand away."
The feel of the pendulums is "The pendulums have a mechanical smoothless and angularity."
The feel of the restless sea is "The water rushes up around your fingers with the enthusiasm of an annoying friend who hasn't talked to you in forever. You know who I'm talking about. That clingy guy."
The feel of the reef is "Your fingers touch the reef and it scratches you! It scratches you a good one."
The feel of the hair is "The Siren is totally cool with your feeling her hair, which falls away like bashful silk through your fingers. She must use one heck of a conditioner."
The feel of the scales is "The Siren allows you to feel her scales, which are basically like a fish's scales. They are gross."
The feel of the song is "As your hands pass over the textures of the Siren's song, you detect that [italic type]actually all the songs she's singing are just Enya songs.[roman type] Not that there's anything wrong with that."
The feel of the vine is "The vine undulates in your hand like a snake. It's a very serpentine vine. Very ophidian."
The feel of the rock wall is "The rock wall is very solid. Especially for a rock wall that technically is just a dream."
The feel of the curious design is "The curves of the design yield to your advances with 'sweet reluctant amorous delay.' ([italic type]PL[roman type], 4:311)".
The feel of the trunk is "The trunk feels heavy, like a brick. Like a lot of bricks at once."
The feel of the depressions is "The depressions feel sharp and angular. They are designed to receive something similarly sharp and angular."
The feel of the wreathed horn is "The horn has a roughness which you find reassuringly natural. Its bumps and ridges fit your hand perfectly."
The feel of the jungle is "The jungle feels [italic type]dangerous.[roman type]".
The feel of the white sand is "The sand is so soft. And so cool."
The feel of the white ship is "The ship rumbles under your fingers, like a tiny animal's heart beating. Creepy."
The feel of yourself is "You feel more or less normal. More or less."
The feel of the girdle is "[if the siren wears the girdle]The girdle is [italic type]taut,[roman type] is what it is.[otherwise]The girdle has the texture of mother-of-pearl, like half the other objects on this island.[end if]".
The feel of the symbol is "The symbol glides like a serpent over your palm."
The feel of the fakecave is "From out here it doesn't feel like much."

Understand "take a break" and "take break" and "rest" and "relax" and "take a break for once" and "take a break for once in my life" and "have a break" and "unwind" and "calm down" and "loosen up" as unwinding.

Unwinding is an action applying to nothing.

Instead of unwinding the first time:
	say "All right. Let me tell you how it's done.[paragraph break]";
	wait for any key;
	say "Sit down[if the location is enchanted gulf] on the sand[end if] and close your eyes. [if the location is enchanted gulf]Listen to the nice lady singing[otherwise]Listen to your own breathing[end if]. [if the location is in caves]Listen to the caves[otherwise]Listen to the wind[end if].[paragraph break]";
	wait for any key;
	say "See? Nothing is urgent. Everything will happen when it needs to happen.[paragraph break]";
	wait for any key;
	say "Maybe the moon is shining through some palm leaves. Maybe an old man is tuning his violin. Maybe it starts to rain a little, but then it stops.[paragraph break]";
	wait for any key;
	say "Okay, open your eyes. There. Wasn't that nice?";
	
Instead of unwinding:
	say "That's a good idea, but I don't have a whole lot of that relaxation exercise material prepared. So just imagine that you're going somewhere that's happy and peaceful and relaxing. Like Nautilisia, for example. Oh hey look you're already here."

Combing is an action applying to one thing.

Understand "comb [something]" and "brush [something]" as combing.

Check combing:
	if the venus comb is enclosed by the player:
		if the noun is the streaming hair:
			say "As you approach her hair with the dangerous shell, the Siren's eyes go wide.[paragraph break]";
			try giving the venus comb to the siren instead;
		otherwise if the noun is the playerhair:
			say "The venus comb pokes your hand something fierce, but it straightens your hair out nicely. When I say 'your hand' and 'your hair' I mean 'your dream-hand' and 'your dream-hair,' obviously." instead;
		otherwise:
			say "You comb [the noun] as best as you can but it is an empty exercise." instead;
	otherwise:
		say "You don't have a combing-instrument with you, do you?"
		
Combingwith is an action applying to two things.

Understand "comb [something] with [something]" and "use [something] on [something]" and "brush [something] with [something]" as combingwith.

Check combingwith:
	if the second noun is not enclosed by the player:
		silently try taking the second noun;
	if the second noun is not enclosed by the player:
		say "You are unable to get a grip on [the second noun]." instead;
	otherwise:
		if the second noun is the venus comb:
			if the noun is the streaming hair:
				say "As you approach her hair with the dangerous shell, the Siren's eyes go wide.[paragraph break]";
				try giving the venus comb to the siren instead;
			otherwise if the noun is the playerhair:
				say "The venus comb pokes your hand something fierce, but it straightens your hair out nicely. When I say 'your hand' and 'your hair' I mean 'your dream-hand' and 'your dream-hair,' obviously." instead;
			otherwise:
				say "You comb [the noun] as best as you can but it is an empty exercise.";
		otherwise if the second noun is the fingers:
			say "You run your dream-fingers through [the noun]. [the feel of the noun][paragraph break]" instead;
		otherwise:
			say "[The second noun] is not toothy enough to comb stuff with. I know this is a dream but if we don't set some boundaries then nothing means anything." instead.
		
The fingers is part of the player. Understand "finger" or "Fingers" or "my fingers" or "hand" or "hands" as the fingers. The printed name of the fingers is "your fingers". The fingers is proper-named. The description of the fingers is "It's generally a good idea in a dream to avoid looking at your hands too closely." The feel of the fingers is "You feel like you feeling you."

The playerhair is part of the player. Understand "hair" or "my hair" as the playerhair. The printed name of the playerhair is "your hair". The playerhair is proper-named. The description of the playerhair is "Your hair looks the same. Same as it ever was." The feel of the playerhair is "Your hair feels the same. It has survived the trip to the dream-world unscathed."
	
Digging is an action applying to nothing. Understand "dig" and "dig a hole" as digging.

Digging in is an action applying to one topic. Understand "dig in [text]" as digging in.

Instead of digging in:
	try digging instead.
	
Instead of digging:
	if the location is in caves:
		say "The floor is too hard and solid and rigid and firm for you to dig in." instead;
	otherwise if the location is enchanted gulf:
		say "The Siren sees you digging and freaks out. 'Great!' she yells. 'Dig it! Dig it! Dig to the center of the earth!!'" instead;
	otherwise if the location is pearl:
		say "The substance of the floor prevents your digging with a singular persistence." instead;
	otherwise if the location is stately manor:
		say "You dig a hole in the floor, but it doesn't lead anywhere. You always come back where you started." instead;
	otherwise:
		say "You dig a little in the dirt. You don't uncover anything." instead.
		
Check pushing:
	if the noun is the keyhole-depression:
		say "Just pushing the depression doesn't do anything. Your hand is not the right shape for this depression." instead;
	otherwise if the noun is the depressions:
		say "Just pushing on the depressions doesn't do anything. Your hand is not the right shape for these zig-zaggy depressions." instead;
	otherwise if the noun is the curious design:
		say "Just pushing on the design doesn't do anything. Your hand is not the right shape for this curvy design." instead;
	otherwise if the noun is the siren:
		say "You push the Siren, so she pushes you back, so you fall on the sand. So you get up and brush off the sand." instead;
	otherwise:
		say "Pushing [the noun] is not very effective." instead.
		
Understand the command "hug" as something new. Understand "hug [something]" and "give [something] a hug" and "embrace [something]" and "cuddle [something]" and "pet [something]" and "pat [something]" and "nuzzle [something]" as hugging. Hugging is an action applying to one thing.

Check hugging:
	if the noun is the Siren:
		say "You hug the Siren and the Siren hugs you back. She is surprisingly warm." instead;
	otherwise if the noun is the goat-fish:
		say "The goat-fish bleats contentedly as you nuzzle its goaty little face." instead;
	otherwise if the noun is the comatose body:
		say "Oh how sweet of you." instead;
	otherwise:
		say "[The noun] does not respond to your embrace. Sorry." instead.

Instead of eating something, try tasting the noun.

A thing has some text called flavor.

Instead of tasting something, say "[one of]Man, how does eating stuff even work in dreams? Can you taste in a dream?[paragraph break]This reminds me of that joke about the guy who dreamed he was eating a big marshmallow and when he woke up his pillow was gone. But I don't think there's any actual food items in this dream.[paragraph break]Actually, that gives me an idea. Here: You taste [the noun], and in accordance with the deranged dream-logic of tastes, [the noun][or]According to the dream-logic of tastes, [the noun][stopping] taste[s] like [the flavor of the noun]."

The zig-zaggy pendulums are plural-named. the webs of gauze are plural-named. The stalagmites are plural-named. The shimmering scales are plural-named. The purple leaves are plural-named. The mysterious initials are plural-named. The boobs are plural-named. The branches are plural-named. The expensive things are plural-named. The long skinny spines are plural-named. The depressions are plural-named. The fingers are plural-named. 

The flavor of the pendulums is "bananas".
The flavor of the player is "vanilla ice cream".
The flavor of the wreathed horn is "Bavarian cream".
The flavor of the white ship is "white chocolate (obviously)".
The flavor of the webs of gauze is "cotton candy".
The flavor of the walls is "glue".
The flavor of the wall of rocks is "glue".
The flavor of the venus comb is "a durian".
The flavor of the unearthly glow is "cardboard".
The flavor of the stalagmites is "styrofoam".
The flavor of the spiral design on the floor is "salt water".
The flavor of the spinning spiraling shape is "milk chocolate".
The flavor of the Siren's song is "cinnamon".
The flavor of the Siren's girdle is "rosemary".
The flavor of the Siren is "strawberries".
The flavor of the shimmering scales is "salmon".
The flavor of the rock wall is "glue".
The flavor of the restless sea is "7-Up".
The flavor of the purple leaves is "gasoline".
The flavor of the pool of still water is "chlorine".
The flavor of the playerhair is "licorice".
The flavor of the pale eerie luminescence is "milk".
The flavor of the mysterious initials is "metal".
The flavor of the magical glamour is "popcorn".
The flavor of the arch is "a hard-shelled taco".
The flavor of the big grandfather clock is "a churro".
The flavor of the boobs is "whipped cream".
The flavor of the branches is "tree bark".
The flavor of the capricorn symbol is "a goat-fish".
The flavor of the cliffs is "powdered sugar".
The flavor of the comatose body is "a comatose person. What is wrong with you".
The flavor of the curious design is "blue raspberry".
The flavor of the dais of nacreous stone is "asay Kleenex".
The flavor of the depressions is "Nutella".
The flavor of the expensive things is "crÃ¨me brÃ»lÃ©e".
The flavor of the fingers is "okra".
The flavor of the goat-fish is "pickles".
The flavor of the idle door is "parsley".
The flavor of the irised ceiling is "the candy coating of an M&M".
The flavor of the jungle is "a hamburger".
The flavor of the keyhole-depression is "turkey".
The flavor of the large leather trunk is "a chocolate bunny".
The flavor of the long skinny spines is "hot pizza".
The flavor of the long streaming hair is "finely-shredded dark chocolate".
The flavor of the long vine is "a snake".
The flavor of the sand is "vanilla-flavored cotton candy".
The flavor of the fakecave is "You can't taste it from outside. Come on."

Does the player mean examining the long streaming hair: it is very likely.