Welcome to the Alaska Zoo by Ryan Veeder

Welcome to the Alaska Zoo

Played 2,675 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Welcome to the Alaska Zoo" by Ryan Veeder

The story headline is "An unofficial guide to the Alaska Zoo of Anchorage, AK, written"

abouting is an action applying to nothing. Understand "about" as abouting.

Instead of abouting, say "My name is Ryan Veeder! On May 21, 2014, I visited the Alaska Zoo. Then I went back to the hotel and wrote this game![paragraph break]This game is not endorsed by the Alaska Zoo and is not intended as an accurate depiction of its facilities. It's more like a diary entry in text adventure form.[paragraph break]Okay have fun in the zoo!"

Use no scoring.

[Version 3 of Exit Descriptions by Matthew Fletcher begins here. Playfic doesn't want to find the actual extension for some reason so I'm just pasting the source in.

"Appends a list of exit directions and names any previously visited rooms at the end of a room description."]

The amount is a number variable.
The amount is 0.

The num is a number variable.
The num is 0.

The ExitsMessage is some text that varies.
The ExitsMessage is "Exits:".

The ExitsAndText is some text that varies.
The ExitsAndText is " and".

The ExitsToText is some text that varies.
The ExitsToText is " to".

After looking (this is the exit descriptions rule):
	Now the amount is the number of adjacent rooms;
	repeat with destination running through adjacent rooms begin; 
		if the num is 0, say "[ExitsMessage]";
		let the way be the best route from the location to the destination, using even locked doors;
		if the way is a direction, say " [way]";
		if the destination is visited, say "[ExitsToText] [the destination]";
		Decrease the amount by 1;
		Increase the num by 1;
		if the amount is 0, say ".";
		if the amount is 1, say "[ExitsAndText]";
		if the amount is greater than 1, say ",";
	end repeat;
	Now the amount is 0;
	Now the num is 0.


[Version 3 of Exit Descriptions by Matthew Fletcher ends here.]

When play begins:
	say "Hello!";
	now the right hand status line is "";

Section - Setting Up Rooms
	


An animal is a kind of thing. Understand "animal" as an animal. A bird is a kind of animal. understand "bird" as a bird.

[A1 is a room.]
B1 is a room. The mountain goat is an animal in B1.
C1 is a room. The snow leopard is an animal in C1.
D1 is a room. The brown bear is an animal in D1.
A2 is a room. The Amur tiger is an animal in A2.
B2 is a room. The coyote is an animal in B2.
C2 is a room. The bald eagle is a bird in C2.
D2 is a room. The caribou is an animal in D2.
[A3 is a room. ]
B3 is a room. The printed name of B3 is "Near the Tiger Enclosure".
[C3 is a room. ]
D3 is a room. The printed name of D3 is "Bee Exhibit".
A4 is a room. The printed name of A4 is "Wolf Enclosure". A wolf is a kind of animal. The plural of wolf is wolves. Six wolves are in A4.
B4 is a room. The great horned owl is an animal in B4.
C4 is a room. The printed name of C4 is "Birds of Prey". The small horned owl is a bird in C4. The merlin is a bird in C4.
D4 is a room. The alpaca is an animal in D4.
A5 is a room. The printed name of A5 is "Orphan Facility". The pup is an animal in A5.
B5 is a room. The printed name of B5 is "Corvid Cages". The magpie is a bird in B5. The raven is a bird in B5.
C5 is a room. The polar bear is an animal in C5.
D5 is a room. The printed name of D5 is "Moose Enclosure".
A6 is a room. The printed name of A6 is "Petting Zoo". The Nigerian dwarf goat is an animal in A6.
B6 is a room. The porcupine is an animal in B6.
C6 is a room. The printed name of C6 is "Entrance".
[D6 is a room.]

B1 is west of C1. C1 is west of D1.
A2 is northwest of B3. B2 is west of C2. C2 is west of D2.
A4 is west of B4. B4 is west of C4. C4 is west of D4.
B5 is west of C5.
A6 is west of B6. B6 is west of C6.

b1 is north of b2. c1 is north of c2.
b2 is north of b3. d2 is north of d3.
b3 is north of b4. d3 is north of d4.
a4 is north of a5. b4 is north of b5. d4 is north of d5.
a5 is north of a6. b5 is north of b6. c5 is north of c6.




Rule for printing the name of a room (called the target):
	let B be indexed text;
	let B be the printed name of the target;
	if the number of characters in B is 2:
		let mal be a random animal in the target;
		let anim be indexed text;
		let anim be "[mal]" in title case;
		say "[anim] Enclosure";
	otherwise:
		say "[the printed name of the target]";
		
