The Ambassador's Daughter by Hannah C

The Ambassador's Daughter

Played 3,735 times
View game source (spoilers!)
Download the .z8 file
Source Code

"The Ambassador's Daughter" by Stormchild

[See bottom of file for changelog]

Book 1 - Mechanics

Release along with an interpreter and a solution.

The story headline is "A Brief Romance".
The release number is 2.
The story creation year is 2015.
The story description is "You really want to ask her for a dance, but alas she is from the opposing delegation. If only you could get her alone and pluck up the courage to speak to her."
The story genre is "Romance".

After printing the banner text:
	say "The author can be contacted via the IntFiction forums - http://www.intfiction.org/forum[line break]"


Chapter A1 (for Glulx only)

[For use with Inform 7 6L38 compiling to Glulx]
Use DICT_WORD_SIZE of 15.

Chapter A2 (for Z-Machine only)

[For use with Playfic and Inform 7 6G60 compiling to Z-Machine]
After reading a command: 
	let N be indexed text; 
	now N is the player's command; 
	replace the text "ambassador's" in N with "daughter"; 
	replace the text "ambassador" in N with "thedad"; 
	change the text of the player's command to N. 

Chapter 1 - Talking

Instead of asking someone about, say "[italic type]Just TALK TO [the noun] instead[roman type]."
Instead of telling someone about, say "[italic type]Just TALK TO [the noun] instead[roman type]."
Instead of asking someone for, say "[italic type]Just TALK TO [the noun] instead[roman type]."
Instead of answering someone that, say "[italic type]Just TALK TO [the noun] instead[roman type]."

Talking to is an action applying to one visible thing.
Understand "talk to/with [something]" as talking to.
Understand "converse with [something]" as talking to.
Understand "speak to/with [something]" as talking to.

