The Game of Setanta by Christina Nordlander

The Game of Setanta

Played 1,412 times
View game source (spoilers!)
Download the .z8 file
Source Code

"The Game of Setanta" by Christina Nordlander

The story genre is "Fantasy". The release number is 1. The story creation year is 2020.

When play begins: say "Outside, it is summer. Bees murmur in the dogroses of the hedge, white-dusted roads lie open for adventure, forests beckon with humid shade. You are a prisoner, cut off from that world in the cool shadows of the attic, with no hint of when you will be released."

A person can be normal or shrunk. A person is normally normal.

A person can be dry or wet. A person is normally wet.

A room can be aboveground, subterranean or suspended. A room is normally aboveground.

A thing can be normal or shrunk. A thing is normally normal.

A thing can be taken or untaken. A thing is normally untaken.

A thing can be burnt or unscathed. A thing is normally unscathed.

A thing can be blocked or unblocked. A thing is normally unblocked.

A thing can be trapped or untrapped. A thing is normally untrapped.

A thing can be disturbed or undisturbed. A thing is normally undisturbed.

A thing can be hit or unhit. A thing is normally unhit.

A thing can be fillable or unfillable. A thing is normally unfillable.

A weapon is a kind of thing.

Imprisonment is a number that varies. Imprisonment is 1.

Boxopened is a number that varies. Boxopened is 0.

Cheesedropped is a number that varies. Cheesedropped is 0.

Gnomeencountered is a number that varies. Gnomeencountered is 0.

Gnomelured is a number that varies. Gnomelured is 0.

Gnometrapped is a number that varies. Gnometrapped is 0.

Gnometaken is a number that varies. Gnometaken is 0.

Gnomesaved is a number that varies. Gnomesaved is 0.

Bedspreadrequested is a number that varies. Bedspreadrequested is 0.

Cursewaiting is a number that varies. Cursewaiting is 0.

Questgiven is a number that varies. Questgiven is 0.

Talked is a number that varies. Talked is 0.

Crackfound is a number that varies. Crackfound is 0.

Firehappening is a number that varies. Firehappening is 0.

Ratsencountered is a number that varies. Ratsencountered is 0.

Ratspresent is a number that varies. Ratspresent is 1.

Ratspanicked is a number that varies. Ratspanicked is 0.

Webpresent is a number that varies. Webpresent is 1.

Heatspiritpresent is a number that varies. Heatspiritpresent is 1.

Heatspirittouched is a number that varies. Heatspirittouched is 0.

Heat is a number that varies. Heat is 0.

Cellarfound is a number that varies. Cellarfound is 0.

Ratsexiled is a number that varies. Ratsexiled is 0.

Appletaken is a number that varies. Appletaken is 0.

Applepushed is a number that varies. Applepushed is 0.

Appleout is a number that varies. Appleout is 0.

Firedefeated is a number that varies. Firedefeated is 0.

Flowerposition is a number that varies. Flowerposition is 1.

Flowertravelled is a number that varies. Flowertravelled is 0.

Boarddiscovered is a number that varies. Boarddiscovered is 0.

Boardpositioned is a number that varies. Boardpositioned is 0.

Confronted is a number that varies. Confronted is 0.

Ratsdefeated is a number that varies. Ratsdefeated is 0.

Questbrought is a number that varies. Questbrought is 0.

Over is a number that varies. Over is 0.

Mealtime is a number that varies. Mealtime is 0.

Waterquestgiven is a number that varies. Waterquestgiven is 0.

Waterquestcompleted is a number that varies. Waterquestgiven is 0.

Mothereating is a number that varies. Mothereating is 0.

Noticed is a number that varies. Noticed is 0.

Exittried is a number that varies. Exittried is 0.

Mealeaten is a number that varies. Mealeaten is 0.

Motherkilled is a number that varies. Motherkilled is 0.

Fatherkilled is a number that varies. Fatherkilled is 0.

Giantsdefeated is a number that varies. Giantsdefeated is 0.

Looking is acting fast. Examining something is acting fast. Taking inventory is acting fast.

The take visual actions out of world rule is listed before the every turn stage rule in the turn sequence rules.

This is the take visual actions out of world rule: if acting fast, rule succeeds.

Attic is a room. "[if Imprisonment is 1]At least your prison is tidy. [end if]A narrow room, the floor nailed from clean, narrow boards. A dense, massy thatch roof[if the player is shrunk] a great distance from you[end if] slopes down on both sides[if the player is normal], so that you can only stand straight in the middle[otherwise]. You can stand straight even at the long sides[end if]."

The player is in Attic.

The attic window is a door. The attic window is west of Attic. "[windowdescript1]." The attic window is open. Description of the attic window is "[windowdescript2]."

Instead of closing the attic window: say "There are no shutters."

Instead of attacking the attic window: say "It is just a space."

To say windowdescript1:
	if the player is in Attic:
		say "In the western wall is a narrow[if the attic window is closed] shuttered[end if] window";
	otherwise:
		say "A great window in the wall leads east".

To say windowdescript2:
	if the attic window is closed:
		say "It is shuttered with horizontal slats of sun-bleached wood[if the player is in Attic]. You see blazing sunlight through the cracks[end if]";
	otherwise:
		if the player is in Attic:
			say "Outside you can see the cloud-vast apple boughs, then the road, dusting white like a strip of flour, winding between green pastures and pale-golden fields. The sun is hidden behind the cottage, but the sky is a block of unwatchable blue, endless as the sea in stories[if Over is 1].The sun is beginning to decline towards the west. Outside the window, a blue flower nods in the breeze.[end if]";
		otherwise:
			say "Through the window, you dimly see the attic room and the angle of the thatch roof."

The sun is backdrop. The sun is in Attic. Description of the sun is "[if Over is 1]It has the richer glow of afternoon[otherwise]You cannot see it from this side of the cottage, but you can see how it makes all objects shine[end if]."

Window Outside is a room. Window Outside is west of the attic window. "A ledge of pale, sun-warm wood, wide as a path, runs along the window to the east. Around you is a vast chasm all the way to the bushes and fruit trees."

Instead of jumping in Window Outside: say "You may be not much larger than an insect, but you don't dare to entrust yourself to the winds."

Instead of going west from Window Outside: say "You can't fly."

Skyabyss is a room. Skyabyss is west of Window Outside.

Walldown is a room. Walldown is below Window Outside.

Instead of going down from Window Outside:
	say "The slivers and grain of the timber are large enough to give you a good grip, but the cottage wall is large as a plain, and the sun's heat confounds your brain and makes shades of blue and purple encroach on your vision.[paragraph break]When the swallow sees the unarmoured morsel crawling down the wall, you can do nothing to defend yourself.";
	end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Instead of going down with the golden apple from Window Outside:
	say "You are not about to lose the thing you have strived so hard to gain.";
	stop the action.

Description of the player is "Sinewy, black-haired, sun-tanned[if the player is shrunk], but no bigger than a grown man's thumb[end if]."

Instead of smelling the player:
	if Firedefeated is 0:
		say "You can't smell anything.";
	otherwise:
		say "You will have the smoke in your hair for a while."

Instead of going west from Attic:
	if the player is normal:
		say "Try as you might, you cannot force your shoulders through the hatch.";
	otherwise:
		if Confronted is 0:
			say "You scramble up the timber wall and pull yourself onto the sill.";
			continue the action;
		otherwise:
			say "If you turn your back to them, they will get you for sure."

Instead of entering the attic window:
	if the player is normal:
		say "Try as you might, you cannot force your shoulders through the hatch.";
	otherwise:
		continue the action.

Instead of smelling Attic: say "The subdued smells of thatch and timber, and the distant lively scent of summer."

The heavy door is a door. The heavy door is east of Attic. "A heavy door leads [if the player is in Attic]east[otherwise]back west to the attic[end if]." Description of the heavy door is "A [if the player is shrunk]towering [end if]door of heavy oaken boards. The keyhole is large, set in a worked brass plate." The heavy door is locked. Understand "oaken" as the heavy door.

Instead of attacking the heavy door with the razor: say "You make a few scores in the wood."

The gap is part of the heavy door. Description of the gap is "[if the player is in Attic]Through the gap, you can see the dusty sunlight in the staircase[otherwise]A slim field of shadow under the door[end if]." The gap is an enterable container.

Instead of inserting something into the gap: say "That would serve no purpose."

Instead of entering the gap:
	if the player is normal:
		say "You can just about get your fingers and palm through there.";
	otherwise:
		say "You could fit through there, but the door is open."

The keyhole is part of the heavy door. The keyhole is a container. Understand "brass plate" or "key-plate" or "plate" as the keyhole. Description of the keyhole is "Unusually large for a keyhole[if the player is normal], you could almost fit your finger through it[end if]. It is set in a notched and burnished brass plate."

Instead of taking the keyhole: say "You can't."

Instead of searching the keyhole:
	if the player is shrunk:
		say "It is much too high for you.";
	otherwise:
		say "Looking through the keyhole, you see the dim forms of the lock mechanism in the grey light sifting through from the other side."

Instead of touching the keyhole:
	if the player is shrunk:
		say "It is much too high for you.";
	otherwise:
		say "You cannot unlock it with your finger."

Instead of inserting the bedspread into the keyhole:
	if the bedspread is normal:
		say "It wouldn't fit.";
	otherwise:
		say "You can't reach."

Instead of inserting the strongbox into the keyhole:
	if the strongbox is normal:
		say "It wouldn't fit.";
	otherwise:
		say "You can't reach."

Instead of inserting the cheese into the keyhole:
	say "It wouldn't fit."

The strongbox is an openable enterable container. The strongbox is in Attic. "On the floor stands an iron-banded strongbox." Description of the strongbox is "A small wooden chest, strengthened with black-iron bands." Understand "chest" or "iron-banded" or "box" as the strongbox. The strongbox is normal. The strongbox is closed. The strongbox is fixed in place.

Carry out opening the strongbox:
	if Boxopened is 0:
		if the bedspread is in the hole:
			say "You hear a quick scuttling behind the bedspread.";
			now Boxopened is 1;
		otherwise:
			say "You hear a brief scuttling from the hole in the wall, but nothing comes out.";
			now Boxopened is 1;
	otherwise:
		continue the action.

Instead of taking the strongbox:
	if the player is normal:
		say "It's too heavy to carry comfortably.";
	otherwise:
		say "It is much larger than you."

Instead of closing the strongbox:
	if the player is shrunk:
		say "Between the height of the box and the weight of the lid, even if you can do it, it would be more trouble than it's worth.";
	otherwise:
		continue the action.

The cheese is a thing. The cheese is in the strongbox. Description of the cheese is "A ball of cheese with a sharp-smelling grey rind[if the cheese is shrunk], small enough that you can hold it in one hand[end if]." Understand "sharp" as the cheese. The cheese is normal.

Instead of touching the cheese: say "The rind is dry and slightly rough."

Instead of tasting the cheese: say "The rind is powdery; the molten inside tastes almost putrid, but deliciously so."

Before taking the cheese:
	if the player is shrunk:
		say "It is larger than you.";
		stop the action;
	otherwise:
		if Gnomelured is 0:
			now Cheesedropped is 0;
			continue the action;
		otherwise:
			if Gnometaken is 0:
				say "If you grab the cheese, he will surely run away.";
				stop the action;
			otherwise:
				continue the action;
				now Cheesedropped is 0.

After taking the cheese:
	say "Taken.";
	now Cheesedropped is 0.

Instead of inserting the cheese into the hole:
	say "That wouldn't lure anything out."



Instead of smelling the cheese:
	say "Almost too sharp."

Instead of eating the cheese: say "You nibble a bit off the edge, savouring the sharp tang, but you're not hungry enough to eat more."

Carry out entering the strongbox:
	if the strongbox is shrunk:
		say "You wouldn't fit.";
		stop the action;
	otherwise:
		if the player is normal:
			say "You can just about fit your feet in it.";
		otherwise:
			say "You clamber over the side and half-fall onto the bottom."

The bedding is an enterable supporter. The bedding is in Attic. "Under the angle of the roof lies some bedding." Description of the bedding is "A little nest of straw and scraps of blanket." The bedding is fixed in place.

Instead of taking the bedding:
	if the player is normal:
		say "You see no point in carrying it with you.";
	otherwise:
		say "It is much too big."

The bedspread is a thing. The bedspread is on the bedding. Understand "spread" or "tapestry" as the bedspread. Description of the bedspread is "On closer look, it seems to be a section of a tapestry, its workmanship still remarkable despite wear and fading. You make out a warrior approaching the walls of a city in his chariot[if the bedspread is shrunk].[line break]It is shrunk down to an appropriate size for you to sleep on[end if]." The bedspread is normal.

Instead of attacking the bedspread: say "Too soft."

The warrior is part of the bedspread. Description of the warrior is "[if Noticed is 0]You can make out the figure's long hair, but its face is too small to have features[otherwise]Yes, you were a warrior. If your imprisonment has not worn too long, perhaps you still are[end if]."

Instead of taking the warrior: say "The warrior is woven among the rest of the threads."

Instead of attacking the warrior: try attacking the bedspread.

Before taking the bedspread:
	if the player is shrunk:
		if the bedspread is normal:
			say "You might as well move the thatched roof off a hall.";
			stop the action;
		otherwise:
			continue the action;
	otherwise:
		continue the action.

Carry out taking the bedspread:
	if the bedspread is in the hole:
		if Bedspreadrequested is 0:
			if Cheesedropped is 1:
				if Gnomelured is 0:
					say "You pull it back out.[paragraph break]A tiny man in a red woollen hat rushes from the mouse-hole and starts shaving slices off the cheese with a knife.";
					move the little man to Attic;
					now Gnomeencountered is 1;
					now Gnomelured is 1;
					continue the action;
				otherwise:
					continue the action;
			otherwise:
				continue the action;
		otherwise:
			if Cheesedropped is 1:
				say "You pull it back out.[paragraph break]The little man quickly shins down the side of the door and scurries to his hole, rolling the cheese before him. They both disappear in the dark.";
				now the hole is unblocked;
				now the little man is in Little Man's Burrow;
				remove the cheese from play;
				now Gnomesaved is 1;
				now Cheesedropped is 0;
				now Cursewaiting is 1;
			otherwise:
				say "You pull it back out.[paragraph break]The little man quickly shins down the side of the door and scurries to his hole, disappearing into the dark.";
				now the hole is unblocked;
				now the little man is in Little Man's Burrow;
				now Gnomesaved is 1;
				now Cursewaiting is 1;
	otherwise:
		continue the action.




