Distracted Wizard! by Hannah Madonna

Distracted Wizard!

Played 630 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Distracted Wizard!" by HJDM

The maximum score is 1.

When play begins:
      say "You have just woken up in your bedroom, at the top of the tower above the Burnt Dragon Tavern.  It is festooned with colorful silks on the walls, quills and ink everywhere, and various other wizardly accoutrements.  You are a little embarrassed you've let it get into this state.  As an up-and-coming young wizard,  you really should be devoting to yourself to your studies instead of partying and adventuring all the time. Your head is aching and you realize that perhaps you indulged in a bit too much of the tavern's fine dwarven ale. You definitely remember drinking (A LOT) and bragging to everyone there what a powerful wizard you are..."

Your Bedroom is a room. "[if your bedroom is unvisited]Today is the day you're going to buckle down and get to work.  Instead of letting yourself get distracted as usual, you're going to scribe spells into your spellbook.  The morning stretches out in front of you, full of potential. The heavy door on the north wall leads to your study.[paragraph break]However, you haven't eaten breakfast yet, and the passage to the east leads to the stairs down to the tavern where no doubt food will be waiting.  The window on the south wall leads to your zipline. Taking that will certainly not be conducive to work. What will you do?[end if][if your bedroom is visited]You are in your bedroom. The study is to the north behind the heavy door, the stairs are to the east, and your zipline outside is to the south. Where do you go now?[end if]"

The pile of clothes is a container in your bedroom. The description is "A large pile of what looks like clothing lies in a corner of the room. There are robes, a pair of pants, a few tunics, and a belt. It's mostly clean, you think, though the last time you washed any of it escapes your memory." The amulet is an object in the pile of clothes.

After taking the amulet:
    say "You see a long, gold filigree chain with a small onyx stone hanging from it.  This was a gift from Brannon, the fighter in your adventuring party who lives on the floor below yours in the tavern.  It took a long time to get him to open up. He's very no-nonsense and you're... well honestly, almost nothing but nonsense.  But you've proven your worth now, not only as the party's wizard but also as a friend.  You were so happy you probably would have cried when he gave you the amulet--commemorating the time you finally managed to throw a punch correctly--but he would have mocked you mercilessly for the rest of time, so you kept your gratitude mostly to yourself.[paragraph break]But it sure feels good to have a friend, doesn't it?" 

After inserting something which is carried by the player into the pile of clothes:
    say "Well you'll probably never see that again."

The mirror is an object in your bedroom. The mirror is fixed in place.
Instead of examining the mirror:
     say "A bleary-eyed face stares back at you in the gilt-framed mirror. You look a little rough after a fitful night of sleep, your hair in disarray and dark circles under your eyes. A blue glow peeks out of the neck of the shirt you're wearing: the protection tattoos you got a few years ago from Grogar, that half-orc in the seedy bar. You're still a bit squishy in a fight, but those will protect you about as well as some decent leather armor." 

The bookcase is a container in the bedroom. The bookcase is fixed in place. The description of the bookcase is "A slightly wobbly bookcase leans against the wall by your bed. There's no rhyme or reason to the contents here: it seems you just shove anything in your hands onto the bookcase to get it off the floor.  There's a replica dragon's egg, a bag of hard candy, and a number of strange tomes.  Even though you know you should be studying your magic, you can't help but be a bit curious as you run your hands along the leather of the spines.  It wouldn't hurt to examine one, just for a moment, right?" 

Inside the bookcase is a tome. The description of the tome is "You pull a book down from the shelf.  The title is written in golden lettering down the spine: [italic type][arcane title].[roman type]"

To say arcane title:
		choose random row in Table 1;
		say "[names entry]";   

Instead of taking tome:
     say "No, best to leave that for later."

Understand "book" as the spellbook.
Understand "tomes" as the tome.

The window is an open door. It is scenery. The window is south of your bedroom and north of zipline.
 
The stairway is east of your bedroom and above the tavern. The stairway is a room. "The stairway is steep and narrow, leading down from your tower to the tavern below.  There is a large painting on the wall, done in brilliant, vibrant color. Go down the stairs to get to the tavern, or west back to your bedroom."
 
