Kill the Troll by Beobe

Kill the Troll

Played 1,401 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Kill the Troll" by Beobe

Chapter 1 - Rules and Setting up

Use no scoring.

Instead of waiting:
	say "You stand there and daydream about [one of]your face[or]your dead fish[or]the movie you want to watch[or]Natalie Portman[at random] for like, a minuto.";
	rule succeeds.

The player has a number called health. The health of the player is 3.
player-has-dodged is a truth state that varies. player-has-dodged is false.

Dodging is an action applying to one thing.
Understand "dodge [something]" or "avoid [something]" or "evade [something]" or "sidestep [something]" as dodging.
Check dodging:
	if the noun is not a person, say "You can't dodge [a noun]!" instead;
	if the noun is the player, say "You don't think you are going to attack yourself anytime soon." instead;
Carry out dodging:
	say "You anticipate [the noun]'s attacks, and you quickly dodge them!";
	now player-has-dodged is true;
	if the health of the player is less than 3:
		increment the health of the player;
	
Memorizing is an action applying to one thing.
Understand "memorize [something]" as memorizing.
Report memorizing:
	say "You memorize [the noun]."

Instead of listening when the player is in the bedroom:
	say "You listen, then you hear. You think there be a troll!";

Instead of going east when the player is in the weird place:
	say "La door = locked. You didn't believe me, did you?"
	
Before attacking the troll:
	say "The trolll is smart. You will have to do something more detailed than just attack it." instead;
	stop the action.
	
Instead of putting the napkin on the troll:
	say "You manage to slap le wet napkin onto the troll's face. After a few seconds the troll faints. Then you kick the troll for good measure. He diedd. YAy!";
	end the story finally saying "Thy winds: You killed the troll with chloroform!".
	
Instead of putting the dirty clothes on the troll:
	say "You slap the troll in the face with the clothes. He immediately dies from the putrid smell.";
	end the story finally saying "You killed the troll with your disgustingness!".
	
Instead of putting something on the troll:
	say "You prob don't need to put that on him."
	
Definition: a person is dead rather than alive if the health of it is 0.

To decide whether troll can attack:
	if player-has-dodged is false, decide yes;
To reset dodging:
	now player-has-dodged is false.

Every turn when the player is in the weird place:
	if troll can attack:
		decrement the health of the player;
		say "[one of]Le troll slaps you across the face. 'Bad dog!' he scolds.[or]Le trol karate chops you. You fall[if the player is alive] for a second, then get back up[otherwise], but can't get back up[end if].[or]The troll yells loudly, then sprints towards you and body slams you. [if the player is alive]You manage to squigle out from under him.[end if][at random][run paragraph on]";
		if player-has-dodged is false and the player is alive:
			say "[one of] You should really try dodging him, maybe...[or][or][at random]";
	otherwise:
		reset dodging;
	if the player is dead:
		say "That final blow kills you. You be ded!";
		end the story saying "You were attacked by a troll. And you didn't even do anything to stop it.";

Table of Scary Noises from the Closet
noise
"The closet creaks. You think you hears a troll from de other side."
"The closet door moves randomly. You hear breathing."
"You hear a smash coming from the closet. Then a loud troll-y voice says 'OUCH!'"

Every turn when a random chance of 1 in 2 succeeds and the player is in the bedroom and the closet is closed:
	choose a random row in the Table of Scary Noises from the Closet;
	say "[noise entry][paragraph break]"

Every turn when a random chance of 1 in 3 succeeds and the banana is eaten and the banana is in the weird place:
	say "As the troll lunges for you he slips on the banana peel and falls. He hits his head and dies. Wow that was easy!";
	end the story finally saying "You killed le trol with a sad little banana peel!"

Before going west when the player is in the bedroom and the closet door is closed:
	say "You attempt to head west but walk right into a closed door. Hmm. Maybe you forgot to open the door?";
	stop the action.

Every turn:
	if the closet has been open for two turns and the player has been in the bedroom for two turns:
		if the banana is eaten and the banana is in the bedroom:
			say "A large troll barges into your room attempting to murder you, but it slips on the banana peel conviniently placed on the ground. It falls and dies. Wowza!";
			end the story finally saying "You killed a troll with a banana. But the real question is, how did the trol get in there??? DUN DUN DUNNNNNNN!";
		otherwise:
			say "A large troll barges into your room and catches you by surprise. It kills you. You is dead.";
			end the story saying "You were smashed in the head by a troll you never even met".

