You've Got a Stew Going! by Ryan Veeder

You've Got a Stew Going!

Played 7,013 times
View game source (spoilers!)
Download the .z8 file
Source Code

"You've Got A Stew Going!" by Ryan Veeder

The story genre is "Humor". The story headline is "An Interactive Fiction in one act".

Part 1 - General Information

The release number is 2.

When play begins:
	now the right hand status line is "Score: [score]".

The wall is a backdrop. understand "walls" or "cave" as the wall. Drew's Burrow contains the wall. Residential Tunnel contains the wall. Fran's Burrow contains the wall. Home contains the wall. Palace Gates contains the wall. The description of the wall is "It's made out of rocks and dirt." Instead of tasting the wall, try smelling the wall. Instead of smelling the wall, say "It's dirt! What do you expect?"

Thanking is an action applying to nothing. Understand "awesome" or "great" or "nice" or "yay" or "hooray" or "good" or "thanks" or "thx" or "thank you" as thanking.

Carry out thanking:
	say "You're welcome."

Understand "wiggle [something]" as pulling. 

When play begins, say "It seemed suspiciously generous of Drew to invite you to his burrow for lunch. It seemed too good to be true when you entered his quarters and saw a simmering stewpot in the center of the room. [paragraph break]But not to worry! There's nothing in the pot but a thin broth, there's no proper food anywhere in sight, and Drew is still the no-account mooch that he's always been. [paragraph break]As reassuring as all this is, though, you're still pretty hungry."

The description of the player is "As murine as ever."

Understand "steal [something]" as taking.

Instead of kissing something, say "What are you, a furry?"

Expressing displeasure is an action applying to nothing. Understand "dangit" or "dang" or "darn" or "drat" or "shut up" or "aw" or "aww" or "awww" or "agh" or "arg" or "argh" as expressing displeasure.

Carry out expressing displeasure:
	say "I'm very sorry."

Making stew is an action applying to nothing. Understand "make stew" or "make some stew" or "stew it" or "make stew happen" or "get this stew on the road" as making stew.

Carry out making stew:
	Say "The only way to make stew is to find some broth, find some ingredients, put the ingredients in the broth, and let the whole thing simmer a while."

Attempting to communicate is an action applying to one thing. Understand "talk [something]" or "talk to [something]" or "speak [something]" or "speak to [something]" or "speak with [something]" or "talk with [something]" or "call [something]" or "greet [something]" or "say [something]" or "beg [something]" as attempting to communicate.

Attempting to talk is an action applying to nothing. Understand "talk" or "speak" as attempting to talk.

Carry out attempting to communicate:
	say "In this interactive fiction/text adventure, you only need to communicate with people using the commands 'tell' or 'ask'. Try 'Ask (name) about (subject)' and see what happens."

Carry out attempting to talk:
	say "In this interactive fiction/text adventure, you only need to communicate with people using the commands 'tell' or 'ask'. Try 'Ask (name) about (subject)' and see what happens."

Digging is an action applying to nothing. Understand "dig" as digging. Instead of digging, try going down.

Digging at is an action applying to one thing. Understand "dig [something]" as digging at. Instead of digging at the floor, try going down. Instead of digging at something, say "You're not a tunneler, and this game doesn't have that level of granularity in terms of manipulable environments."

Understand "bite [something]" as attacking.

Understand "scratch [something]" as attacking.

Understand "gnaw [something]" as tasting.

Understand "nibble [something]" as tasting.

Instead of attacking something, say "Don't be brutish."

Instead of jumping: say "As rat jumps go, that was terrible."

Instead of singing, say "'I had a girl, Donna was her name...'"

Instead of putting something on scenery, say "Don't try to get fancy."

Kicking is an action applying to one thing. Understand "kick [something]" as kicking.

Carry out kicking:
	Say "With those legs?"

Yelling is an action applying to nothing. Understand "yell" or "shout" or "scream" or "cry" or "shriek" or "screech" or "roar" or "howl" or "holler" or "wail" as yelling.

Carry out yelling:
	Say "Your screams echo uselessly."

Yelling at is an action applying to one thing. Understand "yell at [something]" or "shout at [something]" or "scream at [something]" or "shriek at [something]" or "screech at [something]" or "howl at [something]" or "holler at [something]" or "roar at [something]" as yelling at.

Carry out yelling at:
	Say "I don't think [the noun] appreciates being yelled at."

Annoying is an action applying to one thing.

Understand "annoy [something]" as annoying. Understand "harangue [something]" as annoying. Understand "bug [something]" as annoying. Understand "hassle [something]" as annoying. Understand "mess with [something]" as annoying. Understand "antagonize [something]" as annoying. Understand "bother [something]" as annoying.

Carry out annoying:
	say "Don't be so antagonistic."

Lying on is an action applying to one thing.

Understand "lie on [something]" as lying on. Understand "lay on [something]" as lying on.

Carry out lying on:
	say "That's not there for you to lie on."

Instead of lying on the floor:
	say "Oh, get up. You have work to do."

Instead of lying on the bed:
	say "Now is not the time! You can sleep when you're dead. (That's what the Rat King always says, anyway.)"

Gasping is an action applying to nothing. Understand "gasp" as gasping. Instead of gasping, say "Oh my gosh, I know, right?"

Understand "poke [something]" as touching.

Understand "lick [something]" as tasting.

Instead of going nowhere, say "If you want to dig a new route, you're going to need to get approval from the Board of Tunnels first."

Before taking something which is carried by the player:
	say "You already have that.";
	stop the action.

Before inserting something which is not carried by the player into something:
	if the noun is in the second noun, say "Already done." instead;
	say "First you take [the noun].[line break]";
	silently try taking the noun;
	if the player is not holding the noun, stop the action.

Before putting something which is not carried by the player on something:
	if the noun is on the second noun, say "Already done." instead;
	say "First you take [the noun].[line break]";
	silently try taking the noun;
	if the player is not holding the noun, stop the action.

Before wearing something which is not carried by the player:
	if the player is wearing the noun, say "Already done." instead;
	say "First you take [the noun].[line break]";
	silently try taking the noun;
	if the player is not holding the noun, stop the action.

The floor is a backdrop. The floor is everywhere. The description is "Don't you have anything better to do?" Instead of touching the floor, try examining the floor. Instead of smelling the floor, try examining the floor. Instead of tasting the floor, try examining the floor. Instead of listening to the floor, try examining the floor.

Instead of smelling the player, say "Reasonably fresh." Instead of tasting the player, say "As you taste yourself, you realize that you must look really weird."

Part 2 - Drew's Burrow


Drew's Burrow is a room. "[if unvisited]As of right now you are in Drew's hole, a cozy (and murky and grimy) dead end in the tunnels[apostrophe] residential neighborhood. [end if]This is where Drew does his stuff and generally hangs out. Vague piles of junk lurk in the corners. The ceiling roils with a cloud of thin smoke, which spills out of the room through the doorway to the south." Instead of smelling Drew's burrow, say "The smoke from the fire, the aroma of the broth, and the unwashed musk of a male bachelor rat combine more or less agreeably in your nostrils." Instead of listening to Drew's burrow, say "A fire crackling, a stew simmering, and two rat stomachs growling."

The stewsmoke is scenery in Drew's burrow. "You've got to wonder whether it's safe being in here with all this smoke." The printed name of the stewsmoke is "smoke". Understand "cloud" or "ceiling" or "smoke" as the stewsmoke. Instead of taking the stewsmoke, say "The tunnels are a tobacco-free zone." After touching the stewsmoke, say "Wraithlike wisps follow your fingers." Instead of tasting the stewsmoke, say "Smoky." Instead of smelling the stewsmoke, try tasting the stewsmoke.

The junk is scenery in Drew's burrow. "It's just junk. It's not interesting. Besides, it's Drew's junk. Don't mess with it." Instead of touching the junk, try taking the junk. Instead of taking the junk, say "Drew shoots you a glance, and you decide to leave his stuff alone." Understand "pile of junk" or "piles of junk" or "pile" or "piles" or "stuff" or "Drew's junk" as the junk. Instead of smelling the junk, say "Drew's junk emits a wide and potent array of odors, a cornucopia of fragrance that would overwhelm your mind if any of it were interesting."

The beanbag is scenery in Drew's burrow. "It's made of denim and looks extremely comfortable, but it doesn't have room for anyone but the guy sitting on it (Drew)." Instead of touching the beanbag, say "Drew looks at you funny as you touch his denim beanbag. Turns out it feels like denim." Instead of taking the beanbag, say "Drew objects to your absconding with his beanbag and forcibly prevents its removal." Instead of smelling the beanbag, say "It smells like Drew, perhaps even moreso than Drew does."


Section 1 - Drew

Drew is a man in Drew's Burrow. Understand "rat" as Drew. The initial appearance of Drew is "Drew is here, lounging on a beanbag. '[one of]Let's get this stew on the road![or]Let's stew this![or]Let's get this stew going![or]I'm [italic type]soup[roman type]er excited about this stew![or]Are you as ready to make some stew as I am?[or]Can't wait for this stew to be ready![or]Time to make some stew happen![purely at random]' he cries, without getting up.". The description of Drew is "Drew is one of those rats who you don't necessarily have to constantly suspect of treachery--though of course it never hurts. His brown fur is unkempt and his left ear has a big chunk missing."

After touching Drew, say "'Get your claws off me!' He bats you away."

Instead of taking Drew, say "Drew rebuffs your advances with upraised claws. 'I'm fine here, thanks.'"

Instead of smelling Drew, say "Smelling Drew is an interesting and invigorating experience, because he has not bathed in a long time." Instead of tasting Drew, say "Actually, Drew does not want you to lick him."

After asking Drew about a topic listed in the Table of Drew's Answers, say "[answer entry][paragraph break]".

After telling Drew about a topic listed in the Table of Drew's Answers, say "[answer entry][paragraph break]".