Check talking to the player (this is the can't talk to yourself rule):
	say "That would probably get you some strange looks." instead.

Section 1.1 (for Glulx only)

[For use with Inform 7 6L38 compiling to Glulx]

Check talking to something (this is the can't talk to things rule):
	if the noun is a person, continue the action;
	say "[The noun] [aren't] something you can talk to." instead.

Report talking to someone (this is the standard talking to rule):
	say "[The noun] [don't] seem interested."

Section 1.1 (for Z-Machine only)

[For use with Playfic and Inform 7 6G60 compiling to Z-Machine]

Check talking to something (this is the can't talk to things rule):
	if the noun is a person, continue the action;
	say "[The noun] [if the noun is plural-named]aren't[otherwise]isn't[end if] something you can talk to." instead.

Report talking to someone (this is the standard talking to rule):
	say "[The noun] [if the noun is plural-named]don't[otherwise]doesn't[end if] seem interested."

Chapter 2 - Tea

Making tea is an action applying to nothing.

Understand "make almeri leaf tea" as making tea.
Understand "make leaf tea" as making tea.
Understand "make almeri tea" as making tea.
Understand "make tea" as making tea.

Understand the command "brew" as "make".

Check making tea (this is the block making tea rule):
	say "You don't feel like drinking tea right now."

Chapter 3 - Dancing

Dancing is an action applying to nothing.

Understand "dance" as dancing.

Report dancing: say "You aren't really one for dancing alone."

Dancing with is an action applying to one thing.
Understand "dance with [someone]" as dancing with.
Understand "ask [someone] to/for dance" as dancing with.
Understand "ask [someone] to/for a dance" as dancing with.
Understand "invite [someone] to dance" as dancing with.
Understand "invite [someone] to a dance" as dancing with.

Check dancing with the player (this is the can't dance with yourself rule):
	say "You aren't really one for dancing alone."

Section i (for Glulx only)

Check dancing with someone (this is the block dancing rule):
	say "[The noun] [don't] seem interested." instead.

Section ii (for Z-Machine only)

Check dancing with someone (this is the block dancing rule):
	say "[The noun] [if the noun is plural-named]don't[otherwise]doesn't[end if] seem interested." instead.


Chapter 4 - Filling

Filling it from is an action applying to two things.
Understand "fill [something] with/from [something]" as filling it from.
Understand the command "refill" as "fill".

Section i (for Glulx only)

Check filling it from (this is the block filling it from rule):
	say "[The noun] [aren't] something you can fill." instead.

Section ii (for Z-Machine only)

Check filling it from (this is the block filling it from rule):
	say "[The noun] [if the noun is plural-named]aren't[otherwise]isn't[end if] something you can fill." instead.
	
Chapter 5 - Help

Requesting help is an action out of world applying to nothing.
Understand "help" as requesting help.
Understand "hint" as requesting help.
Understand "hints" as requesting help.

Carry out requesting help:
	say "[italic type]This is a diplomatic function, so the best way to start interacting is to TALK TO or LISTEN TO people.[roman type][line break]".


Book 2 - World Map

Chapter 1 - Ball Room

The Ball Room is a room.
"Though the room is filled with chatter, and couples still dance late into the night, it does not take a trained eye to see that the two parties keep entirely to themselves. Almeri to the left, Tanith to the right, barely so much as looking at each other except when etiquette demands. A breeze blows through the tall windows, the curtains drifting gently to reveal glimpses of the gardens beyond, and on the balcony the band still plays.[paragraph break]The kitchens lie to the north, the gardens east and stairs lead up to the balcony above. The main doors lie to the south, but you cannot leave without your father."

After going to the ball room from the dimly lit gardens:
	say "You slip back inside unnoticed.";
	continue the action.

Instead of listening to the ball room:
	say "The band are playing [if the band is spoken]an Almeri anthem[otherwise]a Tanith waltz[end if], and the room is filled with the buzz of conversation. You'd have to be more specific with who you want to listen to to hear anything more."

Every turn when the location is the ball room:
	unless a random chance of 1 in 10 succeeds, continue the action;
	if the band is spoken:
		say "The band start up a new Almeri anthem.";
	otherwise:
		say "The band start up a new Tanith waltz."

The fake-ball-room is scenery in the ball room with printed name "ball room".
Understand "ball" and "room" as the fake-ball-room.
Instead of examining the fake-ball-room, try looking.
Instead of listening to the fake-ball-room, try listening to the ball room.

Instead of smelling the ball room, say "A mix of smoke, perfume and lingering food."

Instead of going south in the ball room:
	say "You cannot leave until your father is ready, and besides, she is still here so why leave now?"
	
Section i - Almeri Delegation

The Almeri delegation is a scenery person in the ball room. It is plural-named.
"Your father, the ambassador, and his entourage are gathered in small groups around the room. None pay any attention to you, of course, though you could easily listen to what they gossip about."

Understand "entourage", "group", "groups", "guest", "guests", "chatter", "couple", "couples", "party" and "parties" as the Almeri delegation.

Instead of listening to the Almeri delegation:
	unless the band is spoken, say "There are numerous whispered complaints about the band's choice of music." instead;
	say "They chat amongst themselves, discussing matters of great import such as what wine to serve with fish."
Instead of talking to the Almeri delegation, say "You don't really feel like talking to anyone from your delegation."
Instead of smelling the almeri delegation, say "A mix of heady perfumes and the distinctive minty smell of southern tobacco."

Section ii - Tanith Delegation

The Tanith delegation is a scenery person in the ball room. It is plural-named.
"Long enemies of your people, the Tanith have only grudgingly sent their ambassador, and his entourage remains separate from your own. None so much as look at you, though you could try listening perhaps, discretely of course."

Understand "entourage", "guest", "guests", "chatter", "couple", "couples", "party" and "parties" as the Tanith delegation.

Instead of doing something when the noun is the Tanith delegation or the second noun is the Tanith delegation:
	if the current action is examining, continue the action;
	if the current action is smelling:
		say "Exotic perfumes mixed with the oddly sweet smell of Tanith tobacco." instead;
	if the current action is listening:
		say "You try to listen in, but you just hear gossip about people and places you don't know," instead;
	say "But they are Tanith! You can't just approach them with everyone watching!"

Section iii - Windows

The ball-room-windows are scenery in the ball room with printed name "tall windows". It is plural-named.
"Running from the floor to nearly twice your height, the windows stand open to let air into the ball room. Beyond them, mostly hidden by the curtains, lie the gardens. You suspect nobody would notice if you stepped outside."
Understand "tall", "window" and "windows" as the ball-room-windows.

Instead of entering the ball-room-windows, try going east.

Instead of opening the ball-room-windows, say "They are already open."
Instead of closing the ball-room-windows, say "That would only draw attention to yourself."

Section iv - Curtains

The ball-room-curtains are scenery in the ball room with printed name "curtains". It is plural-named.
"Long curtains made of expensive cloth and fine silk hang across the windows, drifting slowly in the breeze."
Understand "curtain" and "curtains" as the ball-room-curtains.

Instead of opening the ball-room-curtains, say "That would only draw attention to yourself."
Instead of closing the ball-room-curtains, say "They are already closed."

Section v - Gardens

The ball-room-gardens are scenery in the ball room with printed name "gardens". It is plural-named.
"You cannot see much of the gardens from here - the curtains obscure the view."
Understand "garden" and "gardens" as the ball-room-gardens.

Instead of entering the ball-room-gardens, try going east.


Section vi - Balcony

The ball-room-balcony is scenery in the ball room with printed name "balcony".
"Usually when you are here, the king or one of his aides is giving a speech from the balcony - tonight, however, the band occupy it."
Understand "balcony" as the ball-room-balcony.

Instead of entering the ball-room-balcony, try going up.

Section vii - Band

The ball-room-band are a scenery person in the ball room with printed name "band". It is plural-named.
"The band comes from Cerea, you believe, so as to be neutral."
Understand "band" and "orchestra" as the ball-room-band.

Instead of talking to the ball-room-band, say "You'll need to go onto the balcony to do that."
Instead of listening to the ball-room-band:
	say "[if the band is spoken]An Almeri anthem[otherwise]A Tanith Waltz[end if] fills the room from the balcony above."

Instead of smelling the ball-room-band, say "You'll need to go onto the balcony to do that."

Section viii - Stairs

The ball-room-stairs are scenery in the ball room with printed name "stairs". It is plural-named.
"They lead up to the balcony."
Understand "stairs", "steps", "stairway" and "staircase" as the ball-room-stairs.

Instead of entering the ball-room-stairs, try going up.
Instead of climbing the ball-room-stairs, try going up.

Chapter 2 - The Gardens

The Dimly Lit Gardens are east of the ball room.
"The light from the ball room casts long shadows across the neatly trimmed lawn. Shadowy hedges rise up on all sides, the gloom seeming to seep from their bases to engulf the carefully arranged shrubs and plants.[paragraph break]The ball room lies back west."

After going to the dimly lit gardens:
	say "You slip outside unnoticed.";
	continue the action.

The fake-garden is scenery in the dimly lit gardens with printed name "gardens".
Understand "dimly", "lit", "garden" and "gardens" as the fake-garden.
Instead of examining the fake-garden, try looking.

Instead of smelling the dimly lit gardens, say "Freshly cut grass and fragrant plants make a pleasant change from the ball room."

Section i - Ball Room

The garden-ball-room is scenery in the dimly lit gardens with printed name "ball room".
"You can't see much of the ball room through the curtains."
Understand "ball" and "room" as the garden-ball-room.

Instead of entering the garden-ball-room, try going west.

Section ii - Windows

The garden-windows are scenery in the dimly lit gardens with printed name "tall windows." It is plural-named.
"Running from the floor to nearly twice your height, the windows stand open to let air into the ball room."
Understand "tall", "window" and "windows" as the garden-windows.

Instead of entering the garden-windows, try going west.

Instead of opening the garden-windows, say "They are already open."
Instead of closing the garden-windows, say "That would only draw attention to yourself."

Section iii - Curtains

The garden-curtains are scenery in the dimly lit gardens with printed name "curtains". It is plural-named.
"Long curtains made of expensive cloth and fine silk hang across the windows, drifting slowly in the breeze."
Understand "curtain" and "curtains" as the garden-curtains.

Instead of opening the garden-curtains, say "You would need to be inside to do that."
Instead of closing the garden-curtains, say "You would need to be inside to do that."

Section iv - Lawn

The neatly trimmed lawn is scenery in the dimly lit gardens.
"Though hard to see in this light, you know that the lawn is perfectly flat and level."
Understand "grass" as the neatly trimmed lawn.

Instead of smelling the lawn, say "The distinctive smell of freshly cut grass still lingers."

Section v - Hedges

The shadowy hedges are scenery in the dimly lit gardens.
"Tall and dense to provide some privacy from the outside world, the hedges seem menacing and quite ominous in the dim light."

Section vi - Shrubs

The shrubs are scenery in the dimly lit gardens.
"You can't really make out much in the darkness."
Instead of smelling the shrubs, say "A mix of fragrant smells arise from the garden."


Section viii - Lotus

[This will show up later, but its a garden thing, so define it here ready]
The marbled lotus is scenery in the  dimly lit gardens.
"A rare lotus flower, almost unheard of in Almer."

Instead of taking the marbled lotus when the Tanith ambassador is not listened:
	say "You shouldn't just pick the flowers without good reason."

Check taking the scenery marbled lotus:
	now the marbled lotus is not scenery;
	now the marbled lotus is not fixed in place;
	continue the action.

Report taking the marbled lotus when the marbled lotus is not handled:
	say "You carefully pick the lotus." instead.

Instead of smelling the marbled lotus:
	say "A strong, attractive fragrance, much in demand amongst the Almeri nobility."

Understand "flower" as the marbled lotus.

Section ix - Flowers

The flowers are fixed in place in the dimly lit gardens.
"The mingled scent of flowers fills the calm night air."
Understand "plants" and "plant" as the flowers.

Instead of smelling the flowers, say "A mix of fragrant smells arise from the garden."

The description of the flowers is "In the dim light you can make out a scarlet rose, a white lily[if the marbled lotus is scenery], a marbled lotus[end if] and a purple crocus."

The scarlet rose is scenery in the dimly lit gardens.
"A native Almeri rose, with its scarlet leaves edged in white."
Instead of taking the scarlet rose, say "You shouldn't just pick the flowers without good reason."

The white lily is scenery in the dimly lit gardens.
"A single white lily from the southern duchies."
Instead of taking the white lily, say "You shouldn't just pick the flowers without good reason."

The purple crocus is scenery in the dimly lit gardens.
"One of the largest crocuses you have ever seen."
Instead of taking the purple crocus, say "You shouldn't just pick the flowers without good reason."


Chapter 3 - Kitchens

The Kitchens are north of the ball room.
"Though you would not normally be in such lowly quarters, none of the servants appear to be here to notice. The remnants of the earlier banquet have been cleared away, leaving only empty tables and a cauldron simmering over the embers of a fire.[paragraph break]The ball room lies back south."

After going to the kitchens:
	say "You slip into the kitchens unnoticed.";
	continue the action.

The fake-kitchen is scenery in the kitchens with printed name "kitchens".
Understand "kitchen" and "kitchens" as the fake-kitchen.
Instead of examining the fake-kitchen, try looking.

A thing can be acceptable or unacceptable. A thing is usually acceptable.

Instead of smelling the kitchens, say "The smell of roast meat lingers in the air."

Instead of listening to the kitchens, say "The faint buzz of conversation from the ball room is too quiet to make out in any detail."

Section i - Empty Tables

The empty tables are a scenery supporter in the kitchens. They are plural-named. They have printed name "kitchen tables".
"Once laden with food, now empty."
Understand "kitchen table" and "kitchen tables" as the empty tables.

Section ii - Cauldron

The large cauldron is an open unopenable scenery container in the kitchens.
"A large iron cauldron[if the unexpected ally is happening and the old general is spoken]. You could [bold type]make tea[roman type] with this.[end if]"

Some simmering water is in the large cauldron.
The description of the simmering water is "Ordinary water, simmering in the heat from the fire."

Instead of taking the simmering water, say "There is far too much."

Instead of inserting something into the large cauldron, say "It would just get wet."
Instead of inserting something into the simmering water, say "It would just get wet."

Section iii - Fire

The embers of a fire are scenery in the kitchens.
"The embers will smoulder for hours to come."

Section iv - Tea Leaves

The box of tea leaves is in the kitchens. It is unacceptable.
"Someone has left a box of tea on a shelf beside the door."

The description of the box of tea leaves is "Finest Almeri tea leaves[if the unexpected ally is happening and the old general is spoken]. You could [bold type]make tea[roman type] with this[end if]."

Instead of taking the box of tea leaves (this is the can't take tea rule):
	say "You don't need to carry that round with you."

Instead of smelling the box of tea leaves:
	say "The tea leaves smell faintly sweet."

Section v - Mugs

Some empty mugs are on the empty tables. They are unacceptable.
The description of the empty mugs is "Two ordinary tea mugs."

Instead of taking the mugs (this is the can't take mugs rule):
	say "You don't need to carry those round with you."

Instead of filling the empty mugs from something:
	say "You don't need to do that right now."

Section vi - Acceptability

Before going from the kitchens when the player carries an unacceptable thing:
	say "(Leaving [the list of unacceptable things held by the player] in the kitchen)[command clarification break]";
	now all unacceptable things held by the player are in the kitchens;
	continue the action.

Chapter 4 - Balcony

The Balcony is above the ball room.
"Standing at the back, so as not to disturb the band, the ball room below is hidden from sight, and the music drowns out the dull buzz of conversation."

After going to the balcony:
	say "You quietly ascend to the balcony.";
	continue the action.

The fake-balcony is scenery in the balcony with printed name "balcony".
Understand "balcony" as the fake-balcony.
Instead of examining the fake-balcony, try looking.

Instead of listening to the balcony, try listening to the band.
Instead of smelling the balcony, try smelling the band.

Section i - The Band

The band are a scenery person in the balcony. It is plural-named.
"The band comes from Cerea, you believe, so as to be neutral."
Understand "orchestra" as the band.

The band can be spoken or unspoken. The band is unspoken.

Instead of talking to the band:
	if the band is spoken:
		say "You don't want to interrupt them again.";
	otherwise:
		now the band is spoken;
		say "You quietly whisper to the band master, and as the waltz comes to an end, he begins to play an Almeri anthem instead."

Instead of listening to the band:
	say "[if the band is spoken]An Almeri anthem[otherwise]A Tanith waltz[end if] drowns out all other sound."

Instead of smelling the band, say "The smell of boot polish lingers in the air."


Book 3 - Characters

Chapter 1 - Protagonist

Yourself is a woman in the ball room.

The description of yourself is "As the only daughter of the Almer ambassador, you get dragged to these events often, despite your fathers oft-spoken disappointment of your lack of interest in the foreign noblemen he throws your way."

Instead of listening to yourself:
	say "You hear only the racing beat of your heart."

Instead of smelling yourself:
	say "Did you wear the right perfume? What if she would have preferred the white lily?"



Chapter 2 - The Love Interest

The ambassador's daughter is a woman in the ball room.
"The ambassador's daughter is here, as you had hoped, your heart fluttering as you watch her gracefully dancing with the old general."
Understand "woman" and "girl" as the ambassador's daughter.

The description of the ambassador's daughter is "Her tall slender body, long silver hair and sparkling blue eyes captivate you - ever since you first laid eyes upon her, you have been unable to think of anything else. You look away before anyone catches you staring."

Chapter 3 - Your Father

Your father is a scenery man in the ball room.

The description of your father is "He stands with a group of nobles, likely soothing them with insincere flattery. The conniving duchess of Narn is on his arm - you glance around, but see no sign of your mother."

The nobles are a scenery person in the ball room. It is plural-named.
"Powerful men and women, all of whom you know and none of whom you like."

To say notice (whom - a person):
	set pronouns from whom.

Instead of talking to your father, say "[notice the duchess of Narn]Not while he is with [italic type]her[roman type]."
Instead of listening to your father, say "He says nothing with any real meaning."

Instead of talking to the nobles, say "None of them are interested in anything you have to say."
Instead of listening to the nobles:
	unless the band is spoken, say "There are numerous whispered complaints about the band's choice of music." instead;
	say "They chat amongst themselves, discussing matters of great import such as what wine to serve with fish."

Instead of kissing your father, say "[notice the duchess of Narn]Not while he is with [italic type]her[roman type]."

Instead of smelling your father, say "Strong western tobacco, and just a whiff of your mother's perfume."


Chapter 4 - The Ambassador

The Tanith ambassador is a scenery man in the ball room.
Understand "girl's father" and "her father" as the Tanith ambassador.
Understand "thedad" as the Tanith ambassador.

The description of the Tanith ambassador is "A stern looking man, about as old as your father. You don't know much about him."

The tanith ambassador can be listened. The tanith ambassador is not listened.

Instead of doing something when the noun is the Tanith ambassador or the second noun is the Tanith ambassador:
	if the current action is examining, continue the action;
	if the current action is smelling:
		say "You can't get close enough without drawing attention to yourself." instead;
	if the current action is listening:
		if breaking all the rules is happening:
			say "He is discussing the peace process with the general.";
		otherwise:
			now the tanith ambassador is listened;
			say "He seems to be discussing a blight in Tanis that is wiping out the rare marbled lotus, and bemoaning his inability to find one for his daughter." instead;
	say "But he is Tanith! You can't just approach him with everyone watching!"

Chapter 5 - Old General

The old general is a scenery man in the ball room.

The description of the old general is "The greatest military mind in Tanis, and rumoured to be the architect behind the peace talks. He looks old enough to be your grandfather."

Understand "old man" as the old general.

Instead of doing something when the noun is the old general or the second noun is the old general:
	if the current action is examining, continue the action;
	if the current action is smelling, say "You can't get close enough without drawing attention to yourself." instead;
	if the current action is listening:
		say "He is complimenting her on her dancing." instead;
	say "But he is Tanith! You can't just approach him with everyone watching!"

Chapter 6 - Duchess of Narn

The duchess of Narn is a scenery woman in the ball room.
"You dislike the duchess of Narn, and she makes no secret of her mutual feelings for you. She is, as always, at your father's side."

Instead of talking to the duchess of Narn, say "Not if she was the last person here."
Instead of smelling the duchess of Narn, say "You casually sniff her perfume as you pass. Oddly familiar somehow."
Instead of listening to the duchess of Narn, say "She seems to be flirting with your father, as always."
Instead of kissing the duchess of Narn, say "The very thought makes you shudder."

Book 4 - Scenes

Chapter 1 - The Opening

The Opening is a scene.
The opening begins when play begins.
The opening ends when the band is spoken.
The opening has a number called hint timer.

When play begins:
	say "[italic type]You really want to ask her for a dance, but alas she is from the opposing delegation. If only you could get her alone and pluck up the courage to speak to her.[roman type][paragraph break]".

Every turn during the opening:
	if the hint timer of the opening < 0, continue the action;
	increase the hint timer of the opening by 1;
	if the hint timer of the opening >= 5:
		say "[italic type]You wonder if you shouldn't talk to someone, or maybe just listen.[roman type]";
		now the hint timer of the opening is -1;

After talking to someone during the opening:
	now the hint timer of the opening is -1;
	continue the action.

After listening to someone during the opening:
	now the hint timer of the opening is -1;
	continue the action.

Section i - The Ambassador's Daughter

Instead of doing something when the noun is the ambassador's daughter or the second noun is the ambassador's daughter during the opening:
	if the current action is examining, continue the action;
	if the current action is talking to:
		say "She is Tanith, you can't just walk up to her. Perhaps you could find some way to get her alone?" instead;
	if the current action is listening:
		say "She doesn't seem to be saying much right now." instead;
	if the current action is smelling:
		say "You can't get close enough without attracting attention." instead;
	if the current action is kissing or the current action is dancing:
		say "But she is Tanith! The scandal would bring down your house!" instead;
	say "But she is Tanith! You can't just approach her with everyone watching!"

Section ii - Some Etiquette

Instead of jumping:
	if the location is the ball room, say "That would only draw attention to yourself." instead;
	if the location is the balcony, say "It's quite a way down." instead;
	say "You aren't really dressed for that."

Instead of searching:
	if the location is the ball room or the location is the balcony, say "That would only draw attention to yourself." instead;
	continue the action.
	
Instead of looking under something:
	if the location is the ball room or the location is the balcony, say "That would only draw attention to yourself." instead;
	continue the action.

Instead of dancing in the ball room:
	say "You would need a partner to dance."

Section iii - The Old General

Instead of doing something when the noun is the old general or the second noun is the old general during the opening:
	if the current action is examining, continue the action;
	if the current action is listening:
		if the opening is happening:
			say "He is complimenting her on her dancing." instead;
		otherwise if breaking all the rules is happening:
			say "He is discussing the peace process with the ambassador." instead;
		otherwise:
			say "He isn't talking to anyone." instead;
	say "But he is Tanith! You can't just approach him with everyone watching!"



Chapter 2 - The Old Man

The Unexpected Ally is a scene.
The unexpected ally begins when the opening ends.
The unexpected ally ends when the old general is happy.

The old general can be spoken or unspoken. The old general is unspoken.
The old general can be happy or unhappy. The old general is unhappy.

When the unexpected ally begins:
	move the old general to the dimly lit gardens;
	now the old general is not scenery;
	now the initial appearance of the old general is "The general is standing nearby, admiring the plants.";
	now the initial appearance of the ambassador's daughter is "She has gone to stand beside her father, the ambassador. Of the old general there is no sign.";
	now your father is not scenery;
	now the description of your father is "He has taken to the dance floor with the duchess, and she is far closer to him than etiquette dictates.";
	now the initial appearance of your father is "Your father is dancing with the duchess of Narn. How disgusting."

Instead of smelling the old general during the unexpected ally:
	say "The faint smell of perfume (hers?) lingers, nearly overpowered by the sweet smell of Tanith tobacco."
	
Instead of listening to the old general during the unexpected ally:
	unless the old general is spoken, try talking to the old general instead;
	say "He is silently watching the stars."


Section i - Some Talking

Instead of talking to the old general during the unexpected ally:
	if the old general is spoken:
		say "You don't really know what to say to him. Was he really expecting you to fetch him some tea?";
		stop the action;
	say "You cautiously approach the general, unsure how he will react to your presence. He seems nonplussed, merely nodding as you stand beside him.[paragraph break]'Nice night for a stroll' he says.[paragraph break]'I suppose it is,' your voice perhaps betraying your uncertainty.[paragraph break]'You know what I haven't had for a long time?' He pauses for a moment before continuing. 'Almeri leaf tea.'[paragraph break]Unsure how to reply to that, you remain silent.[paragraph break]He glances to you, giving you a friendly smile before looking up at the stars. 'Just the ramblings of an old man.'";
	now the old general is spoken.

Section ii - Tea


Some Almeri leaf tea is a thing.
The description of the Almeri leaf tea is "Two steaming mugs of Almeri leaf tea."
Instead of smelling the almeri leaf tea, say "The distinctive sweet smell is faintly intoxicating."

Instead of filling some almeri leaf tea from something: say "The mugs are already full."

Instead of inserting the marbled lotus into the almeri leaf tea, say "What are you trying to do? Poison someone?"

Instead of making tea during the unexpected ally:
	unless the old general is spoken, say "You don't need to do that right now." instead;
	if the location is the kitchens and the Almeri leaf tea is off-stage:
		if some mugs of water are on-stage:
			say "You add just the right amount of tea to the water, quickly brewing some sweet smelling tea.";
		otherwise if some mugs of tea are on-stage:
			say "You add some boiling water to the tea leaves, quickly brewing some sweet smelling tea.";
		otherwise:
			say "You quickly find a couple of mugs and some tea leaves, mixing a brew with the hot water from the cauldron.";
		move the Almeri leaf tea to the player;
		remove some empty mugs from play;
		remove some mugs of water from play;
	otherwise if the location is the kitchens:
		say "You have already made the tea.";
	otherwise:
		say "You need some hot water for that."

Instead of drinking the almeri leaf tea, say "Perhaps you should go back to the general first."

Section iia (for Glulx only)

The can't take mugs rule does nothing when the unexpected ally is happening.
The can't take tea rule does nothing when the unexpected ally is happening.

Section iib (for Z-Machine only)

A procedural rule during the unexpected ally:
	ignore the can't take mugs rule;
	ignore the can't take tea rule.


Section iii - Back to the General

Instead of drinking the almeri leaf tea in the presence of the old general during the unexpected ally:
	try giving the almeri leaf tea to the old general.

Instead of giving the Almeri leaf tea to the old general:
	now the old general is happy;
	remove the Almeri leaf tea from play;
	say "The general smiles as you hand him the mug. Sipping it slowly as he watches the stars above. 'I used to visit Almeri a long time ago, before the war. It is a beautiful country.' He pauses before turning to you. 'And you, my dear, are a beautiful young girl, and yet I don't recall seeing a man by your side all evening.'[paragraph break]You blush slightly, looking down into your tea.[paragraph break]'Ah, you have your eyes on someone. Well if you would take the advice of an old man, don't let what other people would think stop you following your heart. Thank you for the tea, it was most delicious.' And with that, he turns and heads back inside."

Section iv - Her

Instead of doing something when the noun is the ambassador's daughter or the second noun is the ambassador's daughter during the unexpected ally:
	if the current action is examining, continue the action;
	if the current action is talking to:
		say "She is Tanith, you can't just walk up to her. Perhaps you could find some way to get her alone?" instead;
	if the current action is listening:
		say "She doesn't seem to be saying much right now." instead;
	if the current action is smelling:
		say "You can't get close enough without attracting attention." instead;
	if the current action is kissing or the current action is dancing:
		say "But she is Tanith! The scandal would bring down your house!" instead;
	say "But she is Tanith! You can't just approach her with everyone watching!"
	

Chapter 3 - Breaking All The Rules

Breaking all the rules is a scene.
Breaking all the rules begins when the unexpected ally ends.

Section i - Start

When breaking all the rules begins:
	move the old general to the ball room;
	now the initial appearance of the old general is "The general has taken the Tanith ambassador to one side, talking to him quietly.";
	now the initial appearance of the ambassador's daughter is "She seems to be alone right now."

The ambassador's daughter can be spoken or unspoken. The ambassador's daughter is unspoken.

Section i - Daughter

Instead of doing something when the noun is the ambassador's daughter or the second noun is the ambassador's daughter during breaking all the rules:
	if the current action is examining, continue the action;
	if the current action is talking to, continue the action;
	if the current action is listening:
		say "She doesn't seem to be saying much right now." instead;
	if the current action is smelling and the ambassador's daughter is unspoken:
		say "You can't get close enough without attracting attention." instead;
	if the current action is smelling and the ambassador's daughter is spoken:
		say "Her perfume reminds you of pale blue roses from the eastern isles." instead;
	if the current action is kissing or the current action is dancing:
		say "Perhaps you should talk to her first." instead;
	say "But she is Tanith! You can't just approach her with everyone watching!"

Instead of talking to the ambassador's daughter during breaking all the rules:
	if the ambassador's daughter is spoken:
		say "You really don't know what to say, perhaps you could do something instead?";
	otherwise:
		say "You take a deep breath and walk over to her. Faltering as you approach and she looks up, your mind going blank as she looks at you with those bright blue eyes. 'Um... hi' you stutter.[paragraph break]'Oh, hello' she smiles, seemingly oblivious to your discomfort.[paragraph break]You blush a little, feeling eyes on you from all over the room, but you can't think of what to say next.";
		now the ambassador's daughter is spoken;
		now the nobles are not scenery;
		now the initial appearance of the nobles is "A group of nobles watches you disapprovingly."

Section iii - Winning

Instead of giving the marbled lotus to the ambassador's daughter during breaking all the rules:
	if the ambassador's daughter is spoken:
		say "'I.. err.. bought you this,' you stammer, fairly sure your face is bright red as you hand over the lotus.[paragraph break]'Oh, it's lovely,' she says, taking it from you carefully. 'These are so hard to find these days.' After a brief awkward pause, she continues. 'Would you like to dance?'";
		win the game;
	otherwise:
		say "Perhaps you should speak to her first."

Instead of dancing with the ambassador's daughter during breaking all the rules:
	if the ambassador's daughter is spoken:
		say "Um... would you like to... dance?' you stammer, fairly sure your face is bright red.[paragraph break]She smiles, reaching down to take your hand. 'I'd love to.'";
		win the game;
	otherwise:
		say "Perhaps you should speak to her first."

Instead of kissing the ambassador's daughter during breaking all the rules:
	if the ambassador's daughter is spoken:
		say "You can't think of anything to say, and so instead you just lean forward and kiss her.[paragraph break]For a moment there is silence, and you just look at each other before she smiles and offers you her hand. 'Would you like to dance?'";
		win the game;
	otherwise:
		say "Perhaps you should speak to her first."

To win the game:
	say "[paragraph break]The rest of the evening passes in a blur as you dance and talk with the girl of your dreams. You vaguely recall your father and the Tanith ambassador getting into a shouting match, the duchess of Narn passing out and the old general happily sipping tea as he watches the fallout.";
	end the story saying "Well, that broke all the rules".

Section iv - Running Away

After going when the ambassador's daughter is spoken during breaking all the rules:
	say "Your nerve fails you, and you ";
	if the location is:
		-- the gardens:
			say "retreat into the gardens";
		-- the kitchens:
			say "flee into the kitchens";
		-- the balcony:
			say "dash upstairs to the balcony";
	say ", staying there for the rest of the night. You're not sure when your father leaves, but when your mother finds you he is notably absent, along with the duchess of Narn. A few days later you are sent to stay with your uncle, and never have to attend a diplomatic function again. Alas, this also means you never see the girl again.";
	end the story saying "It could have been worse, I suppose".


Section v - Everyone Else

Instead of examining the almeri delegation when the ambassador's daughter is spoken during breaking all the rules:
	say "They all seem to be looking furtively your way."

Instead of listening to the almeri delegation when the ambassador's daughter is spoken during breaking all the rules:
	say "You keep hearing your name mentioned in hushed disapproval."

Instead of examining the Tanith delegation when the ambassador's daughter is spoken during breaking all the rules:
	say "They all seem to be looking furtively your way."

Instead of listening to the Tanith delegation when the ambassador's daughter is spoken during breaking all the rules:
	say "You keep hearing her name mentioned in hushed disapproval."

Instead of examining your father when the ambassador's daughter is spoken during breaking all the rules:
	say "Though diplomatically ignoring you, he gives you a stern and disapproving look when he catches your eye."

Instead of examining the duchess of Narn when the ambassador's daughter is spoken during breaking all the rules:
	say "She is too busy clinging to your father to notice you, fortunately."

Instead of examining the nobles when the ambassador's daughter is spoken during breaking all the rules:
	say "They all seem to be looking furtively your way."

Instead of listening to the nobles  when the ambassador's daughter is spoken during breaking all the rules:
	say "You keep hearing your name mentioned in hushed disapproval."

Chapter 4 - On How to Make Almeri Leaf Tea

[Yes, these are all scene-specific to the Unexpected Ally but needed a chapter level heading to properly organise it, so it can go here]

[Path 1: put water in cups, put tea in cups]
[Path 2: put tea in cups, put water in cups]

Section i - Mugs of Water

Some mugs of water are an unacceptable thing. [we can't take intermediary objects out with us]
The description of some mugs of water are "Two ordinary tea mugs filled with boiling water, just waiting for you to add tea."
Instead of inserting something into some mugs of water, say "That wouldn't achieve much."
Instead of inserting the marbled lotus into some mugs of water, say "What are you trying to do? Poison someone?"

Instead of filling some empty mugs from the large cauldron during the unexpected ally:
	unless the old general is spoken, say "You don't need to do that right now." instead;
	move the mugs of water to the player;
	remove the empty mugs from play;
	say "You carefully fill the two mugs with boiling water from the cauldron."

Instead of filling some empty mugs from the simmering water during the unexpected ally:
	try filling the empty mugs from the large cauldron.
Instead of inserting the simmering water into the empty mugs during the unexpected ally:
	try filling the empty mugs from the large cauldron.
Instead of inserting some empty mugs into the large cauldron during the unexpected ally:
	try filling the empty mugs from the large cauldron.
Instead of inserting some empty mugs into the simmering water during the unexpected ally:
	try filling the empty mugs from the large cauldron.

Instead of filling the mugs of water from something during the unexpected ally:
	say "They are already full of water."

Section ii - Mugs of Tea Leaves

Some mugs of tea are an unacceptable thing. [we can't take intermediary objects out with us]
The description of some mugs of tea are "Two ordinary tea mugs with some tea leaves in, just waiting for you to add water."
Instead of inserting something into some mugs of tea, say "That wouldn't achieve much."
Instead of inserting the marbled lotus into some mugs of tea, say "What are you trying to do? Poison someone?"

Instead of filling some empty mugs from the box of tea leaves during the unexpected ally:
	unless the old general is spoken, say "You don't need to do that right now." instead;
	move the mugs of tea to the player;
	remove the empty mugs from play;
	say "You put in just the right amount of tea, just like your mother showed you."

Instead of inserting the box of tea leaves into the empty mugs during the unexpected ally:
	try filling the empty mugs from the box of tea leaves.

Instead of filling the mugs of water from something, say "They already have tea in."

Instead of smelling the mugs of tea, say "The tea leaves smell faintly sweet."

Section iii - Putting Water into Tea

Instead of filling some mugs of tea from the large cauldron during the unexpected ally:
	unless the old general is spoken, say "You don't need to do that right now." instead;
	move the almeri leaf tea to the player;
	remove the mugs of tea from play;
	say "You add boiling water to the tea leaves, quickly brewing some sweet smelling tea."

Instead of filling some mugs of tea from the simmering water during the unexpected ally:
	try filling the mugs of tea from the large cauldron.
Instead of inserting the simmering water into the mugs of tea during the unexpected ally:
	try filling the mugs of tea from the large cauldron.
Instead of inserting some mugs of tea into the large cauldron during the unexpected ally:
	try filling the mugs of tea from the large cauldron.
Instead of inserting some mugs of tea into the simmering water during the unexpected ally:
	try filling the mugs of tea from the large cauldron.

Section iv - Putting Tea into Water

Instead of filling some mugs of water from the box of tea leaves during the unexpected ally:
	unless the old general is spoken, say "You don't need to do that right now." instead;
	move the almeri leaf tea to the player;
	remove the mugs of water from play;
	say "You add just the right amount of tea, just like your mother showed you, and soon have some sweet smelling tea."

Instead of inserting the box of tea leaves into the mugs of water during the unexpected ally:
	try filling the mugs of water from the box of tea leaves.

Section v - Some Miscellaneous Actions

Instead of inserting the box of tea leaves into the large cauldron during unexpected ally:
	try making tea.
Instead of inserting the box of tea leaves into the simmering water during unexpected ally:
	try making tea.

Instead of filling the large cauldron from the box of tea leaves during the unexpected ally:
	try making tea.
Instead of filling the simmering water from the box of tea leaves during the unexpected ally:
	try making tea.

Instead of inserting the simmering water into the box of tea leaves during the unexpected ally:
	try making tea.
	
Instead of filling the box of tea leaves from the large cauldron during the unexpected ally:
	try making tea.
Instead of filling the box of tea leaves from the simmering water during the unexpected ally:
	try making tea.

Book 5 - Change log

[ RELEASE 1 - 16/5/15
* Initial Release
]

[ RELEASE 2
* Added a timer to the opening scene to hint at TALK TO and LISTEN
* Improved response to generic LISTEN in the ball room
* Added missing synonym 'entourage' to both delegations
* Added missing synonyms 'group' and 'groups' to the Almeri delegation
* Added LISTEN hints to the two parties descriptions
* Added the ability to make tea in a series of steps instead of just with MAKE TEA - sooo many new rules :(
* Blocked being able to put things into the cauldron (only really affects the flower)
* Ran a spell-check pass
* Added smells to the garden (how did I forget these?) and other rooms
* Added KISS GIRL as a valid winning move (which seems to have been expected by other code, but not implemented)
* Blocked dancing with yourself
* Added missing plural/singular switch for report dancing with
* Added HELP command
* Renamed Empty Tables to Kitchen Tables since they aren't empty
* Added some EXAMINE and LISTEN responses to the crowd once you have spoken to the girl
* Added some missing bibliographic data
* Moved some misplaced scenery objects out of the ball room
* Added some specific flowers to the garden
* Lotus is now always present, but still not pickable until you listen to the ambassador
]