Princess Gumshoe's First Adventure by Adam Ghozeil

Princess Gumshoe's First Adventure

Played 2,167 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Princess Gumshoe's First Adventure" by Adam Ghozeil

Use American dialect and the serial comma and no scoring.

Section 1 - Escape from the bedroom

Helping is an action applying to nothing.
Instead of helping:
	Say "Welcome to Princess Gumshoe's First Adventure.";
	Say "You will solve puzzles and mysteries by walking around, looking at things, getting and using objects, and talking to people.";
	Say "Some important commands to know are...";
	Say "   help -- get this message.";
	Say "   look -- look around the room, or look at something in particular.";
	Say "   get or take -- pick something up.";
	Say "   put or drop -- put something somewhere, or just put it down.";
	Say "   talk, ask, or say -- talk to someone.";
	Say "   go (direction) or just (direction) -- go to another place.";
	Say "   use (thing) on (other thing) -- a generic use command that comes in handy";
	Say "There are other commands, too. Try stuff and see what happens."
	
Understand "help" as helping.

Your bedroom is a room. "Your bedroom is brightly lit by magic jars your brother Prince Questor brought home from a far-away land. The tower stairs lead down from here."
Your bed is here. Your bed is a supporter and fixed in place.

The description of your bed is "Your bed. Very comfy. Sometimes things roll under it."

Looked_under_bed is a truth state that varies. Looked_under_bed is false.
Calmed_fairy is a truth state that varies. Calmed_fairy is false.
Got_fairy is a truth state that varies. Got_fairy is false.

Instead of looking under your bed when looked_under_bed is false:
	Say "Under your bed is a frightened fairy.";
	Now a frightened fairy is in your bedroom;
	Now looked_under_bed is true.
	
Instead of looking under your bed when calmed_fairy is false:
	Say "Under your bed is a frightened fairy."
	
Instead of looking under your bed when calmed_fairy is true and got_fairy is false:
	Say "There is a glowing fairy relaxing under your bed."
	
Instead of looking under your bed when got_fairy is true:
	Say "There's nothing under your bed anymore."

The description of the frightened fairy is "There is a fairy here. She looks scared."
Instead of taking the fairy: say "She shakes her head and backs away."

The description of the glowing fairy is "The fairy seems quite calm now. She glows pleasantly."

Your desk is here. Your desk is a supporter and fixed in place. The drawer is part of the desk. The drawer is a closed, openable container. In the drawer is a magnifying glass and a pen. On your desk is a case log and a broken magic jar.

The description of your desk is "Your desk is your favorite place to puzzle out mysteries. So far they've all been in books, but you're hoping to solve a real one soon. You keep useful things organized in its one drawer."

The description of the drawer is "The desk only has one drawer, but it can hold a lot without getting cluttered."

The description of the magnifying glass is "Makes little things look big. It's not magic, but it seems like it."

The description of the pen is "Your favorite pen. The ink is purple!"

The description of the case log is "The pages are blank. For now."

The description of the broken magic jar is "One of your magic jars stopped working. You haven't gotten rid of it yet because you think you might be able to fix it." The broken magic jar is a closed openable container.
After opening the broken magic jar:
	Say "This looks like a comfy little fairy house inside.";
	now the description of the broken magic jar is "It's a comfy little fairy house. It needs a fairy."

The description of the glowing magic jar is "Your magic jar is fixed now. It should help in dark places." The glowing magic jar is lit.

The Tower stairs is down from your bedroom.
Tower stairs  is a dark room. "These spiral stairs lead from your bedroom in the highest tower of the castle down to the grand hall hall. The grand hall is down through the tower door."

Talking is an action applying to one visible thing.
Understand "talking to [something]" as talking.
Understand "talk to [something]" as talking.
Understand "calm [something]" as talking.
Understand "soothe [something]" as talking.

Showing is an action applying to two visible things.
Understand "show [something] to [something]" as showing it to.

Check showing it to:
	if the the second noun is not the fairy or the second noun is not a person, say "That doesn't make a lot of sense." instead.
	
Report showing it to:
	say "You show [the noun] to [the second noun]."
	
Instead of showing broken magic jar to frightened fairy:
	Say "You show the jar to the fairy. Recognizing her old home, she calms down immediately.";
	Remove the frightened fairy from play;
	Now calmed_fairy is true;
	Now a glowing fairy is in your bedroom.