The hole is an enterable container. The hole is in Attic. "In the wall next to the door is a[if the player is normal] small[end if] dark hole." Description of the hole is "[if the player is normal]Dark and irregular, a little wider than your arm[otherwise]Dark and irregular, the size of a wide doorway[end if]." The hole is fixed in place. The hole is unblocked.

Instead of taking the hole: say "You can't."

Instead of talking to the hole: say "Nothing reacts."

Instead of attacking the hole: say "There is nothing for you to hit."

Instead of touching the hole:
	try searching the hole.

Instead of searching the hole:
	if the player is normal:
		say "You stick your arm shoulder-deep into the burrow, feeling around. You fancy you hear something scuttling, but there is nothing there for you to grab.";
	otherwise:
		say "You poke your head into the hole. You see a burrow, lit by the occasional chink of light from outside."

The thatch roof is scenery in Attic. Description of the thatch roof is "A dense mass of peat and greying straw, smelling aromatically."

Instead of attacking the thatch roof: say "It would take a long time for you to dig your way through the thatch, and even if you could, you might not have any way to get down from the roof."

Instead of taking the thatch roof: say "It would take a long time for you to rip out enough handfuls of the thatch to open a way through. Even if you could, you might not have any way to get down from the roof."

The little man is a man. "[littlemandescript].". Description of the little man is "[if the player is normal]He is no longer than your thumb, but stockier than a human man would be if shrunk to the same size. His coat and long hat appear to be wool, deep-dyed red. His face is brown and wrinkled as a walnut[otherwise]Taller than you now, and considerably heftier. His eyes glitter as if he is trying not to laugh at you[end if]." Understand "gnome" or "leprechaun" or "red" or "tiny" as the little man. The little man is unhit.

Instead of eating the little man:
	if the player is normal:
		say "The thought makes your stomach turn.";
	otherwise:
		say "He wouldn't let you get that close."

To say littlemandescript:
	if the little man is in Attic:
		if Gnomelured is 1:
			say "A little man is busy cutting long strips off the cheese";
		otherwise if Gnometrapped is 1:
			say "The little man is gazing this way and that for a way to escape";
	otherwise:
		say "The little man stands in front of the fireplace, feet set wide, gaze fixed on you".

After inserting the bedspread into the hole:
	if the bedspread is shrunk:
		say "It is far too small.";
		stop the action;
	otherwise:
		if Gnomelured is 0:
			say "You cram the bedspread into the hole.";
			now the hole is blocked;
		otherwise:
			if Gnometaken is 0:
				say "Sidling around the little man, fast-slow, you reach the wall and cram the bedspread into the hole.";
				now the hole is blocked;
				now Gnometrapped is 1;
			otherwise:
				say "You cram the bedspread into the hole."

After dropping the cheese:
	if the player is in Attic:
		if Gnomeencountered is 1:
			continue the action;
		otherwise:
			if the bedspread is in the hole:
				say "You hear something scuttling inside the hole, but whatever it is, it can't come out.";
				now Cheesedropped is 1;
			otherwise:
				say "Moments after the cheese touches the floorboards, a tiny man in a red woollen hat rushes out of the mouse-hole and starts shaving slices off the cheese with a knife.";
				now Cheesedropped is 1;
				move the little man to Attic;
				now Gnomeencountered is 1;
				now Gnomelured is 1;
	otherwise:
		continue the action.

The block attacking rule is not listed in any rulebook.

Instead of attacking the player: say "You give yourself a whiffling box about the ear. It makes nothing better."

Instead of attacking the heavy door: say "You only manage to hurt the soft part of your fists."

Instead of attacking the razor: say "You slice the side of your hand open."

Instead of attacking the golden apple: say "You are too weak to do any damage to the pulp."

Instead of attacking the little man:
	if player is shrunk:
		say "He deals you a blow that sends you stumbling back and landing on your bottom on the floorboards. When you look up, the gnome's face is creased with laughter. 'Returned the favour with interest, didn't I?'";
	otherwise:
		if the little man is carried:
			if the little man is unhit:
				say "You flick his head with the tip of your index finger. Even then, you are unsure whether you have done him permanent harm -- but the little man only spits and looks away from you, as if everything will be fine if he refuses to acknowledge you.";
				now the little man is hit;
			otherwise:
				say "You flick his head, more of a poke than anything, conscious of the fact that you might injure him. The little man spits.";
		otherwise:
			say "If you try to hurt him, he will undoubtedly escape."

The can't take other people rule is not listed in any rulebook.

Before taking the little man:
	if the player is shrunk:
		say "You don't dare to try.";
		stop the action;
	otherwise:
		if the bedspread is in the hole:
			continue the action;
		otherwise:
			say "You don't dare to try to grab him as long as he is able to escape into his burrow.";
			stop the action.

After taking the little man:
	say "You make a grab for him. He darts back towards his hole, but the shock of finding it blocked makes him stop in his tracks, and you are able to grab him around the waist. He wriggles in your grip like a fresh-caught newt.";
	now Gnometaken is 1.

Tickling is an action applying to one thing. Understand "tickle [thing]" as tickling.

Instead of tickling the little man:
	if the player is shrunk:
		say "You don't even get close enough before he puts his hand up, holding you at arm's length, then pushes you hard enough to make you stumble.";
	otherwise:
		if the little man is carried:
			say "You tickle his belly with a finger. He squirms, almost jumping out of your grip.";
		otherwise:
			say "You don't dare to do anything with him as long as he might run away."

Instead of inserting the little man into the hole:
	say "If you did, he would get away."

Talking to is an action applying to one thing. Understand "talk to [thing]" as talking to.

Carry out talking to the little man:
	if the player is normal:
		if the little man is carried:
			say "'I'll do anything, if you promise to let me go!'";
		otherwise:
			say "You don't want to spook him.";
	otherwise:
		if Talked is 0:
			if Questbrought is 0:
				say "Glass-bright eyes glitter at you, not friendly. 'Come back to apologise, have we?' He knows there is only one answer. 'Tell you what. Bring me a fine golden apple, like the ones the housewife stores in the kitchen downstairs, and I will restore you to man-size.'";
				now Talked is 1;
			otherwise:
				say "As he looks at you, his expression softens a bit. 'Go back outside and push the apple into my burrow. I want to see it before I transform you.' A glitter in his eye. 'You don't want to be in here when I do it.'";
		otherwise:
			if Questbrought is 0:
				say "'Didn't you hear me the first time? Bring me a golden apple, and I will give you your size back.'";
			otherwise:
				say "As he looks at you, his expression softens a bit. 'Go back outside and push the apple into my burrow. I want to see it before I transform you.' A glitter in his eye. 'You don't want to be in here when I do it.'"

Instead of dropping the little man:
	if Gnomesaved is 0:
		say "If you let him go, he may escape."

Instead of inserting the little man into the strongbox:
	if Gnomesaved is 0:
		say "You have a good grip on him now; putting him in the strongbox would only increase the risk of him escaping."

After inserting the little man into the keyhole:
	if the bedspread is in the hole:
		say "The man willingly crawls into the keyhole. You hear a sound of tinkering from within, then the tumbler turning. The door swings open. The little man sticks his head out.[paragraph break]'There, it's done. Please unblock my front door, so I can go home.'";
		now the heavy door is unlocked;
		now the little man is in Little Man's Burrow;
		now Bedspreadrequested is 1;
	otherwise:
		if Cheesedropped is 1:
			say "The man willingly crawls into the keyhole. You hear a sound of tinkering from within, then the tumbler turning. The door is unlocked. The little man sticks his head out. 'There, it's done.'[paragraph break]He quickly shins down the door and returns to his hole, rolling the cheese before him. Both cheese and gnome disappear.";
			remove cheese from play;
			now the heavy door is unlocked;
			now the little man is in Little Man's Burrow;
			now Gnomesaved is 1;
			now Cursewaiting is 1;
		otherwise:
			say "The man willingly crawls into the keyhole. You hear a sound of tinkering from within, then the tumbler turning. The door is unlocked. The little man sticks his head out. 'There, it's done.'[paragraph break]He quickly shins down the door and returns to his hole, disappearing into the shadows.";
			now the heavy door is unlocked;
			now the little man is in Little Man's Burrow;
			now Gnomesaved is 1;
			now Cursewaiting is 1.

After opening the heavy door:
	if Over is 0:
		say "Opened.[paragraph break]There is a sting as if an invisible snake has sunk its fangs into your hand, and a burning light that persists until you are certain it has ruined your sight. Something tosses you about and won't let go.[paragraph break]Nausea ebbs from your body as you find yourself lying on the floor. The floorboards underneath you are gigantic, wider than your body length. You sit up and gaze into the great, sky-vast vault of the attic roof.";
		now Imprisonment is 0;
		now Cursewaiting is 0;
		now Questgiven is 1;
		now the player is shrunk;
		if the bedspread is carried:
			now the bedspread is shrunk;
		if the cheese is carried:
			now the cheese is shrunk;
	otherwise:
		continue the action.

Before closing the heavy door:
	if the player is shrunk:
		say "You could never move it.";
		stop the action;
	otherwise:
		continue the action.



Instead of entering the hole:
	if the player is normal:
		say "A rat might be able to get in there, not you.";
		stop the action;
	otherwise:
		say "You take a few tentative steps inside and see the tunnel ahead widen to a low room.";
		move the player to Little Man's Burrow.

Little Man's Burrow is a room. "A cavern carved out of the timber and thatch, a few floorboards wide. By one wall is a fireplace, unlit. The back of the room is occupied by dark rows of barrels and bundles of provisions. Sunlight glitters in the hole to the west."

The bed is an enterable supporter. The bed is in Little Man's Burrow. "A bed stands here, covered with a red woollen blanket." Understand "blanket" as the bed. The bed is fixed in place. Description of the bed is "The blanket is as well dyed as the little man's clothes."

Instead of taking the bed: say "You wouldn't be able to carry it."

Instead of pushing the bed: say "You know better now than to make a mess of the little man's home."

Instead of pulling the bed: say "You know better now than to make a mess of the little man's home."

Instead of entering the bed: say "That belongs to the little man."

The razor is a weapon. The razor is on the bed. Description of the razor is "An iron blade, tapering to bluish edge, its blunt end weighted like that of a cleaver. It looks like it might pack a wallop in a fight when not used to keep chins smooth." Understand "cleaver" or "shaving-knife" or "iron" or "blade" as the razor. The razor is untaken. The razor is shrunk.

Carry out taking the razor:
	if the razor is untaken:
		say "The little man nods with a grim smile. 'Take it, if you think it will help you.'";
		now the razor is taken;
	otherwise:
		continue the action.

Instead of talking to the razor: say "It is inanimate."

Carry out showing the razor to the little man: say "'Yes, that is my razor.'"

Instead of giving the razor to the little man: say "'You may keep it, if it will help you get hold of an apple. It will find its way back to its master."

The little fireplace is scenery. The little fireplace is in Little Man's Burrow. Description of the little fireplace is "Unlit now."

Tunnel is a room. Tunnel is west of Little Man's Burrow.

Instead of going west from Little Man's Burrow:
	move the player to Attic.

Staircase is a room. Staircase is east of the heavy door. "A shadowy space[if the player is shrunk]. The roof above you is as distant as the dome of the stars[end if]. Shafts of dusty gold sift through gaps in the thatch. Wooden steps[if the player is shrunk], each taller than you,[end if] lead down into the shadows."

The beams are scenery in Staircase. Understand "shafts" as the beams. Description of the beams are "So full of immobile dust-motes, they look almost solid."

Instead of taking the beams: say "You try, but they are just light."

The steps are scenery in Staircase. Description of the steps is "Dusty, well-built steps, wood worn sleek as water."

Before going down from Staircase:
	if the player is shrunk:
		say "You scrabble off the step, lower yourself onto the next one, and repeat the action. It feels like it takes an hour, and you prefer not to think about getting up again.";
		continue the action;
	otherwise:
		continue the action.

After going down from Staircase:
	if Mealtime is 1:
		say "Your mother is waiting for you at the bottom of the stairs; your father already sat at his meat. Your mother smiles at you, half-stern, and hands you a maple-wood ewer. 'Fill this with water from the trough, then you can sit down and eat. You must be ravenous.'";
		now the player is carrying the ewer;
		now Waterquestgiven is 1;
	otherwise:
		continue the action.

Cottage Room is a room. Cottage Room is below Staircase. "[cottageroomdescript]."

Before going up from Cottage Room:
	if Mealtime is 0:
		say "Drawing a breath, you grab onto the lowest stair and pull yourself up. After three stairs, you are already tired. It gets no easier. By the time you reach the top, you have to sit down and rest before you are able to walk again.";
	otherwise:
		say "You have nothing left to do up there.";
		stop the action.

To say cottageroomdescript:
	if Firehappening is 0:
		say "A large room, taking up the bulk of the cottage. [if the rush-covering is unscathed]Fresh yellow rushes are laid in a pattern on [otherwise]Fire-blackened rushes cover[end if] the stamped earth floor. In the middle is an oblong fire-pit[if the player is shrunk] the size of a lake[end if]. Next to it stands a table of heavy timber[if the player is shrunk], the height of a high-ceilinged palace hall[end if]. A seat-bench stands along the southern wall under a large window on the sunlit garden.[paragraph break]The room narrows to a doorway to the west, and a stairway leads [if the player is shrunk]high[end if] into the shadows";
	otherwise:
		say "Small flames are racing across the rush-covered floor from the kitchen, picking themselves up, hissing, roaring. The heavy table and the window are merely backdrops to the flame.[paragraph break]The room narrows to a doorway to the west, and a set of steps lead [if the player is shrunk]high[end if] into the rafters".