Table of Drew's Answers
Topic	Answer
"life"	"'Life is a tale told by a... hmm.' He belches."
"drew"	"'I'm just fine. A little hungry. If you get my drift. Specifically, hungry for stew. If you know what I'm saying.'"
"me"	"'Um, you're pretty cool, I guess? Are we having a heart-to-heart conversation here?[paragraph break]'Because if so, let's not.'"
"myself"	"'Um, you're pretty cool, I guess? Are we having a heart-to-heart conversation here?[paragraph break]'Because if so, let's not.'"
"stew"	"Drew nods sagaciously. 'The thing about stew is, it needs ingredients.' is his sagacious reply."
"ingredients"	"'I dunno, man! You can put basically whatever in a stew.' His gaze is fixed on the ceiling. 'Just look around.'"
"ingredient"	"'I dunno, man! You can put basically whatever in a stew.' His gaze is fixed on the ceiling. 'Just look around.'"
"piles"	"'Like your place is so spick and span? Give it a rest.'"
"pile"	"'Like your place is so spick and span? Give it a rest.'"
"stewpot"	"He smiles contentedly. 'That's right, I got this broth together all by myself. So you won't mind if I leave the other ingredients to you.'"
"pot"	"He smiles contentedly. 'That's right, I got this broth together all by myself. So you won't mind if I leave the other ingredients to you.'"
"recipe"	"'That's no way to live! You gotta improvise!'"
"broth"	"He smiles contentedly. 'That's right, I got this broth together all by myself. So you won't mind if I leave the other ingredients to you.'"
"smoke"	"'It's no problem! The circulation and everything in here is completely up to code, I promise.'"
"fire"	"'Yeah, yeah, dangerous, whatever. Just don't let your tail fall in it.'"
"junk"	"'Like your place is so spick and span? Give it a rest.'"
"stuff"	"'Like your place is so spick and span? Give it a rest.'"
"burrows"	"'Pretty sweet pad, huh? Um, sorry there's nowhere for you to sit.'"
"burrow"	"'Pretty sweet pad, huh? Um, sorry there's nowhere for you to sit.'"
"tunnel"	"'Pretty sweet pad, huh? Um, sorry there's nowhere for you to sit.'"
"tunnels"	"'Pretty sweet pad, huh? Um, sorry there's nowhere for you to sit.'"
"Miko"	"'That's Fran's pet, right? Yeah, I don't care about it.'"
"roach"	"'Now that you mention it, I've never had roach before. I bet it's crunchy.'"
"roaches"	"'Now that you mention it, I've never had roach before. I bet it's crunchy.'"
"cockroach"	"'Now that you mention it, I've never had roach before. I bet it's crunchy.'"
"cockroaches"	"'Now that you mention it, I've never had roach before. I bet it's crunchy.'"
"Fran"	"'She's a downer. Oh, man, you didn't invite her, did you?'"
"rat"	"'Yeah, we're the best! Humans suck!'"
"rats"	"'Yeah, we're the best! Humans suck!'"
"us"	"'We're buds, don't worry."
"human"	"'I hate those guys! Sometimes I see one and I just wanna bite it. Just get in there and pull off some skin.'"
"humans"	"'I hate those guys! Sometimes I see one and I just wanna bite it. Just get in there and pull off some skin.'"
"Zeke"	"'Oh yeah, Zeke! I heard he's got a gig in medical research.'"
"palace"	"'I haven't been down there in a while. Everything's cool with the, royal court, and stuff, right?'"
"king"	"'He's okay. I don't have any problems with him. You'd know him better than me."
"rat king"	"'He's okay. I don't have any problems with him. You'd know him better than me."
"steam tunnel"	"'Oh, that'd be a great place to look for ingredients! You should get on that.'"
"steam tunnels"	"'Oh, that'd be a great place to look for ingredients! You should get on that.'"


After asking Drew about something, say "'I got nothing to say on that subject, dude.'"

After telling Drew about something, say "'That's interesting, dude, that's really interesting,' Drew responds, as he inspects his hind-claws."

A fire is scenery in drew's burrow. "A low fire, keeping the stew-in-making at a simmer." Instead of taking the fire, say "Nice try, Prometheus." After touching the fire, say "Ow!" Instead of smelling the fire, say "Smoky." Instead of tasting the fire, say "That is such a bad idea." Instead of listening to the fire, say "Okay, here's my impression of a fire crackling: ksshkshsh POP kshskshssshs. Pretty great, right?"



Part 3 - Geography & Stunnels


Drew's Burrow is north of the Residential Tunnel. Fran's Burrow is west of the Residential Tunnel. Home is south of the Residential Tunnel. Residential Tunnel is west of Steam Tunnel South.

STunnels is a region. Steam Tunnel South, Below Sidewalk Grate, Steam Tunnel North, Hill Grate, Steam Tunnel Depths, and Steam Fork are in STunnels. Steam Tunnel South is south of Sidewalk Grate. Steam Tunnel North is northeast of Sidewalk Grate. Hill Grate is above Steam Tunnel North. Sunny Hill is above Hill Grate. Palace Gates is south of Steam Tunnel South. Steam Fork is southeast of Steam Tunnel North. Steam Tunnel Depths is south of Steam Fork and east of Steam Tunnel South.


The brickwall is a backdrop. Understand "wall" or "walls" or "bricks" or "brick" or "brick wall" or "brick walls" as the brickwall. The brickwall is in stunnels. The description of the brickwall is "The bricks are old, and chipped, and red. Any one of them could be hiding a secret compartment." Instead of pushing the brickwall, try pulling the brickwall. Instead of pulling the brickwall, say "You pick a random brick and pull on it, then push on it, then wiggle it, but it stays stuck in the wall." Instead of smelling the wall, say "Even to your finely-tuned nose, bricks don't smell like much." Instead of tasting the wall, say "It tastes like rust and dust. You cough."

The steam pipes are a backdrop. The steam pipes are in STunnels. "The pipes run along the tunnels, carrying extremely hot, extremely pressurized steam to the various buildings above. Don't touch them." Instead of touching the steam pipes, say "Seriously, don't." Instead of tasting the steam pipes, say "As a text parser, I see a lot of stupid ideas over the course of a day, over the course of a career. Most of them I parse and forget, just like that. 'Over the cliff? Okay, [bold type]*** You Have Died ***[roman type], see you later.' But the really stupid ones, the crimes against reason--Those, I write down. I have a little book here, dedicated to only the most idiotic examples of Interactive Fiction input that I come across. Right now it's a book with a lot of blank pages. I don't take it out very often, while I'm on the job anyway. I'm selective. I have to be, considering the sheer volume of stupid commands I have to parse. [paragraph break]That one is going in the book." Instead of eating the steam pipes, say "No." Instead of taking the steam pipes, say "As much as you resent the humans[apostrophe] using the below-ground world to transport their oh-so-precious steam, you cannot retaliate by simply stealing their steam pipes, because that is an insane idea." Instead of listening to a room in stunnels, try listening to steam pipes. Instead of listening to steam pipes, say "hisssssssssssssss[paragraph break]". Understand "pipe" or "pipes" or or "steam pipes" or "steam" or "steam pipe" as the steam pipes.

Instead of smelling steam tunnel south, say "You can smell rust all around you, but mostly the tunnels just smell [italic type]hot[roman type]."

Instead of smelling hill grate, say "You can smell rust all around you, but mostly the tunnels just smell [italic type]hot[roman type]."

Instead of smelling steam tunnel north, say "You can smell rust all around you, but mostly the tunnels just smell [italic type]hot[roman type]."

Instead of smelling steam fork, say "You can smell rust all around you, but mostly the tunnels just smell [italic type]hot[roman type]."



Part 4 - Residential Tunnel


Residential Tunnel is a room. "[if unvisited]You probably already know this, but I feel like I should stop here and say it anyway: [paragraph break]You have a really keen sense of smell. And a fine sense of hearing, and taste, sure. But probably your number one sense is smell. Go ahead and try smelling some things. It'll be rewarding. [paragraph break][end if]A sizeable network of tunnels leading to the hidey-holes of your fellow rats branch off from this central cavity. This is an older neighborhood, and the struts and archways supporting the walls are cobbled together in an architectural patchwork that would say 'building code violation' to an Above-Dweller, but to you it says 'home'. [paragraph break]A faint trail of smoke curls out of the tunnel leading north to Drew's burrow. Your friend Fran's burrow is west of here. Your own home is to the south, and in the east you can access the steam tunnels."

The architecture is scenery in Residential Tunnel. The description of the architecture is "Examining the architecture too closely tends to diminish your confidence in its integrity, so unless you really have to, you don't." Understand "arch" or "patchwork" or "strut" or "arches" or "archway" or "archways" or "struts" or "tunnel" or "roof" or "tunnel" or "tunnels" as the architecture. Instead of listening to Residential Tunnel, say "The scritching and chittering of rats going about their lives." Instead of smelling residential tunnel, say "Your keen nose informs you that someone is cooking something somewhere to the north. You already knew that."

The smoke is scenery in Residential Tunnel. Understand "wisp" or "trail" as the smoke. "If you didn't know better, you'd assume Drew had set his burrow on fire. The smoke seems to be dissipating safely out in this tunnel, though." Instead of smelling the smoke, say "The smell of smoke is always a little bit alarming, isn't it? Yes, it is. You find yourself very slightly alarmed."


Part 5 - Fran's Burrow


Fran's Burrow is a room. "[if unvisited]You're always welcome in Fran's home. You and her go way back. [paragraph break][end if]Fran keeps her place quite a bit nicer than Drew does his. Whereas Drew's burrow is full of vague piles of junk, Fran has arranged her junk into stacks. [paragraph break]The rest of the neighborhood is to the east." Instead of listening to Fran's Burrow, say "The click-clicking of knitting needles." Instead of smelling Fran's burrow, say "That's a nice smell. Tomato-y." instead;

Instead of smelling Fran's burrow:
	If the tomato is not handled:
		say "There are a few different odors going on here, but the one that commands your attention is that of Fran's precious tomato.";
	otherwise:
		say "The lingering odor of tomato is still detectable by your powerful nostrils."

The stacks of stuff are scenery in Fran's Burrow. The description is "Scraps of cloth, balls of yarn, Enya cassettes, that kind of thing." Instead of taking the stacks, say "Man, don't mess with Fran's stuff!" Instead of touching the stacks, try taking the stacks. Instead of tasting the stacks, try taking the stacks. Instead of smelling the stacks, say "Smells like yarn." Understand "cloth" or "yarn" or "stacks" or "stuff" or "junk" or "stack" or "stack of stuff" as the stacks.

The pillow is scenery in Fran's Burrow. The description is "That pillow is looking pretty good. Where did Fran get such a nice pillow?" Instead of touching the pillow, say "Oh, that feels nice." Instead of smelling the pillow, say "It smells a little like Fran and a little like cockroach." Instead of tasting the pillow, say "It tastes a little like Fran and a little like cockroach." Instead of taking the pillow, say "Fran's sitting on it!" 

The knitting is scenery in Fran's burrow. Understand "scarf" or "sock" or "bag" or "sleeping bag" or "yarn" as the knitting. The description is "It's an oblong container of some sort, like a really big sock or a really tiny sleeping bag. You don't know much about knitting, but this piece seems to have a lot of mistakes in it." Instead of taking the knitting, say "Don't worry, you don't have any use for that." Instead of smelling the knitting, say "Just the smell of yarn. A fairly basic smell." Instead of tasting the knitting, say "You don't want to get your tongue caught in that while Fran's still poking those needles at it."

Section 1 - Fran

Fran is a woman in Fran's Burrow. Understand "rat" as Fran. The initial appearance of Fran is "Fran is here, sitting on a pillow and knitting. She glances at you distractedly as you enter." The description of Fran is "Brown-haired and mousy--not an uncommon look, among rats. Fran isn't as lazy as Drew, but that just makes her more dangerous. On the other hand, she has a very unratlike sentimental streak that has proved exploitable in the past. She is one of your best friends." Instead of smelling Fran, say "Of all your friends, Fran is probably the easiest on the olfactory system." Instead of tasting Fran, say "She would probably object to that." Instead of taking Fran, say "Unless you're taking her for ice cream, you should probably try something else."

Fran is either frazzled or placated or angry. Fran is frazzled.

Instead of asking Fran about something while the roach is in Fran's Burrow, say "Fran is too busy playing with her bug to talk to you."

Instead of telling Fran about something while the roach is in Fran's Burrow, say "Fran is too busy playing with her bug to talk to you."

After asking Fran about a topic listed in the Table of Fran's Answers, say "[answer entry][paragraph break]".