The painting is fixed in place in the stairway. The painting is scenery. The painting can be enterable. The painting is enterable. The description of painting is "The large painting hangs on the wall in a fancy silver frame, with a small attribution card underneath. It depicts a verdant jungle filled with many different kinds of birds, all with beautiful plumage.  The colors are so bright you could swear that you are right there in the scene with them.  The longer you stare, in fact, the more you feel that you could step right through the canvas into the jungle.  One bird, with jewel-toned feathers and a golden beak that seems to glitter even in the dim light, seems so alive you could swear you could hear it squawking.  Perhaps if you reached out... And just touched it...[paragraph break]Just before your fingers brush the canvas it occurs to you that it's possible the painting is enchanted.[paragraph break]You're getting distracted again. Perhaps you could head back to your bedroom? Or, if you must, continue down to the tavern..." Understand "attribution" as the painting. Understand "card" as the painting. The printing of the painting is "the attribution card. The title of the painting is [italic type]Jungle Scene[roman type]. And then you see the artist's name.  Ahh, of course, that's right! It was a gift from your sister. She's becoming a rather well-known artist and you're proud you snapped up such a good piece before it went to auction.  And besides that, your sister is probably the only member of your family you get along with. It's nice to have something to remind you of her.[paragraph break]But wait. If she painted it... it couldn't be enchanted, could it? Is there a way to... step [italic type]into[roman type] the painting?  Could you try to [bold type]ENTER[roman type] the painting?"

After entering the painting:
     say "Your fingers touch the canvas and suddenly you find yourself sucked in to the busy jungle scene.  Birds are squawking and the air around you is humid and much warmer than the cool air of your comfortable tower.[paragraph break]It might be nice to explore here sometime, but for now you should probably get out of here.[paragraph break]Maybe you can [bold type]EXIT[roman type] the same way you came in?"
    

The tavern is below the stairway and west of the kitchen. The tavern is a room. "Though normally the tavern is bustling with activity, there is a sort of calm you've learned to appreciate in the morning before opening.  Everything is neat and clean and ready for any patrons that might come in for lunch.  However, no one is there. There are no delicious smells of breakfast cooking, though there is one flagon with the last dregs of ale in it. Somehow that doesn't sound very appetizing. Serves you right for neglecting your studies. Unless you want to head east into the kitchen, it's time to head back upstairs then.[paragraph break]You see a flagon on a table."

The flagon is in the tavern. The flagon is a container. The flagon is scenery. The description of the flagon is "This is one of the old mugs that the barkeep uses to serve the ale.  Is that... something in there... ?" 

Inside the flagon is the key. The key unlocks the heavy door. The description of the key is "A small, brass key with your initials engraved on it. You recognize this as the key to the heavy door that leads to your study."

Instead of taking the flagon:
     say "What are you going to do with that? Maybe you need what's inside it instead of the flagon itself."

After taking the key:
      say "Now you can unlock the door to your study and finally get to work! Up the stairs. Go, go!"

The Kitchen is east of the tavern. Syl is a person in the kitchen. The description is "You maneuver past the bar into the tavern's kitchen.  It is clean and well-stocked, with gleaming pots and pans, a stove, and barrels upon barrels of fine ale. You see Syl, a dwarven cleric and also the tavern's accountant."

The heavy door is north of your bedroom and south of the study. The heavy door is a closed, locked door. 

The study is north of the heavy door. The study is a room. "For the most part, your study is neat and orderly. And, compared to your bedroom, obviously neglected. You feel a twinge of guilt at how long it has been since you've sat down to work.  There is a bookshelf full of mysterious tomes against the far wall, and a crystal ball sitting atop a table covered in a black velvet cloth. In the center of the room, however, there is what looks like a portal of chaos.  It's your desk, or at least it was your desk. It's mostly just a shelf now.  Piles of papers are stacked with little care, wobbling precariously. An empty birdcage your familiar grew out of sits next to them.  There are bent quills, crystals, and some finely wrought runestones made of bone.  Perhaps you should examine the desk more closely."

The bookshelf is a container in the study. The bookshelf is fixed in place. The description of the bookshelf is "Against the wall stands a sturdy, well-made bookshelf. You've filled this bookshelf fit to bursting with books. There are books on magical theory, a biography of an evocation wizard you admire, some old textbooks, a book of drawings you did as a child, and several novels.  Yes, novels... Including...[paragraph break]Yes! There it is! Your favorite novel, The Amazing Adventures of the Mild-Mannered Mage.  You haven't read that in years.  You go to grab it, but now's not the best time. Maybe later." Inside the bookshelf is the novel. The description of the novel is "This thick, well-loved novel has a picture of Alex Xela, the Mild-Mannered Mage.  (The real twist is that he's not mild-mannered at all!)  You've always thought that maybe you bear a little bit of resemblance to him. Something in the face, at least. Like maybe you could be siblings." The printing of the novel is "[italic type]Alex Xela was a fine, young wizard, most mild-mannered in nature. He...[roman type] Hey! Snap out of it. You can read your novel later."