Section - Many Cages

The enclosure is a backdrop. The enclosure is everywhere. Understand "fence" and "cage" and "cages" and "fences" and "enclosures" as the enclosure.

Instead of climbing the enclosure, say "That is against the rules!"

Instead of entering the enclosure, say "Please stay on the designated walkways!"

The printed name of the enclosure is "[if a bird is in the location]cage[otherwise]enclosure[end if]".

Instead of examining the enclosure:
	let beastie be a random animal in the location;
	if beastie is a thing:
		say "[The enclosure] appears to contain [the beastie] very securely, although it's probably a little smaller than [the beastie] would prefer.";
	otherwise:
		say "There's no enclosure here!"
		
Section - Many Trees

The tree is a backdrop. The tree is everywhere. Understand "trees" and "foliage" and "plants" as the tree. The description of the tree is "There are trees and stuff all over the place. Plants are less interesting than animals, though! That's my opinion!"

	
Section - Things on the other side of fences

A thing can be distant.

Instead of doing something other than examining or taking with a distant thing:
	say "[The noun] is inside the enclosure!"

Section - Saying Exits
[
After looking (this is the listing exits rule):
	say exits.
	
Exitrequesting is an action applying to nothing. Understand "exits" as exitrequesting.

Instead of exitrequesting, say exits.

To say exits:
	let L be a list of texts;
	repeat with way running through directions:
		let place be the room way from the location;
		if place is a room:
			let G be "to the [place]";
			add G to L;
	say "From here you can go [L]."]
			

Section - All About the Player

The description of the player is "[textar]".

Textar is an indexed text that varies.

Check examining the player:
	if textar is "":
		now the command prompt is "Enter Description Now Please > ";
		say "Why don't you write your own description of yourself? That should be fun! Go ahead and type it in now. Remember to use the second-person singular voice, the present tense, and correct capitalization/punctuation! Also, please limit yourself to at most fifteen words." instead;

		
To decide whether collecting descriptions: 
	if the command prompt is "Enter Description Now Please > ", yes; 
	no.
	
After reading a command when collecting descriptions:
	now textar is the player's command;
	now the command prompt is ">"; 
	say "All right! Thanks! You can go ahead and examine yourself now.";
	reject the player's command.
	
Section - The Rules

Instead of taking something scenery, say "That's Alaska Zoo property!"

Instead of taking an animal, say "Sorry, but [the noun] belongs here, at the Alaska Zoo!"

Instead of touching an animal, say "Please do not touch the animals!"

Section - Entrance

The player is in C6. The description of C6 is "[first time]This is the Alaska Zoo! There are a lot of animals to see! But not right here, though. [only]This is just the entrance to the zoo. You can leave through the gate to the south, but why would you want to?"

The gate is scenery in C6. Instead of entering the gate, try going south. The description of the gate is "Remember when you walked through this gate earlier? That was great. Up until that point, it was like you weren't in a zoo at all. But now you are in a zoo! The Alaska Zoo!"

Instead of going south in c6:
	if the number of visited rooms is less than 10:
		say "You can't leave yet! There's so much you haven't seen!";
	otherwise:
		say "All right, thanks for visiting!";
		end the story saying "I hope you had fun!"

Section - Polar Bear

The description of C5 is "On the other side of the big glass wall is a pool of water and a bunch of rocks. They might be fake rocks."

The big glass wall is scenery in C5. The description of the big glass wall is "The glass is pretty clean!"

The bunch of fake rocks is distant scenery in C5. Understand "rock" and "fake rock" as the fake rocks. The description of the fake rocks is "It's pretty cynical of you to assume that the rocks are fake. You don't know!"

The pool of water is distant scenery in C5. The description of the pool of water is "The water is kind of dark. You can't really see down in there." Instead of searching the pool of water, try examining the noun.

The initial appearance of the polar bear is "On top of those rocks is a huge polar bear!"

The description of the polar bear is "Its white fur is matted with dampness and a little bit yellow. This polar bear needs some shampoo! In a couple of spots its hair is gone, and you can see its skin underneath is black."

Bearloop is a number that varies. Bearloop is 3.

Every turn:
	Increment bearloop;
	if Bearloop is 5:
		now Bearloop is 1;
	if the location is C5:
		choose row with a value of bearloop in Table of Bear Antics;
		say "[antic entry][paragraph break]".
		