After telling Fran about a topic listed in the Table of Fran's Answers, say "[answer entry][paragraph break]".

Table of Fran's Answers
Topic	Answer
"life"	"'Life? Don't talk to me about life.'"
"knitting"	"'It's for Miko.' She sighs."
"Miko"	"'You know, my pet roach. She got out in the steam tunnels the other night and hasn't come back...' [paragraph break]Looking down, Fran realizes her hands have stopped knitting."
"roach"	"'Humans think they're gross, but Miko's not gross, is she?'"
"roaches"	"'Humans think they're gross, but Miko's not gross, is she?'"
"cockroach"	"'Humans think they're gross, but Miko's not gross, is she?'"
"cockroaches"	"'Humans think they're gross, but Miko's not gross, is she?'"
"me"	"'You're just fine. Don't worry about it.'"
"myself"	"'You're just fine. Don't worry about it.'"
"her"	"'I'm a little worried, I guess. I mean, Miko's probably fine. But, yeah.'"
"herself"	"'I'm a little worried, I guess. I mean, Miko's probably fine. But, yeah.'"
"Fran"	"'I'm a little worried, I guess. I mean, Miko's probably fine. But, yeah.'"
"Drew"	"'Oh, give me a break. I don't need to think about that guy right now.'"
"Zeke"	"'From school? I haven't heard from him in a while.'"
"stew"	"'Thanks for offering, but a meal with Drew is just about the last thing I need today.'"
"ingredient"	"'I'm not much of a cook, sorry...'"
"ingredients"	"'I'm not much of a cook, sorry...'"
"recipe"	"'I'm not much of a cook, sorry...'"
"tomato"	"'Yeah, I'll probably finish it tonight, but I was hoping to share it with Miko.'"
"burrow"	"She turns her gaze around the room. 'It's not much, but it's home.'"
"burrows"	"She turns her gaze around the room. 'It's not much, but it's home.'"
"tunnel"	"She turns her gaze around the room. 'It's not much, but it's home.'"
"tunnels"	"She turns her gaze around the room. 'It's not much, but it's home.'"
"steam tunnels"	"'That's where I saw Miko last. If you're headed that way, do you think you could keep an eye out for her?'"
"rat"	"She squints. 'What [italic type]about [roman type]us?'"
"rats"	"She squints. 'What [italic type]about [roman type]us?'"
"us"	"She squints. 'What [italic type]about [roman type]us?'"
"king"	"She hesitates. 'I feel a little weird talking about him with one of his employees.'"
"rat king"	"She hesitates. 'I feel a little weird talking about him with one of his employees.'"
"palace"	"'That's your area of expertise, not mine.'"
"human"	"'Have you seen those girl-humans going around with hair all the way down their back? That can't be real, right? You could probably pull it right off.'"
"humans"	"'Have you seen those girl-humans going around with hair all the way down their back? That can't be real, right? You could probably pull it right off.'"

After asking Fran about something, say "'I have other things on my mind right now, sorry.'"

After telling Fran about something, say "As you finish speaking, Fran turns to you with a vacant look. 'Sorry. I was distracted.'"

The tomato is an object in Fran's Burrow. The tomato is edible. The initial appearance of the tomato is "Your nose alerts the rest of your body to the presence of a juicy-looking half-eaten tomato." The description of the tomato is "Red. Juicy. Appetizing. Yes. This is exactly what you need for that stew." Instead of smelling the tomato, say "It hasn't even gone bad yet!" Instead of tasting the tomato, try smelling the tomato.

Instead of eating the tomato the first time:
	Say "Are you sure? Drew probably wants it for the stew. But, I mean, if you're really hungry..."
	
Instead of eating the tomato:
	Say "All right, it's your call. [paragraph break]Hey, that was pretty tasty, actually. The stew will be fine without it anyway.";
	remove the tomato from play;
	increase progression by 1;
	now the player is sated.

Instead of taking the tomato in Fran's burrow while the roach is not in Fran's Burrow, say "Fran glares at you. 'I'm saving that!' she growls."

Instead of taking the tomato in Fran's burrow while the roach is in Fran's burrow:
	Say "While Fran is distracted by her pet roach, you snatch her piece of tomato.";
	now the player has the tomato.
	
After dropping the roach in Fran's burrow the first time:
	say "Fran drops her knitting and rises from her seat. 'Miko!' she cries, as the insect runs to her arms. [paragraph break]'Thank you so much for finding her,' she says, and quickly she begins cooing and goo-gooing at her pet. [italic type]The tomato is undefended[roman type].";
	now Fran is placated;
	now the initial appearance of Fran is "Fran is here, playing with her pet roach.";
	increase progression by 1.
	
After dropping the roach in Fran's burrow:
	say "Fran scoops up her pet immediately. 'Did you have fun?' she asks it. 'Did you? Did you? Oh, I bet you did! I bet you did!'";
	increase progression by 1.

Instead of asking Fran about something while Fran is placated and the roach is not in Fran's Burrow, say "'Never mind that; isn't it about time for you to drop Miko off from her playdate?'"

Instead of telling Fran about something while Fran is placated and the roach is not in Fran's Burrow, say "'Never mind that; isn't it about time for you to drop Miko off from her playdate?'"
	

After taking the roach in Fran's burrow:
	say "'Aw, where are you taking her?' Fran grumbles. 'Well, bring her back soon.'";
	now the player has the roach;
	decrease progression by 1;
	now the initial appearance of Fran is "Fran looks up at you expectantly as you enter. 'Where's Miko?'".

instead of eating the roach in fran's burrow:
	say "Fran looks up at you in shock, then rage. She dashes across the room and snatches her darling roach out of your hands. [paragraph break]Then, with a strength you wouldn't have thought she possessed, she shoves you out of her burrow into the tunnels.";
	now the roach is in fran's burrow;
	now fran is angry;
	now the player is in residential tunnel.
	
Instead of going west in residential tunnel while Fran is angry:
	say "You should probably avoid Fran's place for the time being."

Check for showing something to Fran:
	If the noun is the roach:
		try dropping the roach instead;
	Otherwise:
		If Fran is frazzled:
			say "'That's nice,' she says, without looking up from her knitting." instead;
		Otherwise:
			If the roach is in Fran's burrow:
				say "'Can it wait? I'm teaching Miko to do a trick.'" instead;
			Otherwise:
				say "'Okay, but where's Miko?'" instead.

Check for giving something to Fran:
	If the noun is the roach:
		try dropping the roach instead;
	Otherwise:
		If Fran is frazzled:
			say "'That's nice,' she says, without looking up from her knitting." instead;
		Otherwise:
			If the roach is in Fran's burrow:
				say "'Can it wait? I'm teaching Miko to do a trick.'" instead;
			Otherwise:
				say "'Okay, but where's Miko?'" instead.

Section 2 - Miko

The roach is an object. The roach is edible. The initial appearance of the roach is "A cockroach is here, skittering playfully up and down the walls." Instead of smelling the roach, say "Surprisingly bearable." Instead of dropping the roach in Sunny Hill, say "You'd never see her again if you let her go out here!" Understand "Miko" or "cockroach" or "bug" or "pet" as the roach.

When play begins:
	Now the roach is in a random room in Stunnels.

Rule for printing a parser error when the latest parser error is the can only do that to something animate error:
	Say "That's not something you can talk to."

Instead of tasting the roach while the player is not holding the roach:
	Say "You're going to have to catch her first!"
	
Instead of tasting the roach, say "Ooh! Roaches taste rather nice, it turns out. Probably nice and crunchy too."

Instead of examining the roach for the first time:
	Say "Actually, this is probably Fran's pet roach Miko. Hey, Miko!";
	now the printed name of the roach is "Miko";
	now the roach is proper-named;
	now the description of the roach is "Fran's little pet roach. She looks like every other roach.";
	now the initial appearance of the roach is "Miko skitters up and down the walls of the room."


Instead of taking the roach in Stunnels:
	If a random chance of 1 in 3 succeeds:
		say "The little scamp [one of]crawls between your legs[or]jumps over your head[or]slips under a pipe[purely at random], evading your grasp. Well, next time you'll be ready for that." instead;
	Otherwise:
		If a random chance of 1 in 3 succeeds:
			now the roach is in a random room in Stunnels;
			say "The wriggly little thing is too fast for you, and runs off down the tunnels. After her!" instead;
		Otherwise:
			now the player has the roach;
			say "Gotcha! She put up a fight, but you caught her.".

Instead of dropping the roach in Stunnels:
	Say "The moment you let go of her, the roach takes off like a bullet down the tunnels.";
	Now the roach is in a random room in Stunnels.

Instead of eating the roach the first time:
	If the printed name of the roach is "Miko":
		say  "Are you sure? Fran would probably get pretty mad. But, I mean, if you're really hungry...";
	Otherwise:
		say "Are you sure? There's got to be a better use for it. But, I mean, if you're really hungry...".
		
Instead of eating the roach:
	Say "All right, it's your call. [paragraph break]Hey, that was pretty tasty, actually. The stew will be fine without her anyway.";
	remove the roach from play;
	now the player is sated;
	increase progression by 1;
	if the tomato is in fran's burrow:
		increase progression by 1.
	


Part 6 - Home


Home is a room. "[if unvisited]Ah, hole sweet hole. [paragraph break][end if]The nice thing about your own place is that everything is exactly where it should be. Other people's burrows are always just a little bit [italic type]off,[roman type] you know? But even if your home is a dirty little hole in the ground, at least you can keep it the way you like it." Instead of listening to Home, say "The reassuring silence that only one's own home can supply." Instead of smelling Home, say "It's [italic type]your[roman type] burrow. It doesn't smell like anything."

The trunk is an opaque openable container in Home. The trunk is closed. The initial appearance of the trunk is "Your trunk is in here, wedged between the bed and the cave wall." The description is "Your trusty trunk, for all those possessions of yours you'd rather not keep out in the open. Only an idiot would try pilfering from it." Instead of taking the trunk, say "That's too big to lug around." Instead of smelling the trunk, say "It smells like potatos." Instead of tasting the trunk, say "The combined tastes of everything you've stored in here over the years makes for an interesting experience."

The bed is scenery in Home. "Your good old bed, your dear old bed. You wouldn't be able to get through the day if you didn't know that, at the end of the day, this bed will be for you to fall on top of." Instead of taking the bed, say "But it's so perfect where it is!" Instead of smelling the bed, say "It smells delicious. You can tell right away that it's exactly what Drew's stew needs. I'm kidding you. It smells like sheets that need laundering." Instead of tasting the bed, say "It tastes like you're bored!"

The cap is in the trunk. The printed name of the cap is "diplomat's cap". The indefinite article is "your". The description is "This black cap is symbol of your occupation as Diplomat representing the Rat King. A little pin shining above the bill in front bears the insignia of his Highness." Understand "bill" or "black" or "hat" or "diplomat's cap" as the cap. The cap is wearable.

After examining the cap the first time:
	say "One thing that you, the player, probably didn't know, unless you're a rat too:[paragraph break]In rat culture, the word 'diplomat' means something very different from how human speakers of English understand the term. A rat diplomat is less like an ambassador, and more like a human American Navy SEAL, a human Norwegian [italic type]Marinejegerkommando,[roman type] or a human British International Person of Mystery.[paragraph break]Not that any of this matters much right now. Today is your day off. Let's stay focused on stew."

