Roman Adventure by Peter Risser

Roman Adventure

Played 2,163 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Roman Adventure" by Peter Risser and Robert Cannon.
[-- Revision: 2012-04-10 --]
[-- For comments, bugs and suggestions, please email playfic.risser@xoxy.net --]

[-- ** TO DO LIST
- Put/throw/drop things into fountain & take them out again; note they are damp
 -- **]

test solution with "s / take sword / x toga / x fence / hang belt on hook / throw sword over fence / climb belt / take sword / kill roman with sword / n / take crown"

Include Plurality by Emily Short.
[Include Extended Banner by Stephen Granade.]
Use American dialect and brief room descriptions.
The story headline is "A tiny adventure in Rome,".
The story description is "Roman Adventure is a super-simple four room adventure my friend created for testing text-adventure authoring systems.  It's easy enough to program quickly, but has enough in it to learn the basics of the system.".
The story genre is "Historical".

After printing the banner text:
	say "[line break](Revision: 2012-04-10.  For comments, bugs and suggestions, please email playfic.risser@xoxy.net.)[paragraph break]"; 

[-- Player --]
The description of the player is "You are a noble Roman citizen dapperly dressed in his noble Roman toga."


[=*= ROOMS =*=]

The Foyer is a room. "You are in a grandiose entry way to a Roman villa.  It is covered in tile forming beautiful mosaics and an archway decorates the room to the south.  There is a fountain here that looks like a fish spitting water."

The Armory is south of the foyer. "You are standing in the armory.  You can see the racks where the swords and pikes are normally kept, but they are empty.  There is a tall fence to the east[if the belt is on the hook] with a belt hanging from it[end if].  The foyer is to the north."

The Troop Barracks is a room.  "These are the spartan barracks where the troops bunk.  There are a couple of well-made bunks here, but no other personal effects to be seen.  The troops must keep their stuff elsewhere.  There is a fence to the west and an archway to the north.[if unvisited][paragraph break]You notice the fence is much shorter on this side.  The troop barracks must be raised off the ground a bit.[end if]"

The Treasure Room is north of the Barracks.  "This is a brilliant marble room that is probably normally full of glorious treasure, but now has a single marble pedestal in the dead center."

[=*= ITEMS =*=]

[-- Toga & Belt --]
The belt is a wearable thing.
The description of the belt is "It is a nice strong leather belt with a brass buckle."

The player is wearing the toga.

Instead of searching the toga, try examining the toga.
Instead of examining the toga:
	say "It's your standard issue Roman toga. [run paragraph on]";
	If the belt is off-stage:
		say "  Oh, and it has a belt holding it shut.";
		now the player is wearing the belt;
	otherwise:
		say "";

Instead of taking off the toga, say "I'd rather not. The local constabulary frowns on public nudity."
Instead of dropping the toga, try taking off the toga.

test toga with "take off toga / drop toga / x toga / take off belt / drop belt / wear belt";


[-- Pebble: A red herring --]
The player is carrying the tiny pebble. The description of the pebble is "It is a very tiny pebble.  It's sort of red and smells vaguely of fish."

test pebble with "gonear pebble / take pebble / x pebble / drop pebble / look";

Instead of attacking the guard with the pebble:
	say "You hurl the pebble at the guard.  It bounces off his chest and clatters away.  I don't think he noticed.";
	remove the pebble from play.

test pebble-attack with "gonear living / attack guard with pebble"

[-- Fish Fountain --]
The fish fountain is scenery in the foyer. "It's a gorgeous marble fish, standing on its head, spouting water into a carved marble basin."

Instead of taking the fountain:
	say "You climb up onto the fish and attempt to shake it loose in order to add it to your inventory.  However, the statue is slicker than you thought and you lose your grip, falling backwards and smashing your head on the tiled floor below. ";
	end the game in death.

test fish with "gonear fish / x fish / take fountain";

[-- mosaic --]
Mosaic is scenery in the foyer.  "You see a gorgeous tile mosaic that looks sort of like a giant sea turtle.  Or maybe a small hill.  It's kind of hard to tell."

[-- Water --]
Water is scenery in the foyer. "It's sparkling and clear.  It looks refreshing and inviting."

Instead of taking the water:
	say "You dip your hands into the cool water, and scoop some out of the fountain.  You watch as it slowly slips away between your cupped fingers."

Instead of drinking the water:
	say "You cup your hands together, bring some water to you mouth and sip a little.  It's cool and refreshing." 

test water with "gonear water / x water / take water / drink water"

[-- Broadsword --]
The two-handed broadsword is in the armory.  "There is a two-handed broadsword here, leaning up against a wall."  The description of the broadsword is "It's a very sharp, very heavy, two-handed broadsword." Understand "broad sword" and "sword" as broadsword.

After taking the broadsword:
	say "Taken.  Boy, it's heavy.";

test sword with "gonear sword / look / take sword / x broad sword / swing broadsword / drop sword / look";


[-- Fence --]
The tall fence is scenery in the armory.