The piece of mushroom is a container. The piece of mushroom is in Cottage Room. "[if the mushroom is untaken]A piece of dried mushroom lies on the brick edge of the fire-pit[otherwise]You see a grey mushroom here[end if]." Description of the piece of mushroom is "A small piece of grey tree-mushroom, the kind you use for tinder, hollowed out like a little bowl. It is very dry." Understand "piece" or "mushroom" or "dry" or "grey" or "fungus" or "tinder" as the mushroom. The mushroom is untaken.

After taking the piece of mushroom:
	if the piece of mushroom is untaken:
		say "It is light as foam, making it no trouble to carry.";
		now the piece of mushroom is taken;
	otherwise:
		continue the action.

Instead of inserting something into the piece of mushroom:
	say "It is too big for the hollow."

Instead of eating the mushroom: say "You try to nibble the mushroom, but it is hard enough to hurt your front teeth. Besides, it tastes like dry wood pulp."

Instead of tasting the mushroom: say "So dry, it sucks the spittle from your tongue."

Instead of smelling the mushroom:
	if the mushroom is burnt:
		say "You smell smoke.";
	otherwise:
		say "It has next to no odour."

The rush-covering is scenery in Cottage Room. Understand "rushes" or "reeds" or "rush covering" as the rush-covering. Description of the rush-covering is "[if the rush-covering is unscathed]Healthy yellow reeds, probably picked only a few days ago, laid in groups forming a braid-like pattern[otherwise]Blackened rushes, some still holding their shape[end if]." The rush-covering is unscathed.

Instead of taking the rush-covering: say "[if the player is shrunk]Lugging the rushes around would serve no purpose[otherwise]There is no point in moving the rushes[end if]."

Instead of searching the rush-covering: say "[if the player is shrunk]You dig away some of the rushes[otherwise]You brush away a few rushes[end if], but find nothing underneath except the earth floor."

Before going up with the golden apple:
	if the player is in Cottage Room:
		say "You try, despite the evident impossibility, but there is no way for you to get the apple onto the first step, let alone all the way to the attic.";
		stop the action;
	otherwise:
		say "There is nothing there to hold it."

The table is scenery in Cottage Room. Description of the table is "[tabledescript].". The table is a supporter.

To say tabledescript:
	if Firehappening is 0:
		if the player is normal:
			say "A table built from pine timber brushed pale";
		otherwise:
			say "A huge, shadowy vault. You cannot see if there is anything on it";
	otherwise:
		say "The flames haven't taken in the wood yet, but they are licking the table-legs black and leaping in the rushes underneath".

Instead of taking the table: say "You could never do that."

Instead of pushing the table: say "[if the player is shrunk]That is impossible[otherwise]Perhaps you could budge it, but you see no point[end if]."

Instead of pulling the table: say "[if the player is shrunk]That is impossible[otherwise]Perhaps you could budge it, but you see no point[end if]."

The fire-pit is scenery in Cottage Room. The fire-pit is an enterable container. Understand "pit" as the fire-pit. Description of the fire-pit is "Lined and edged with black-streaked brick. This time of year, it is only filled with white ashes."

Carry out exiting from the fire-pit:
	if the player is normal:
		continue the action;
	otherwise:
		say "With effort, you scrabble up the side."

The ashes are scenery in Cottage Room. Description of the ashes is "White and grey[if the player is shrunk]. At this size, you can make out the single grains[end if]."

Instead of taking the ashes: say "They would serve no purpose."

Instead of searching the ashes: say "You sift the [if the player is normal]fine powder through your fingers[otherwise]grainy ashes between your hands[end if], but find nothing."

The cottage window is scenery in Cottage Room. Description of the cottage window is "[if the player is normal]You see blazing sky and the hedge set with white roses[otherwise]From this far below, you only see sky[end if]."

Instead of doing something other than examining with the cottage window: say "You are too far away."

The bench is scenery in Cottage Room. The bench is an enterable supporter. Understand "seat-bench" or "seat bench" or "seat" as the bench. Description of the bench is "Built from horizontal boards of yellow pine, flush with the southern wall under the window[if the player is normal], and covered with thin woven cushions[end if][if the player is shrunk]. It is many times your height.[paragraph break]A piece of ribbon hangs from the side of the bench, almost touching the floor[end if]."

Instead of entering the bench:
	if the player is shrunk:
		say "The boards are too flush, but there is a hanging ribbon that could support your weight.";
	otherwise:
		continue the action.

Instead of climbing the bench:
	if the player is shrunk:
		say "The planks are too smooth, but a ribbon hangs down from the cushion and looks sturdy enough to carry your weight.";
	otherwise:
		say "It's barely higher than your knees."

The ribbon is part of the bench. Description of the ribbon is "Braided, fine-dyed red wool, as wide as your thigh is thick."

Instead of taking the ribbon: say "You yank it, but its end seems firmly attached."

Instead of pulling the ribbon: say "It doesn't give."

Instead of pushing the ribbon: say "It swings for a moment."

Instead of climbing the player: say "You can't."

Instead of climbing something: say "That would get you nowhere."

Instead of climbing the table: say "You try, but the wood is too smooth."

Instead of climbing the ribbon:
	if the player is normal:
		say "It is far too small.";
	otherwise:
		say "The braiding gives a good grip. You shin up the ribbon without much effort.";
		move the player to Top of the Bench.

The outer door is a door. The outer door is south of Cottage Room. "A stoutly carpented door leads out to the south." Description of the outer door is "Built from strong yellow wood, looking as stout as the cottage walls. The iron latch is on." Understand "latch" or "stout" or "stoutly" as the outer door.

Outdoors is a room. Outdoors is south of the outer door.

Instead of opening the outer door:
	if the player is shrunk:
		say "Even if you were able to climb to the latch and lift it, you would never be able to budge the door.";
	otherwise:
		if Waterquestcompleted is 0:
			say "Your father shoots you a glare. 'You will finish the chore your mother gave you before you do anything else.'";
		otherwise:
			if Mealeaten is 0:
				if Exittried is 0:
					say "Your mother speaks up behind you:[line break]'Eat your supper. There will be plenty of time to play after.'";
					now Exittried is 1;
				otherwise:
					say "Your mother sighs. 'Well, you only have yourself to blame when you get hungry later.'[paragraph break]You lift the latch and open the door on the gold-laced evening world outside.";
					continue the action;
			otherwise:
				say "You lift the latch and open the door. The evening sun hits your eyes, low enough to lavish the fields in molten gold.";
				continue the action.

Instead of climbing the outer door:
	if the player is shrunk:
		say "The wood is splintery, but sheer; try as you might, you can barely climb your own height before losing your grip. Even if you could get to the latch, you have no way to move the door.";
	otherwise:
		say "That would get you nowhere."

Carry out going south from Cottage Room:
	say "You step outside.";
	end the story saying "YOU ARE FREE".

Instead of smelling Cottage Room:
	if Firehappening is 0:
		say "Rushes, fresh from the stream, and timber still beaded with dark-red gum.";
	otherwise:
		say "The salty smell of smoke is around you. Underneath it, a toxic prickling at the back of your head."

Top of the Bench is a room. "Wide as a plain. To the east is the shadowy gap between the bench and the table[if Boarddiscovered is 0].[paragraph break]Beneath the cushions, a board tilts whenever you move your feet[end if]."

The cushion is a thing in Top of the Bench. "[if the cushion is undisturbed]Cushions, roughly patterned in red and white, cover the bench[otherwise]Cushions, roughly patterned in red and white, cover the bench. One has been pushed up halfway over another[end if]." Description of the cushion is "[if the cushion is undisturbed]Thin cushions woven from white and red yarn, the pattern of the weave clearly visible to you. One of them lies slightly lumpy over the seat of the bench[otherwise]The cushion lies rumpled, half-covering another[end if]." Understand "cushions" as the cushion. The cushion is undisturbed.

Instead of attacking the cushion:
	if the player is shrunk:
		say "You are small enough that the stuffing feels hard against your fist.";
	otherwise:
		say "Too soft to hurt your knuckles."

Instead of attacking the cushion with the razor:
	say "That would serve no purpose other than to blunt the edge."

Instead of touching the cushion:
	if Boarddiscovered is 0:
		say "Something seems to move underneath when you walk on it.";
	otherwise:
		say "The comforting feel of fabric."

Instead of taking the cushion:
	say "While they may be light, they would be too cumbersome to carry."

Instead of searching the cushion: try pushing the cushion.

Instead of pushing the cushion:
	if the cushion is disturbed:
		say "There is no need to replace it.";
	otherwise:
		say "You drag the cushion to the side, exposing a loose board.";
		now the cushion is disturbed;
		now Boarddiscovered is 1;
		now the board is in Top of the Bench.

Instead of pulling the cushion:
	if the cushion is disturbed:
		say "There is no need to replace it.";
	otherwise:
		say "You drag the cushion to the side, exposing a loose board.";
		now the cushion is disturbed;
		now Boarddiscovered is 1;
		now the board is in Top of the Bench.

The board is pushable between rooms.

Instead of pushing the board:
	if Boardpositioned is 0:
		say "You wedge your fingers under the edge and brace with your feet to move it.";
	otherwise:
		say "It's good where it is."

Instead of pulling the board:
	if Boardpositioned is 0:
		say "You wedge your fingers under the edge and brace with your feet to move it.,";
	otherwise:
		say "It's good where it is."

Instead of attacking the board:
	if Boardpositioned is 0:
		say "That would serve no purpose.";
	otherwise:
		say "You give it a slap. It rocks briefly, but stays firm."

Instead of attacking the board with the razor: say "You make a few squeaking hacks in the edges."

Instead of going down with the board from Window Sill:
	say "If you do that, you would never be able to get it back up."

Before going down from Top of the Bench with the board:
	say "Carefully, you push the end of the board so that it slides down to the rushy floor, the upper end remaining securely on the edge of the bench and forming a ramp.";
	now Boardpositioned is 1.




Fakeroom2 is a room. Fakeroom is north of Top of the Bench.

Instead of going north from Top of the Bench:
	try going down.

Instead of going north from Top of the Bench with the board:
	try going down.

Instead of climbing the board:
	if Boardpositioned is 1:
		say "You walk up the board with less effort than climbing a set of stairs in your old form.";
		move the player to Top of the Bench;
	otherwise:
		say "There is nowhere to climb."



The end of the ribbon is a thing. The end of the ribbon is in Top of the Bench. "The upper end of the ribbon is sewn on to the corner of a cushion." Understand "upper end" as the end of the ribbon. Description of the end of the ribbon is "A red woollen ribbon with a roughly braided texture." The end of the ribbon is fixed in place.

Instead of taking the end of the ribbon: say "It is sewn onto the cushion."

Instead of attacking the ribbon with the razor: say "You would gain nothing by destroying it."

The board is a thing. "[boarddescript]." Description of the board is "[boarddescript2]." Understand "narrow" or "slender" or "loose" as the board. The board is pushable between rooms.

Instead of taking the board:
	if Boardpositioned is 1:
		say "It's good where it is.";
	otherwise:
		say "It is much too long for you to carry, but you may be able to push it."

Instead of inserting the board into the flower: say "It is far too big."

To say boarddescript:
	if the board is in Cottage Room:
		say "A board leans on the seat-bench at a gentle slope, leading south";
	otherwise:
		say "You see a narrow board here".

To say boarddescript2:
	if the board is in Cottage Room:
		say "About as wide as a forest path. You can walk on it comfortably";
	otherwise:
		say "A long strip of pine wood, thin enough that you should be able to drag it about".

Instead of climbing the end of the ribbon:
	say "You shin nimbly down.";
	move the player to Cottage Room.

Underbench is below Top of the Bench.

Instead of going down from Top of the Bench:
	if Boardpositioned is 0:
		say "You shin back down the ribbon.";
		move the player to Cottage Room;
	otherwise:
		say "You walk back down, the board rocking gently under your steps.";
		move the player to Cottage Room.

The southern window is a door. The southern window is south of Top of the Bench. "[if the player is in Top of the Bench]Just behind the bench, a great bright window opens southward on the garden, the sill only barely higher than the surface where you stand[otherwise]A great window leads north into the cottage[end if]." The southern window is open. Description of the southern window is "[if the player is in Top of the Bench]A great gap of air, facing out on the green and blue of the garden. The brushed, pale-wood sill is almost level with the bench[otherwise]The shutters are tied open, flush with the cottage walls. Inside you see the shadows of the room[end if]."

Instead of closing the southern window:
	if the player is normal:
		say "You should let your father decide that.";
	otherwise:
		say "You could never manipulate such large shutters, and besides, there is no need."

Window Sill is a room. Window Sill is south of the southern window. "A comfortably broad wooden ledge jutting from the timber wall. A man's waist-height below you, green grass ripples with the breeze. A path paved with white stones winds away from the cottage door. The rest of the world is an explosion of sky, foliage, and the distant flicker of white birds."

Carry out smelling Window Sill: say "You smell all the greenery of summer."

The wide sill is scenery. The wide sill is in Window Sill. Description of the wide sill is "Dry, summer-hot wood, even the knots bleached with long sun."

The birds are scenery. The birds are in Window Sill. Understand "bird" as the birds. Description of the birds is "You think they are gulls, but this far away, they are white motes against the sky."

The grass is scenery. The grass is in Window Sill. Description of the grass is "A green main below you, glittering with paler seed-heads."

Instead of doing something other than examining with the grass: say "You can't reach it."

The plant is a thing. The plant is in Window Sill. "An odd plant clings up the wall just next to the window, a large blue flower resting almost on the sill." Description of the plant is "A clinging vine of a kind you have never seen. It climbs up the wall in almost a single strand. The blue calyx of a large flower bends gracefully from the vine, [if Flowerposition is 1]almost resting on the window sill[otherwise]right next to the window sill[end if]."

Instead of taking the plant: say "It is rooted in the soil."

Instead of smelling the plant: say "It smells no different than any other weed soaked full of summer sun."

Instead of smelling the flower: say "It smells like no flower you have come across."

Instead of talking to the plant: say "Your words disappear into the serenity brooding over the flower."

The flower is part of the plant. The flower is an enterable container. Understand "calyx" or "blue" or "blossom" as the flower. "A large, pale blue flower rests like a weary head on the sill." Description of the flower is "[if the player is normal]A closed calyx, the pale blue of the sky[otherwise]A large, somewhat asymmetrical flower, the petals a dreamy blue and close together. You could sit in it like a boat."