Instead of talking frightened fairy:
	Say "You talk soothingly to the frightened fairy. She seems to calm down quite a lot.";
	Remove the frightened fairy from play;
	Now calmed_fairy is true;
	Now a glowing fairy is in your bedroom.
	
After closing broken magic jar:
	If glowing fairy is inside broken magic jar:
		Say "The jar begins to glow brightly.";
		Remove the glowing fairy from play;
		Remove the broken magic jar from play;
		Now the player has a glowing magic jar;
		
After taking glowing fairy:
	Say "You gently pick up the little fairy.";
	Now got_fairy is true.
	
The tower door is a door and down of Tower stairs and north of Grand hall.

instead of opening the tower door when the tower door is not visible:
	Say "You know there's a door here somewhere, but you can't see a thing."

Section 2- The mystery begins

The Grand hall is a room. "This is the grand hall of your family's castle. The door leading to your tower is to the north. An archway to the south leads to the garden. A doorway to the west leads to the kitchen. A decorated entryway to the east leads to the throne room." The Grand hall is down and south from Tower stairs.

A table is here. It is a supporter and fixed in place.
The description of the table is "A large oak table fills the center of the gand hall."

A trophy case is here. It is a closed locked openable container. It is fixed in place. The brass key unlocks the trophy case.
The description of the trophy case is "This is the case where your father, the King, keeps his favorite magic items. The key is usually kept in the dungeon."

The maid is here. The maid is a woman.

maid_introduced is a truth state that varies.
maid_introduced is false.

Every turn when the player can see the Maid:
	if maid_introduced is false:
		say "The maid rushes up to you and says, 'Oh dear. Oh dear. Princess Gumshoe, the King's favorite walking stick has been stolen!'";
		Now maid_introduced is true;
	otherwise:
		 if the repaired walking stick is not in the trophy case:
			say "The maid frets nervously."
			
Instead of asking the maid about something:
	Say "The maid looks too flustered to think. She says, 'The walking stick was in the trophy case over there, and now it's gone! I don't know what to do. We must find it before your father comes home.'"
	
Instead of telling the maid about something:
	Say "She doesn't look like she's listening. She just keeps talking about how upset the King will be."
	

Using it with is an action applying to one carried thing and one visible thing.
Understand "use [something] on [something]" as using it with.
Understand "use [something] with [something]" as using it with.

Check using it with:
	Say "I don't see how to use [the noun] with [the second noun]." instead.
	
Report using it with:
	say "You use [the noun] with [the second noun]."

Instead of using the magnifying glass with the trophy case:
	Say "You see small tracks in the dust by the trophy case. They lead to a two-inch hole in the case you hadn't noticed before.";
	Now the description of the trophy case is "This is the case where your father, the King, keeps his favorite magic items. There is a small hole in the side of it. The key is usually kept in the dungeon.";
	Now the tracks in the dust are in the Grand hall.

Instead of using the magnifying glass with the hole:
	Say "You see small tracks in the dust by the trophy case. They lead away from the hole.";
	Now the description of the trophy case is "This is the case where your father, the King, keeps his favorite magic items. There is a small hole in the side of it. The key is usually kept in the dungeon.";
	Now the tracks in the dust are in the Grand hall.

After opening the trophy case:
	Say "The trophy case is full of fine treasures from around the kingdom. The walking stick is missing. You notice a small hole in case beside the stick's usual spot.";
	Now the description of the trophy case is "This is the case where your father, the King, keeps his favorite magic items. There is a small hole in the side of it. The key is usually kept in the dungeon.".

Every turn when the player can see the trophy case:
	if the repaired walking stick is inside the trophy case:
		Say "The walking stick is back where it belongs. Hopefully, it won't go for a walk without the King again.";
		End the game in victory.
		
Every turn when the player can see the trophy case:
	if the damaged walking stick is inside the trophy case:
		Say "The walking stick is back in its place, but something's still not right.".
		
The hole is part of the trophy case. The description of the hole is "There is a two-inch hole in the trophy case. There are marks around it, but they are too small to make out clearly."
		
The tracks in the dust are fixed in place.
The description of the tracks in the dust is "You see small footprints in the dust leading from the trophy case out the south archway."

Some treasures are in the trophy case. They are fixed in place. The description of the treasures is "Beautiful treasured from around the kindom."