Instead of wearing the cap:
	Say "Nice. That looks nice. You go around like that and you'll have to beat them away with a stick. Everyone loves a uniform.";
	Now the player is wearing the cap.
	
The pin is part of the cap. Understand "symbol" or "silver" or "metal" or "insignia" as the pin. The description is "A stylized rat's face with a little crown on top, worked in some shiny silver metal. Probably not real silver." Instead of taking the pin, say "It really belongs in the cap, though. Otherwise the cap isn't a uniform; it's just a cap."

The potato is in the trunk. The initial appearance of the potato is "You can't help but smell a thick piece of potato in the vicinity." The description is "You've been nibbling at this potato for days, but there's still quite a bit left. It's exactly what Drew's stew needs." Instead of smelling the potato, say "Just a sniff gets your saliva glands going. This is going to be tasty." Instead of tasting the potato, say "Mmm. You're really going to enjoy this when the time comes..."

Instead of eating the potato the first time:
	Say "Are you sure? Drew probably wants it for the stew. But, I mean, if you're really hungry..."
	
Instead of eating the potato:
	Say "All right, it's your call. [paragraph break]Hey, that was pretty tasty, actually. The stew will be fine without it anyway.";
	remove the potato from play;
	increase progression by 1;
	now the player is sated.

Pilfering is an action applying to one thing. Understand "pilfer [something]" or "pilfer from [something]" as pilfering.

Carry out pilfering:
	If the noun is a container:
		If the noun is open:
			Say "Okay, idiot.";
			Repeat with item running through things contained by the noun:
				silently try taking item;
				say "You take [the item].";
		If the noun is closed:
			say "You've got to get it open first, idiot!";
			stop the action;
	Otherwise:
		if the noun is portable:
			Say "Okay, idiot.";
			silently try taking the noun;
			say "You take [the noun].";
		otherwise:
			say "You can't exactly pilfer [the noun]."


Part 7 - Steam Tunnel South

Steam Tunnel South is a room. "[if unvisited]All of a sudden the ceiling is too high and the lights are too bright. [paragraph break][end if]These tunnels were built by humans like a hundred years ago to maintain the pipes that move pressurized steam from their big fancy power plant to all their big fancy buildings. Even close to the floor, the air in here is uncomfortably warm: for humans, with their big fancy heads up near the ceilings, it's probably unbearable. The arched walls are made out of cracked, ancient bricks that would be fun to climb if they weren't lined with all those steam pipes. [paragraph break]There's more natural light in the leg of the tunnel north of here; to the east is a darker, less traveled section. The residential neighborhood is back west, and to the south is the palace of the Rat King."



Part 8 - Palace Gates


Palace Gates is a room. "[if unvisited]I should let you know right now: There's no food, or any stew-related material, over this way. Nothing critical is going on in this area. You can hang out if you want, but I don't want you to end up banging your head against the wall. [paragraph break][end if]This sparsely-decorated courtyard functions as a waiting area for those seeking audience with the Rat King. The doors to the palace, in the south, are closed. In the meantime, an impatient visitor might satisfy him or herself by instead having an audience with a nearby life-sized statue of the Rat King. [paragraph break]The path to the north leads back to the steam tunnels." Instead of smelling palace gates, say "Is someone wearing cologne?" Instead of listening to palace gates, say "The voice of the Rat King is the most recognizable and loudest of those you hear inside the palace. From the sound of it, his Highness is very busy being dissatisfied."

being clever is an action applying to nothing. Understand "bang your head against wall" or "bang your head against the wall" or "bang guard's head against wall" or "bang Zeke's head against wall" or "bang guard's head against the wall" or "bang Zeke's head against the wall" or "bang head against wall" or "bang my head against the wall" or "bang my head against wall" or "bang head against the wall" as being clever.

Carry out being clever:
	say "'Bang' isn't a verb I recognize, [italic type]Chuckles!!![roman type][paragraph break]"

The pdoor is scenery in palace gates. The printed name of the pdoor is "doors to the palace". The indefinite article is "the". Understand "door" or "doorjamb" or "doors" or "palace door" or "gate" or "gates" or "entry" as the pdoor. The description of the pdoor is "The mighty doors to the royal palace, windowless and grim. Your understanding is that the palace was built to be riot-proof; these doors certainly look more utilitarian than palatial. There is one nod to aesthetics in the entryway, though: The Royal Arms, carved in the stone over the doors." Instead of opening the pdoor, try going south. Instead of touching the pdoor, try going south. Instead of tasting the pdoor, try going south. Instead of smelling the pdoor, try going south. Instead of listening to the pdoor, try listening to palace gates.

The Royal Arms is part of the pdoor. Understand "arms" or "etching" or "royal crest" or "crest" or "shield" or "insignia" or "royal" or "symbol" or "carving" as the royal arms. The description is "The Royal Arms incorporates the royal insignia of a crown over a stylized rat's face; within a shield, however, the ears and nose of the rat instead suggest the eyes and beak of an owl. Not many people notice that, but it's probably one of the reasons that looking at the Royal Arms makes a lot of rats nervous. [paragraph break]Etched beneath the shield is a scroll emblazoned with the motto of the Rat King, written in the ancestral language of the rats."

The motto is part of the Royal Arms. Understand "scroll" or "etching" as the motto. The description is "You are embarrassed to recall that you can't read your own ancestral language."

The statue of the Rat King is scenery in palace gates. Understand "statue" or "rat king" or "rat" as the statue of the Rat King. The description is "This iron effigy, posed with scepter in claw, doesn't really look like his Highness. It might actually be a statue of a previous Rat King, or it might just be a lousy statue. The appearance of the rat doesn't matter that much; the important detail is the crown." Instead of tasting the statue, say "Eugh. Tastes like old blood. Because of the iron, I guess." Instead of tasting something that is part of the statue, try tasting the statue. Instead of smelling the statue, say "The never-appetizing scent of metal. It seems like metal always smells clean, but it always smells old." Instead of tasting something that is part of the statue, try tasting the statue. Instead of touching the statue, say "Cold. Cold like a broken promise." Instead of touching something that is part of the statue, try touching the statue.

The scepter is part of the statue of the Rat King. Understand "sceptre" or "rod" or "pole" or "stick" or "royal sceptre" or "royal scepter" as the scepter. The description of the scepter is "Smooth yet disconcertingly irregular, in accordance with the popular myth that the King's scepter is made from a human finger bone. You've seen the real scepter; it looks more like a human golf tee." Instead of taking the scepter, say "You can't take that! The Rat King is holding it, and it's welded to his hand." 

The crown is a part of the statue of the Rat King. The description of the crown is "This isn't the real crown, obviously, but it at least looks like the genuine article. Not that it's a particularly interesting design to being with--It falls within the bountifully-populated 'pointy golden circle' category of royal headwear." Instead of taking the crown, say "Brilliant! Why not take the crown for yourself, and, with the authority it grants its wearer, rule over your fellow rats for the rest of your days? [paragraph break]Oh, it's welded to the statue's head. Nice try, I guess."

Instead of going south in Palace Gates while Zeke is in Palace Gates, say "[one of]As you reach for the door, you hear a sound like heavy machinery breaking down. It's the Rat King, screaming at some poor son of a gun. He must be in a worse mood than usual.[paragraph break]You look cautiously over at Zeke.[paragraph break]'How are you enjoying your day off?' he asks[or]When you try to go in that palace, you're telling me you don't want to play this game about making a stew, that you want to [italic type]go to work[roman type] and [italic type]do your job[roman type] instead. I won't let you[stopping]."

Instead of going south in Palace Gates while Palace Guard is in Palace Gates, say "[one of]As you reach for the door, you hear a sound like heavy machinery breaking down. It's the Rat King, screaming at some poor son of a gun. He must be in a worse mood than usual.[paragraph break]You look cautiously over at the guard.[paragraph break]'How are you enjoying your day off?' he asks[or]When you try to go in that palace, you're telling me you don't want to play this game about making a stew, that you want to [italic type]go to work[roman type] and [italic type]do your job[roman type] instead. I won't let you[stopping]."

Section 1 - Zeke

Barracks is a room. Zeke is a man in Barracks.

The palace guard is a man in Palace Gates. Understand "guard" or "rat" or "zeke" as the palace guard.

Understand "him" as the palace guard. Understand "him" as zeke.

The initial appearance of the Palace guard is "One of the palace guards is here, leaning against the doorjamb." Instead of smelling the palace guard, say "He seems to be wearing cologne. Who is he trying to impress?" Instead of tasting the palace guard, say "Zeke uncomfortably endures your licking, and for your trouble you get a palateful of gross cologne. Congratulations."

Instead of examining the palace guard:
	Say "Hold on a second... It's Zeke! From school!";
	Remove the palace guard from play;
	Now Zeke is in Palace Gates.
	
Instead of asking the Palace guard about "name":
	Say "'It's Zeke. Remember? From school?' [paragraph break]Oh yeah. You thought you knew that guy from somewhere. [paragraph break]Awkward.";
	Remove the Palace guard from play;
	Now Zeke is in Palace Gates.

The description of Zeke is "Zeke, a guy you kind of know from school, stands/slouches at his post here at the entrance to the royal palace. He seems a little bored. Slung at his waist is a cudgel, and on top of his head is a blue cap, the uniform of a palace guard." The initial appearance of Zeke is "Zeke is here, leaning against the doorjamb." Understand "guard" or "rat" or "palace guard" as Zeke.

The cudgel is an object worn by the palace guard. Understand "stick" or "baton" or "truncheon" or "nightstick" or "bludgeon" or "club" or "billy club" or "bat" as the cudgel. The description of the cudgel is "Black and mean-looking. You wouldn't want to get hit by one. (You know this for sure, because you got hit by one once, and you didn't enjoy it.)" Instead of taking the cudgel, say "But it looks so nice on him."

The zcudgel is an object worn by Zeke. The printed name is "cudgel". Understand "cudgel" or "stick" or "baton" or "truncheon" or "nightstick" or "bludgeon" or "club" or "billy club" or "bat" as the zcudgel. The description of the zcudgel is "Black and mean-looking. You wouldn't want to get hit by one. (You know this for sure, because you got hit by one once, and you didn't enjoy it.)" Instead of taking the zcudgel, say "But it looks so nice on him."

The blue cap is an object worn by the palace guard. understand "cap" or "blue" or "hat" or "bill" as the blue cap. The description is "Like your diplomat's cap, but blue. The royal insignia is pinned above the bill." Instead of taking the blue cap, say "You already have one. A black one. It's way cooler."

The blue insignia is part of the blue cap. The printed name is "pin". Understand "pin" or "symbol" or "silver" or "metal" or "insignia" as the pin. The description is "A stylized rat's face with a little crown on top, worked in some shiny silver metal. Probably not real silver." Instead of taking the blue insignia, say "It really belongs in the cap, though. Otherwise the cap isn't a uniform; it's just a cap."

The bblue cap is an object worn by Zeke. The printed name is "blue cap". Understand "blue cap" or "cap" or "blue" or "hat" or "bill" as the bblue cap. The description is "Like your diplomat's cap, but blue. The royal insignia is pinned above the bill." Instead of taking the bblue cap, say "You already have one. A black one. It's way cooler."

