MuddyFootprints by Mary Swift

MuddyFootprints

Played 2,760 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Footprints" by Mary Swift

The Story description is "A fast, lightweight game. Chase down your wayward and extremely muddy dog for a bath."
The release number is 2.

Use American dialect and the serial comma.

The maximum score is 2. The carrying capacity of the player is 2.

Chapter 1 - setup

Section 1 - Mud

A room has an object called FromWay. A room has an object called ToWay.

A room has a number called muddyness. The muddyness of a room is usually 0.

A room can be muddy or clean. A room is usually clean.

Definition: a room is muddy if the Muddyness of the location is greater than 0.

Mud is a backdrop. It is not scenery. [It is everywhere.]  The description of mud is "[MudTrack]". Understand "tracks" as Mud.

The printed name of mud is "[MudDesc]".

To say MudTrack:
	if the muddyness of the location is 0 and the location of fido is not the location:
		say "Your dog doesn't seem to have made it to this part of the house yet.";
	otherwise:
		say "[Muddy tracks come] [from where][heading towards where]";
	say run paragraph on.
   
 To say Muddy tracks come:
	if muddyness of location is greater than 16:
		Say "It's hard to pick out through all the mud, but the freshest tracks seem to come";
	otherwise if muddyness of location is greater than 8:
		Say "The multiple crossing tracks make it confusing, but you think the most recent tracks are coming";
	otherwise if muddyness of location is greater than 2:
		say "The freshest tracks seem to come";
	otherwise if Fido is visible:
		Say "Muddy tracks come";
	otherwise if muddyness of location is greater than 0:
		Say "The muddy tracks lead".

To say from where:
	say "from ";
	If FromWay of the location is nothing:
		If location is Bathroom:
			say "the tub";
		Otherwise:
			say "... well, from somewhere";
	otherwise:
		say "the [FromWay of the location]".
   
To say heading towards where:
	If ToWay of the location is nothing:
		If fido is visible:
			say " and lead straight to the culprit, still in the room and madly wagging his tail.";
		Otherwise:
			say " and don't go anywhere! Maybe he teleported.";
	otherwise if ToWay of the location is FromWay of the location:
		say " before doubling back the way they came.";
	Otherwise:
		say ", heading towards the [ToWay of the location].".

To say MudDesc:
	let muddy be the muddyness of location;
	If there is a muddy of muddy in the Table of MudDescriptions:
		say "[description corresponding to muddy of muddy in the Table of MudDescriptions]";
	Otherwise: [assume starts with a 'you can see', ends with 'here.']
		say "that the entire room is completely coated with mud. You're pretty sure your dog is some kind of mud-generating monster now. There's no other way to explain what's going on".

[modified from Exit Descriptions - version 2 by Matthew Fletcher]
The amount is a number variable.
The amount is 0.

The num is a number variable.
The num is 0.

After printing the locale description (this is the show exits rule):
	[say "Debug - The muddyness of this room is [muddyness] - tracks lead from [FromWay] to [ToWay].";]
	[say "Debug - This room is [if muddy]muddy.[otherwise]clean.";]
	Change the amount to the number of adjacent rooms;
	repeat with destination running through adjacent rooms begin; 
	if the num is 0, say "You can go";
	let the way be the best route from the location to the destination, using even locked doors;
	if the way is a direction, say " [way] to the [the destination]";
	Decrease the amount by 1;
	Increase the num by 1;
	if the amount is 0, say ".";
	if the amount is 1, say ", and";
	if the amount is greater than 1, say ",";
	end repeat;
	Change the amount to 0;
	Change the num to 0.


Table of MudDescriptions
muddy	description [assume starts with a 'you can see', ends with 'here.']
0	"a surprisingly small amount of mud"
1	"some spatters of mud dotting the room"
2	"smudges of mud"
3	"streaks of mud"
4	"muddy tracks criss-crossing the room"
5	"default mud description #5"
6	"default mud description #6"
7	"default mud description #7"
8	"default mud description #8"
9	"trails of mud winding through the room"
10	"default mud description #10"
11	"default mud description #11"
12	"default mud description #12"
13	"default mud description #13"
14	"default mud description #14"
15	"default mud description #15"
16	"default mud description #16"
17	"default mud description #17"
18	"default mud description #18"
19	"a staggering amount of mud coating the room"
20	"that the entire room is completely coated with mud. You're pretty sure your dog is some kind of mud-generating monster now. There's no other way to explain what's going on"