Instead of taking the flower: say "It is larger than you."

Carry out touching the flower: say "When your hand is a hair away from the petal, a feeling of contentment comes over you, like the moments before falling asleep."

Instead of attacking the flower with the razor:
	say "When you get close enough to strike, a sudden cramp claims your muscles and makes your hand sink."

Instead of eating the flower: say "Try as you might, it always seems to be some inches away from your mouth."

Instead of talking to the flower: say "Your words disappear into the serenity brooding over the flower."

After entering the flower:
	if Flowerposition is 1:
		if Flowertravelled is 0:
			say "You get inside the flower's calyx. The petals feel warmer around you, and a slow tremor shakes the flower. When you look over the side, you are several inches above the window sill. The vine snakes up the cottage wall overhead, just fast enough to be noticeable by sight. Having nothing else to do but wait, you settle yourself as best you can[if the golden apple is in the flower] with the apple taking up most of the space[end if]. It seems as if the sky flickers above you.[paragraph break]Eventually, the tremor dies down, making you aware of its absence. The flower has come to rest outside the attic window.";
			now Flowerposition is 2;
			now Flowertravelled is 1;
			now the flower is in Window Outside;
		otherwise:
			say "You get inside the flower again, and it takes its slow journey up the cottage's side. It comes to rest just outside the attic window.";
			now Flowerposition is 2;
			now the flower is in Window Outside;
	otherwise:
		say "You get inside the calyx. Again, a slow tremor of life makes the petals hum beneath you. The vine retraces its path down the timbers. When you glance over the side, it seems like the trees outside the garden have shrunk, their foliage becoming less luxurious.[paragraph break]You come to rest at the edge of the lower window.";
		now Flowerposition is 1;
		now the flower is in Window Sill.

Instead of inserting the golden apple into the flower:
	say "Moving carefully to stay away from the edge, you give the apple a push. It settles safely in the calyx.";
	now the golden apple is in the flower.

Carry out going east with the golden apple from Window Outside:
	if the golden apple is in the flower:
		say "You are easily able to roll the apple out of the flower and into the shadowy attic room.";
		continue the action.

Carry out touching the wide sill: say "Dry and warm."

Instead of taking the wide sill: say "It is built into the cottage wall."

Before going south from Top of the Bench:
	if the player is normal:
		say "There is no point in perching on the window sill.";
		stop the action;
	otherwise:
		say "You skip onto the window sill.";
		continue the action.

Lawn is a room. Lawn is below Window Sill.

Instead of going down from Window Sill:
	if a random chance of 1 in 2 succeeds:
		say "You lower yourself as best you can from the sill and let go. It is still a grievous fall. The world swirls around you, and despite the tall grass, the impact knocks the air out of you.[paragraph break]When the snake slides up to you, you lie undefended. Fangs sink into your body, almost too quickly to hurt.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU";
	otherwise:
		say "You lower yourself as best you can from the sill and let go. The air whistles around you, but thanks to the cushioning grass, you make the fall with nothing worse than a sprained ankle.[paragraph break]As you get up to find out the lay of the land, a yellow-striped cat pads around the corner of the cottage. It's spotted you. It bounds towards you and sends you flying with the swipe of a paw the size of a war chariot. Dazed, you try to get up again, but something in your head is failing. In a moment, your skull crunches between the jaws.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

The can't push vertically rule is not listed in any rulebook.

Instead of going south with the golden apple from Cottage Room:
	if Boardpositioned is 0:
		say "There is nowhere for it to go.";
		stop the action;
	otherwise:
		say "You roll the apple up the board. The slope makes it exerting, and you feel the wood creak below the solid weight of the apple, but soon you are up on the bench.";
		move the player to Top of the Bench;
		move the golden apple to Top of the Bench.

Kitchen is a room. Kitchen is west of Cottage Room. "A high room, tidy with scrubbed wooden walls and a stamped floor. Knives and copper pans hang on the western wall above a tall workbench. From the ceiling-beams hangs a web of strings of apples and onions, glinting with the light coming through the small unshuttered windows.[if Firehappening is 1][paragraph break]While most of the floor is still safe, little leaf-like flames are spreading across the walls and towards the ceiling.[end if][paragraph break]A doorway to the east leads back to the main room."

Instead of listening to Kitchen:
	if Firehappening is 0:
		say "The rustle of the flames all around you.";
	otherwise:
		say "Everything is quiet."

The flames are scenery. "Small, transparently thin, multiplying on the timbers and snaking along beams. Every moment you spend looking, they consume something."

The workbench is scenery in Kitchen. Description of the workbench is "A long-legged wooden construction, built into the wall."

Instead of climbing the workbench: say "Try as you might, the legs are too smooth for you to climb[if Questgiven is 1]. Even if you could climb it, there would be no way to get to the apples[end if]."

The knives are scenery in Kitchen. Description of the knives is "[if the player is shrunk]The workbench blocks most of your view[otherwise]Knives, tools, small bright copper pans, hanging from rows of nails on the wall[end if]." Understand "pans" as the knives.

Instead of taking the knives:
	if the player is shrunk:
		say "You can't reach.";
	otherwise:
		say "There is already a knife on the table."

Instead of smelling Kitchen:
	if Firehappening is 0:
		say "Salt pork, and old cooking-smoke, and fresh summer air seeping in under the rafters.";
	otherwise:
		say "The salty smell of smoke is around you. Underneath it, a toxic prickling at the back of your head."



The oven is an openable enterable container. The oven is in Kitchen. "In the middle of the floor stands an oven, made entirely of black iron[if the oven is closed]. A double hatch on the front is closed[otherwise]. The hatch is open[end if]. A narrow chimney leads almost all the way up to the smoke-vent in the ceiling." Description of the oven is "Made entirely of sheets of black iron riveted together and set on a gradated stone plinth. [if the oven is closed]The hatch on the front is closed[otherwise]The oven is open[end if]. Under the oven is a brick firebox." The oven is closed. Understand "hatch" or "baking oven" or "baking" as the oven. The oven is fixed in place.

The firebox is an enterable container. The firebox is part of the oven. Description of the firebox is "A low masoned box, brushed clean." Understand "fire-box" as the firebox.

Before entering the firebox:
	if the player is normal:
		say "You would never fit.";
		stop the action;
	otherwise:
		if Firehappening is 1:
			say "You would burn.";
			stop the action;
		otherwise:
			continue the action.

Instead of inserting the heat spirit into the firebox:
	say "You toss the mushroom into the firebox. Not one, but three of the living flames come out of the mushroom and scatter joyously across the space under the oven. As you look, more of them come into being, as if they are unfolding from one another.";
	remove the mushroom from play;
	move the heat spirit to the firebox;
	now Firehappening is 1;
	now Heat is 1;
	now the flames are in Kitchen;
	the timer rings in 1 turn from now.

Instead of inserting the mushroom into the firebox:
	if the heat spirit is in the mushroom:
		say "You toss the mushroom into the firebox. Not one, but three of the living flames come out of the mushroom and scatter joyously across the space under the oven. As you look, more of them come into being, as if they are unfolding from one another.";
		remove the mushroom from play;
		move the heat spirit to the firebox;
		now Firehappening is 1;
		now Heat is 1;
		now the flames are in Kitchen;
		the timer rings in 1 turn from now;
	otherwise:
		continue the action.

Instead of inserting the heat spirit into the oven:
	try inserting the mushroom into the firebox.

Instead of inserting the mushroom into the oven:
	try inserting the mushroom into the firebox.

At the time when the timer rings:
	if the player is in Kitchen:
		say "You hear the panicked tinkle of claws on metal, and indistinct voices booming inside the chimney.";
		now Ratspanicked is 1;
		the second timer rings in 1 turn from now;
	otherwise:
		now Ratspanicked is 1;
		the second timer rings in 1 turn from now.

At the time when the second timer rings:
	if the player is in Kitchen:
		say "The rats burst out of the heated oven. Without even giving you a glance, they skedaddle out the kitchen doorway, too fast for your eyes to register more than a packed flurry of fur and scrabbling claws. The noise fades.";
		now Ratspresent is 0;
		move the white rat to Fakeroom;
		move the black rat to Fakeroom;
		the third timer rings in 3 turns from now;
	otherwise if the player is in Cottage Room:
		say "With a loud scampering, two large rats hurtle out of the kitchen, pressed so close together they are almost a single ball of fur. Without paying you any heed, they scrabble up the stairs and you see them no more.";
		now Ratspresent is 0;
		move the white rat to Fakeroom;
		move the black rat to Fakeroom;
		the third timer rings in 3 turns from now;
	otherwise:
		now Ratspresent is 0;
		move the white rat to Fakeroom;
		move the black rat to Fakeroom;
		the third timer rings in 3 turns from now.

Fakeroom is a room.

At the time when the third timer rings:
	the fourth timer rings in 8 turns from now;
	if the player is in Kitchen:
		say "The flame spirits have so multiplied, you can no longer tell which ones are living beings and which ones are just flames. They are bubbling in the firebox, threatening to spill over the sides.";
		now the flames are in Kitchen;
		now Heat is 2;
	otherwise if the player is in Chimney Shaft:
		say "The heat grows underneath you, the air in the shaft going from warm to sweltering.";
		now the flames are in Kitchen;
		now Heat is 2;
	otherwise:
		now the flames are in Kitchen;
		now Heat is 2.

At the time when the fourth timer rings:
	now Heat is 3;
	now the rush-covering is burnt;
	the fifth timer rings in 12 turns from now.





At the time when the fifth timer rings:
	if Firedefeated is 1:
		stop the action;
	otherwise:
		if the player is in Kitchen:
			say "The timbers and ceiling have caught completely. As burning fragments start falling, you are mercifully unconscious, your lungs gasping at boiled and useless air.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in a subterranean room:
			say "You can hold out longer down here, in the dank chill, but when the flames gnaw through the trapdoor, they suck out the air here as well.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Cottage Room:
			say "With a soft roar, the rushes catch fire around you. Even the pain is brief.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Staircase:
			say "The flames roar up the stairs. You have no time to react, let alone escape.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in the fire-pit:
			say "With a soft roar, the rushes catch fire around you. Even the pain is brief.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Attic:
			say "The flames are at the door. The thatch catches on fire, too abruptly for you to see anything but light.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in the strongbox:
			say "The flames are at the door. The thatch catches on fire, too abruptly for you to see anything but light.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Little Man's Burrow:
			say "A blast of sparks-laden air comes through the burrow. Soon, the woodwork is smouldering around you.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Window Outside:
			say "The flames are at the door. The thatch catches on fire, too abruptly for you to see anything but light.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Top of the Bench:
			say "With a soft roar, the rushes catch fire around you. Even the pain is brief.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Window Sill:
			say "The rushes of the room behind you catch fire with a soughing wind. Even the pain is brief.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in the flower:
			say "The rushes of the room behind you catch fire with a soughing wind. Even the pain is brief.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Chimney Shaft:
			say "The air around you contracts with heat. You roast to a crisp on the iron oven bottom.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Chimney Shaft Top:
			say "The air around you contracts with heat. You roast to a crisp on the iron wall.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in Chimney Ledge:
			say "The iron chimney begins to glow in murky spots around you. Soon, your body cooks on the metal.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE";
		otherwise if the player is in a suspended room:
			say "The kitchen is an inferno below you. For a time, you are able to manage, even with the heat and the breathlessness, but the flames race to the ceiling and eat through the strings. You fall through the surrounding flames.";
			end the story saying "YOU HAVE DIED IN THE BURNING HOUSE".



The plinth is scenery in Kitchen. Description of the plinth is "Masoned from unplaned stone."

Instead of taking the oven:
	if Ratsencountered is 0:
		say "It is built onto a stone plinth set in the earth floor. Not even a giant could budge it.";
	otherwise:
		if Ratspresent is 0:
			say "It is built onto a stone plinth set in the earth floor. Not even a giant could budge it.";
		otherwise:
			say "Even if you were able to budge it, you are not going anywhere near it while they are in there."

After opening the oven:
	if Ratsencountered is 0:
		say "The moment before you touch the hatch, you hear a metallic chinking and the two doors swing open. A large white rat pokes its head out of the left door. An equally large black rat pokes out of the right one.";
		now Ratsencountered is 1.

Instead of climbing the oven:
	if Ratsencountered is 0:
		say "As you step up to the iron structure, you hear a metallic chinking and the two doors swing open. A large white rat pokes its head out of the left door. An equally large black rat pokes out of the right one.";
		now the oven is open;
		now Ratsencountered is 1;
	otherwise:
		if Ratspresent is 0:
			say "You are not going anywhere near it while they are in there.";
		otherwise:
			if the player is shrunk:
				say "The outside surface is polished black iron, hardly scalable.";
			otherwise:
				say "There is no need."

Instead of climbing the chimney: try climbing the oven.

Instead of attacking the oven:
	if the player is shrunk:
		say "You are too small to even make an echo. You only hurt your hand.";
	otherwise:
		say "The metal booms hollowly."

The trough is a container. The trough is in Kitchen. "A[if the player is shrunk] huge[end if] water-trough stands next to the oven." Description of the trough is "[troughdescript]." The trough is fixed in place. Understand "water trough" or "water-trough" as the trough.

To say troughdescript:
	if the player is shrunk:
		say "Hollowed out from heavy oak. It stands right underneath the strings of apples";
	otherwise:
		say "Hollowed out from heavy oak. It stands right underneath the strings of apples.[paragraph break]The trough is filled nearly to the brim with murky water".

Instead of entering the trough:
	if the player is shrunk:
		say "You can't reach.";
	otherwise:
		say "That would only get your feet and legs wet."

Instead of taking the trough:
	if the player is shrunk:
		say "It is too heavy, and much too large.";
	otherwise:
		say "It is too heavy."

Instead of climbing the trough: say "The sides are too smooth."

Instead of inserting something into the trough:
	if the player is shrunk:
		say "You can't reach.";
	otherwise:
		say "That would serve no purpose."