Instead of examining the fence:
	say "It's a very tall wooden fence";
	if the player can see the hook:
		say " with a brass hook attached to it[run paragraph on]";
	otherwise:
		say ".  You notice there's a brass hook firmly attached to it near the top[run paragraph on]";
		now the hook is part of the fence;
	say ".  [if the belt is on the hook]There is a belt hanging from the hook.  [end if]The fence is far too tall to vault over."

test fence with "gonear tall fence / e / x hook / x fence / x hook / x fence";

[-- Backside of Fence --]
The backside of the fence is scenery in the barracks.  The description of the backside of the fence is "It's a normal wooden fence.  There's no hook, but you could probably climb it pretty easily."

[-- Hook on fence --]
The hook is a supporter.

The description of the hook is "It's a very sturdy brass hook, firmly attached to the fence[if the belt is on the hook], with a strong leather belt hanging from it[end if]."

[-- Racks --]
The racks are scenery in the armory.  "The racks are empty, but you can see that they are normally used to store weapons.  The troops must be out on maneuvers or something."

[-- Roman --]
The living Roman guard is a man in the Barracks.  The printed name of the living Roman guard is "Roman guard".  Understand "soldier" as the living Roman guard.  The description of the living Roman guard is "He is a big, mean Roman guard in military dress, full of muscles and carrying a sharp, pointy sword.  He's not going to let you get any closer for a better view.";

The Roman has a number called anger-count.  The anger-count of the Roman is 0.

Instead of taking the living Roman guard:
	now the anger-count of the living Roman guard is 5;

test taking-guard with "gonear living / take guard";


[-- Dead Roman --]
The dead body is a thing.  The printed name of the dead body is "the dead body of the Roman guard".  The description of the dead body is "It's the dead body of the Roman guard, lying in a pool of blood.".  Understand "soldier", "guard" and "Roman" as the dead body.

Instead of taking the dead body, say "It's far too heavy to carry.";


[-- Pedestal --]
The pedestal is a scenery supporter in the Treasure Room.  The description of the pedestal is "It's a marble pedestal, about waist high.".

[-- Crown --]
The golden crown is on the pedestal.  The description of the golden crown is "It's a beautiful golden crown covered in fine gems.  It must be worth a fortune.".


[-- Bunks --]
The bunks are scenery in the Barracks.  Understand "bunk", "beds" and "bed" as the bunks.  The description of the bunks is "These are very well-made bunks.  Clearly the sign of a well-disciplined military.";

Instead of doing anything other than examining to the bunks:
	say "That's a bad idea.  These soldiers would probably kill you for touching their stuff.";


[=*= ACTIONS =*=]

[-- Hanging --]
Hanging is an action applying to one thing.
Hanging it with is an action applying to two things and requiring light.

Understand "Hang [someone]" as hanging.
Understand "Hang [someone] with [something]" as hanging it with.
Understand "Hang [something] on [something]", "Put [something] on [something]", "Place [something] on [something]" as tying it to.

Carry out hanging:
	say "I don't think [the noun] is going to agree to let me do that.".

Carry out hanging it with:
	say "I don't think [the noun] is going to agree to let me do that.".

Instead of hanging the player:
	if the player is not carrying the belt and the player is not wearing the belt:
		say "With what, the sheer force of my will?";
	otherwise:
		say "You wrap the belt around your neck, pull it tight and look for something to attach the other end to.  However, pulling it tight has caused the buckle to lock and with the belt cinched tight around your neck, you find yourself unable to breath.  You stumble about, desperately clawing at the belt to no avail.  As your vision begins to narrow, you fall to the floor, where you proceed to suffocate to death.";
		end the game in death.

Instead of tying something to the fence:
	if the player can see the hook:
		try putting the noun on the hook;
	otherwise if the noun is the belt:
		say "You try to hook the belt onto the top of the fence, but you can't get a good purchase.  Out of the corner of your eye, you notice something on the fence.";
	otherwise:
		say "Not sure what else to do, you hurl [the noun] at the fence.  Naturally, it's a futile gesture, as [the noun] clatters to the ground.";
		move the noun to the location;

Instead of tying something to the hook:
	try putting the noun on the hook.

test hang-self with "hang self / x toga / hang self".
test hang-guard with "gonear guard / x toga / hang guard / hang guard with belt".
test hang-fence with "gonear fence / x toga / hang belt on fence / hang pebble on fence / x fence / hang belt on fence / look / x fence / x hook".

Instead of putting something on the hook:
	if the noun is the belt:
		say "You hang the belt on the hook and give it a sharp tug.  That's a good strong belt you've got firmly attached to that hook.";
		move the belt to the hook;
	otherwise:
		say "You carefully place [the noun] on the hook and step back to admire your handiwork. 'No, that's foolish,' you say to yourself and you remove it again.";

test hook with "gonear fence / x fence / x toga / hang pebble on hook / hang belt on hook";