Instead of smelling the napkin:
	say "You put the napkin up to your nose. Uh oh. Everything turns bla---";
	end the story saying "You passed out by inhaling chloroform. You idiot."
	
Instead of smelling the dirty clothes:
	say "[one of]You smell the dirty clothes. Cheese! SO DISGUST! It's a miracle you didn't faint![or]You don't need to smell it again. You know what it smells like. It's been imprinted in your brain... (If you don't remember it smelled terrible and almost made you faint).[stopping]";

Instead of eating the banana:
	if the banana is eaten:
		say "You probs don't wanna eat the peel, you don't particularly like the taste of peels.";
	otherwise:
		say "You eat the sad little baneyney. Delishcious fish! Now it is a peel!";
	now the banana is eaten.
	
Instead of examining the player:
	say "You are a child. That is all you must know."
	
Instead of putting something on a floor, try dropping the noun instead.

Instead of examining the lamp, say "The lamp [if switched off]sits gloomily because it is not on. [else]glows like a giant firefly. Except it is a firefly. Wait no it isn't. You smack yourself on the head. Stop fantasizing about fireflies! Or should you say... FLYntasizing!" 

Instead of doing something other than switching on or switching off to the lamp, say "You don't want to risk getting electrocuted. It is a VERY old lamp[if the lamp has been switched on], and it already took you some courage to switch on the lamp before.[else]."

To realize you are a fish:
	say "You attempt to memorize [the noun], but then everything starts to swirl around like a trapped fish in a fish bowl. Then you realize you are a fish and you have been halucinating your whole life.";
	end the story saying "You are actually a fish."

Instead of memorizing the bed when the lamp is switched on and the player is on the bed:
	realize you are a fish.
	

Rule for amusing a victorious player:
	say "You should try da following tings:[line break]";
	say "	Opening the door and leaving it open for a while[line break]";
	say "	Smelling the napkin[line break]";
	say "	Smelling the clohtes[line break]";
	say "	Examine the lamp when it is on[line break]";
	say "	Okay this one is weird: try turning on the lamp, then sitting on the bed, then memorizing the bed. (That is the most random ending)[line break]";
	say "[line break]";
	


Chapter 2 - The rooms and items

A floor is a kind of thing. There is a floor in every room. A floor is always scenery. The description of a floor is usually "Just a plain old floor. Nothing special about the floor. Nothing at awlllll."
Understand "ground" as the floor.

Section 1 - Bedroom

Bedroom is a room. "You sit in your little bedroom. Such messy."

There are dirty clothes in the bedroom. The dirty clothes are wearable. "Clothes are beaucoup all over the floor." The description of the clothes is "very dirt. Why didnt you wash them?"

The closet door is a door in the bedroom. It is west of the bedroom. Through it is the Weird Place. The initial appearance of the closet is "A[if the door is open]n open[end if] blue closet door is to le west." The description of the closet is "Old. Very old. You haven't been in that closet for years."

The bed is an enterable supporter in the bedroom. The bed is not scenery. "Thy bed sits lonely-ly at the corner of your room." The description of the bed is "Your sheets are rumpled. Other than that, your bed is pretty normal." 
Understand "sheet" or "sheets" or "pillow" or "pillow" as the bed.

The nightstand is a supporter in the bedroom. "The nightstand is real rickety."

A lamp is a device on the nightstand. "A very old lamp sits on your nightstand. It is [if switched on]on[else]off[end if]." It is fixed in place. 

A wet napkin is on the nightstand. "A wet napkin sits on the nightstand." The description of the napkin is "A normal napkin, but soaking wet. But then you get a whiff of a very peculiar smel!"
Understand "table" as the nightstand.

A banana is an edible thing on the nightstand. The banana can be eaten or not eaten. It is not eaten. "A sad little baneyney[if eaten] peel[end if] sits on the nightstand." The description is "[if not eaten]Looks delish![otherwise]Stringy things coming off efverywhere." The printed name of the banana is "baneyney[if eaten] peel".
Understand "fruit/food/baneyney/peel" as the banana.

Section 2 - Weird place

The printed name of the weird place is "Weird Random Room That You Didn't Know About". The description of the weird place is "[first time]You enters. The door swish-swishities shut and you cannot get out. Then you look ahead. And yuo see a trol. What were you expecting?[paragraph break][only]Weird fingerprints are on the walls. Wait... aren't fingerprints invisible? DUN DUN DUNNNNNN! But yeah you THINK there are fingerprints." 

In the weird place is a troll. The troll is a man.