Instead of inserting the mushroom into the trough:
	if the mushroom is burnt:
		say "You might put it out.";
	otherwise:
		say "You can't reach."

Filling it with is an action applying to two things. Understand "fill [container] with [thing]" as filling it with.

Before filling the ewer with water:
	if the quantity of water is in the ewer:
		say "There is already water in it.";
		stop the action;
	otherwise:
		if the player is holding the ewer:
			say "You dip the ewer, filling it with dark water.";
			now the quantity of water is in the ewer;
			stop the action;
		otherwise:
			try taking the ewer.

Before filling the ewer with something:
	say "You can't do that.";
	stop the action.

Before filling the strongbox with something:
	say "You can't do that.";
	stop the action.

The chimney is scenery in Kitchen. Description of the chimney is "You can make out the dark opening of a flue near the top, with an iron ledge outside, almost hidden by the strings of apples." The chimney is fixed in place.

Instead of taking the chimney: say "It is attached to the oven."

The white rat is an animal. The white rat is in the oven. "[whiteratdescript1]." Description of the white rat is "[whiteratdescript2]." Understand "white" or "white head" or "rats" as the white rat.

The black rat is an animal. The black rat is in the oven. "[blackratdescript1]." Description of the black rat is "[blackratdescript2]." Understand "black" or "black head" as the black rat.


To say whiteratdescript1:
	if the white rat is in the oven:
		say "A white rat sticks its head, pointy and snake-eyed, out of the oven hatch";
	otherwise:
		if Ratsdefeated is 0:
			say "A monstrous rat stands in your path. The heads and forequarters -- one white, one black -- seem like those of healthy rats, but the back parts of their bodies meld together, like a furred snake with two heads and no tail";
		otherwise:
			say "The rat-creature is slithering across the floor, fighting itself, paying no attention to you".

To say blackratdescript1:
	if the black rat is in the oven:
		say "A black rat sticks its head out on the other side of the hatch";
	otherwise:
		if Ratsdefeated is 0:
			say "Both heads are fixing their eyes on you";
		otherwise:
			say "The rat-creature is slithering across the floor, fighting itself, paying no attention to you".

To say whiteratdescript2:
	if the white rat is in the oven:
		say "Its short fur white, its teeth sharp, its eyes unblinking like pieces of amber. Most of it is hidden in the oven, but its whole body must be at least thrice as long as yours";
	otherwise:
		say "The forequarters of two rats, joined together to form one long snake-like body on short clawed legs. The black and black fur weave together in the middle. It is positioned so that its long body blocks most of the attic, and at either end is a head, teeth bared, eyes glaring like embers".

To say blackratdescript2:
	if the black rat is in the oven:
		say "Its short fur black, its teeth sharp, its eyes unblinking like pieces of glass. Most of it is hidden in the oven, but its whole body must be at least thrice as long as yours. It is as like the white one as a shadow";
	otherwise:
		say "The forequarters of two rats, joined together to form one long snake-like body on short clawed legs. The black and black fur weave together in the middle. It is positioned so that its long body blocks most of the attic, and at either end is a head, teeth bared, eyes glaring like embers".

Instead of taking the white rat: say "You know better than to get that close."

Instead of taking the black rat: say "You know better than to get that close."

Instead of eating the white rat: say "You know better than to get that close."

Instead of eating the black rat: say "You know better than to get that close."

Instead of eating the white rat: say "You know better than to get that close."

Instead of eating the black rat: say "You know better than to get that close."

Instead of touching the white rat: say "You know better than to get that close."

Instead of touching the black rat: say "You know better than to get that close."

Instead of attacking the white rat:
	if the white rat is in the oven:
		say "The rat simply darts its head back into the darkness of the oven, long before your fist can connect. You are certain there is a smirk on its face.";
	otherwise:
		say "You launch yourself at the rat and lay into it with your fists. It feels like you score one or two blows strong enough to hurt, but then the other head darts into the edge of your field of sight. Your last sensation is the crunch of teeth through your ribcage.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Instead of pushing the white rat:
	if the white rat is in the oven:
		say "The rat simply darts its head back into the darkness of the oven, long before your fist can connect. You are certain there is a smirk on its face.";
	otherwise:
		say "You launch yourself at the rat and lay into it with your fists. It feels like you score one or two blows strong enough to hurt, but then the other head darts into the edge of your field of sight. Your last sensation is the crunch of teeth through your ribcage.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Instead of attacking the black rat:
	if the black rat is in the oven:
		say "The rat simply darts its head back into the darkness of the oven, long before your fist can connect. You are certain there is a smirk on its face.";
	otherwise:
		say "You launch yourself at the rat and land a blow that you feel in your own knuckles. The black head hisses in pain.[paragraph break][bold type]'You dare to try to harm me, you little vermin?'[roman type][paragraph break]The jaws lunge for you, and you have no time to back out of its reach.[paragraph break]Then something slams into the black head from the side, distracting it. The white head snarls at its brother. [italic type]'You only speak my words!'[roman type][paragraph break]The black head draws back, like a cat about to lick itself after a fall.[paragraph break][bold type]'My words... I say what I want!'[roman type][paragraph break]With that, it goes for the white head, which spits and snaps a bite at its jaws. Soon the rat is fighting itself, snaking and biting on the floorboards like two polecats locked in battle.[paragraph break]Their fighting takes them closer to the stairway. They slip into the shadows, and you hear the biting and scrabbling continue down the stairs.";
		remove the white rat from play;
		remove the black rat from play;
		now Confronted is 0;
		now Questbrought is 1;
		now Ratsdefeated is 1.

Instead of pushing the black rat:
	if the black rat is in the oven:
		say "The rat simply darts its head back into the darkness of the oven, long before your fist can connect. You are certain there is a smirk on its face.";
	otherwise:
		say "You launch yourself at the rat and land a blow that you feel in your own knuckles. The black head hisses in pain.[paragraph break][bold type]'You dare to try to harm me, you little vermin?'[roman type][paragraph break]The jaws lunge for you, and you have no time to back out of its reach.[paragraph break]Then something slams into the black head from the side, distracting it. The white head snarls at its brother. [italic type]'You only speak my words!'[roman type][paragraph break]The black head draws back, like a cat about to lick itself after a fall.[paragraph break][bold type]'My words... I say what I want!'[roman type][paragraph break]With that, it goes for the white head, which spits and snaps a bite at its jaws. Soon the rat is fighting itself, snaking and biting on the floorboards like two polecats locked in battle.[paragraph break]Their fighting takes them closer to the stairway. They slip into the shadows, and you hear the biting and scrabbling continue down the stairs.";
		remove the white rat from play;
		remove the black rat from play;
		now Confronted is 0;
		now Questbrought is 1;
		now Ratsdefeated is 1.

Instead of attacking the white rat with the razor:
	if the white rat is in the oven:
		say "The rat darts its head back, your weapon clanging against the metal of the oven.";
	otherwise:
		say "You lunge at the rat, blade raised, but it swipes at you with its forepaw. Its claws catch on the razor, and it's all you can do to clutch the handle to prevent it flying out of your hands. You stumble back, dazed with the fact that you're still alive."

Instead of attacking the black rat with the razor:
	if the black rat is in the oven:
		say "The rat darts its head back, your weapon clanging against the metal of the oven.";
	otherwise:
		say "You launch yourself at the rat, blade raised. It swipes at you, but you stagger back in time, blade only nicking its foreleg. The black head hisses in pain.[paragraph break][bold type]'You dare to try to harm me, you little vermin?'[roman type][paragraph break]The jaws lunge for you, and you have no time to back out of its reach.[paragraph break]Then something slams into the black head from the side, distracting it. The white head snarls at its brother. [italic type]'You only speak my words!'[roman type][paragraph break]The black head draws back, like a cat about to lick itself after a fall.[paragraph break][bold type]'My words... I say what I want!'[roman type][paragraph break]With that, it goes for the white head, which spits and snaps a bite at its jaws. Soon the rat is fighting itself, snaking and biting on the floorboards like two polecats locked in battle.[paragraph break]Their fighting takes them closer to the stairway. They slip into the shadows, and you hear the biting and scrabbling continue down the stairs.";
		remove the white rat from play;
		remove the black rat from play;
		now Confronted is 0;
		now Ratsdefeated is 1.

Carry out talking to the white rat:
	if the white rat is in the oven:
		if Ratspanicked is 0:
			say "The white rat opens its mouth. The voice that comes out is unlike a human's, but comprehensible:[paragraph break][italic type]'We are not going to get out of here!'[roman type][paragraph break]The black rat chimes in:[paragraph break][bold type]'Get out of here!'[roman type][paragraph break]Four ember eyes, two of each colour, glare at you.";
		otherwise:
			say "The rat only glares at you, but makes no move to attack.";
	otherwise:
		say "They only growl as they poise themselves to strike."

Carry out talking to the black rat:
	if the black rat is in the oven:
		if Ratspanicked is 0:
			say "The black rat only watches you. The white one speaks instead:[paragraph break][italic type]'We are not going to get out of here!'[roman type][paragraph break]The black rat chimes in:[paragraph break][bold type]'Get out of here!'[roman type][paragraph break]Four ember eyes, two of each colour, glare at you.";
		otherwise:
			say "The rat only glares at you, but makes no move to attack.";
	otherwise:
		say "They only growl as they poise themselves to strike."





The flue is backdrop. The flue is in Kitchen and Chimney Shaft. Description of the flue is "[if the player is in Kitchen]A small dark opening; only the ledge underneath makes it clear that you're not imagining it. The strings of apples hang quite close to it." Understand "opening" as the flue.

The string of apples is backdrop. The string of apples is in Kitchen, Chimney Ledge, String One, String Two, String Three and String Four. Understand "strings of apples" or "strings" or "apples" as the string of apples. Description of the string of apples is "[applesdescript]."

To say applesdescript:
	if the player is in Kitchen:
		say "Fine yellow apples strung from the ceiling, as distant as the stars[if the golden apple is in String Four]. You recognise the one the gnome asked for: hanging a bit away from the chimney, it is clearly superior to its kin in colour, lustre and rotundity";
	otherwise if the player is in Chimney Ledge:
		say "The nearest string sways west of you, close enough to jump";
	otherwise if the player is in String One:
		say "The string trembles with your movements, but it is nearly as thick as your arm and holds up under the added weight";
	otherwise if the player is in String Two:
		say "The string trembles with your movements, but it is nearly as thick as your arm and holds up under the added weight";
	otherwise if the player is in String Three:
		say "The string trembles with your movements, but it is nearly as thick as your arm and holds up under the added weight";
	otherwise if the player is in String Four:
		say "You can see the twist of individual fibres".

Instead of taking the string of apples:
	if the player is in Kitchen:
		if the player is normal:
			say "You don't need those any more.";
		otherwise:
			say "Even if you were your old size, you could barely reach them.";
	otherwise:
		say "They are all knotted to nails in the beams. You would never be able to move an entire string by yourself."

The trapdoor is a door. The trapdoor is below Kitchen. "[if the player is in Kitchen]A trapdoor of unpainted boards is set in the floor[otherwise]Above you, sunlight falls through the trapdoor[end if]." Description of the trapdoor is "[if the player is shrunk]A vast surface of splintery planks. [end if]While it seems sturdy enough, there is a dark crack between the two door-halves." The trapdoor is closed. Understand "cellar door" as the trapdoor.

Instead of opening the trapdoor: say "[if the player is shrunk]You could never budge it[otherwise]You don't need anything down there[end if]."

Instead of going down from Kitchen:
	if Cellarfound is 1:
		try entering the crack;
	otherwise:
		try opening the trapdoor.

Instead of attacking the trapdoor with the razor: say "You would blunt it long before you got through the wood."

The crack is part of the trapdoor. The crack is an enterable container. Description of the crack is "[if the player is shrunk]A dark crevasse, issuing cold air that smells of soil. You could probably force yourself through it if you squeeze yourself together[otherwise]A couple of inches wide[end if]." Understand "crevice" or "crevasse" as the crack.

Instead of entering the crack:
	say "When the splintery boards are about your waist, you get a brief touch of panic, but just as easily your chest and head slip through and you land on the step underneath.";
	now Cellarfound is 1;
	move the player to Underground Stairs.

Instead of entering the oven:
	if Ratspresent is 1:
		say "The white rat darts its head out and hisses. The black rat does the same a fraction later, the two of them completely blocking the hatch.[paragraph break][italic type]'Are you just walking in here? What makes you think we will let you?'[roman type][line break][bold type]'Think we will let you?'[roman type][paragraph break]They pull back, satisfied that you are unable to come closer.";
	otherwise:
		if Appletaken is 0:
			move the player to Chimney Shaft;
		otherwise:
			say "You have no business going back up there."

Chimney Shaft is a room. "A shaft of soot-caked iron, wide as a tower around you. A series of little crampons runs up the wall, presumably all the way. From above, pale daylight falls in. The hatch is to the south.[paragraph break][if Heat is 1]The air is warm around you[otherwise if Heat is 2]The stench of heated metal makes your eyes water and your lungs revolt[otherwise if Heat is 3]A flame-pattern of red glows behind the char deposits[end if]."

Instead of smelling Chimney Shaft: say "The stink of heated metal pounds on your throat and the back of your nose."

Instead of smelling Chimney Shaft Top: say "The stink of heated metal pounds on your throat and the back of your nose."

Getting Out is a room. Getting Out is south of Chimney Shaft.

Instead of going south from Chimney Shaft:
	move the player to Kitchen.

The crampons are backdrop. The crampons are in Chimney Shaft and Chimney Shaft Top. Understand "crampon" or "series" or "series of crampons" or "ladder" as the crampons. Description of the crampons is "[if Heat is 0]Almost the perfect size for your hands. Maybe the rats have used them[otherwise if Heat is 1]Almost the perfect size for your hands. Maybe the rats have used them[otherwise if Heat is 2]They are warm like flesh under your palms, but the charred coating makes them bearable to touch[otherwise if Heat is 3]You need to climb as quickly as you can to avoid resting your hands on them[end if]."

Instead of taking the crampons: say "They are of a piece with the chimney wall."

Instead of climbing the crampons:
	try going up.