Section 3 - Outside

The Garden is a room. "The castle's garden is surrounded by low walls. In the middle of the garden, down a few steps, is a hedge maze. The archway to the grand hall is to the north." It is south of the Grand hall.

instead of searching the garden:
	Say "The tracks disappear in the neatly mown grass."
	
The Maze entrance is a room. "The walls of the hedge maze are too high to see over.  The exit is up some stairs, and there are paths to the east and west that lead deeper into the maze." The maze entrance is down from the garden.

The Maze intersection is a room. "The walls of the hedge maze are too high to see over. There are exits to the north, south and west." The maze intersection is east of the maze entrance.

The Maze east-bypass is a room. "The walls of the hedge maze are too high to see over. There are exits to the north and west." The maze east-bypass is south of the maze intersection.

The Maze west-bypass is a room. "The walls of the hedge maze are too high to see over. There are exits to the north and east." The maze west-bypass is west of the maze east-bypass.

The Maze elbow is a room. "The walls of the hedge maze are too high to see oveer. There are exits to the south and east." The maze elbow is north of the maze west-bypass and west of the maze entrance.

The Resting spot is a room. "The walls of the hedge maze open up to form a little clearing here. There are exits to the north, south, and west. A little fountain bubbles cheerfully beside some stone benches." The resting spot is north of the maze intersection.

The fountain is in the resting spot. The fountain is a container. The fountain is fixed in place.
The description of the fountain is "The fountain magically circulates water from a small pool up through a statue of a frog."

The gem is in the fountain.

The description of the gem is "This red gem looks just like one from the handle of your father's walking stick!"

Some benches are in the resting spot. The benches are fixed in place.
The description of the benches is "Some nice stone benches. Not very comfortable, but better than sitting on the ground."

The Dead end is a room. "The walls of the hedge maze are too high to see over. The only exit is back to the east."
The dead end is west of the resting spot.

The Pit edge is a room. "The walls of the hedge maze are too high to see over. The only exit is back to the south. There appears to be a narrow but deep hole in the ground here."
The pit edge is north of the resting spot.

The ground hole is in the pit edge. It is fixed in place.
The description of the ground hole is "There is a narrow but deep hole in the ground. Is something moving in it?"

Instead of talking the ground hole:
	Say "You hear whimpering and scratching sounds from in the hole. Maybe someone is stuck down there?"

Understand "lower [something] down [something]" as using it with.
	
Instead of using the rope with the ground hole:
	Say "You lower the rope down the hole. Something grabs on, and you gently pull it out. It is the walking stick, holding onto the rope with its many tiny wooden feet.";
	Say "There is a damaged walking stick here.";
	Now the damaged walking stick is in the pit edge.
	
The description of the damaged walking stick is "Your father's walking stick. It must have gone for a walk. One of its gems is missing."

Instead of using the gem with the walking stick:
	Say "You press the gem back into its spot. The walking stick seems much happier.";
	Remove the gem from play;
	Remove the damaged walking stick from play;
	Now the player has the repaired walking stick.
	
The description of the repaired walking stick is "Your father's walking stick. A little dirty, but at least it is all in one piece."

The Kitchen is a room. "The kitchen is a very busy place, full of cooks and pots and pans. There is an exit back to the grand hall to the east." It is west of the Grand hall.

The rope is in the kitchen. "There is a rope here. Why is there a rope in the kitchen? That doesn't belong here."

After taking the rope:
	Say "rope: taken.";
	Now the description of the rope is "A nice length of rope. Seems like it will come in handy."

The Throne room is a room. "Your father's throne is really just a big, comfy chair. There are nice sofas around the edge of the room so that when people come for an audience with the King they have somewhere to sit. Stairs lead down from here to the dungeon. The entryway leads west to the grand hall." It is east of the Grand hall.

The comfy chair is here. It is fixed in place.
The description of the comfy chair is "A comfy chair. Some people call it a throne."
Some sofas are here. They are fixed in place.
The description of the sofas are "Comfortable, but fashionable."

The Dungeon is a room. "The dungeon is a much cheerier place than the name would suggest. It is full of knicknacks and old junk the King likes, but doesn't want to show off in the grand hall." The Dungeon is down of the Throne room.

The brass key is here. The description of the brass key is "This is a nice brass key. It unlocks the trophy case in the grand hall."