Section 2 - the Dog

Fido is a male animal. Fido is improper-named. The printed name of fido is "dog". The indefinite article of fido is "your". The description of fido is "Covered in so much mud, it's nearly impossible to see the actual dog. He bounces excitedly and barks, delighted to be playing this wonderful game with you!"

Understand "dog" as Fido.

Every turn (this is the rampaging dog rule):
	Let origin be the location of fido;
	increment the muddyness of origin;
	Let NextSpace be a random room which is adjacent to origin; [dog will go here]
	If fido is visible:
		[player and dog began in the same room]
		If the player carries the dog treat:
			increment the score;
			say "[line break]The dog manages to filch the dog treat right out of your hand and crunches it loudly!";
			say "[line break]";
			say "You suddenly realize that he is within grabbing distance![run paragraph on]";
			end the story finally saying "With a desperate lunge you tackle the dog and haul him away for his bath!";
		Otherwise:
			If the dog treat is in origin:
				say "The dog snarfs up your cleverly deployed bait, and rushes off to continue the game.";
				say "Perhaps you should rethink this plan.";
				remove the dog treat from play;
				say "[line break]The dog barks happily and charges off into another part of the house!";
			otherwise:
				say "The dog barks happily and charges off into another part of the house!";
	make tracks for NextSpace;
	if fido is visible:
		If the player carries the dog treat:
			say "The dog gallops in from the [FromWay of the location], knocking you over, then pauses to nose at the dog treat cluched in your fist.";
		Otherwise:
			say "The dog gallops in from the [FromWay of the location], knocking you over, and continues out the room without even slowing down.";
			make tracks for a random room that is adjacent to the location;
	update backdrop positions.
			
To make tracks for (destination - an object):
	Now FromWay of destination is the location of Fido;
	Now ToWay of the location of Fido is destination;
	[say "DEBUG: Fido going from [location of fido] to [destination].";]
	[showme FromWay of the location of Fido;
	showme ToWay of the location of Fido;
	showme FromWay of destination;
	showme ToWay of destination;]
	move fido to destination;
	increment the muddyness of destination.

Section 3 - the Exits

When play begins: 
	now left hand status line is "Exits: [if a room is adjacent][the list of adjacent rooms][end if][if a room is adjacent and a door is visible] and [end if][if a door is visible][the list of visible doors][end if]";
	now right hand status line is "Footprints";
	say "It's summer, and your dog managed to find the biggest and slimest mud pit in existance. You had almost managed to wrestle him into the tub when he slipped his collar and bolted for the rest of the house. You need to re-capture him before he does any serious mud-related damage to the house.";
	move the mud backdrop to all muddy rooms.
	
After printing the name of a room (called the target) while constructing the status line:
	let way be the best route from the location to the target;
	say " ([way])".
	
Rule for printing the name of a direction (called the way) while constructing the status line: 
	choose row with a heading of the way in the Table of Abbreviation; 
	say "[shortcut entry]". 

Table of Abbreviation 
heading	shortcut
north	"N"
northeast	"NE"
northwest	"NW"
east	"E"
southeast	"SE"
south	"S"
southwest	"SW"
west	"W"
up	"U"
down	"D"
inside	"IN"
outside	"OUT"

Section 4 - Messages for Every Action

After waving something:
	If the noun is the dog treat:
		If fido is in location:
			say "You wave the [noun] in your dog's general direction. He looks interested.[run paragraph on]";
		Otherwise:
			say "You wave the [noun] at empty air. Here doggy doggy doggy...";
	Otherwise:
		If fido is in the location:
			say "You wave the [noun] in your dog's general direction. [TryAgain]";
		Otherwise:
			say "You wave the [noun] grandly! But there's no time for that now, you've got a dog to catch!".

Instead of throwing the dog treat at fido:
	say "You toss the treat at your dog, who snaps it out of the air and crunches it loudly before rushing off to continue the game.";
	say "Perhaps you should rethink this plan.";
	remove the dog treat from play.

Does the player mean throwing the dog treat at the dog treat: it is very unlikely.

To say DogInterest:
	say "You reveal the dog treat to your dog, who sniffs at it with great interest.[run paragraph on]".

Instead of giving the dog treat to fido, say "[DogInterest]". Instead of telling someone about something, try asking the noun about it. Instead of answering the noun that something, try asking the noun about it.  Instead of asking fido about "dog treat", say "[DogInterest]".
Instead of showing the dog treat to fido, say "[DogInterest]".
Instead of tying the dog treat to fido, say "[DogInterest]".