Chimney Shaft Top is a room. Chimney Shaft Top is above Chimney Shaft. "Clinging to the slowly warming crampons at the top of the shaft. Westward, pale daylight enters through a door-like flue."

Chimney Ledge is a room. Chimney Ledge is west of Chimney Shaft Top. "You are standing on a little iron ledge outside the opening[if Heat is 2]. The heat is bearable out here[otherwise if Heat is 3]. You are forced to move your feet constantly to keep the searing heat bearable[end if]. The chimney interior is back to the east.[paragraph break]To the west sways the closest of the drying-strings. You would be able to jump to it."

Instead of going east from Chimney Ledge:
	if the razor is not held:
		if the razor is not in Chimney Ledge:
			continue the action;
	otherwise:
		say "As you approach the opening, a gust of metal-acrid heat scorches you. If you try going down that way, you will roast."

Instead of jumping in Chimney Ledge:
	say "You cross the vast abyss underneath you and land easily on the closest string of apples.";
	now the player is in String One.

Before going west from Chimney Ledge:
	say "You cross the vast abyss underneath you and land easily on the closest string of apples."

String One is a suspended room. String One is west of Chimney Ledge. "You are holding on to the vertical string, the apple under your feet providing a rounded, swaying island. The other strings of apples are a floating forest to the west. To the east is the chimney, reachable by a jump[if the golden apple is in String Four]. The golden apple gleams with the full sunlight, hanging on the string to the northwest[end if][if Heat is 3].[paragraph break]You can smell smoke in the air[end if]."

Instead of jumping in String One:
	say "You need to specify which direction you want to go."

Instead of dropping something in String One:
	say "It might slip off."

Instead of dropping something in String Two:
	say "It might slip off."

Instead of dropping something in String Three:
	say "It might slip off."

Instead of dropping something in String Four:
	say "It might slip off."

Instead of smelling in a suspended room: say "The dried gold of the apples, and the peppery bite of smoke."

String Two is a suspended room. String Two is southwest of String One. "Another string in the little forest. The apple under you trembles when you move your feet[if the golden apple is in String Four]. You cannot make out the golden apple anywhere[end if]."

Instead of jumping in String Two:
	say "You need to specify which direction you want to go."

String Three is a suspended room. String Three is west of String One. "Another string in the little forest. The apple under you trembles when you move your feet[if the golden apple is in String Four]. The apple gleams, hanging on the string just north of you[end if]."

Instead of jumping in String Three:
	say "You need to specify which direction you want to go."

String Four is a suspended room. String Four is northwest of String One. String Four is north of String Three. "Another string in the little forest. The apple under you trembles when you move your feet. The water-trough gleams dark underneath you."

Instead of jumping in String Four:
	say "You need to specify which direction you want to go."

The golden apple is an enterable supporter. The golden apple is in String Four. Understand "gleaming" or "round" or "full" as the golden apple. "[goldenappledescript]." Description of the golden apple is "The apple tree has honoured the gifts of the sun by creating something like it[if the golden apple is hit]. There is only slight bruising, despite its fall onto the earthen floor[end if]." The golden apple is trapped. The golden apple is pushable between rooms.

To say goldenappledescript:
	if the golden apple is untaken:
		say "The golden apple hangs surrounded on both sides by apples that look withered and colourless in comparison";
	otherwise:
		if the apple is in Trough Inside:
			if Applepushed is 2:
				say "The apple bobs right next to the rim of the trough.";
			otherwise:
				say "The apple bobs on the water not far from you";
		otherwise:
			say "You see a fine golden apple here".

Instead of eating the golden apple: say "Even a nibble, and the gnome might consider you to have broken your agreement."

Instead of attacking the golden apple: say "You don't want to damage it."

Instead of attacking the apple with the razor: say "You don't want to damage it."

Instead of entering the golden apple: say "Climbing onto it would be hard and serve no purpose."

Instead of putting anything on the golden apple: say "It would fall off."

Instead of taking the golden apple:
	if the golden apple is trapped:
		say "The apple is threaded on the string, with other apples above and below. Even if you were your full size, you wouldn't be able to get it off.";
	otherwise:
		say "It weighs more than you."

Instead of pulling the golden apple: say "Pushing it would be much easier."

Before pushing the golden apple:
	if the golden apple is trapped:
		say "The most you can do is rock it slightly.";
		stop the action;
	otherwise:
		if the player is in Trough Inside:
			if Applepushed is 0:
				say "Bracing against the apple with your palms and paddling ferociously with your legs, you force it closer to the rim. You seem to swim for minutes without making any headway, and it feels as if this task would be too much even for your giant self, but when you stop to gasp for air, the edge of the trough is closer.";
				now Applepushed is 1;
				stop the action;
			otherwise if Applepushed is 1:
				say "You brace against the water-slick apple a second time and paddle it towards the rim of the trough. By the time you reach the rim, your limbs are so exhausted you can barely keep afloat.";
				now Applepushed is 2;
				stop the action;
			otherwise if Applepushed is 2:
				say "With one final effort, you cling to the edge and heave the apple over the side. The force pushes you into the water over your head, but the apple is wedged onto the edge, teeters, and falls off.[paragraph break]You hear it thump onto the kitchen floor.";
				move the golden apple to Kitchen;
				now the golden apple is hit;
				now Appleout is 1;
				stop the action;
		otherwise if the golden apple is in the flower:
			if Flowerposition is 1:
				say "You easily roll the apple out of the calyx.";
				now the golden apple is in Window Sill;
				stop the action;
			otherwise:
				say "You easily roll the apple out of the calyx.";
				now the golden apple is in Window Outside;
				stop the action;
		otherwise if the player is in Cottage Room:
			if Boardpositioned is 1:
				say "You roll the apple up the board. The slope makes it exerting, and you feel the wood creak below the solid weight of the apple, but soon you are up on the bench.";
				move the player to Top of the Bench;
				move the golden apple to Top of the Bench;
				stop the action;
			otherwise:
				say "The apple rolls easily.";
				stop the action;
		otherwise if the player is in Attic:
			if Confronted is 1:
				say "The rats block the way to the burrow entrance. You wouldn't get the apple past them.";
				stop the action;
			otherwise:
				try inserting the apple into the hole;
				stop the action;
		otherwise:
			say "The apple rolls easily.";
			stop the action.

Understand "roll [something]" as pushing.



Instead of attacking the string of apples:
	if the player is in String Four:
		say "You could never tear it off with your bare hands.";
	otherwise:
		say "Even if you could tear off the string, it would serve no purpose."

Instead of attacking the string of apples with the razor:
	if the player is in String Four:
		say "You bend yourself to the task. The rope is as thick as an aspen sapling, and you feel every fibre as you saw through it, but the razor does not seem to dull.[paragraph break]With a hiss, the last fibres fray. The string breaks and you fall with the apples, all seeming to hang like star-globes in the air. Then you plunge into cold dark.[paragraph break]You feel the trough's bottom beneath your toes, then you shoot back up into the smoke-spicy brightness of the kitchen.[paragraph break]The apple is bobbing on the water not far from you.";
		now the player is in Trough Inside;
		now the golden apple is in Trough Inside;
		now the player is wet;
		now the golden apple is taken;
		now the golden apple is untrapped;
		now Appletaken is 1.





Instead of inserting anything into the crack: say "That would not benefit you."

Underground Stairs is a subterranean room. "Damp-slick cobblestone steps lead down through the chill soil. The steps are shallow enough to give you little trouble."

The cobweb is a thing in Underground Stairs. "[if Webpresent is 1]Ahead of you, a fine-meshed cobweb blocks the path.[otherwise]A huge cobweb fills the passage, but a door-shaped hole has been cut in it." Understand "web" or "spider web" or "spiderweb" or "spider-web" or "gossamer" as the cobweb. The cobweb is fixed in place.

Description of the cobweb is "The meshes are narrow even compared to your size. Between the ropes of gossamer, you think you can make out a faint blue glow[if Webpresent is 0]. The strands hang lax around a door-shaped hole[end if]."

Instead of taking the cobweb: say "The ropes feel tacky under your fingers. You let go before you become permanently stuck."

Instead of pulling the cobweb: say "The ropes feel tacky under your fingers. You let go before you become permanently stuck."

Instead of pushing the cobweb: say "The ropes feel tacky under your fingers. You let go before you become permanently stuck."

Instead of climbing the cobweb: say "There is nowhere to climb to, and you might get stuck."

Attacking it with is an action applying to two things. Understand "attack [thing] with [weapon]" or "cut [thing] with [weapon]" or "slice [thing] with [weapon]" or "slash [thing] with [weapon]" as attacking it with.

Before attacking something with the razor:
	if the player does not have the razor:
		try taking the razor.

Before attacking something with the knife:
	if the player does not have the knife:
		try taking the knife.

Instead of attacking the player with the razor:
	say "You swing the heavy razor at yourself. The blade slices the artery in your arm. Your life-warmth soon ebbs, then the light from your vision.";
	end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Instead of attacking the player with the knife:
	say "You slash at your arm with the meat-knife. Warmth gushes out of you.";
	end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Instead of attacking the little man with the razor:
	say "You rush at the little man, brandishing his own razor. He merely lifts his hand, and another flash of light sears you. This time, the results of the spell are not as pleasant.";
	end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Instead of attacking the cobweb:
	say "The strands are sticky, and filthy, and you soon realise that you cannot tear them up with your bare hands."

Carry out attacking the cobweb with the razor:
	say "Raising the shaving-knife in both hands as high as you can, you slash down through the web. The strands shiver, but nothing tries to stop you. Another slash, then a diagonal cut, and a section falls away, clearing your path.";
	now Webpresent is 0.

Crevice Interior is a room. Crevice Interior is above Underground Stairs.

Instead of going up from Underground Stairs:
	say "You scramble up and manage to get through the crack without too much difficulty.";
	move the player to Kitchen.

Northern Space is a room. Northern Space is north of Underground Stairs.

Instead of going north from Underground Stairs: try going down.

Southern Space is a room. Southern Space is south of Cold Cellar.

Instead of going south from Cold Cellar: try going up.

Cold Cellar is a subterranean room. Cold Cellar is below Underground Stairs. "A masoned cellar room, narrow and fairly long. There are no hatches or openings to let in the sun, yet it is not utterly dark. A blue glow moves through the cellar and glitters on the walls and earthen floor. Dark stacks of foodstuffs line the walls. The air is so cold it savages your skin, and the coating on the floor is no longer moisture, but frost.[paragraph break]The stairs in the south end of the room lead up, and a doorway leads north."

Before going down from Underground Stairs:
	if Webpresent is 1:
		say "You are not going anywhere as long as the spider's web is blocking your path.";
		stop the action;
	otherwise:
		say "As you lower yourself down step by step, you feel the draft against your skin grow winter-cold.";
		continue the action.

Instead of smelling in Cold Cellar: say "It smells like a night under the brilliant stars."

The floor is scenery. The floor is in Cold Cellar. Description of the floor is "A pattern of glittering frost."

The stacks are scenery. The stacks are in Cold Cellar. Description of the stacks is "Towering dark walls of baskets." Understand "piles" or "foodstuffs" as the stacks.

Instead of searching the stacks:
	if Questgiven is 0:
		say "The few baskets you can get a look inside contain onions, turnips, meat and round cheeses. You are not hungry yet.";
	otherwise:
		say "All the apples are strung from the kitchen ceiling."

The doorway is scenery. The doorway is in Cold Cellar. Description of the doorway is "Dark, but you can make out a flickering, smoky-red light."

The cold spirit is a person. The cold spirit is in Cold Cellar. "On the frost-hard floor, a little off from the middle, sits a circle of strange blue-glowing beings, each swaying gently." Understand "blue" or "cold spirits" or "cold creature" or "cold creatures" or "cold spirits" or "frost creature" or "frost creatures" or "ice spirits" or "ice creatures" or "ice beings" or "ice spirit" or "ice creature" as the cold spirit. Description of the cold spirit is "Onion-shaped beings from which the blue glow emanates. They might have been mistaken for flames, but the air around them is an aching cold. Each has a little face with eyes, fixed on you."

Instead of touching the cold spirit:
	say "You reach out your hand and feel the cold beginning to consume your skin. You still make some attempts to grab it, but the cold has made your hand a useless lump. Finally you withdraw it, and it seems a long time before life returns to your fingers."

Instead of taking the cold spirit:
	say "You reach out your hand and feel the cold beginning to consume your skin. You still make some attempts to grab it, but the cold has made your hand a useless lump. Finally you withdraw it, and it seems a long time before life returns to your fingers."

Carry out talking to the cold spirit:
	if Firehappening is 0:
		say "[one of]'We like it down here. Almost as cold as the darkness between the stars.'[or]'We doubt you would want to pick one of us up, little human.'[at random]";
	otherwise:
		say "The blue flames seem to burn straighter as they listen to you.[paragraph break]'Heat must be held in check. Thank you for telling us, little human.'[paragraph break]Without further words, the beings rise and zip across the cellar vault, vanishing one by one up the steps.[paragraph break]You realise you can no longer hear the perpetual rustle of the flames, and the smell of smoke dies down.[paragraph break]After a while's waiting, the spirits return.";
		remove the flames from play;
		now Firehappening is 0;
		now Firedefeated is 1;
		now Heat is 0;
		move the heat spirit to Warm Cellar.

Before going north from Cold Cellar: say "As you approach the dark doorway, the air around you becomes tolerable, then balmy, then hot."

Before going south from Warm Cellar: say "As you approach the doorway, you feel a blessed coolness in the air, deepening to star-etching cold."

Warm Cellar is a subterranean room. Warm Cellar is north of Cold Cellar. "A bare room, a little smaller than the one you came from. The only exit is a doorway to the south, where a draft of cooler air enters. Sacks of grain cast slow-stretching shadows on the walls.[paragraph break][if Heatspiritpresent is 1]The air is a dry, smoky heat that makes your eyes blink convulsively to stay moist[otherwise]It is warm here[end if]."

The sacks are scenery. The sacks are in Warm Cellar. Description of the sacks are "This grain is too hot and dry to grow again."