After taking the novel:
     say "Really? Is now really the time to be reading for pleasure? If you're going to pick up a book, perhaps it should be your spellbook! You know? The book with all the spells in it? The book that makes you a wizard?![paragraph break]Well it's in your inventory now, I hope you're happy."

The desk is a supporter in the study. Understand "papers" as the desk. Understand "chaos" as the desk. Understand "mess" as the desk. The description of the desk is "A large desk made of dark wood is in the middle of the room. You fondly remember selecting the piece, though the idea of having a lovely desk at which to study is much more attractive than, well, actually studying.  You vaguely remember leaving your spellbook on the desk at... some unspecified point in time.  (How long has it been again?)  It might still be there, if you search through those papers."

The birdcage is an object in the study. The birdcage is scenery. The description of the birdcage is "A well-made birdcage painted gold sits on your desk next to a large pile of papers. It's been empty for a long time, as your familiar is too big to fit in it now. He's also a bit of a diva, so even if he fit he probably wouldn't let you put him in the cage anyway." The printing of the birdcage is "[italic type]Michael [roman type] in your handwriting on a piece of paper affixed to the cage.  Ahh, Michael, your dear old familiar. Your shenanigans have gotten him killed once or twice, but luckily you always have the Find Familiar spell prepared!"

Instead of taking the birdcage:
     say "It's rather large and unwieldy, so best to leave it where it is."

Instead of taking the desk, say "You're a wizard! Put that big brain of yours to good use and use magic to lift the desk, not those weak arms of yours. Perhaps a SPELL? From a BOOK? That might help."

The crystal ball is an object in the study. The crystal ball is scenery. The description is "A mysterious glass orb sits on a small table covered in a crushed black velvet cloth.  A nebulous cloud of glittering particles swirls around inside." The printing is "a little placard that sits in front of the ball. It says [italic type]Mysterious and arcane crystal ball. Secrets inside?[roman type]"

Instead of taking the crystal ball:
     say "It probably would be a bad idea to take this, even though it might fetch a nice price."

The spellbook is an object. The description is "A large, rarely-used book bound in supple purple leather sits atop the desk.  Magical runes and elaborate scrollwork are etched into the leather, and a small onyx stone is set in the center of the book. You know, if you open it up, there will be far more blank pages than there should be. You should take it and get to work." The printing of the spell book is "your name written with a flourish in the inside cover. The first page is littered with arcane symbols you can feel pulsing with your own particular power. This is the culmination of your life's work up to this point.[paragraph break]...most of the book is empty." The spellbook can be found or lost. The spellbook is lost.

Instead of searching the desk when the spellbook is lost:
    now the spellbook is found;
    say "There's something there.  Something familiar. Yes! You've found your spellbook! It's been so long you've almost forgotten what it looked like.";
    move the spellbook to the desk.

After taking the spellbook:
    increase the score by 1;
    say "At last, you can finally get to work!"

Instead of searching the desk:
    say "There sure is a lot of junk on this desk. Nothing else you need, though. Maybe you should take the book so you can get to work."

Table 1
names
"Prestigious Prestidigitators"
"Gyms and Gemstones: When You Want to Transform From Sweaty to Sparkly"
"Magical Occupational Outlook"
"Cats. They're Great!"
"Magical Properties of Syrup"
"Runes and Reconciliations: Using Magic to Impress Your Family and Repair Relationships"

A thing has some text called printing. The printing of a thing is usually "nothing".

Understand the command "read" as something new. Understand "read [something]" as reading. Reading is an action applying to one thing. Carry out reading: say "You read [printing of the noun][line break]". Report reading: do nothing.


Rule for printing room description details of a container: stop.

[ENDING]

Every turn:
	if the player is in Zipline:
		say "The sun is shining and there are plenty better things to do that work.  Why bother, that spellbook will still be there tomorrow.  On to better and more exciting things. Zip away![paragraph break]Ahem.[paragraph break]Well, despite your--rather questionable it seems now--intentions, you decided to flitter off and have fun instead of actually doing any productive work.  Hmm.  Perhaps your father was right about you after all...?";
		end the story.


Every turn:
    if score is 1
    begin;
        say "When you pick your spellbook up, feel the heavy weight of it in your hands, recognition rushes through you. This is your magic, [italic type]your[roman type] power. For so long, everyone told you that you were useless, that you wouldn't amount to anything. But this you can do. This you understand. There's something empowering, you think, almost beautiful, in knowing what you're capable of.[paragraph break]There's plenty else that you could be doing, but you have your book. That's something. That's the first step. After all, those spells won't inscribe themselves. [paragraph break]Maybe you'll finally figure out that teleportation spell that's been giving you so much trouble.  Well, even if you don't, there's always your zipline!";
        end the story finally;
        end if.