Broken Stairs by Mary Swift

Broken Stairs

Played 2,202 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Broken Stairs" by Mary Swift

The story description is "Proof of concept, not much of an actual game. Can you make it to the top?"

The description of Yourself is "[description]".
To say description:
	If the score is 10:
		say "Well starched.";
		stop;
	If the score is greater than 7:
		say "A bit ragged around the edges.";
		stop;
	If the score is greater than 3:
		say "Battered and brused.";
		stop;
	Otherwise:
		say "A complete mess."
		
Understand "climb stairs" as a mistake ("Try just 'climb' or 'up' to make your way up to the top!")

Bottom of the Stairs is a room. "[if RubbleClimbing is happening]You stand at the foot of a rubble-strewn slope, littered with the sad remains of a staircase. Gathered near the top of the slope are the wicked little children you were sent to mind.[otherwise]You stand at the foot of some alarmingly wobbly granite steps. Gathered near the top of the stairs are the children you were sent to tutor.
The Reverend Mother warned you that they were a wild and unruly bunch, but you're certain that they're just misunderstood. You'll be getting along with them in no time!"

Top of the Stairs is a room. "A crowd of suddenly nervous children stand here, tucking rocks away into hiding."

Rubble is a region.

Rubble1 is a room in Rubble. "You stand near the bottom of a rocky slope, pieces of staircase scattered about you. Above you, the children start laughing mockingly, and, more alarmingly, start throwing rocks.".

Rubble2 is a room in Rubble. "You're near the midpoint of the rocky slope, loose stones turning underfoot. The mocking laughter above you grows louder, and, between rocks, you think you can hear some of the children making bets.".

Rubble3 is a room in Rubble. "You're near the top of the rocky slope, just a little bit more and you'll be on solid ground again!".

The printed name of Rubble1 is "Climbing the Rubble". The printed name of Rubble2 is "Climbing the Rubble". The printed name of Rubble3 is "Climbing the Rubble".

Bottom of the Stairs is down from Rubble1. Rubble1 is down from Rubble2. Rubble2 is down from Rubble3. Top of the Stairs is up from Rubble3. Nowhere is down from Top of the Stairs.

Instead of going while in the Top of the Stairs, say "After all your work to get up here, you've no desire to go anywhere else!".

Instead of going down from Rubble, say "You're not about to give up now! You have a duty[one of] to these children![or] to the Reverend Mother![or]![at random]" instead.

Before going to Rubble1:
	say "[if Rubble1 is unvisited]After climbing only a few steps, the stairs suddenly collapse beneath your feet, casting you to the rubble-strewn hillside! You think you hear the children snicker above you.[otherwise]You begin your long climb over from the beginning, resolving to be more careful of rocks.".

Before going to Rubble2, say "[if Rubble2 is unvisited]You climb your way up the rocky slope.[otherwise]Once again, your work your way up the rocky slope.".

Before going to Rubble3, say "[if Rubble3 is unvisited]You claw your way further up the rocky slope. You think you've almost made it.[otherwise]You claw your way back up to the top of the slope. 'This time', you tell yourself, 'This time [one of]I[']m going to make it[or]they'll be sorry[at random].'".

Before going to Top of the Stairs, say "You finally clamber up to the top of the stairs, ready to give these children whatfor!"

Understand "climb" as special climbing. Special climbing is an action applying to nothing. Instead of special climbing, try going up.

Children is a backdrop. The description of Children is "[GoblinDescription]". Understand "child" as Children. Children is everywhere.

 Instead of doing something other than examining Children while RubbleClimbing has not happened, say "Alas, they are still too far away." 

To say GoblinDescription:
	If location is Top of the Stairs:
		say "You're finally close enough to give these hellions what they deserve!";
	Otherwise if RubbleClimbing is happening:
		say "Out of your reach, at the top of the slope, your pupils await.";
	Otherwise:
		say "You see, up near the top of the stairs, a gathering of sweet and angelic children.".
	
The maximum score is 10. When play begins, now the score is 10.
	
RubbleClimbing is a scene. RubbleClimbing begins when Rubble1 is visited. RubbleClimbing ends when Top of the Stairs is visited.

Every turn during RubbleClimbing:
	If location is Bottom of the Stairs:
		say "[Idle]";
	Otherwise if a random chance of score in 20 succeeds:
		say "[You've Been Hit]";
		decrement the score;
		If the player is in Rubble1, now the player is in Bottom of the Stairs;
		If the player is in Rubble2, now the player is in Rubble1;
		If the player is in Rubble3, now the player is in Rubble2;
	Otherwise:
		say "[Missed]".
	
[to do - add alternate text, rotate randomly]
To say You've Been Hit:
	say "You duck as a thrown rock barely misses you, then lose your footing and slide backwards. Mocking laughter follows you.".
	
To say Missed:
	say "You hear jeers and catcalls from the children above you, and a rock goes whizzing by your ear.".
	
To say Idle:
	say "Loud conversation about how they hoped you'd last longer than the last governness drifts down from the hillside.".
	
When RubbleClimbing ends:
	scorecounting happens in one turn from now.
	
At the time when scorecounting happens:
	End the story finally.
Log in

Broken Stairs

Source Code