The heat spirit is a person. The heat spirit is in Warm Cellar. "A circle of dully-red creatures sits on the floor. They resemble flames, but flames with eyes." Understand "flame being" or "flame beings" or "fire spirits" or "fire spirit" or "fire creatures" or "fire creature" or "red circle" or "heat creatures" or "red" as the heat spirit. Description of the heat spirit is "[if the heat spirit is in the mushroom]It seems smaller than when moving freely, changing its size as easily as any flame. The eyes are large, turning this way and that[otherwise]Onion-shaped flames with eyes and faces, wider and lower than yourself. They turn to watch you, but seem neither hostile nor friendly[end if]."

Instead of touching the heat spirit:
	if Heatspirittouched is 0:
		say "Before your hand even gets close, the heat stings. You persist for a moment, but you can feel your skin breaking out in blisters and have to withdraw.";
		now Heatspirittouched is 1;
	otherwise:
		say "You lunge for it, trying to catch it in both arms before the heat can drive you away. You try to hold on, but before you can take more than a few steps, your clothes are smouldering. Flames soon lick up from your clothes and hair.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Instead of taking the heat spirit:
	if the heat spirit is in the mushroom:
		say "You already have it. Better not to risk disturbing it.";
	otherwise:
		say "Before your hand even gets close, the heat stings. You persist for a moment, but you can feel your skin breaking out in blisters and have to withdraw."




The block giving rule is not listed in any rulebook.

Instead of giving something to the little man:
	if the player is normal:
		say "You can leave him the cheese, that is enough.";
	otherwise:
		say "'I don't want anything you have. Bring me a fine apple from the kitchen, and I'll restore you.'"

Instead of giving something to the white rat:
	if the white rat is in the oven:
		say "[italic type]'We don't need anything you can give!'[roman type][line break][bold type]'You can give!'[roman type][paragraph break]Four eyes glare at you.";
	otherwise:
		say "[italic type]'Oh, it's too late now.'[roman type][line break][bold type]'Late now.'[roman type]".

Instead of giving something to the black rat:
	if the black rat is in the oven:
		say "[italic type]'We don't need anything you can give!'[roman type][line break][bold type]'You can give!'[roman type][paragraph break]Four eyes glare at you.";
	otherwise:
		say "[italic type]'Oh, it's too late now.'[roman type][line break][bold type]'Late now.'[roman type]".

Instead of attacking the cold spirit: say "Before you get close enough to touch it, your fists turn cramped, and senseless, and perhaps brittle. You stumble back in time. The creatures show no sign of having noticed."

Instead of attacking the cold spirit with the razor: say "As you bring the razor close to the creatures, a winter-star cold creeps from the edge into your fingers. You are forced to lower it before you suffer permanent injury. The creatures show no sign of having noticed."

Instead of giving the mushroom to the cold spirit:
	say "The cold beings pay it no attention."

Instead of giving something to the cold spirit:
	say "The cold beings pay it no attention."

Instead of giving the mushroom to the heat spirit:
	say "You hold out the mushroom. One of the flame creatures, indistinguishable from the others, jumps into the hollow and sits there, spinning around slowly.[paragraph break]The other creatures slowly scatter towards the sides of the room.";
	now the heat spirit is in the mushroom;
	now the mushroom is burnt.

Instead of showing the mushroom to the heat spirit:
	say "You hold out the mushroom. One of the flame creatures, indistinguishable from the others, jumps into the hollow and sits there, spinning around slowly.[paragraph break]The other creatures slowly scatter towards the sides of the room.";
	now the heat spirit is in the mushroom;
	now the mushroom is burnt.

Instead of inserting the heat spirit into the mushroom:
	if the mushroom is burnt:
		say "You can't.";
	otherwise:
		try showing the mushroom to the heat spirit.

Instead of giving something to the heat spirit:
	say "The creature spins slowly. 'How could that help me get past the cold spirits?'"

Instead of attacking the heat spirit:
	say "As you approach, the prickling in your skin becomes unbearable. You back off before your clothes start smouldering."

Instead of attacking the heat spirit with the razor:
	say "The edge lights up with a sooty glow, and irritated red prickles cover your hand. You step back before your fingers start charring."

Instead of smelling the heat spirit: say "You smell peppery smoke, and the choking heat of the core of the flames."

Carry out talking to the heat spirit:
	if Firehappening is 1:
		say "The s are as mute as the flames they are spawning.";
	otherwise:
		if Ratsencountered is 0:
			say "[one of]'The cold spirits are in our way! We would love to be out on the surface. Sun... deserts...'[or]'Apples? There were apples where we come from. Each a sun-globe burning the branch where it dangled.'[at random]";
		otherwise:
			if the heat spirit is in the mushroom:
				say "The creature looks around with large eyes, like an infant being carried to another room for the first time, and doesn't seem inclined to talk to you.";
			otherwise:
				if Firedefeated is 0:
					say "'If it's heat you need, we can help you. You will need to carry us upstairs, though. We can't get past the cold spirits on our own.'";
				otherwise:
					say "The s appear to be dozing."




Trough Inside is a room. "An oval surface of water around you, all the way to the darkened edges of the trough. Outside, the kitchen still seems unaffected by the fire, but the smoke prickles in the air."

Troughwest is a room. Troughwest is west of Trough Inside.

Trougheast is a room. Trougheast is east of Trough Inside.

Troughnorth is a room. Troughnorth is north of Trough Inside.

Troughsouth is a room. Troughsouth is south of Trough Inside.

Instead of going west from Trough Inside:
	say "You just have to get out."

Instead of going east from Trough Inside:
	say "You just have to get out."

Instead of going north from Trough Inside:
	say "You just have to get out."

Instead of going south from Trough Inside:
	say "You just have to get out."

Instead of smelling Trough Inside:
	if Heat is 1:
		say "The subdued smell of deep still water.";
	otherwise:
		say "Smoke hangs in the air."

The invisiblea cube is scenery. The invisiblea cube is an enterable container. Description of the invisiblea cube is "". The invisiblea cube is fixed in place.

The edge is scenery. The edge is in Trough Inside. The edge is an enterable supporter. Description of the edge is "Dark-streaked wood, wide enough that you can sit on it comfortably. A bit below you, you can see the stamped earth floor of the kitchen." Understand "rim" as the edge.

Instead of taking the edge: say "You can't."

Instead of going down:
	if the player is on the edge:
		if the golden apple is in Trough Inside:
			say "You are not leaving without it.";
		otherwise:
			say "You scramble over the edge, lower yourself and let go.";
			move the player to Kitchen;
	otherwise:
		continue the action.

Instead of exiting from Trough Inside:
	if Appleout is 0:
		say "You are not leaving without it.";
	otherwise:
		say "You scramble over the edge, lower yourself and let go.";
		move the player to Kitchen.

The water is backdrop. The water is in Trough Inside and Kitchen. Description of the water is "Dark but clear, smooth except where your flailing breaks it. It seems to continue far below you."

Instead of drinking the water: say "You sip some, not enough to make a visible difference. It is cold and sweet."

Instead of taking the water:
	if the player is in Trough Inside:
		say "You can't carry it in your hands.";
	if the player is in Kitchen:
		if the player is shrunk:
			say "You cannot get to it.";
		otherwise:
			if the player is holding the ewer:
				say "You dip the ewer, filling it with dark water.";
				now the quantity of water is in the ewer;
			otherwise:
				say "You can't carry it in your hands."

Instead of dropping the mushroom:
	if the mushroom is burnt:
		say "Any place you dropped it would likely go up in a blaze.";
	otherwise:
		continue the action.

After going east from Window Outside with the golden apple:
	say "You hear the apple bump onto the floorboards, and lower yourself after it.[paragraph break]The attic room is shadowy and quiet, but something new has arrived. As your eyes adjust, you see new outlines in front of you, and hear the hissing breath from two throats. The rats are crouched in front of you, blocking your way. Without the shelter of the oven, their monstrous single form is exposed to view.";
	now the white rat is in Attic;
	now the black rat is in Attic;
	now Confronted is 1.

Instead of going east from Attic:
	if Confronted is 1:
		say "You make an attempt at breaking through. The black rat head slithers into your path and snaps at you, eyes glowing like embers. You back away until the window wall is close behind you, and the head gives up pursuit for now.";
	otherwise:
		if Cursewaiting is 1:
			if the heavy door is closed:
				try opening the heavy door;
			otherwise:
				continue the action;
		otherwise:
			continue the action.

Instead of going west from Attic with the golden apple:
	if Confronted is 1:
		say "There is no way to get the apple up to the window.";
	otherwise:
		say "There is no way to get the apple up to the window. Nor do you need to."

Instead of going east from Attic with the golden apple:
	if Confronted is 1:
		say "The rats hiss at you, their maws and smouldering eyes more serpentine than rodent.";
	otherwise:
		say "You have not come this far to bring the apple back downstairs."

Instead of inserting the golden apple into the hole:
	if Ratsdefeated is 1:
		say "As you roll it towards the hole, you see a little man in the red hat step outside. Even at this distance, you can tell that he has a smirk on his face. He steps up to you and puts a proprietary hand on the apple.[paragraph break]'Thank you, and well done. Shake on it?' He holds his other hand out for you. 'And mind your head.'[paragraph break]As you take the gnome's hand, a blinding light fills your eyes, and some vast force shakes you about.[paragraph break]You blink and stretch your arms and legs.[paragraph break]A voice calls from behind the door: 'Come down! Your supper's ready!'";
		remove the white rat from play;
		remove the black rat from play;
		remove the golden apple from play;
		remove the board from play;
		now Boardpositioned is 0;
		now the heavy door is closed;
		now Over is 1;
		now Mealtime is 1;
		now the player is normal;
		now mother is in Cottage Room;
		now father is in Cottage Room;
		now the dish of food is on the table;
		now the knife is on the table;
		move the little blue flower to Attic;		
		if Firedefeated is 0:
			remove the flames from play;
			now Firedefeated is 1;
			now Firehappening is 0;
		if the bedspread is carried:
			now the bedspread is normal;
		if the cheese is carried:
			now the cheese is normal;
		if the razor is carried:
			now the razor is normal;
	otherwise:
		say "The rats block the way."

The little blue flower is scenery. Description of the little blue flower is "The blue calyx of a flower leans gracefully onto the window sill."

Instead of taking the little blue flower: say "Perhaps it belongs there."

Mother is a woman. "[motherdescript]." The printed name of mother is "your mother". Description of mother is "[motherdescript1]." Understand "woman" or "giantess" or "giant-wife" or "giantwife" as mother.

To say motherdescript:
	if Mothereating is 0:
		say "Your mother stands at the foot of the stairs, watching you with a half-stern expression";
	otherwise:
		if Noticed is 2:
			say "The giant-wife has risen at her end of the table, watching you";
		otherwise:
			say "Your mother is tucking into the fish with the appetite of a young goddess".

To say motherdescript1:
	if Noticed is 2:
		say "The being has all the parts of a human, but is grey and corded like something born from the rocks rather than from a woman. Its expression is so alien, you cannot interpret it";
	otherwise if Noticed is 1:
		say "With her sun-tanned skin and bristle-thick black hair, she is a perfect replica of the mother you remember";
	otherwise if Noticed is 0:
		say "With her sun-tanned skin and bristle-thick black hair, she looks much like you. Her eyes always smile when she looks at you, even if her mouth is scolding".

Instead of taking mother: say "[if Noticed is 2]You are not going to[otherwise]You might be able to lift her off the ground, but that would be disrespectful[end if]."

Instead of touching mother:
	if Noticed is 0:
		say "When you brush against her, her skin feels cold, perhaps clammy. You involuntarily pull away and don't know whether she has noticed.";
		now Noticed is 1;
	otherwise if Noticed is 1:
		say "You don't really want to.";
	otherwise if Noticed is 2:
		say "It will kill you if you get that close."

Instead of pushing mother:
	if Noticed is 2:
		say "To tangle bare-handed with such a creature would be death.";
	otherwise:
		say "You make an attempt at grappling her. Her kirtle feels coarse, more like fur than wool, and when you brush against her skin, it feels unlike human skin.[line break]Your mother casts a lightning glare at you. 'Sit quiet and eat.'"

Instead of going up with mother:
	say "You can't do that."

Instead of going west with mother:
	say "You can't do that."

Instead of going south with mother:
	say "You can't do that."

Instead of pulling mother:
	if Noticed is 2:
		say "It could kill you.";
	otherwise:
		say "There would be no point."

Instead of attacking mother:
	if Noticed is 2:
		say "To tangle bare-handed with such a creature would be death.";
	otherwise:
		say "You drive your fist towards her face. A great grey hand grabs your arm and holds you powerless for a moment, then the giant-wife swings you into the air. The flames of the torches whirl around you. You crash back first into the rock wall, a blaze of light flaring up behind your eyes.[line break]You slip to a sitting position against the wall. You see the giants approaching, but your body does not respond to your will.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".


Father is a man. "[fatherdescript]". The printed name of father is "your father". Description of father is "[fatherdescript1]." Understand "giant" as father.

To say fatherdescript:
	if Noticed is 2:
		say "The giant is watching you with eyes like ice-dull mountain pools";
	otherwise:
		say "Your father is sitting on the window-bench, munching salt-fish and turnip greens"

To say fatherdescript1:
	if Noticed is 2:
		say "A human-shaped thing from an older and crueller world. You don't even reach his waist";
	otherwise if Noticed is 1:
		say "Fair of hair and beard, bent from his own swelling muscles. [if Noticed is 1]This man is not your father, and perhaps not human";
	otherwise if Noticed is 0:
		say "Fair of hair and beard, bent from his own swelling muscles. Sometimes you dream that you are the child of a king or a god, but when he calls your name after returning home from the field, you wouldn't have any other man for a father".

Instead of taking father: say "[if Noticed is 2]You are not going to[otherwise]You are not going to treat your father that way[end if]."

Instead of touching father:
	if Noticed is 0:
		say "When you brush against him, her skin feels cold, a bit like putty. His breath smells like leaf-choked ponds. Your body feels chilled.";
		now Noticed is 1;
	otherwise if Noticed is 1:
		say "You don't really want to.";
	otherwise if Noticed is 2:
		say "It will kill you if you get that close."