[-- Climbing the fence --]
Instead of climbing the tall fence:
	if the belt is on the hook:
		if the player encloses the broadsword:
			say "You try to pull yourself up using the belt, but the need to keep one hand on the hilt of your sword and its sheer weight keep you from getting both feet off the ground.";
		otherwise:
			say "You use the belt to pull yourself up and heave yourself over the fence.";
			move the player to the barracks;
	otherwise:
		say "You scrabble against the fence, but can't seem to find any place to grab ahold.";

Instead of climbing the backside of the fence:
	say "You easily clamber over the top of the fence and drop to the other side.";
	move the player to the armory.

Instead of climbing the belt, try climbing the fence.
Instead of climbing the hook, try climbing the fence.

Climbing over is an action applying to one thing.  Understand "climb over [something]" as climbing over.

Carry out climbing over:
	try climbing the noun.

test climbing with "gonear tall fence / climb fence / x fence / climb over fence / x toga / hang belt on fence / climb fence / climb fence / take sword / climb fence";

[-- Throwing over --]
Throwing over is an action applying to two things.  Understand "throw [something] over [something]" and "toss [something] over [something]" as throwing over.

Carry out throwing over:
	if the player is not holding the noun:
		say "I can't throw something I'm not carrying.";
	[otherwise if the player cannot see the second noun:
		say "I don't see [the second noun].";]
	otherwise if the second noun is the tall fence:
		say "With all your might you hurl [the noun] over the fence and it clatters to the ground on the other side.";
		move the noun to the Barracks;
	otherwise if the second noun is the backside of the fence:
		say "With all you might you hurl [the noun] over the fence and it clatters to the ground on the other side.";
		move the noun to the Armory;
	otherwise if the player is holding the second noun:
		say "You hold out [the second noun] and toss [the noun] over it.  That was fun.";
		move the noun to the location;
	otherwise:
		say "You toss [the noun] over [the second noun] and it clatters to the ground.";
		move the noun to the location.

test throwing with "gonear sword / throw belt over fence / throw pebble over belt / throw pebble over sword / throw sword over fence / x toga / take pebble / throw pebble over belt / throw fence over belt";

[-- Swinging --]
Instead of swinging the broadsword:
	if the player can see the guard:
		try attacking the guard;
	otherwise:
		continue the action;

Instead of swinging something, say "You swing [the noun] wildly around your head.  That was fun!";

test swinging with "purloin sword / swing sword / swing pebble / gonear living roman / swing sword / swing sword";

[-- Change attacking  to attacking with --]
Understand the commands "attack" and "punch" and "destroy" and "kill" and "murder" and "hit" and "thump" and "break" and "smash" and "torture" and "wreck" as something new. 

Understand "attack [something] with [something preferably held]" as attacking it with.  Attacking it with is an action applying to one thing and one carried thing.

Understand the commands "destroy" and "kill" and "murder" and "hit" and "thump" and "smash" and "beat" as "attack". 

[-- kill the roman --]

Check an actor attacking something with something (this is the can't attack a non-guard rule):
	if the noun is not the Roman guard and the noun is not the dead body:
		if the actor is the player, say "You whack [the noun] as violently as you can with [the second noun] but nothing really happens.";
		stop the action. 

Instead of attacking the Roman guard with the broadsword:
	say "You swing your sword viciously at the guard, nearly slicing him in two.  He falls to the ground dead.";
	remove the guard from play;
	move the dead body to the location.

Instead of attacking the Roman guard with something:
	say "You lunge at the Roman with [the second noun].  He deftly parries your thrust and runs you through with his sword.";
	end the game in death.

Does the player mean attacking the dead body with the broadsword: it is likely.

Instead of attacking the dead body with something:
	say "He's already dead.  There's not much more you can do.".

test killing with "purloin sword / kill guard / gonear living guard / kill guard with sword/ kill guard";

test no-killing with "gonear living guard / kill guard / kill guard with pebble";

[-- prevent the player from going north when the guard is alive --]
Instead of going north while the Roman guard is in the Barracks and the player is in the Barracks: 
	say "The guard growls at you menacingly.  He's not going to let you pass.";
	increase the anger-count of the living Roman guard by 1;

test going-north with "purloin sword / gonear living roman / n / kill roman with sword/ n";

[-- winning --]
Instead of taking the crown:
	say "You have taken the crown and won the game!";
	end the game in victory.

[-- anger count --]
Every turn when the player can see the living Roman guard:
	increase the anger-count of the living Roman guard by 1;
	if the anger-count of the living Roman guard is 3:
		say "The guard looks fidgety and a little angry.";
	if the anger-count of the living Roman guard is 4:
		say "The guard looks angry and places his hand on the hilt of his sword.";
	if the anger-count of the living Roman guard is 5:
		say "The guard looks very angry.  He begins shouting in Latin and gesturing at you to leave.";
	if the anger-count of the living Roman guard is at least 6:
		say "The guard is utterly furious.  He draws his sword and runs me through!";
		end the game in death;

test anger with "gonear living / z / z / z / z / z";
test more-anger with "gonear living / n / n / n";
test delayed-anger with "gonear tall fence / purloin belt / x fence / hang belt on hook / climb fence / z / z / climb fence / take sword / throw sword over fence / climb fence / take sword / z";