Exterminator Simulator 2014 by Ryan Veeder

Exterminator Simulator 2014

Played 10,861 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Exterminator Simulator 2014" by Ryan Veeder

Use no scoring.

When play begins:
	say "You are an exterminator. Do your job.";
	now the right hand status line is "".

The description of the player is "You are an exterminator. Feel free to imagine that you are whatever race, body type, or gender you want to imagine that you are. Anybody can be an exterminator."

Foyer is a room. "This room is the foyer of the house that you need to do your exterminations in. Scientists have proven that exterminators are reasonable and intelligent individuals. A framed photograph on the wall depicts the family of humans that lives in this house.[paragraph break]North: a kitchen. South: a parlour. Up: the upstairs of this house.".

The framed photograph is scenery in foyer. The description of the framed photograph is "The parents and the children and the dog (since deceased)." Understand "family" and "photo" and "picture" and "frame" as the photograph.

Instead of going outside in Foyer, say "You can't leave before you're done with your job (exterminating)."

Kitchen is a room. "When you were first training as an exterminator, your mentor said: 'Leave the kitchens to me, kid. You're not ready.'[paragraph break]South: a foyer. North: a walk-in freezer." Kitchen is north of Foyer.

The refrigerator is here. Understand "fridge" as the refrigerator. The initial appearance of the refrigerator is "Nearby stands an 80s-style refrigerator[if a random chance of one in ten succeeds], quietly mocking you[end if]."

Instead of taking the refrigerator, say "Not a portable refrigerator."

The description of the refrigerator is "It doesn't have an ice dispenser or a water dispenser or a freezer compartment or anything like that."

The refrigerator is a closed openable container.

After opening the refrigerator:
	if the refrigerator contains a pest:
		say "You open the refrigerator, revealing [the pestname]."

Freezer is a room. "The air inside of this walk-in freezer is cold, cold like a broken promise. Your breath stands and waits around in front of your face like a cruel and impatient friend[unicode 8212]but you have no other friends. No living being could survive for long in such a frigid relationship, I mean environment.". Freezer is north of Kitchen.

The breath is scenery in Freezer. The description of the breath is "Haughtily the ghost of the shadow of your ice-companion laughs, neither with nor at you."

Parlour is a room. "[italic type]'Won't you come around my parlour,'[line break]Said the spider to the louse?[line break]To which the louse said, 'What's a parlour?'[line break]And then the spider said 'It is a room inside of my house.'[roman type][paragraph break]North: a foyer. East: a conservatory/greenhouse kind of room.". Parlour is south of Foyer.

Greenhouse is a room. "All the different gorgeous plants in here are like themed hotel rooms when it comes to pests breeding with each other.[paragraph break]West: a parlour.". Greenhouse is east of Parlour.

Some gorgeous plants are scenery in Greenhouse. Understand "plant" as the plants. The description of the plants is "A plant is a type of alive thing, but an exterminator such as yourself exterminates non-plant alive things exclusively."

The cellar door is a door. The cellar door is below greenhouse and above Tunnel. The initial appearance of the cellar door is "[if the location is greenhouse]A cellar door is around as well[otherwise if the cellar door is open]A cellar door (open and providing light) is around as well[otherwise]The door to the cellar is closed and it is almost impossible to see even that hatchet you call a nose in front of that salmon croquette you call a face[end if]." The cellar door is locked.

The description of the cellar door is "'You'll need to get down in the cellar,' the man of the house said to you. 'I think the key is in,' he continued, but he was interrupted by the sound of a van running over his dog."

Upstairs is a room. "The awful musk of a stranger's home is all up in your nostrils. You creep stealthily along in Exterminator Mode, ready to exterminate at a moment's notice. The old boards creak like dreaming serpents.[paragraph break]Down: the downstairs. North: children's bedroom. South: adults['] bedroom. East: toilet.". Upstairs is above Foyer.

Master Bedroom is a room. "The mother and father sleep in here. But the word 'mother[quotation mark], which you just thought to yourself internally without speaking aloud, reminds you of something:[paragraph break]Exterminators whisper, in the darkness of the night, of the Ur-Pest, She Who Skitters, Mother of Flies. She is a myth, a goofy urban legend that you cannot stop thinking about and which you constantly think you see in the corner of your eye.[paragraph break]North: [restofupstairs].". Master Bedroom is south of Upstairs.