Instead of pushing father:
	if Noticed is 2:
		say "To tangle bare-handed with such a creature would be death.";
	otherwise:
		say "You make an attempt at grappling him by the shoulders. He doesn't move more than a boulder would, and you can't tell whether he has noticed."

Instead of going up with father:
	say "You can't do that."

Instead of going west with father:
	say "You can't do that."

Instead of going south with father:
	say "You can't do that."

Instead of pulling father:
	if Noticed is 2:
		say "It could kill you.";
	otherwise:
		say "There would be no point."

Instead of attacking father:
	if Noticed is 2:
		say "To tangle bare-handed with such a creature would be death.";
	otherwise:
		say "You drive your fist towards his face. A great grey hand grabs your arm and holds you powerless for a moment, then the giant swings you into the air. The flames of the torches whirl around you. You crash back first into the rock wall, a blaze of light flaring up behind your eyes.[line break]You slip to a sitting position against the wall. You see the giants approaching, but your body does not respond to your will.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

The knife is a weapon. Understand "table-knife" or "meat-knife" as the knife. Description of the knife is "A slender knife for cutting your meat, with a snake pattern inlaid in the blade. It looks quite sharp."

The dish of food is a thing. Understand "food" or "meal" as the dish of food. The dish of food is edible. Description of the dish of food is "Crisp greens and a chunk of pale salt-fish from the cold cellar. The scents make your mouth water. When did you last eat?"

Instead of taking the dish of food: say "You are not going to carry food around in your pockets."

Instead of eating the dish of food:
	if Waterquestcompleted is 0:
		say "'I know you heard me. Go and fill up that ewer with water.'";
	otherwise:
		say "You fling yourself into your dish and scoff the food almost too quickly to feel how it tastes. Soon, all that is left is an oily stain around your lips and a few threads of green on the dish.";
		remove the dish of food from play;
		now Mealeaten is 1.

Instead of talking to mother:
	if Waterquestcompleted is 0:
		say "'Didn't you hear? Go and fetch the water.'";
	otherwise:
		say "She doesn't respond."

Instead of talking to father:
	if Waterquestcompleted is 0:
		say "'Didn't you hear? Go and fetch the water.'";
	otherwise:
		say "He doesn't respond."

Instead of giving the ewer to mother:
	if the quantity of water is in the ewer:
		say "Your mother takes just a half-step back. 'Just put it on the table.'"

Instead of giving the ewer to father:
	say "'Just put it on the table.'"

Instead of giving the knife to mother:
	say "She gently pushes it away. 'You need that to eat with.'"

Instead of giving the knife to father:
	say "He shakes his head. 'You need that to eat with.'"

The ewer is a container. "You see a maple-wood ewer here." Understand "maple" or "maple-wood" or "maple-wood ewer" or "bowl" or "vessel" as the ewer. Description of the ewer is "A low bowl with a pouring-spout, finely turned and smoothed so that the paler flecks of the wood grain form a pattern in the bottom." The ewer is fillable.

The quantity of water is a thing. Understand "dark water" as the quantity of water. Description of the quantity of water is "[ewerdescript]."

Instead of taking the quantity of water: say "It's already in the vessel."

Instead of drinking the quantity of water:
	if Waterquestcompleted is 0:
		say "You only sip the water. It tastes sweet.";
	otherwise:
		say "As you lift the bowl, your reflection looks back at you. It seems older and rougher-boned. It ripples into nothing as you drink a draught."

After putting the ewer on the table:
	if the quantity of water is not in the ewer:
		say "'You heard me, child. Go and fill it with water first.";
		stop the action;
	otherwise:
		say "As you put the ewer down, it jiggles on a bump in the wood. Instinctively, your father reaches out to steady it. No water is spilled, but quick as a blink of light, you see something else than the reflection of his hand, something grey and perhaps withered.";
		now Waterquestcompleted is 1;
		now Mothereating is 1.

To say ewerdescript:
	if the ewer is on the table:
		if Noticed is 0:
			say "You keep your eyes on the ewer. Neither your mother nor your father drink from it, as far as you can tell, but sometimes they move their hands over it when taking more food. The reflections of their hands and arms are grey and withered, not human";
			now Noticed is 1;
		otherwise:
			say "You reach for the ewer, and surreptitiously tilt it to see the reflection of the room.[paragraph break]You see yourself against a grey, cavernous hall, the roof far higher. Where your father should sit is a grey, craggy form, human only in its outlines, huge even in this vast space. Even your own reflection looks different: still tanned and black-haired, but older. Torches burn with cold halos on the distant walls, their flames something other than fire";
	otherwise:
		say "A mirror of dark, fresh water. You can see your reflection in it".

Instead of attacking mother:
	say "As you punch, a hand, withered-grey and more sinewy than that of the strongest man, effortlessly catches your fist. The creature flings you backwards. You feel your head and spine crash into the wall, then there is merciful blackness.";
	end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Instead of attacking father:
	say "As you go for him, the creature unfolds from the bench, seemingly twice the height of a man under the roof that is dwindling into shadows. It lifts you between its hands. As your feet leave the ground, all you can do is struggle until those huge hands snap your spine.";
	end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Instead of attacking mother with the razor:
	if the razor is shrunk:
		say "The only way anyone would be harmed by this would be if they were to eat it.";
	otherwise:
		if Fatherkilled is 0:
			say "You watch for her gaze to turn the other way, then reach out and slash her throat. She has time to notice and jolt her head away, but not far enough. Your arm seems to have grown in length and bulk, bridging the gap.[paragraph break]Hot blood spills over your hand and arm. For a long while, there is only your mother, slumping in her seat as her eyes lose focus, blood stiffening the front of her smock. Then, as if some nameless insect emerges from its cocoon, every part of her body twists and stretches. You are looking at a giantess, grey-skinned and ridged with muscle, but equally dead, slumped in her high stone seat. Even the blood coating your arm has a different colour and texture.[paragraph break]The male giant has risen from his seat, but is still vacillating, gaze flicking between you and the corpse.";
			now Motherkilled is 1;
			remove mother from play;
			move the player to Giant Hall;
			move father to Giant Hall;
			move the corpse of a giantess to Giant Hall;
			now Noticed is 2;
			the sixth timer rings in 1 turn from now;
		otherwise:
			say "As she slams her open hand down towards your face, you nick her thumb with the razor, giving yourself enough time to run onto the table and slash her throat. She continues to swipe at you even as blood rushes from the gash, getting in your mouth and eyes, until finally she slows, rolls her eyes back, and slumps cold against her seat.";
			remove mother from play;
			move the corpse of a giantess to Giant Hall;
			now Giantsdefeated is 1.

Instead of attacking mother with the knife:
	if Fatherkilled is 0:
		say "You watch for her gaze to turn the other way, then reach out and lodge the blade in her throat. She has time to notice and jolt her head away, but not far enough. Your arm seems to have grown in length and bulk, bridging the gap.[paragraph break]Hot blood spills over your hand and arm. For a long while, there is only your mother, slumping in her seat as her eyes lose focus, blood stiffening the front of her smock. Then, as if some nameless insect emerges from its cocoon, every part of her body twists and stretches. You are looking at a giantess, grey-skinned and ridged with muscle, but equally dead, slumped in her high stone seat. Even the blood coating your arm has a different colour and texture.[paragraph break]The male giant has risen from his seat, but is still vacillating, gaze flicking between you and the corpse.";
		now Motherkilled is 1;
		remove mother from play;
		move the player to Giant Hall;
		move father to Giant Hall;
		move the corpse of a giantess to Giant Hall;
		now Noticed is 2;
		the sixth timer rings in 1 turn from now;
	otherwise:
		say "As she slams her open hand down towards your face, you nick her thumb with the knife, giving yourself enough time to run onto the table and slash her throat. She continues to swipe at you even as blood rushes from the gash, getting in your mouth and eyes, until finally she slows, rolls her eyes back, and slumps cold against her seat.";
		remove mother from play;
		move the corpse of a giantess to Giant Hall;
		now Giantsdefeated is 1.

Instead of attacking father with the razor:
	if the razor is shrunk:
		say "The only way anyone would be harmed by this would be if they were to eat it.";
	otherwise:
		if Motherkilled is 0:
			say "The moment his attention shifts elsewhere, you draw the razor across his throat. He tries to cry out. His hand lashes for you, but flops onto the tabletop.[paragraph break]For a slow moment, you do not know whether you have made a mistake. Then, as if a thick film were torn from the surface of your eyes, you see his limbs twist and warp into a huge grey bulk. The table itself and the very walls around you also warp, and grow.[paragraph break]At the end of the table, the giant-wife stands, petrified for another moment.";
			now Fatherkilled is 1;
			remove father from play;
			move the player to Giant Hall;
			move mother to Giant Hall;
			move the corpse of a giant to Giant Hall;
			now Noticed is 2;
			the seventh timer rings in 1 turn from now;
		otherwise:
			say "As he swipes at you, you brace yourself and turn the knife in his direction, fixing the blade through his palm. As he howls, you pull it free, scramble onto the table and get close enough to cut his throat. In his struggle, he makes a grab for you, but soon slumps back against his seat, eyes misting over.";
			remove father from play;
			move the corpse of a giant to Giant Hall;
			now Giantsdefeated is 1.

Instead of attacking father with the knife:
	if Motherkilled is 0:
		say "The moment his attention shifts elsewhere, you draw the knife across his throat. He tries to cry out. His hand lashes for you, but flops onto the tabletop.[paragraph break]For a slow moment, you do not know whether you have made a mistake. Then, as if a thick film were torn from the surface of your eyes, you see his limbs twist and warp into a huge grey bulk. The table itself and the very walls around you also warp, and grow.[paragraph break]At the end of the table, the giant-wife stands, petrified for another moment.";
		now Fatherkilled is 1;
		remove father from play;
		move the player to Giant Hall;
		move mother to Giant Hall;
		move the corpse of a giant to Giant Hall;
		now Noticed is 2;
		the seventh timer rings in 1 turn from now;
	otherwise:
		say "As he swipes at you, you stick the blade into the air and cut him across the palm. As he howls, you scramble onto the table and get close enough to cut his throat. In his struggle, he makes a grab for you, but soon slumps back against his seat, eyes misting over.";
		remove father from play;
		move the corpse of a giant to Giant Hall;
		now Giantsdefeated is 1.



At the time when the sixth timer rings:
	if Giantsdefeated is 1:
		stop the action;
	otherwise:
		say "The giant lifts you in one hand by the scruff of your neck. A quick twist would put an end to you now, but you see from the intelligence in his deep-set eyes that he intends to take his time. As the giant twists off the first of your limbs, your vision fails, and unconsciousness soon follows.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

At the time when the seventh timer rings:
	if Giantsdefeated is 1:
		stop the action;
	otherwise:
		say "You manage to evade a few times, but at last the giantess cups her hands around you. Light fails as she begins to squeeze, slowly enough to relish the popping of your bones.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

The corpse of a giantess is a thing. "The corpse of a giantess lies here, with the slackness of all things dead." Description of the corpse of a giantess is "Grey-skinned, thick-boned, clad in raw hides. The blood cooling on her front is a sickly bluish-black." The corpse of a giantess is fixed in place.

Instead of searching the corpse of a giantess: say "You have no time to waste here."

The corpse of a giant is a thing. "The corpse of a male giant lies slumped against the bench." Description of the corpse of a giant is "Never human, more like a crag or a sea-storm given life." The corpse of a giant is fixed in place.

Instead of searching the corpse of a giant: say "You have no time to waste here."

Instead of taking the corpse of a giantess: say "You could never budge it."

Instead of pushing the corpse of a giantess: say "It is too heavy to push."

Instead of pulling the corpse of a giantess: say "It is too heavy to pull."

Instead of taking the corpse of a giant: say "You could never budge it."

Instead of pushing the corpse of a giant: say "It is too heavy to push."

Instead of pulling the corpse of a giant: say "It is too heavy to pull."

Giant Hall is a room. "It is bitter cold, darkness always luring just outside the torches. The hall is so great, you cannot even tell whether it is masoned or a cave.[paragraph break]A dark passage, rough and twisted as if gnawed out of the rock, leads west, and another seems to climb upwards. A vast portal leads south."

Passage is a room. Passage is west of Giant Hall.

Instead of going west from Giant Hall:
	if Giantsdefeated is 1:
		say "You take one last look back at the carnage. Sneaking, but not in the manner of prey, you proceed into the tunnels.";
		end the story saying "YOU ARE FREE";
	otherwise:
		say "You dart for the blackness of the passage, but the giant overtakes you in two steps.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

Upper Passage is a room. Upper Passage is above Giant Hall.

Instead of going up from Giant Hall:
	if Giantsdefeated is 1:
		say "You take one last look back at the carnage. Sneaking, but not in the manner of prey, you pick your way up the slope.";
		end the story saying "YOU ARE FREE";
	otherwise:
		say "You dart for the blackness of the passage, but the giant overtakes you in two steps.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".

The torches are scenery in Giant Hall. Description of the torches is "That is not fire clinging around their ends, it is some form of jelly-slow light, cold as the stars." Understand "torch" as the torches.

Instead of doing something other than examining with the torches:
	if Giantsdefeated is 1:
		say "It is too high for you to reach.";
	otherwise:
		say "The giant is trying to kill you!"

The portal is a door. "A portal masoned from sharply jagged blocks of stone leads south." The portal is south of Giant Hall. The portal is open. Description of the portal is "Rough, but well masoned. Merely looking at one of the blocks makes you feel their bone-smashing weight."

Mountain Path is a room. Mountain Path is south of the portal.

Carry out going south from Giant Hall:
	if Giantsdefeated is 1:
		say "The air is still cold around you as you step outside, but it smells of the freedom of the mountains. The stars and moon shine in the blackness over you and far below the winding mountain path.[paragraph break]You turn and face the cyclopean fastness of the giants one last time, then draw your cloak about you against the wind and set out for the valley.";
		end the story saying "YOU ARE FREE";
	otherwise:
		say "You run across the floor, darting around as the giant swipes for you. For a moment, your path to the gate seems clear, then a great hand grabs you and lifts your feet off the ground. You scrabble at it, your fingernails not even making a mark.";
		end the story saying "NO-ONE WILL KNOW WHAT HAPPENED TO YOU".