The bblue insignia is part of the bblue cap. The printed name is "pin". Understand "pin" or "symbol" or "silver" or "metal" or "insignia" as the bblue insignia. The description is "A stylized rat's face with a little crown on top, worked in some shiny silver metal. Probably not real silver." Instead of taking the bblue insignia, say "It really belongs in the cap, though. Otherwise the cap isn't a uniform; it's just a cap."

Instead of asking Zeke about "name", say "'It's Zeke. Remember? From school?"

After asking the palace guard about a topic listed in the Table of Zeke's Answers, say "[answer entry][paragraph break]".

After asking Zeke about a topic listed in the Table of Zeke's Answers, say "[answer entry][paragraph break]".

Instead of giving or showing the cap to Zeke, say "'Yeah, yeah. I have one of my own, see?'"

Instead of giving or showing something to Zeke, say "'That does look nice, but I don't need it right now.'"

Table of Zeke's Answers
Topic	Answer
"life"	"'Well, as you can see, there's not much going on in mine.'"
"crown"	"'I hear he doesn't even take it off while he's sleeping.'"
"meeting"	"'My guess is, they're negotiating some sort of policy. But don't quote me on that.'"
"cap"	"'I guess I like mine just fine. Blue is a nice color.'"
"caps"	"'I guess I like mine just fine. Blue is a nice color.'"
"humans"	"'You know, I've never had human... I wonder what it tastes like.'"
"humans"	"'You know, I've never had human... I wonder what it tastes like.'"
"Zeke"	"'Can't complain.'"
"Him"	"'Can't complain.'"
"Himself"	"'Can't complain.'"
"me"	"'To be honest, I'm a little jealous. You're the one who gets to go out on diplomatic missions.'"
"myself"	"'To be honest, I'm a little jealous. You're the one who gets to go out on diplomatic missions.'"
"diplomat"	"'Unfortunately, diplomacy isn't going to help with the boss's situation. You're better off putting your talents to use somewhere else.'"
"diplomacy"	"'Unfortunately, diplomacy isn't going to help with the boss's situation. You're better off putting your talents to use somewhere else.'"
"negotiation"	"'I don't even know what they're negotiating in there. But I'm not expecting it to stop anytime soon. It's nothing you have to worry about, though.'"
"negotiations"	"'I don't even know what they're negotiating in there. But I'm not expecting it to stop anytime soon. It's nothing you have to worry about, though.'"
"Drew"	"'Yeah, he and I aren't exactly friends. I mean, we move in different social circles.'"
"Fran"	"'Oh, from school! I saw her the other day, actually. She looked busy, though, so I didn't talk to her or anything.'"
"king"	"'Yeah, he's in one of his moods today. As is usually the case when he has to be at a meeting. But you don't need to worry about that.'"
"Rat King"	"'Yeah, he's in one of his moods today. As is usually the case when he has to be at a meeting. But you don't need to worry about that.'"
"boss"	"'Yeah, he's in one of his moods today. As is usually the case when he has to be at a meeting. But you don't need to worry about that.'"
"palace"	"'I don't get to see the insides that often. It's not as pretty as you'd expect, though, is it?'"
"door"	"'It's gonna stay shut for a while, I'm afraid. You know how much the boss enjoys negotiating. Besides, isn't it your day off? Go enjoy yourself.'"
"statue"	"'You probably don't realize this, but I have to stare at that thing all day. I keep thinking it's going to look over at me and tell me to stop slouching.'"
"tunnel"	"'Well, you should see [italic type]my[roman type] place.'"
"here"	"'Well, you should see [italic type]my[roman type] place.'"
"tunnels"	"'Well, you should see [italic type]my[roman type] place.'"
"steam tunnel"	"'It's a good place to go for a walk, just to be alone, you know? Not that I'm not alone enough of the time, doing my job out here.'"
"steam tunnels"	"'It's a good place to go for a walk, just to be alone, you know? Not that I'm not alone enough of the time, doing my job out here.'"
"Miko"	"'You mean Fran's roach? I think I saw her over in the steam tunnels.'"
"school"	"'Yeah, those were the days, right? Remember that one time, when... No, that wasn't you. Did we have any classes together?'"
"class"	"'Yeah, those were the days, right? Remember that one time, when... No, that wasn't you. Did we have any classes together?'"
"roach"	"'One thing I know about roaches: They're slippery, but if you keep at it, you can catch one. You just have to outlast it.'"
"roaches"	"'One thing I know about roaches: They're slippery, but if you keep at it, you can catch one. You just have to outlast it.'"
"cockroach"	"'One thing I know about roaches: They're slippery, but if you keep at it, you can catch one. You just have to outlast it.'"
"cockroaches"	"'One thing I know about roaches: They're slippery, but if you keep at it, you can catch one. You just have to outlast it.'"
"rat"	"'Yeah, go rats. Civic pride, right? I guess?'"
"rats"	"'Yeah, go rats. Civic pride, right? I guess?'"
"stew"	"'Never met him.'"
"recipe"	"'I actually left my cookbook at home, if you can believe it.'"
"cookbook"	"'It's at home.'"
"home"	"Yeah. That's where I go when I'm not here.'"
"ingredient"	"'My favorite ingredient is probably... cayenne pepper.'"
"pepper"	"'Cayenne pepper is the best pepper.'"
"cayenne"	"'Cayenne pepper is the best pepper.'"
"cayenne pepper"	"'[italic type]Yes. I know. It is the best pepper[roman type].'"
"guard"	"'It's not exciting, that's for sure. But it pays the bills.'"
"guarding"	"'It's not exciting, that's for sure. But it pays the bills.'"
"guard duty"	"'It's not exciting, that's for sure. But it pays the bills.'"


After asking Zeke about something, say "'I don't really know for sure... You should ask someone else about that.'"

After asking the palace guard about something, say "'I don't really know for sure... You should ask someone else about that.'"

ZPatience is a number that varies. ZPatience is 0.

Every turn while in Palace Gates:
	if ZPatience is less than 30:
		increase ZPatience by 1;
	if ZPatience is 9:
		if Zeke is in Palace gates:
			say "Zeke coughs. 'You know, you're not the one on guard duty. You don't have to hang out here. There really isn't anything for you to do here. Not that I don't appreciate the company? But you must have better things to do.";
		otherwise:
			say "The guard coughs. 'You know, you're not the one on guard duty. You don't have to hang out here. There really isn't anything for you to do here. Not that I don't appreciate the company? But you must have better things to do.'";
	if ZPatience is 18:
		if Zeke is in Palace gates:
			say "Zeke coughs again and repeats his speech. 'You know, you're not the one on guard duty. You don't have to hang out here. There really isn't anything for you to do here. Not that I don't appreciate the company? But you must have better things to do.";
		otherwise:
			say "The guard coughs again and repeats his speech. 'You know, you're not the one on guard duty. You don't have to hang out here. There really isn't anything for you to do here. Not that I don't appreciate the company? But you must have better things to do.'";
	if ZPatience is 27:
		say "'Seriously, man, don't you have a stew to build or something?'".




Part 9 - Sidewalk Grate


Sidewalk Grate is a room. The printed name of Sidewalk Grate is "Beneath a Grate in the Sidewalk". The description is "[if unvisited]You hear a snatch of conversation from the world above: 'No, [italic type]you[roman type] hang up!' [paragraph break][end if]It's about lunch time, and a few rays of sunlight fall directly through the access grate above you. A ladder underneath conveniently allows the climber to avoid contact with the steam pipes. [paragraph break]The tunnels continue to the south and northeast." 

The ladder is scenery in sidewalk grate. The ladder is a supporter. "Rough bands of bent steel stick out of the wall. Obviously this ladder was built for use by humans, but that's never stopped you before." Instead of taking the ladder, say "That ladder needs to stay there so people can climb up to the grate! Also, it's stuck to the wall."

Instead of climbing the ladder:
	move the player to the noun, without printing a room description;
	say "You navigate the human ladder without difficulty. Who needs thumbs?".

Before climbing the ladder:
	if the ladder supports the player:
		try getting off the ladder instead.

instead of going up in sidewalk grate:
	if the player is on the ladder:
		try opening the applegrate;
	otherwise:
		move the player to the ladder, without printing a room description;
		Say "You navigate the human ladder without difficulty. Who needs thumbs?".

Understand "climb off" as exiting.
			
Before going down in sidewalk grate:
	if the ladder supports the player:
		try getting off the ladder instead.

The sky is scenery in sidewalk grate. "Disconcertingly blue."

The applegrate is scenery in sidewalk grate.The printed name of applegrate is "grate". Understand "grate" or "vent" or "door" or or "access grate" or "panel" as the applegrate. The description of the applegrate is "A horizontal iron door is fitted into the grate, for the use of human maintenance staff. Sometimes they forget to lock the grates after they're done poking around in the tunnel. [paragraph break]A welcome current of cool air flows down from the grate onto your face. All you can see through the holes are little patches of sky."

Instead of looking in the applegrate, try examining the applegrate.

After examining the applegrate the first time:
	say "One of the holes is obstructed by--Is that a piece of an apple? Yes! Nice! Go get that piece of apple!";
	now the apple slice is in sidewalk grate.

Before opening the applegrate:
	If the ladder holds the player, say "You give the door a good push, but it seems to be locked from the outside." instead;
	Otherwise say "But you're way down there, and it's way up there!" instead.

The apple slice is an object in barracks. The initial appearance of the apple slice is "A slice of apple is wedged in a hole in the grate." The description of the apple slice is "A good-sized chunk of green-skinned apple, its flesh beginning to brown around the edges. Your mouth waters. This belongs in a stew, no question." Instead of tasting the apple slice, say "Oh, that's the stuff. It's almost too sweet." Instead of smelling the apple slice, say "So sweet, so juicy, you can almost taste it. Hold on, you [italic type]are[roman type] tasting it. Try to control yourself."

Check for taking the apple slice:
	if the apple slice is not handled:
		if the ladder does not support the player:
			say "That's what I said, but it's way up there in the grate, and you're way down there on the floor.";
			stop the action.

Instead of eating the apple slice the first time:
	Say "Are you sure? Drew probably wants it for the stew. But, I mean, if you're really hungry..."
	
Instead of eating the apple:
	Say "All right, it's your call. [paragraph break]Hey, that was pretty tasty. The stew will be fine without it anyway.";
	remove the apple slice from play;
	increase progression by 1;
	now the player is sated.

Instead of smelling in sidewalk grate:
	If the apple slice is not handled:
		say "Wafting on the fresh air from above is the scent of something sweet.";
	otherwise:
		say "The fresh air does little to diminish the pervasive odor of rust."

Part 10 - Steam Tunnel North

Steam Tunnel North is a room. The description is "[if unvisited]You hear a muffled thump from far above. An ominous feeling comes over you. [paragraph break][end if]Here the tunnel curves away to the southeast and southwest. A tall ladder leads up and out of sight."

The northladder is scenery in steam tunnel north. The northladder is either unclumb or clumb. The northladder is unclumb. Understand "ladder" or "tall ladder" as northladder. The description is "Rough bands of bent steel stick out of the wall. Obviously this ladder was built for use by humans, but that's never stopped you before." Instead of climbing the northladder, try going up. Instead of taking the northladder, say "That ladder needs to stay there so people can climb up and down it! Also, it's stuck in the wall."