To say restofupstairs:
	say "[one of]the rest of the upstairs[or]the hallway at the top of the stairs where you were before[or]the top of the stairs[or]the rest of the upstairs[stopping]"

Bedroom For Children is a room. "'Maybe you should exterminate some of these children!' Somebody said that sentence to you, once. A joking human adult wanted you to exterminate human children, because the adult felt that the children were 'pests[quotation mark], because the adult had forgotten what it is like to be a child. But there already is an exterminator of children, and his name is The Fact That Everybody Is Continuously Aging.[paragraph break]South: [restofupstairs].". Bedroom For Children is north of Upstairs.

A child's diary is here. Understand "journal" as the diary. The diary is a closed openable container. The initial appearance of the diary is "You are able to find a child's diary without too much trouble."

The description of the diary is "[if open]The writing in the diary says:[paragraph break][italic type]daer diary. I love KYLE. I want to kisss him over and over and over and over and over and over and over and over and over and over[paragraph break]dear diary. today it rained six inches.[paragraph break]dear diary. dad said I could not hang out with KYLE so I stole the celler key and will keep it from him until I am given permission to hang out with him.[roman type][otherwise]The diary is closed."

After opening the diary the first time: try examining the noun.

The key to the cellar is in the diary. The indefinite article of the key to the cellar is "the". The description of the key to the cellar is "This key may be the 'key' to your success as an exterminator." The key to the cellar unlocks the cellar door.

Toilet is a room. "It does not do to pass judgment on the toilets of others.[paragraph break]West: [restofupstairs].". Toilet is east of upstairs.

Tunnel is a room. "The dankness of this narrow and labyrinthine cellar is almost as debilitating as your fear of confined spaces."

The rat is a woman in Tunnel. The initial appearance of the rat is "A rat is in the room with you." The description of the rat is "The rat is huge and furred. It looks up at you with a contempt that spans millenia."

After examining the rat the first time, say "It speaks![paragraph break]'I am the Ur-Pest, She Who Skitters, Mother of Flies! I scrape the moon from the sky each month, and you dare to exterminate me?'"

Instead of saying yes:
	If the rat is in the location:
		say "'Shut up!' the rat shrieks.";
	otherwise:
		say "Exactly."

Instead of saying no:
	If the rat is in the location:
		say "'Shut up!' the rat shrieks.";
	otherwise:
		say "Precisely."

Section - Exterminating

A pest is a kind of thing. Understand "pest" as a pest.

One pest is in Toilet. One pest is in Parlour. One pest is in Greenhouse. One pest is in the refrigerator.

The printed name of a pest is usually "[the pestname]".

To say the pestname: say "[one of]a sickening[or]a beastly[or]a hideous[or]a horrible[or]a detestable[or]an unwanted[or]an abhorrent[or]a despicable[at random] pest".

Understand "sickening" and "beastly" and "hideous" and "horrible" and "detestable" and "unwanted" and "abhorrent" and "despicable" and "sickening pest" and "beastly pest" and "hideous pest" and "horrible pest" and "detestable pest" and "unwanted pest" and "abhorrent pest" and "despicable pest" as a pest.

The initial appearance of a pest is usually "Your gaze lands upon [the pestname]!"

The description of a pest is usually "It squirms and writhes and hisses and creeps around maniacally without any regard for decency. It is [the pestname] indeed."

Understand "exterminate [something]" and "murder [something]" and "dispatch [something]" and "eradicate [something]" and "eliminate [something]" and "kill [something]" as attacking.

Instead of attacking something:
	say "You are not being paid to exterminate [the noun]."

Instead of attacking a pest:
	say "With all due force and excessive prejudice you exterminate the pest. It's pesting in Hell now.";
	remove the noun from play.

Instead of taking a pest, say "You cannot pick up a pest! You forgot to wear gloves! YOU FORGOT TO WEAR GLOVES."

Instead of attacking the rat:
	say "You strike down the Mother of Flies.[paragraph break]'That's what you think, Exterminator!' the rat gurgles...[paragraph break]What have you done?";
	end the game saying "The End?!?!?!"

[NOTE TO SOURCE DIVERS: I think I'm gonna change this ending.]