Table of Bear Antics
value	antic
1	"The polar bear walks over to the edge of the pool."
2	"The polar bear turns away from the pool."
3	"The polar bear walks over to the far end of its enclosure."
4	"The polar bear lifts its head high into the air and turns itself around."


Section - Porcupine

The description of B6 is "The walls of this little enclosure are lined with wooden shelves connected by ladders."

The shelf is distant scenery in B6. Understand "shelves" as the shelf. The description of the shelf is "Why do porcupines like sitting on shelves so much? I have no idea!"

The wooden ladder is distant scenery in B6. Understand "ladders" as the ladder. The description of the ladder is "The wooden ladders are scuffed up a lot from being used by animals with big claws. Apparently a porcupine can climb up a normal human ladder!"

The initial appearance of the porcupine is "A porcupine is sitting on one of the shelves!"

The description of the porcupine is "Her back is covered in long quills that make her look much bigger than she really is. She's still about the size of a medium-sized dog, though![paragraph break]Despite having front legs that are powerful and flexible enough to pull herself up that ladder, this porcupine is scratching herself behind the ears with the claws on her back foot[unicode 8212]hey, like a dog! Porcupines aren't related to dogs, though. They're rodents."

Section - Corvidae

The description of B5 is "There are two big cages here!"

The initial appearance of the magpie is "In one cage is a magpie."

The description of the magpie is "The magpie is shaped basically like a big crow, but she has a white belly and white-and-blue wings. A glint of mischievous intelligence is in her eye!"

The initial appearance of the raven is "In the other cage is a raven!"

The description of the raven is "A raven is a big black bird with a long, skinny beak.[paragraph break]Here are some helpful tips for distinguishing between black birds:[paragraph break]- Blackbirds are pretty small, about the size of a robin, with pointy beaks. The males have shiny black feathers and the females are dark brown. They eat insects and seeds.[line break]- Crows are bigger than blackbirds, with longer beaks. They are scavengers (they eat dead animals that they find).[line break]- Ravens are like crows, only bigger!"

Every turn while the player is in B5:
	if a random chance of 1 in 2 succeeds:
		say "[one of]The magpie poops[or]The raven poops[or]The raven makes a noise that sounds like a turkey gobbling[or]The raven squawks[or]The magpie squawks[or]The raven hops around[or]The magpie hops around[at random]!"
		
Section - Great Horned Owl

The description of B4 is "The cage here is pretty tall, with roosting places at the tops of big posts inside[if the piece of meat is in the location]. On the floor of the cage is a piece of meat[end if]."

The big post is distant scenery in B4. Understand "posts" and "big post" and "roosting place" and "roost" and "roosting places" and "perch" and "perches" and "roosts" as the big post. The description of the big post is "It looks like it's made of wood!"

The initial appearance of the great horned owl is "On one of the posts is a great horned owl!"

The description of the great horned owl is "The owl is hard to see, up there in the darkness of the top of the cage. You can just about see the feathers on the top of his head, though[unicode 8212]the ones that look like horns. Scary!"

The piece of meat is distant scenery in B4. The description of the piece of meat is "It's a red square of meat. You can't tell what animal it came from. The zookeepers must have left it here for the owl to eat!"

Every turn:
	if the turn count is 24:
		remove the piece of meat from play;
		if the location is B4:
			say "Suddenly! The owl swoops down from his perch and grabs the meat in his talons! Then he flies back up to its perch and gobbles that meat down."

Section - Tiger Exterior

The description of B3 is "[if a2 is unvisited]Careful! Northwest of here is the Amur Tiger Enclosure! If you're scared of tigers, you should stay away![otherwise]You're very brave for going to see that tiger all by yourself.[end if]"

Section - Amur Tiger

The description of A2 is "You're standing on a raised walkway, high above the Amur Tiger Enclosure. You have a great view of the entrance to the tiger's cave and the great big area outside, where the tiger's hanging ball toy is slung between two trees."

The tiger's cave is distant scenery in a2. Understand "entrance" and "door" as the tiger's cave. the description of the tiger's cave is "It's dark in there!". Instead of searching the tiger's cave, try examining the noun.

The hanging ball toy is distant scenery in a2. The description of the hanging ball toy is "A long line has been set up between two trees, and a ball on a pulley thing is hanging in the middle. That tiger probably has a lot of fun pushing that ball back and forth!"

Understand "siberian tiger" and "siberian" as the amur tiger.

The initial appearance of the Amur tiger is "The tiger is down there, walking around!"

The description of the Amur tiger is "The Amur tiger is also called the Siberian tiger. He's orange with black stripes[unicode 8212]well, on his belly he's white with black stripes. His fur seems to hang down around its paws like a set of really comfy pajamas. He doesn't look lazy, though. He looks dangerous!"