Before going up in Steam Tunnel North the first time, say "The ladder wasn't designed with individuals of your size in mind, and each rung is its own struggle to climb. Usually you don't even bother with ladders this tall. You aren't a quitter, though... [paragraph break]".
	
Before going up in Steam Tunnel North while the northladder is clumb, say "Now that you've done it once, climbing the ladder again is a piece of cake. Still painful though.[paragraph break]".

Part 11 - Grate Under Hill

Hill Grate is a room. The printed name of Hill Grate is "Beneath a Grate on the Hill". The description is "[if unvisited]That wasn't so bad! Although all of your muscles now ache horribly.[paragraph break][end if]It occurs to you that this room constitutes a liminal space: above, the bright and open domain of humans; below, your native world of claustrophobic tunnels. And you in between, an ambassador of the darkness. [paragraph break]You can go up through the grate if you want, or you can go down the ladder."

The gladder is scenery in hill grate. Understand "ladder" as the gladder. The description of the gladder is "It's a long way down."

Instead of going down in hill grate the first time, say "Now that you think of it, climbing all the way down that ladder is probably a lot more difficult and dangerous than climbing up. You should pause here for a moment, consider the pros and cons." 

Instead of going down in hill grate while the northladder is unclumb:
	say "Okay, it's your funeral. [paragraph break]... [paragraph break]Well, it looks like you made it in one piece. Congratulations.";
	now the northladder is clumb;
	now the player is in steam tunnel north.

The ugrate is scenery in hill grate. Understand "grate" or "vent" or "door" or "access" or "access grate" or "access vent" as the ugrate. The description of the ugrate is "It looks like this grate is unlocked. You can see a sliver of light where the door is slightly ajar." Instead of opening the ugrate, say "It's already open wide enough for your willowy frame." Instead of closing the ugrate, say "There's no handle inside, so I can't figure out how you plan to do that from in here." Instead of entering the ugrate, try going up.

Part 12 - Sunny Hill

Sunny Hill is a room. Instead of going up in Sunny Hill, say "Up the tree? You're not a [italic type]cat[roman type]." Instead of going nowhere in Sunny Hill, say "Broad daylight doesn't really flatter you. Better to head back underground." The description of Sunny Hill is "[if unvisited]Fresh air! The sun on your face! How do humans endure this all day long? [paragraph break][end if]This particular steam tunnel grate is on top of a grass-covered hill, near a pitiful little spit of a tree. Around you on all sides you can see the distressingly clean, intolerably bright world of the surface. [paragraph break]You can return to the comfort of the steam tunnels via the access vent beneath you." Instead of listening to Sunny Hill, say "The thrumming, beeping, chattering noise of human society, no longer muffled comfortably by a layer of earth." Instead of smelling Sunny Hill, say "Too much grass, not enough dirt."

The sgrate is scenery in sunny hill. The printed name of the sgrate is "grate". Understand "vent" or "access vent" or "access grate" or "door" as the sgrate. The description is "Someone forgot to lock up this particular tunnel access grate. The rusty horizontal door is ever so slightly open." Instead of opening the sgrate, say "It's already open.". Instead of closing the sgrate, say "If you do that, how are you going to get back inside?". Instead of smelling the sgrate, say "The air rising from the grate carries on it the smells of heat and rust." Instead of entering the sgrate, try going down.

The sun is scenery in sunny hill. The description of the sun is "Your least favorite star, by a wide margin."

The air is scenery in sunny hill. Understand "wind" or "breeze" as the air. The description of the air is "Air is invisible." Instead of smelling the air, say "Wafting gently on the breeze is the odor of millions of humans sweating all over everything."

The grass is scenery in sunny hill. "At least it's high enough for you to be sneaky in, but it still stinks like someone's been mowing it." Instead of smelling the grass, say "Some human had to go and cut this grass, and the normally inoffensive odor of grass is overpowering now."

The shill is scenery in sunny hill. Understand "hill" as the hill. "What? It's a hill." Instead of smelling the hill, try smelling the grass.

The tree is scenery in sunny hill. "It does supply some shade, but it looks really pathetic up here on this hill all by itself." Instead of smelling the tree, say "There are much more interesting things to smell than this stupid tree." Instead of tasting the tree, say "Not very appetizing." Instead of taking the tree, say "Your burrow could use some green, but it wouldn't get any sunlight." Instead of climbing the tree, try going up.

A bone is in barracks. The initial appearance of the bone is "A chewed-up chicken bone lies in the grass, unattended." The description is "There's still plenty of meat on that bone! You take that home, throw it in a pot, add some broth, a potato? Baby, you've got a stew going!" Instead of tasting the bone, say "Oh, that's the stuff." Instead of smelling the bone, say "A fragment, a mere whiff, of the glorious smell of that styrofoam box."

Instead of eating the bone the first time:
	Say "Are you sure? Drew probably wants it for the stew. But, I mean, if you're really hungry..."
	
Instead of eating the bone:
	Say "All right, it's your call. [paragraph break]Hey, that was pretty tasty, actually. The stew will be fine without it anyway.";
	remove the bone from play;
	increase progression by 1;
	now the player is sated.

Every turn while in sunny hill:
	if the human is in sunny hill:
		if a random chance of 1 in 6 succeeds:
			say "The human idly flicks her hair over her shoulder."

The human is a woman in sunny hill. Understand "Alex" or "woman" or "girl" or "lady" or "person" as the human. The initial appearance of the human is "As if just being on the surface weren't enough, there's a human here, eating her lunch in the shade of the tree." The description is "She's a human. Her face is flat, arranged in the bizarre manner of human faces; her revoltingly orange hair is draped over her otherwise nude shoulders in unnatural curls; and her hands are huge and wide. [paragraph break]But, still more offensive than all this, she is using those hands to eat delicious-looking fried chicken out of a styrofoam container, biting and sucking and chewing each piece with that air of superiority that all humans always have." Instead of smelling the human, say "The cloying fruitiness of her shampoo is mitigated slightly by the odor of grease that cascades from her lips and her hands and her box full of chicken." Instead of climbing the human, try touching the human. Instead of eating the human, try tasting the human. Instead of taking the human, say "Historically, for rats anyway, holding humans for ransom has not been a successful enterprise."

Instead of annoying the human, say "That is an excellent idea. But [italic type]how?[roman type][paragraph break]".

The hands are part of the human. Understand "hand" or "thumb" or "thumbs" or "her thumb" or "her thumbs" or "her hands" or "her hand" as the hands. The description of the hands is "As ugly as they are, it must be nice to have thumbs." Instead of attacking the hands, try taking the hands. Instead of of touching the hands, try taking the hands. Instead of taking the hands, say "The human cleverly keeps her hands out of your reach."

The face is part of the human. Understand "head" or "her head" or "her face" as the face. The description of the face is "It's so goofy-looking, especially with all that hair."

The hair is part of the human. Understand "red hair" or "red" or "her hair" as the hair. The description of the hair is "Red and curly. It shines like it's wet, but it moves like it's rigid. Unsettling." Instead of smelling the hair, say "Besides smelling like plastic, it also smells like way too many different fruits. Is this supposed to attract insects?'" Instead of touching the hair, try touching the human. Instead of taking the hair, say "It looks like it's stuck pretty securely to her head. But maybe that gives you an idea..." Instead of tasting the hair, try touching the human.

Instead of pulling the hair the first time:
	Say "You disappear from the human's vision, slinking through the grass like a viper. Now you are behind her, melting into the shadow of the tree, and now her hair is in front of you, splayed across her back for you to abuse according to your whim. You give it a good yank. [paragraph break]She screeches, and whirls around to smack you, but you are already safe and sound back at the steam grate. [paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services! [roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.

Instead of attacking the hair the first time:
	Say "You disappear from the human's vision, slinking through the grass like a viper. Now you are behind her, melting into the shadow of the tree, and now her hair is in front of you, splayed across her back for you to abuse according to your whim. You give it a good chomp. [paragraph break]She screeches, and whirls around to smack you, but you are already safe and sound back at the steam grate. [paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services! [roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.
		
Instead of attacking the hair, say "Oh, but to execute that maneuver again would only cheapen it."

The human carries a box. Understand "lunch" or "styrofoam container" or "styrofoam" or "container" as the box. The box is an open transparent container. Instead of taking the box, try touching the box. Instead of inserting something into the box, try touching the box. Instead of removing something from the box, try touching the box. Instead of opening the box, try touching the box. Instead of closing the box, try touching the box. Instead of tasting the box, try touching the box. The description of the box is "It's one of those styrofoam boxes that humans always use to store the leftovers they throw out. This one is daubed in ketchup and overflowing with french fries and fried chicken." Instead of smelling the box, try smelling the chicken.

Instead of touching the box the first time:
	Say "You move in on the chicken, mouth watering, but that human bats you away. 'Mine,' she snaps. [paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services![roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.
		
Instead of touching the box, say "You won't be able to get near it now. She's got her eye on you."

The ketchup is part of the box. The description is "This human seems to get ketchup all over everything she eats. Evidently the two of you have at least one thing in common." Instead of smelling the ketchup, say "You can barely smell the vinegar of the ketchup between that human's stink and her chicken's greasy perfume." Instead of taking the ketchup, try touching the box. Instead of tasting the ketchup, try touching the box.

The chicken is part of the box. Understand "grease" or "fried" or "food" or "fried chicken" as the chicken. The description is "There's so much of it in that box, and it's all so [italic type]greasy.[roman type] And it's all being wasted on this human." Instead of smelling the chicken, say "This is a complicated smell. There's the chicken flesh itself, which drips with an odor that recalls all at once the agony of pursuit, the thrill of capture, and the purity of possession. There are spices and herbs, each of which calls to you from a different distant forest, or field, or swamp.[paragraph break]But wreathed around all this is the scent of hot grease, announcing its decadence to the world, defiling the body fried in it with the same lusciousness that defiles the body that consumes it. Oh, if only that body could be yours." Instead of taking the chicken, try touching the box. Instead of tasting the chicken, try touching the box.

The fries are part of the box. Understand "french fries" or "fried" or "food" as the fries. The description is "Fat crinkle-cut french fries, little sticks of heaven." Instead of smelling the fries, say "You can barely detect the smell of potato between the stench of the human and the singular fragrance of greasy chicken." Instead of taking the fries, try touching the box. Instead of tasting the fries, try touching the box.

Patience is a number that varies. Patience is 4.

Instead of tasting the human the first time:
	say "You start to lick her leg, but before you can get a good taste, she screams and starts kicking violently, so you back off. [paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services![roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.

Instead of tasting the human, say "The last time you tried that, you almost got your head knocked off. I'm going to prevent you from trying it again."

Instead of touching the human the first time:
	say "She recoils from your touch. 'Get! Get away!' she shrieks. [paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services![roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.
		
Instead of touching the human, say "You can't bring yourself to bring another claw near her. She's too gross."

Instead of kissing the human, say "The very thought repulses you."

Instead of attacking the human for the first time:
	say "Her fat calf is sitting there just begging to be bitten. So that's what you do. [paragraph break]'Ow! What is wrong with you? Do you have rabies?' [paragraph break]Again with the rabies. Humans love bringing that one up. So insensitive. [paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services![roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.