Instead of clumsy behavior, say "[TryAgain]".

To say TryAgain:
	say "He wags his tail (spattering mud everywhere) and leaps away. You're going to have to be more cunning than that.";
	increment the muddyness of the location.

Taking fido is clumsy behavior.  Kissing fido is clumsy behavior.  Waking fido is clumsy behavior. Touching fido is clumsy behavior. Waving fido is clumsy behavior. Pulling fido is clumsy behavior. Pushing fido is clumsy behavior. Tasting fido is clumsy behavior. Buying fido is clumsy behavior. Turning fido is clumsy behavior.  Switching on fido is clumsy behavior. Switching off fido is clumsy behavior. Rubbing fido is clumsy behavior. Squeezing fido is clumsy behavior.  Tying fido to something is clumsy behavior. Drinking fido is clumsy behavior. Smelling fido is clumsy behavior. Swinging fido is clumsy behavior. Looking under fido is clumsy behavior. Searching fido is clumsy behavior.

Before opening or closing fido:
	say "[TryAgain]";
	stop the action.

Before climbing fido:
	say "[TryAgain]";
	stop the action.

Instead of throwing something which is not the dog treat at fido, say "[Never]".
Instead of giving something which is not dog treat to fido, say "[TryAgain]".
Instead of showing something which is not dog treat to fido, say "[TryAgain]".
Instead of tying something which is not dog treat to fido, say "[TryAgain]".

Instead of agressive behavior, say "[Never]".

To say Never:
	say "You couldn't do that! That might hurt your dog!"
	
Attacking fido is agressive behavior. Eating fido is agressive behavior. Burning fido is agressive behavior. Cutting fido is agressive behavior.

Instead of wasting time, say "[DogError]".

To say DogError:
	say "There's no time for that now! You've got a dog to catch!".

Attacking is wasting time. Kissing is wasting time. Touching is wasting time. Turning is wasting time. Squeezing is wasting time. Burning is wasting time. Thinking is wasting time. Smelling is wasting time. Tasting is wasting time. Cutting is wasting time. Jumping is wasting time. Tying is wasting time. Swinging is wasting time. Rubbing is wasting time. Setting is wasting time. Waving hands is wasting time.  Buying is wasting time. Singing is wasting time. Sleeping is wasting time. Pulling is wasting time. Pushing is wasting time. Switching on is wasting time. Switching off is wasting time. Drinking is wasting time.

Instead of climbing something which is not the chair, say "[DogError]".
Instead of opening or closing something which is not the cookie jar, say "[DogError]".

Instead of eating something, try tasting the noun.
		
Instead of tasting something, say "You already know what [noun] tastes like!".

Section 5 - Remaining Setup

Instead of listening, say "You don't hear anything. Your dog is surprisingly stealthy for a shambling mud monster."

The description of Yourself is "You're well-spattered with mud from the dog. You hope that you're not next in line for a bath."

The player is holding a collar. The description of the collar is "The thick coat of slimy mud covering this collar is probably what let the dog slip out of it in the first place." Understand "dog collar" as the collar. The collar is wearable.

After wearing the collar:
	say "You put on the collar, and mud oozes down your neck.";
	now the description of Yourself is "You're well-spattered with mud from the dog and from the dog collar you tried on. You suspect that you're next in line for a bath.".
	
After taking off the collar, say "You take off the collar, but that doesn't help the mud already on you."

After dropping the collar, say "It hits the ground with a squishy thump."

After taking the collar, say "You pick up the collar. It oozes mud through your fingers."

Instead of eating the collar, say "That's too gross, even for you.". Instead of tasting the collar, try eating the collar.

Instead of listening to the collar, say "You fancy you can hear the mud burble as it oozes off the collar."

Instead of smelling the collar, say "It reeks of muck and slime. You can't wait to get back out there."

Fido is in the Bathroom.

[The player is holding the dog treat.]

Chapter 2 - rooms

Section 1 - Bathroom

Bathroom is a room. "The bathroom, like the rest of the house, is a place of organized chaos. It contains the usual toilet, sink, mirror, and of course the bathtub." A toilet is here. The description of the toilet is "A short, off-white toilet, still with traces of crayan wax from where your sister drew on it". A sink is here. The description of the sink is "Crusted with dried toothpaste, soap, and the occasional toy". A tub is here. The description of the tub is "Still filled with warm water for the bath." Understand "bathtub" as the tub. A mirror is here. The toilet, the sink, the tub, and the mirror are scenery. A rubber ducky is here. The indefinite article of the rubber ducky is "your". The description of the rubber ducky is "It's your very favorite bath toy. You were going to add it to the dog's bath before he escaped."
The towels are here. The towels are scenery. The description of towels is "There aren't actually any towels in here, they're all outside.". Understand "towel" as towels.