Every turn while the player is in A2:
	if the Amur tiger is in A2:
		remove the Amur tiger from play;
		say "The tiger walks into his cave!";
	otherwise:
		now the Amur tiger is in A2;
		say "The tiger walks out of his cave!"
		
Section - Coyote

The description of B2 is "Here's a small enclosure where a coyote lives!"

The initial appearance of the coyote is "The coyote is walking back and forth around the enclosure."

The description of the coyote is "The coyote looks like a wolf, only smaller. Or, like a fox, only bigger.[paragraph break]I feel bad for this coyote. He has to live in the enclosure right next to that huge tiger!"

Section - Goat

The description of B1 is "On the other side of the enclosure is a miniature mountain."

The initial appearance of the mountain goat is "And on top of the miniature mountain is a grizzled goat!"

Understand "grizzled goat" as the mountain goat.

The miniature mountain is distant scenery in b1. Understand "rocks" and "rock" as the miniature mountain. The description of the miniature mountain is "A bunch of big rocks have been arranged into the shape of a mountain. I wonder if the goat is fooled?"

The description of the mountain goat is "This goat has a sour look on his face, like the look of a curmudgeonly grandpa. His horns have almost curled all the way around in a circle, which means he's about six years old. Is that pretty old for a mountain goat? I don't know!"

Section - Snow Leopard

The description of C1 is "This enclosure has a big pile of rocks in it and a big net over the top of it."

The big pile of rocks is distant scenery in c1. The description of the big pile of rocks is "This may be the snow leopard enclosure, but there's no snow on the rocks! It's 59 degrees out! There's no snow anywhere around! Even though this is Alaska! Alaska has summer too, you know!"

The big net is distant scenery in c1. The description of the big net is "If it weren't for that big net, the leopard could probably jump right out of his enclosure!"

The initial appearance of the snow leopard is "A snow leopard is hanging out on top of the rocks!"

The description of the snow leopard is "A big, serious-looking cat, grey with black spots. His shaggy tail is as long as the rest of his body! What a huge tail!"

section - brown bear

The description of D1 is "From this platform you can see all the way across the huge brown bear enclosure."

The initial appearance of the brown bear is "The brown bear is way on the other side! What is she doing?"

The description of the brown bear is "You can't see her very well. She looks like she's just walking around, looking for something to do.[paragraph break]A brown bear is bigger than a black bear. There's a black bear at the Alaska Zoo, but not in this game! I forgot to put one in!"


section - bald eagle

The description of C2 is "I don't remember this part of the zoo very well. I got distracted."

The initial appearance of the bald eagle is "I remember there was a bald eagle there though!"

The description of the bald eagle is "A bald eagle is a giant killing machine of a bird, with a big white head. When they're flying around, they're the most majestic sights in the world. This one is sitting down, though."

The brown mouse is a thing. Mousewait is a number that varies. Mousewait is 0.

Every turn while the player is in C2:
	if mousewait is less than 10:
		increment mousewait;
	if mousewait is 2:
		move the mouse to the location;
		say "An adorable brown mouse scampers into view. That's what distracted me from the eagles! Hey, little guy!";
	if mousewait is 6:
		remove the mouse from play;
		say "The mouse scampers away. So long, little guy!".
		
After taking the mouse:
	say "In real life you'd have to be pretty fast to catch this mouse, but since this is a computer game I'll let you get away with it. You pick up the mouse!";
	now mousewait is 10.

The initial appearance of the mouse is "A cute brown mouse is scampering around outside the cage, where it can't get caught by that eagle!"

The description of the mouse is "It's a brown mouse with spots on the sides. It's not a zoo animal, it's just an animal that lives in a zoo. Do they have this kind of mouse in the continental 48 states of the USA? I don't know!"

Instead of touching the mouse, say "You pet the little mouse on its fuzzy little head!"

instead of kissing the mouse, say "You nuzzle the mouse! Adorable!"

section - caribou

The description of d2 is "This enclosure has a lot of open flat space for running around on."

the initial appearance of the caribou is "A caribou is lounging around on the ground in there!"

The description of the caribou is "He's a deer with fuzzy white fur and big branched horns. He might actually be a reindeer. I'm not sure!" Understand "reindeer" as the caribou.

section - bees

The description of d3 is "Here you see a gazebo devoted to bees! You might call it a '[one of]ga-bee-bo[or]gaze-bee[at random][quotation mark]! In the center of it is a display with a bunch of windows."