Instead of attacking the human, say "Yeah, no thanks. You don't need to hear another murophobic crack about rabies."

After asking the human about a topic listed in the Table of Human Answers, say "[answer entry][paragraph break]".

After telling the human about a topic listed in the Table of Human Answers, say "[answer entry][paragraph break]".

Table of Human Answers
topic	answer
"life"	"'It's pretty great, I've got to say! I'm [italic type]really[roman type] enjoying this chicken.'"
"human"	"'An interesting thing happened to me today! I was sitting outside, having a delicious lunch, and then a filthy rodent came up to me and started trying to ruin my day! How about that.'"
"humans"	"'I don't know what they teach you in your rat schools, but humans are actually the dominant species on this planet. You can look it up.'"
"her"	"'An interesting thing happened to me today! I was sitting outside, having a delicious lunch, and then a filthy rodent came up to me and started trying to ruin my day! How about that.'"
"herself"	"'An interesting thing happened to me today! I was sitting outside, having a delicious lunch, and then a filthy rodent came up to me and started trying to ruin my day! How about that.'"
"Alex"	"'An interesting thing happened to me today! I was sitting outside, having a delicious lunch, and then a filthy rodent came up to me and started trying to ruin my day! How about that.'"
"name"	"'It's Alex. What's it to you?'"
"vermin"	"'It means pests. Undesirable animal infestations. Like rats. Hey, like you!"
"rodent"	"'I happen to think you're all garbage-munching, filth-encrusted, beady-eyed evolutionary mistakes, but that's just my opinion.'"
"rodents"	"'I happen to think you're all garbage-munching, filth-encrusted, beady-eyed evolutionary mistakes, but that's just my opinion.'"
"rat"	"'I happen to think you're all garbage-munching, filth-encrusted, beady-eyed evolutionary mistakes, but that's just my opinion.'"
"rats"	"'I happen to think you're all garbage-munching, filth-encrusted, beady-eyed evolutionary mistakes, but that's just my opinion.'"
"me"	"'I guess I don't know you that well. But you're not making much of a first impression.'"
"myself"	"'I guess I don't know you that well. But you're not making much of a first impression.'"
"hair"	"'I just had it done; thanks for noticing. I [italic type]would[roman type] give you the name of my stylist, but I'm afraid you'd scare off all her customers.'"
"stew"	"'You're making a stew? I didn't know rats ate real food. What are you putting in it? Feces?'"
"food"	"'Sorry. I don't share my food with vermin.'"
"chicken"	"'Sorry. I don't share my food with vermin.'"
"fries"	"'Sorry. I don't share my food with vermin.'"
"fried chicken"	"'Sorry. I don't share my food with vermin.'"
"lunch"	"'Sorry. I don't share my food with vermin.'"
"ketchup"	"'Sure, maybe you can lick some off of this box when I'm done.'"
"grease"	"'Sure, maybe you can lick some off of this box when I'm done.'"
"tunnel"	"'Speaking of, why don't you go back there where you belong?'"
"tunnels"	"'Speaking of, why don't you go back there where you belong?'"
"steam tunnel"	"'Speaking of, why don't you go back there where you belong?'"
"steam tunnels"	"'Speaking of, why don't you go back there where you belong?'"
"bone"	"'Bones? You want the bones? And what are you going to give me in exchange, some used gum?'"
"bones"	"'Bones? You want the bones? And what are you going to give me in exchange, some used gum?'"
"roach"	"'Oh, gross.'"
"cockroach"	"'Oh, gross.'"
"roaches"	"'Oh, gross.'"
"cockroaches"	"'Oh, gross.'"
"worm"	"'I guess I don't have any strong feelings about worms.'"
"worms"	"'I guess I don't have any strong feelings about worms.'"

Instead of showing the roach to the human, try giving the roach to the human.

Instead of telling the human about "feces", try asking the human about "feces".

Instead of asking the human about "feces" the first time:
	say "'Do you [italic type]mind?[roman type] I'm trying to enjoy a meal here.' [paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services![roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.
		
Instead of asking the human about "feces", say "She studiously ignores you."

Instead of telling the human about "boyfriend", try asking the human about "boyfriend".

Instead of asking the human about "boyfriend" the first time:
	say "'What about him? Did he send you here? I tell him I need space, and he sends a rodent to check up on me. You know what? [italic type]He's[roman type] a rodent. He's a slimy, peabrained, beady-eyed rodent, but I'd still take him over you any day of the week. Don't tell him I said that.' [paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services![roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.
		
Instead of asking human about "boyfriend", say "'This is the last time I let him buy me chicken.'"

Instead of giving the roach to the human the first time:
	say "She recoils. 'Get that thing away from me!' she shouts, and she pulls her lunch up to her chest to defend it.[paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services![roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.

Instead of giving the roach to the human, say "She acted like she didn't want it, though. Maybe she already has one?"

Instead of showing the worm to the human, try giving the worm to the human. Instead of giving the worm to the human the first time, say "She considers the worm for a second. When she finally responds, she says 'No thanks,' and turns her attention back to her chicken. [paragraph break]Well, it was worth a shot." Instead of giving the worm to the human, say "'No, really, I'm fine without it.'"

Instead of giving or showing something to the human, say "She scoffs. 'Am I supposed to be impressed?'"

Instead of yelling at the human in sunny hill, try yelling.

Instead of yelling in sunny hill while the human is not in sunny hill, say "But there's nobody here to yell at."

Instead of yelling in sunny hill while the human is in sunny hill the first time:
	say "The human covers her ears as you scream at the top of your lungs for a few seconds.[paragraph break]When you run out of breath, though, she responds by shrieking at an even higher pitch for even longer, like the harpy she is. [paragraph break]'How about [italic type]that?[roman type]' she smirks, but now her face is red and her chest is heaving. [paragraph break]";
	decrease patience by 1;
	if patience is 3:
		say "'Don't be rude.'";
	if patience is 2:
		say "'Can't a girl eat her lunch out here in peace?'";
	if patience is 1:
		say "'Are you [italic type]trying[roman type] to annoy me?'";
	if patience is 0:
		say "The human starts collecting her things. 'If you're going to keep pestering me, I'll just eat my lunch somewhere else,' she grumbles. 'And just so you know, I'm going to call campus services and tell them to lock this steam vent up.' Oh, [italic type]no![roman type] Not [italic type]campus services![roman type][paragraph break]Presently, the odious human and her lunch are gone. But hold on! Looks like she left a bone here on the ground.";
		now the bone is in sunny hill;
		remove the human from play.

Instead of yelling in sunny hill while the human is in sunny hill, say "You don't have the pipes to compete with this harridan."

After asking the human about something, say "She either didn't hear you, or she's blowing you off."

After telling the human about something, say "She either didn't hear you, or she's blowing you off."

Part 13 - Steam Tunnel Depths

Steam Tunnel Depths is a room. "[if unvisited]You hear a faint 'plink' as a drop of condensation somewhere on the other end of the tunnel falls to the floor. [paragraph break][end if]This is the darkest corner of the tunnels. It seems to have been forgotten even by the maintenance staff. The floor is thickly matted with dead and rotting leaves. [paragraph break]Better-traveled stretches of tunnel lie to the north and west." 

Every turn when in steam tunnel depths:
	if a random chance of 1 in 5 succeeds:
		If the worm is in barracks:
			say "You hear something moving under the leaves."

After listening to steam tunnel depths:
	if a random chance of 1 in 5 succeeds:
		if the worm is in barracks:
			say "You hear something moving under the leaves."

Instead of smelling steam tunnel depths:
	If the worm is in barracks:
		say "The smell of decay is all up and down this tunnel, but beneath that you can detect the faint odor of something living.";
	Otherwise:
		say "The smell of decay is all up and down this tunnel, like lice on a human."

The leaves are scenery in steam tunnel depths. The description of the leaves is "A thick, wet, clumpy mass of plant matter, months old and still not decomposed completely."  Instead of tasting the leaves, say "Slimy. [paragraph break]Eugh. More slimy than you can handle." Instead of taking the leaves, say "They're all stuck together and slimy, like a big slippery carpet over the whole floor. And they wouldn't do much for your stew anyway." Instead of searching the leaves, try pushing the leaves. Instead of pulling the leaves, try pushing the leaves. Instead of digging in steam tunnel depths, try pushing the leaves. Instead of digging at the leaves, try pushing the leaves. Instead of looking under the leaves, try pushing the leaves.

Instead of smelling the leaves:
	if the worm is in barracks:
		say "Although rotting leaves do a lot to obscure other smells, careful sniffing reveals that there's something else under your feet.";
	Otherwise:
		say "Just a bunch of rotting leaves.".

Instead of pushing the leaves the first time:
	Say "Wet leaves aren't your favorite material to dig through, but your instincts lead you straight for the pulsing, wiggling thing deep underneath the layers of leaves: A fat worm.";
	now the worm is in steam tunnel depths.
	
Instead of pushing the leaves, say "More digging and searching only reveals a layer of better-composted leaves. You should come back here when you get around to planting that herb garden."

The worm is an object in barracks. The initial appearance of the worm is "A worm lies on the floor, wriggling desperately." The description of the worm is "It's a thick one, and it undulates hypnotically. You've never had worm, but you've heard it's juicy. Maybe it's just what that stew needs." Instead of smelling the worm, say "Curiously, it smells mostly of blood. Is that because these things have so many hearts?" Instead of tasting the worm, say "Oh, that's... exotic. Not bad, though." 

Instead of eating the worm the first time:
	Say "Are you sure? Drew probably wants it for the stew. But, I mean, if you're really hungry..."
	
Instead of eating the worm:
	Say "All right, it's your call. [paragraph break]Hey, that was pretty tasty, actually. The stew will be fine without it anyway.";
	remove the worm from play;
	increase progression by 1;
	now the player is sated.



Part 14 - Steam Tunnel Fork

Steam Fork is a room. The printed name of Steam Fork is "Fork in the Steam Tunnels". [9:05 by Adam Cadre, 2000? end game by going east]

The description of Steam Fork is "[if unvisited]A lightbulb in the distance dims for a moment, then flares up again. [paragraph break][end if]This well-traveled juncture is where the local steam tunnel system links up with the main network, eventually leading back to the power plant. [paragraph break]Your usual route back home is to the northwest; a disused 'shortcut' is south of here. The eastern fork leads to the main tunnel system." 

The hfork is scenery in Steam Fork. Understand "fork" or "fork in the tunnel" or "eastern fork" as the hfork. The description is "It's not a literal fork. There isn't a dining implement here or anything like that." Instead of taking the hfork, try examining the fork. Instead of tasting steam fork, try tasting hfork. Instead of tasting hfork, try examining hfork. 

Instead of going east in Steam Fork the first time, say "The only reason to leave this neighborhood would be if you were giving up on helping Drew put that stew together. Have you ever played [italic type]9:05[roman type] by Adam Cadre (published in 2000)? You know how in that game, if you didn't stop at the office building, you could just get on the freeway and drive out of town and 'vanish without a trace' and that's the end? And you're like 'What, was that the game?' [paragraph break]That's basically what will happen if you go east and head out for the main tunnel system here. You can go ahead and do it, if you want; I'm not going to stop you. I just thought I should warn you first."