The muddyness of Bathroom is 1.

Instead of examining a mirror:
say "Standing on your tiptoes, you can see yourself! At least, you can see yourself down to your nose. Below that it's a mystery."

Understand "duck" as the rubber ducky.

After taking the rubber ducky, say "You decide to bring along your rubber ducky for moral support, and pick it up."

After dropping the rubber ducky, say "You carefully set your rubber ducky down. It will make an excellent guard duck."

Instead of listening to the rubber ducky, say "It used to squeak when you squeezed it, but no longer."

Instead of eating the rubber ducky, say "Eat your very favorite rubber ducky??? Maybe when you were still a baby you would have, but now you're older and know better."

Instead of tasting the rubber ducky, say "It tastes like soap with a hint of rubber."

Instead of smelling the rubber ducky, say "It smells like soap with a hint of rubber."

Section 2 - Kitchen

Kitchen is a room. The counter is in the kitchen. The counter is scenery. The cookie jar is on the counter. The cookie jar is openable and closed. The description of the cookie jar is "It's decorated with cartoon dog bones." The description of the counter is "You've never figured out what kind of arcane magic Mom uses to open the cabinet doors, but the best stuff is on top of the counter anyway." The cabinet doors are part of the counter. The cabinet doors are scenery. The description of the cabinet doors are "As always, you are only able to open these a crack before they stop. There's probably nothing interesting inside, anyway."

Instead of opening the cabinet doors, try examining the cabinet doors.

Instead of climbing the counter, say "While you can indeed get high enough to fully survey the countertop, you don't have enough leverage to actually do anything. After a moment[one of], you drop back down to the floor[or], you drop back down to the floor. If only you had something you could stand on, then you could reach the cookie jar[stopping]."

Instead of climbing the cabinet doors, try climbing the counter.

Instead of opening the cookie jar:
	If the chair (called kitchenChair) is in the location:
		If cookie jar is closed:
			say "Standing on the chair, you pry open the cookie jar.";
			silently try entering kitchenChair;
			continue the action;
		Otherwise:
			say "It's already open!";
	Otherwise:
		say "You're far too short to reach. You're lucky you can even see the cookie jar.".
		
Instead of closing the cookie jar:
	If the chair is in the location:
		continue the action;
	Otherwise:
		say "You're far too short to reach. You're lucky you can even see the cookie jar.".
		
Instead of taking the cookie jar:
	If the chair is in the location:
		say "You tug at the jar, but it's too heavy to move easily. You leave it where it is.";
	Otherwise:
		say "You're too short to reach!".

A jumble of dog treats is inside the cookie jar. The description of the jumble of dog treats is "You consider the treats in the jar. Mom always yells at you when you try to eat these." Understand "treat" as the jumble of dog treats when the dog treat is off-stage.

There is a dog treat. The description of the dog treat is "It smells delicious. You can't understand why no one else eats these."

Instead of taking the jumble of dog treats:
	If a chair is in the location:
		If the dog treat is off-stage:
			If the dog treat is not handled:
				increment the score;
				say "You take a single dog treat from the jar. Mom might notice if you take more than one.";
			Otherwise:
				say "You take another dog treat from the jar. [one of]Mom probably won't notice two missing...[or]You hope you won't need more.[or]You'll just have to explain to Mom later.[stopping]";
			move the dog treat to the player;
		Otherwise:
			say "You reach for another treat, and hesitate. Mom is going to be mad enough already, better not push it.";
	Otherwise:
		say "You can't even reach the jar, let alone its contents!".

Instead of eating the dog treat:
	say "You can't resist, and gobble it down. [one of]Delicious as always![or]Delicious as always![or]You're feeling a bit queasy now.[stopping]";
	remove the dog treat from play.

The cookie counter is a number that varies. The cookie counter is 0.

Instead of tasting the dog treat:
	say "You nibble gently on the edge of the treat";
	If the cookie counter is less than 3:
		say ". Just a nibble, and no more...";
		try eating the dog treat;
		increment the cookie counter;
	otherwise:
		say ". Strangely, you have no urge to devour it.".
	