The gazebo is scenery in d3. UNDerstand "gaze-bee" and "gazebee" and "gabeebo" and "ga-bee-bo" as the gazebo. The printed name of the gazebo is "[one of]gazebo[or]ga-bee-bo[or]gaze-bee[at random]". The description of the gazebo is "What a lovely gazebo!"

The display is scenery in d3. Understand "column" as the display. The description of the display is "The column in the center of the gazebo displays several beautiful paintings of bees, as well as some windows into the interior of the column."

The painting is scenery in d3. Understand "paintings" as the painting. The description of the painting is "Whoever painted all these images of bees must be very knowledgeable about bees as well as very talented artistically!"

The window is scenery in d3. Understand "windows" as the window. The description of the window is "You're meant to look in these windows to see what's going on inside the column!"

Instead of searching the window, say "It's completely dark in there. You can't see a thing[unicode 8212]certainly not any bees! What gives?"

section - alpaca

The description of d4 is "The alpaca's pen is pretty tiny. I guess she doesn't need a lot of space!"

The initial appearance of the alpaca is "[one of]The alpaca chews on some grass[or]The alpaca continues to chew[or]The alpaca chews rhythmically and unceasingly[or]She keeps chewing[or]She won't stop chewing[then at random]!"

The description of the alpaca is "The way her hair falls over her eyes gives her a very sleepy look.[paragraph break]Llamas and alpacas look very similar, but llamas are about a foot taller at the shoulder!"

The grass is distant scenery in d4. The description of the grass is "It doesn't look very tasty to me, but I'm not an alpaca!"

section - moose

The description of d5 is "This is where the moose would be, if there were a moose here!"

section - birds of prey

The description of c4 is "There are two cages here: A cage for a merlin, and a cage for a small horned owl."

The initial appearance of the merlin is "The merlin is eyeing you suspiciously!"

The description of the merlin is "He's a small falcon with a mean-looking beak. Merlins are also called 'pigeon hawks' because they look like pigeons while flying, and also they eat pigeons. I don't know why they're called 'merlins' though!" Understand "hawk" and "pigeon hawk" as the merlin.

The initial appearance of the small horned owl is "The owl is hiding in the darkness near the roof of her cage."

The description of the small horned owl is "The small horned owl is different from the great horned owl, but how? Is it the owl or the horns that are either small or great? I guess if it were the horns, then it would be 'great-horned owl' and 'small-horned owl'. This owl's horns are large in proportion to her body, but objectively speaking they're pretty tiny.[paragraph break]She seems a little sad."

section - wolves

The description of a4 is "There's a lot of space in this enclosure!"

The description of a wolf is usually "[one of]This wolf is lying down on the ground, as bored as heck[or]This wolf is trotting around, looking for something to do[then at random]."

section - orphans

The description of A5 is "This enclosure is for baby animals who don't have parents."

The initial appearance of the pup is "A coyote pup is in there! Adorable!" Understand "coyote" and "coyote pup" as the pup.

The description of the pup is "So fuzzy!"

The zookeeper is a woman in A5. The initial appearance of the zookeeper is "A zookeeper is in there with the pup."

The description of the zookeeper is "She is a lady wearing a blue uniform. Her job is to help out all these great animals!"

puploop is a number that varies. puploop is 3.

Every turn:
	Increment puploop;
	if puploop is 5:
		now puploop is 1;
	if the location is A5:
		choose row with a value of bearloop in Table of Pup Antics;
		say "[antic entry][paragraph break]".
		
To say athe:
	say "[one of]a[or]the[stopping]"

Table of Pup Antics
value	antic
1	"The zookeeper tosses [athe] stick across the enclosure."
2	"The coyote pup rushes across the enclosure to pick up [athe] stick!"
3	"The coyote pup carries [athe] stick over to the zookeeper."
4	"The zookeeper accepts [athe] stick from the coyote pup and scratches him behind the ears."

The stick is distant scenery in a5. The description of the stick is "That baby coyote sure loves fetching that stick!"

section - petting zoo

The description of a6 is "This is the one part of the zoo where you're allowed to pet an animal!"

Understand "pet [something]" as touching.

The initial appearance of the Nigerian dwarf goat is "That animal is the Nigerian dwarf goat."

The description of the dwarf goat is "It looks like his horns have been removed from his head, probably for safety reasons. He's pretty big for a 'dwarf' goat. Maybe this is really some other kind of goat."

Instead of touching the dwarf goat:
	say "When you approach the fence, the goat does too. But when he figures out you don't have any food for him, he trots away. No petting for you!"