Instead of going east in Steam Fork:
	say "Yeah, let Drew make his own stew.";
	end the story saying "You have better things to do."
	
Instead of going east in Steam Fork during Stewmageddon:
	if the score is greater than 0:
		say "Okay, if that's what you want to do. [paragraph break]Drew has his stew, but he will enjoy it alone. The wide world of the steam tunnels opens before you: there are wider worlds, probably, but this one has plenty of excitement to offer. I can't think of any examples, though, so I'm going to have to end your game here.";
		end the game saying "Good job with that stew, anyway.";
	otherwise:
		say "And so, with a full stomach and a glint in your eye, you escape into the vast network of steam tunnels. Neither Drew, nor Fran, nor whatshisface, the guard guy, will ever hear from you again.";
		end the game saying "It's just like that one ending from Adam Cadre's 9:05!".

Part 15 - Stew, Ingredients, Endgame

The pot is a transparent open unopenable container in drew's burrow. The initial appearance of the pot is "In the center of the room, over a small fire, sits a stewpot." The description is "Filling the pot about three quarters of the way is amount of thin broth." Understand "stewpot" or "cauldron" as the pot. Instead of taking the pot, say "Ah! Ow! Hot! You don't need to carry it around anyway." Instead of tasting the pot, say "And now your tongue is burnt." Instead of smelling the pot, say "It smells a little like the fire and a little like the stew, but mostly it smells like metal." Instead of listening to the pot, say "It bubbles." Instead of pushing the pot, try taking the noun. Instead of pulling the pot, try taking the noun.

The stew is scenery in drew's burrow. The stew is edible. Understand "soup" or "food" or "recipe" as the stew. The description of the stew is "So far, it's really only an attempt at a stew." Instead of touching the stew, try touching the broth. Instead of listening to the stew, try listening to the pot.

The broth is scenery. The broth is in the pot. The description is "It's not much of a broth, to be honest." Instead of taking the broth, say "It is critical to your enjoyment of the stew that the broth remains in the pot." Instead of touching the broth, say "You should wash your hands first." Instead of tasting the broth, say "You wouldn't say it tastes like anything, but on the other hand it doesn't have what you'd call a [italic type]flavor.[roman type][paragraph break]". Instead of inserting something into the broth, try inserting the noun into the pot. Instead of smelling the broth, try smelling the stew. Instead of listening to the broth, try listening to the pot. Instead of tasting the broth, try tasting the stew.

Instead of inserting something into the stew, try inserting the noun into the pot.

Instead of taking something contained by the pot, say "Too late! That's part of the stew now."

Before eating the stew:
	say "It's not ready! It needs to [italic type]stew[roman type], you know?";
	stop the action.

Before eating the pot:
	say "Wouldn't you rather eat the stew?";
	stop the action.

Before eating the broth:
	say "Wouldn't you rather eat the stew?";
	stop the action.

Instead of drinking the stew, try eating the stew.

Understand "try [something]" as eating.

Instead of smelling the stew:
	If the score is greater than 0:
		say "It's starting to smell pretty good. Starting to smell like a stew.";
	Otherwise:
		say "It doesn't smell delicious, that's for sure. But it smells like it has the potential for deliciousness."

Instead of tasting the stew:
	If the score is greater than 0:
		say "Say! That almost tastes like a proper stew!";
	Otherwise:
		say "It's not there yet. It's still just some broth that Drew procured by dubious means."
	
Instead of eating the cap, say "Oh, I get it. Like the idiom. Do us both a favor and leave the jokes to the parser." Instead of inserting the cap into the pot, say "I wouldn't mind letting you do that, but the Rat King would probably get pretty mad if he heard you disrespected your office by making your diplomat's cap into stew. I'm just looking out for you, you know?"

Instead of smelling the cap, say "It smells like your own furry head."

Instead of tasting the cap, say "Oh. Hmm. You should get that washed soon."

Instead of giving or showing the cap to Drew, say "'Diplomacy isn't really my thing. It's just--Can I be honest with you, man? Diplomacy sounds like too much [italic type]work[roman type] for a guy like me.'"

The maximum score is 6. Ingredient is a kind of thing. The potato is an ingredient. The tomato is an ingredient. The apple slice is an ingredient. The bone is an ingredient. The worm is an ingredient. The roach is an ingredient. Instead of giving or showing an ingredient to Drew, say "'Looks tasty! Drop it in there.' He makes the slightest possible gesture in the direction of the pot."

Instead of giving or showing an ingredient to Zeke, say "'Oh, I just ate.' He pats his stomach unconvincingly. 'Thanks anyway, though.'"

Instead of giving or showing an ingredient to the palace guard, say "'Oh, I just ate.' He pats his stomach unconvincingly. 'Thanks anyway, though.'"

After inserting the potato into the pot:
	say "The potato falls in with a plop and bobs up and down in the broth.";
	increase the score by 1;
	increase progression by 1;
	now the description of the potato is "It floats in serene circles around the perimiter of the broth. It has found its home."
	
After inserting the bone into the pot:
	say "The bone floats in the pot serenely, its meaty essences dispersing.";
	increase the score by 1;
	increase progression by 1;
	now the description of the bone is "Tiny fibers of chicken meat detach from the bone and swirl around in the broth happily."
	
After inserting the tomato into the pot:
	say "The tomato falls in and immediately its juices begin to mingle with the broth.";
	increase the score by 1;
	increase progression by 1;
	now the description of the tomato is "The tomato permeates the stew, making everything smell a little tangier."
	
After inserting the apple slice into the pot:
	say "As the apple slice falls into the broth and resurfaces, it seems to speak to you in a sizzling whisper: [italic type]'thaaaank yooooou...'[roman type][line break]";
	increase the score by 1;
	increase progression by 1;
	now the description of the apple slice is "More mouthwatering than ever."
	
After inserting the worm into the pot:
	say "The worm writhes uselessly at the bottom of the pot. Gradually it stops writhing and starts cooking.";
	increase the score by 1;
	increase progression by 1;
	now the description of the worm is "Not so lively anymore."
	
After inserting the roach into the pot:
	say "You smash the roach's head and throw it in the pot. It floats partially submerged in the broth, twitching momentarily.";
	increase the score by 1;
	increase progression by 1;
	now the description of the roach is "Now an ex-roach, lending its flavor and crunch to the stew.";
	if the tomato is in fran's burrow:
		increase progression by 1.

Progression is a number that varies. Progression is 0.

A person is either hungry or sated. A person is usually sated. The player is hungry.

Stewmageddon is scene. Stewmageddon begins when progression is 6.

When Stewmageddon begins:
	say "[if the player is in Fran's burrow]It occurs to you presently that that stew is probably ready by now.[otherwise if the player is in Drew's Burrow]The stew looks like it's ready now.[otherwise]Speaking of which, that stew is probably ready by now.[end if]";
	now the description of the pot is "[if the score is greater than 0]It looks like the stew is about as ready as it's ever going to be.[else]The stew is still just a broth. Whose fault is that, do you think?[end if]";
	now the initial appearance of Drew is "Drew groans at you from his beanbag. 'Hey. Hey. Try that stew, see if it's ready.'"
	
Before eating the stew during Stewmageddon:
	If the player is hungry:
		If the number of objects contained by the pot is 7:
			say "Drew directs you toward a ladle, and you start dishing out the stew. [paragraph break]It is quite a fine stew--Probably the best you could have put together, circumstances being what they are. It's sweet, it's savory, and it's crunchy. As you eat, Drew pretends to listen to your stories about Fran, and the human with the fried chicken, and so on.[paragraph break]Eventually the stew is gone, and lying face up on his beanbag, Drew now appears more immobile than ever. [paragraph break]'Well,' he says, 'We did a pretty nice job, huh?' [paragraph break]The next day, Fran shows up at your house, asking you what you've done with Miko.";
			end the game saying "You've made one heck of a stew.";
		If the number of objects contained by the pot is 6:
			if the roach is in fran's burrow:
				say "Drew directs you toward a ladle, and you start dishing out the stew. [paragraph break]It's a pretty good stew. It might be missing a little something, but you couldn't say what. As you eat, Drew pretends to listen to your stories about Fran, and the human with the fried chicken, and so on.[paragraph break]Eventually the stew is gone, and lying face up on his beanbag, Drew now appears more immobile than ever. [paragraph break]'Well,' he says, 'I guess you did your best.'";
				end the game saying "You've made a fine stew.";
			otherwise:
				say "Drew directs you toward a ladle, and you start dishing out the stew. [paragraph break]It's a pretty good stew. It might be missing a little something, but you couldn't say what. As you eat, Drew pretends to listen to your stories about Fran, and the human with the fried chicken, and so on.[paragraph break]Eventually the stew is gone, and lying face up on his beanbag, Drew now appears more immobile than ever. [paragraph break]'Well,' he says, 'I guess you did your best.' [paragraph break]The next day, Fran shows up at your house, asking you what you've done with Miko.";
				end the game saying "You've made a fine stew.";
	Otherwise:
		if the number of objects contained by the pot is 1:
			if the roach is in fran's burrow:
				say "Drew directs you toward a ladle, and you start dishing out the 'stew'. It's not really a stew. It's just broth, broth that was sitting here simmering while you ran around and ate everything. [paragraph break]What with your full stomach, you can't force much of it down; Drew glares at you as he sips from his own bowl. Because he is glaring at you instead of paying attention to his spoon, he spills the broth all over himself. [paragraph break]He will not invite you over for stew again.";
				end the game saying "You've lost a friend, but not a good one.";
			otherwise:
				say "Drew directs you toward a ladle, and you start dishing out the 'stew'. It's not really a stew. It's just broth, broth that was sitting here simmering while you ran around and ate everything. [paragraph break]What with your full stomach, you can't force much of it down; Drew glares at you as he sips from his own bowl. Because he is glaring at you instead of paying attention to his spoon, he spills the broth all over himself. [paragraph break]He will not invite you over for stew again. [paragraph break]The next day, Fran shows up at your house, asking you what you've done with Miko.";
				end the game saying "You've lost at least one of your friends!";
		otherwise:
			if the roach is in fran's burrow:
				say "Drew directs you toward a ladle, and you start dishing out the stew. [paragraph break]It's not much of a stew. There are some key components missing, but you don't mind. Drew is none the wiser; he consumes his share greedily, making smacking noises as you attempt to tell him about what you've been doing with your time. [paragraph break]Eventually the stew is gone, and lying face up on his beanbag, Drew now appears more immobile than ever. [paragraph break]'Well,' he says, 'See you later!'";
				end the game saying "You've succeeded in making a stew.";
			otherwise:
				say "Drew directs you toward a ladle, and you start dishing out the stew. [paragraph break]It's not much of a stew. There are some key components missing, but you don't mind. Drew is none the wiser; he consumes his share greedily, making smacking noises as you attempt to tell him about what you've been doing with your time. [paragraph break]Eventually the stew is gone, and lying face up on his beanbag, Drew now appears more immobile than ever. [paragraph break]'Well,' he says, 'See you later!' [paragraph break]The next day, Fran shows up at your house, asking what you've done with Miko.";
				end the game saying "You've succeeded in making a stew.".