Instead of smelling the dog treat, say "It smells delicious. Surely just a taste wouldn't hurt..."

Instead of listening to the dog treat, say "You can almost hear the crunching."

After dropping the dog treat, say "You carefully place the dog treat on the floor, and wait."

After taking the dog treat, say "Thinking better of your cunning plan, you pick up the dog treat."

Section 3 - Dining Room

Dining Room is a room. The table is in the Dining Room. It is fixed in place. The description of the table is "It's covered in Dad's papers. You'll be in trouble if you mess any of them up." A chair is a kind of supporter. A chair is usually enterable. A chair is usually pushable between rooms. The description of a chair is usually "These chairs are the best kinds of chairs to climb on." The plural of chair is chairs. Four chairs are in the Dining Room.

Instead of entering the chair:
	If the location is the Dining Room:
		say "There's no point in climbing on the chair here - the only thing you can reach are Dad's papers on the table, and you'll be in trouble if you mess any of them up.";
		stop;
	If the location is the Kitchen:
		continue the action;
		stop;
	Otherwise:
		say "There's no point in climbing on the chair here.".
		
Instead of taking a chair, say "It's too heavy for you to lift - but you can at least push it between rooms."
	
Instead of climbing the chair (called testChair), try entering testChair.

Instead of pushing or pulling a chair, say "You'll have to push the chair in a specific direction."

[stolen from example 104 from the Inform Recipe Book]
After going a direction (called way-pushed) with something (called the thing-pushed): 
	say "You push [the thing-pushed] [way-pushed] to [the location]."; 
	continue the action. 

Instead of looking under the table, say "There is no sign of the dog underneath this table.".
Instead of searching the table, say "You can't actually see the top of the table. Nevertheless, you are sure the dog is not up there.".
Instead of turning the table, say "If only it were that easy.".

Section 4 - Other rooms

Hallway is a room. The description of Hallway is "The walls are covered in framed photos. Every year, Mom adds more."
The photos are scenery in Hallway. The description of photos is "They're all pictures of different people. You're only in a few of them."

Instead of taking the photos, say "They're too high up for you to reach, even standing on a chair."

Entryway is a room. "The front door is securely closed, and the baby-gate blocks off the stairs, so at least you don't have to worry about the dog getting upstairs." The baby-gate is in the Entryway. It is scenery. The description of the baby-gate is "There's a matching baby-gate at the top of the stairs. Your sister is still too young to handle the awesome responsibility of climbing stairs." Understand "baby gate" or "gate" as the baby-gate.

Taking the baby-gate is wasting time.

Living Room is a room. The small sofa is in the Living Room. The small sofa is a supporter. The small sofa is enterable. The description of the sofa is "[SofaDesc]".

Entering the sofa is wasting time.
Instead of looking under the sofa, say "There's no way the dog could fit under there!.".
Instead of taking the sofa, say "That's far to heavy to even budge.".

Instead of searching the sofa:
	if muddyness of location is greater than 2:
		say "There is nothing on the small sofa. Except for the mud, of course.";
	otherwise:
		say "There is nothing of interest on the small sofa.".

To say SofaDesc:
	if muddyness of location is greater than 16:
		Say "At this point, it's less of a 'sofa' and more of a 'sofa shaped mud pile'. Maybe Mom won't notice.";
	otherwise if muddyness of location is greater than 8:
		Say "It's solidly coated with mud. Maybe Mom won't notice.";
	otherwise if muddyness of location is greater than 2:
		Say "It's spattered with mud. Maybe Mom won't notice.";
	otherwise:
		Say "With only two cushions, it's hard to made a decent fort, but you get by".

Garage is a room. The description of the Garage is "It's full of Dad's tools and you're not allowed to be in here." The Garage door is a door. It is east of the Garage and west of the Living Room. The Garage door is closed. The description of the Garage door is "It's a portal to mystery and forbidden adventures.".
Tools are scenery in Garage. The description of Tools is "There are spinny things that cut, and pointy things that drill, and hammers, and nails, and screwdrivers, and wires, and you are never ever allowed to touch any of it.".

Instead of opening the Garage door, say "You can't do it. Dad will find out and then you'll be in trouble.".
Instead of smelling the Garage door, say "It smells like sawdust and mystery.".

Bathroom is north of Hallway. Entryway is south of Hallway. Dining Room is west of Hallway. Living Room is west of Entryway. Kitchen is west of Dining Room. Dining Room is north of Living Room.