It takes Dead-ication (Horror/Fantasy) by Pompi

It takes Dead-ication (Horror/Fantasy)

Played 1,742 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Dead-ication" by Pompi

[OPENING STUFF]

Include Basic Help Menu by Emily Short.
Include Basic Screen Effects by Emily Short.

When play begins:
	say "[bold type][red letters]Warning! Depending on your actions, this game may contain scenes of graphic fantasy violence. There is multiple endings, along with a pacifist, neutral and genocide route. If you are at all disturbed by fantasy violence and graphic dismemberment then I suggest you play a different game, or at least try to behave yourself in this one. [default letters][line break][line break][roman type][blue letters]The game is my first attempt at a long interactive fiction, and is untested by anyone other than me, so apologies in advance for the inevitable bugs. I'll be trying to fix them as I notice them. [line break][line break]There are a few non-standard commands in the game - look out for text written in capital letters, as this might give you a clue on how to progress (but probably not).[line break][line break]Thank you.[default letters]"

[PREPARE FOR END GAME]

Endgame is a scene. Endgame begins when the number of people who are alive is 0.
When Endgame begins:
	The siren goes off in 3 turns from now.;
	The evacuation begins in 8 turns from now.;
	The evacuation continues in 9 turns from now.;
	The evacuation ends in 10 turns from now.

At the time when the siren goes off:
	If the player is in The Town Square:
		Say "A siren goes off from behind the barricade. You wonder what's going on.";
	Otherwise:
		Say "A siren goes off from the direction of St. George's Square. You wonder what's going on."
At the time when the evacuation begins:
	If the player is in The Town Square:
		Say "A policeman climbs to the top of the barricade and announces through a megaphone, 'People! We are no longer aware of any surviving civilians in the town. Evacuation is now in progress. If you can hear this message, please try to contact the authorities and we will come back for you. We will come back!' The policeman and everybody else behind the barricade rush for the labs.";
	Otherwise:
		Say "From somewhere in the direction of St. George's Square you hear a voice speaking through a megaphone. It's hard to make out, but you can just about understand, 'People! We are no longer aware of any surviving civilians in the town. Evacuation is now in progress. If you can hear this message, please try to contact the authorities and we will come back for you. We will come back!'".;
At the time when the evacuation continues:
	Remove the policeman from play.;
	Now the barricade is unmanned.;
	If the player is in the Town Square:
		Say "You see the last of the people disappear into the labs and door shuts behind them."
At the time when the evacuation ends:
	Say "The sound of a helicopter taking off drowns out everything else in the town. Now there is nobody left except you and the monsters."

[SET UP DEATH TOLL SCORE]
Use no scoring.

Requesting the death toll is an action out of world. Understand "toll" or "death toll" as requesting the death toll. 
Carry out requesting the death toll:
	say "At the moment, you have killed [the number of people that are dead] of the townsfolk. On a lighter note, [the number of people that are escaped] people have escaped from you."
[PROPERTIES]
A thing can be fixed,  damaged, broken or destroyed. A thing is usually fixed.
A person can be alive, dead, undead, notcounted or escaped. The person is usually alive. The player is undead.
A thing can be pluggable or nonpluggable. A thing is usually nonpluggable.
A thing can be plugged or unplugged. A thing is usually unplugged.
A person can be hidden or unhidden. The person is usually unhidden. The player is unhidden.

There is a thing called the nothidden.
The player has a thing called the hiding place. The hiding place of the player is the nothidden.

[ACTIONS]
	[Scratching]
Scratching is an action applying to nothing. Understand "scratch" as scratching.
	[Screaming]
Screaming is an action applying to nothing. Understand "scream" as screaming. Understand "shout" as screaming. Understand "shriek" as screaming. Understand "cough" as screaming.
	[Playing]
Playing is an action applying to one thing. Understand "play [something]" as playing.
Carry out playing:
	Say "You play play it like a maestro, despite its obvious inadequacies as a musical instrument."
	[Jumping from]
Jumping from is an action applying to one thing.
Understand "jump from [something]" as jumping from.
Understand "jump off [something]" as jumping from.
Understand "jump over [something]" as jumping from.
Carry out jumping from:
	Say "Fun for a few minutes."
	[Chasing]
Chasing is an action applying to one thing and one visible thing.
Understand "chase [a person] [a direction]" as chasing.
Chasing around is an action applying to one thing.
Understand "chase [a person]" as chasing around.
Definition: a direction (called thataway) is viable if the room thataway from the location is a room.
Check chasing around:
	If the player is in something, try exiting;
	If the noun is dead:
		Say "[The noun] is dead - it won't be much of a chase.";
	Otherwise:
		Say "You chase [the noun] around for a bit, but get nowhere." instead.;
Check chasing:
	If the noun is dead:
		Say "[The noun] is dead - it won't be much of a chase." instead.;
	Otherwise:
		If the second noun is not viable, say "You chase [the noun] around for a bit, but get nowhere." instead.;	
Carry out chasing:
	silently try the noun going the second noun.;
	Say "Although you're not quick, you manage to corral [the noun] in the direction you want go.";
	try going the second noun.
	[Devouring]
Understand the command "eat" as something new. Devouring is an action applying to one thing. Understand "eat [something]" as devouring. 
Check devouring:
	If the noun is a person:
		If the noun is alive:
			Try attacking the noun instead.;
	If the noun is not a person:
		Say "Not edible. Not even for you." instead.;
Carry out devouring:
	If the noun is dead:
		Say "You [one of]munch on[or]gorge on[or]chow down on[or]feast on[or]guzzle at[or]feed on[or]snack on[or]devour[at random] the [noun]'s [one of]brains[or]heart[or]liver[or]eyes[or]face[or]lungs[or]skin[or]kidneys[or]intestines[or]thighs[or]arms[or]blood[at random]."
	[Dodging]
Dodging is an action applying to nothing. Understand "dodge" as dodging. Understand "duck" as dodging.
Carry out dodging:
	Say "You duck and weave like a prize fighter."
	[Kicking]
Kicking is an action applying to one thing. Understand "kick [something]" as kicking.
Check kicking something:
	If the noun is a person:
		If the noun is dead:
			Say "You give [the noun] a kick. Unsurprisingly, there is little response." instead.;
		If the noun is alive:
			Say "You try to kick [the noun] but your co-ordination is a bit off. You end up swinging at thin air and looking foolish." instead.;
Carry out kicking something:
	Say "You give the [noun] a kick."
	[Plugging in]
Plugging in is an action applying to one thing. Understand "plug in [something]" as plugging in. Understand "plug [something]" as plugging in.
Check plugging in:
	If the noun is not pluggable:
		Say "How on earth would you do that!?" instead.
	[Unplugging]
Unplugging is an action applying to one thing. Understand "unplug [something]" as unplugging.
Check unplugging:
	If the noun is not pluggable:
		Say "How would that even be plugged in in the first place!?"
[Typing]
Typing is an action applying to one topic. Understand "type [text]" as typing.
Check typing:
	If the player is not in The Alley, say "You simulate tapping on the keys of a typewriter, like a crazy person." instead. 
	[Hiding]
Hiding behind is an action applying to one thing. Understand "hide behind [something]" as hiding behind.
Carry out hiding behind:
	Say "What would be the point?"
	[Swiping]
Swiping is an action applying to one thing. Understand "swipe [something]" as swiping.
Check swiping:
	If the noun is not the security card:
		Say  "Swipe what with what? That seems a bit too random to be useful." instead.
Carry out swiping:	
Say  "You swipe, but manage to knock yourself off balance. You fall flat on your face, though it hurts less then you would have expected." instead.

[THE GAME!]
[Generic stuff not related to a room]
Instead of examining the player:
	say "You've seen better days if you're honest. You have quite a nice suit on, with a tie you've never seen before. One of your fingers seems to be broken (probably where you smashed your way out of the box) but you can't feel it, which is nice. Your skin is really pale, and you're quite itchy."
Instead of scratching:
	Say "You give yourself a good scratch. Quite a lot of skin flakes off."
Instead of screaming:
	say "You try to make a noise, but all that comes out is a throaty gargle, not loud enough for anyone outside to hear."
Instead of playing the player:
	say "Tricky... you whistle, and click your fingers."
Instead of kicking the player:
		say "You take a big swing and try to kick yourself in the face. Instead, you perform quite an astounding backflip. Shame nobody was recording that."
Instead of devouring the player:
	Say "You take a bite out of your forearm. You're definitely not as tasty as other people."
Instead of telling someone about something:
	Say "You try to speak, but a gargled groan is all that comes out. Perhaps you need a cough drop?"
Instead of asking someone about something:
	Say "You try to speak, but a gargled groan is all that comes out. Perhaps you need a cough drop?"
Instead of listening to the player:
	Say "You pause to listen to yourself. Weirdly, you can't even hear yourself breathing."

[The Box]
The Box is a room. "You seem to be lying down inside a box. It's not much bigger than you are, but there is some room to move your arms and legs around. [If the inside box is broken]The small amount of light coming in through the hole you punched doesn't really illuminate anything useful.[Otherwise]It's very dark and very claustrophobic in here. You're feeling hot and itchy. [End if]".
The inside box is scenery in The Box. The printed name of the inside box is "Box". The inside box is fixed.

Every turn when the player is in The Box and the inside box is fixed:
	say "You can hear some low mumbling from outside of the box."

Instead of examining the player when the player is in The Box:
	say "It's too dark to see anything. You don't think you're hurt, but you're beginning to panic a little."
Instead of examining the inside box when the player is in The Box and the inside box is fixed:
	say "There's a little bit of room to wriggle around. From the feel of it, the box is made of wood."
Instead of examining the inside box when the player is in The Box and the inside box is damaged:
	say "There's a little bit of room to wriggle around. From the feel of it, the box is made of wood."
Instead of listening when the inside box is fixed:
	say "The mumbling is too indistinct to make out the words."
Instead of jumping when the player is in The Box:
	say "You're lying down in a small box, but you try to jump anyway. Your bottom leaves the floor of the box and your nose connects with with the ceiling of the box. There's a crunch, but it hurts less than you expected. Idiot."

Instead of opening the inside box when the player is in The Box:
	say "There's no handle, and none of the walls move."
Instead of going a direction in the box:
	say "You're going nowhere while you're trapped in the box."
Instead of exiting when the player is in the box:
	say "You're going nowhere while you're trapped in the box."

Instead of attacking the inside box when the player is in The Box and the inside box is fixed:
	say "You give the top of the box a mighty thump. The wood is fairly flimsy, and gives slightly under your attack. The mumbling voices stop abruptly.";
	now the inside box is damaged.
Instead of attacking the inside box when the player is in The Box and the inside box is damaged:
	say "You give the top of the box another hit. Your arm goes straight through the wood. Immediately, somebody outside screams, and within seconds they are joined by a cacophony of other terrified shouts. What the hell is going on!? You need to get out of here before something bad happens!";
	now the inside box is broken.
Instead of attacking the inside box when the player is in The Box and the inside box is broken:
	say "Double fisted, you give the top of the box one final smash. The wood splinters into a thousand pieces and you burst out of your wooden prison!";
	now the inside box is destroyed.;
	now the player is in the broken coffin.
	
[The Cemetery]
The Cemetery is a room. "It's daytime, but the sky rolls with dark black clouds, and a cold cloying drizzle makes the graveyard almost as claustrophobic as the box was.[If the player is in the coffin] Actually, it turns out that the box you were in was a coffin. You're sitting in its splintered remnants.[End if] There are gravestones all around and there's a deep hole next to the coffin. There is a little church to the north. To the south, the church gate leads to the rest of the town. [if unvisited]A large crowd of people are fleeing in panic - there is much screaming, wailing and waving of arms.[end if]".

The broken coffin is an enterable container in The Cemetery. The broken coffin is scenery. The description of the broken coffin is "It's definitely a coffin. A pretty cheap one, but a coffin nevertheless. The lid is smashed up pretty badly. Why the hell did someone put you in a coffin!?"

The deep hole is an enterable container in The Cemetery. "The hole is rectangular, six-feet deep and empty. [If the priest is dead]There's a used priest at the bottom of the hole.[End if]". The hole is scenery.

The gravestones are plural-named scenery in The Cemetery. "Bits of stone with words and dates on. Some are a bit mossy. Not terribly interesting."

Instead of exiting when the player is in the broken coffin:
	say "With a groan, you climb slowly out of the coffin.";
	now the player is in The Cemetery.
Instead of going up when the player is in the broken coffin:
	try exiting.
	
Instead of entering the hole:
	say "You try to climb into the hole carefully, but you end up toppling in on your face.";
	now the player is in the hole.;
	if the priest is alive:
		say "The priest looks down into the hole and sees you in a tangle at the bottom. While you are recovering your dignity, he turns on his heels, and runs off across the graveyard, disappearing into a copse of trees.";
		remove the priest from play.;
		now the priest is escaped.;
Instead of exiting when the the player is in the hole:
	say "It's a bit of an effort, but you drag yourself out of the hole.";
	now the player is in The Cemetery.
Instead of going up when the player is in the hole:
	try exiting.
	
[The lines below force the player to do something with the priest - removed this so the blood lust is gone.]
[Instead of going somewhere in The Cemetery when the priest is alive and the priest is in The Cemetery and the player is not in the broken coffin:
	say "You want to leave, but something is stopping you from straying too far. You sniff the air and smell food... so hungry..."
Instead of going nowhere in The Cemetery when the priest is alive and the priest is in The Cemetery and the player is not in the broken coffin:
	say "You want to leave, but something is stopping you from straying too far. You sniff the air and smell food... so hungry..."]
	
	[Character - the priest]
The priest is a man in the Cemetery. The priest is alive. The description of the priest is "He cowers, covering his face with his bible - perhaps he's trying to protect himself from the rain? You can't make out the exact words, because he's speaking really quickly, but he seems to be mumbling a prayer. He's clearly terrified of something."
Instead of chasing the priest when the priest is alive:
	say "You try to provoke the priest into fleeing, but he's too afraid to turn his back on you."
	
Instead of attacking the priest when the player is in the broken coffin:
	say "It's difficult to go on a violent rampage when you're sitting in a box."	
Instead of attacking the priest when the priest is alive:
	say "This is a bit of an ethical dilemma. To be honest, you've always been quite anti-violence, preferring to use communication and negotiation to resolve conflict. Society would fall to pieces if everybody just hurt everybody else to get what they wanted. That said, you're pretty hungry... so in this instance you choose to rip the priest's intestines out through his stomach, and toss his quivering corpse into the hole. Mmmm, tasty.";
	now the priest is dead.;
	now the priest is in the hole.;
	now the priest is undescribed.;
	now the printed name of the priest is "dead priest".

Instead of examining the priest when the priest is dead:
	say "He's a bit of a bloody mess. There's a hole in his stomach with some intestines poking out, but you've already eaten all the best bits."
Instead of taking the priest when the priest is dead:
	say "If you carry him around, things are going to spill everywhere."	
Instead of taking the priest when the priest is alive:
	say "He tries to fend you off with his bible."
[The Church]	
The Church is north of The Cemetery. "It's picturesque little 16th-century chapel. You can feel the history oozing from the smooth stone columns... or it could just be damp. The doors through which you entered are massive and heavy. In front of you there are rows of empty pews. The entrance to the tower is to the west, and the front of the church is to the east.[If the verger is visible] The verger stares at you in fear... 'P-p-p-please don't CHASE me', she sobs.[End if]".

The pews are scenery in The Church. "Uncomfortable wooden seats."
The massive doors are scenery in The Church. "Ten feet high, eight inches thick, and heavily rivetted. It's lucky the hinges swivel so smoothly, or they'd be impossible to open. Without some kind of wedge, the doors swing shut by themselves when opened."
The columns are scenery in The Church. "Made of grey stone, they hold the ceiling up. Some have gargoyles on."

[The line below forces the player to do something with the verger - removed this so the blood lust is gone.]
[Instead of going south when the verger is alive and the player is in The Church:
	say "You try to leave the church, but the urge to eat the verger is almost overwhelming. You'll have to do something about it."]
	
	[Character - the verger]
The verger is a woman in The Church. The verger is alive. The description of the verger is "She has bright red hair, a short skirt and leather boots... admittedly unusual for a verger."

Instead of attacking the verger:
	Say "She's pretty agile, and avoids your clumsy attempts to chew her face off."

Instead of chasing the verger when the player is in The Church:
	let N be indexed text;
	let N be the player's command;
	If N matches the regular expression ".* south" or N matches the regular expression ".* s":
		say "You shamble around after the verger, but she doesn't have time to open the heavy doors of the church and escape before you catch up to her. She runs back into the pews.";
	Otherwise:
		Continue the action.
Instead of chasing the verger when the player is in The Top of the Tower:
	let N be indexed text;
	let N be the player's command;
	If N matches the regular expression ".* east" or N matches the regular expression ".* e":
		say "You manouevre the verger to the balcony. She has no choice but to jump... Amazingly, she grabs onto the rope and half climbs and half slides down to the tower floor. The ringing of the bell makes your head shake. You hear the verger escaping through the church doors.";
		remove the verger from play.;
		now the verger is escaped.;
	Otherwise:
		Continue the action.
Instead of chasing the verger when the player is in The Organ Balcony:
	let N be indexed text;
	let N be the player's command;
	If N matches the regular expression ".* west" or N matches the regular expression ".* w":
		say "You manouevre the verger to the railing. She has no choice but to jump... She screams as she plunges down into the church and there's a horrible squelch as she lands on the pulpit's angel wings. Peering over the side, you can see her pierced body hanging from the sculpture.";
		now the verger is dead.;
		now the verger is in The Front of the Church.;
	Otherwise:
		Continue the action.		
				
[The Tower Floor]
The Tower Floor is west of The Church. "The ground floor of the bell tower is plain to say the least. The only ornamentation is a bell rope hanging down from high up in the tower, and a flight of stairs heading up into the darkness.".

The rope is scenery in The Tower Floor. "A thick rope, dangling from high above."
Instead of pulling the rope:
	say "BOOONNNNG!!!"

The wooden staircase is scenery in The Tower Floor. "The stairs are wooden, and climb the inside of the tower in a kind of square spiral, if that makes any sense."

[The Top of the Tower]
The Top of the Tower is up from The Tower Floor. "It's hard to see up here. The only light comes in through a small slit window. The stairs end at a balcony to the east, which is adjacent to a big bell. The bell swings on a large wooden axle, to which a rope is attached."

The bell is scenery in The Top of the Tower. "It's made of metal and has a larger clanger inside."

The tower balcony is scenery in The Top of the Tower. "It's a wooden safety barrier, to prevent anyone who is examining the bell from plunging to the ground."

Instead of jumping from the tower balcony when the player is in The Top of the Tower:
	say "You throw yourself off the balcony and plummet to the bottom of the tower. There's quite a crunch as you land, and you suspect that various bits of your body have been inappropriately rearranged. It doesn't seem to have affected your mobility much though. You stand up.";
	now the player is in The Tower Floor.

Instead of going east in the Top of the Tower:
	Say "Fortunately, the balcony rail prevents you from toppling off the edge."

[The Front of the Church]
The Front of the Church is east of The Church. "In front of the pews is a pulpit, ornately decorated. Behind that is an altar, and above it is a balcony on which you can see a large pipe organ. A small spiral staircase goes up to the balcony. [If the verger is dead]The verger is bent backwards over the pulpit, the sharp wings piercing her chest. You take the opportunity to have a bit of a nibble on her innards.[End if]".

The pulpit is scenery in The Front of the Church. "It's quite an extraordinary sculpture. The priest can stand a few feet above his congregation, and his readings are held in the wings of a beautiful angel."
The angel is scenery in The Front of the Church. "Its features are exquisitely carved. However, the most impressive features are the wings. They are raised to the sky and finish in sharp points."
The altar is scenery in The Front of the Church. "It's basically a flashy table with some religious knick-knacks on it. You don't know what any of it does."
The front of church balcony is scenery in The Front of the Church. "It's a thin platform built over the pulpit where the organist can sit and play."
The spiral staircase is scenery in The Front of the Church. "It's a dainty little staircase, tightly spiralled, leading up to the organ balcony."

Instead of examining the verger when the verger is dead:
	say "Not much you can say about someone when their torso has been pierced by two pointy angel wings.";
Instead of taking the verger when the verger is dead:
	say "It's too difficult to get her off those wings."

[The Organ Balcony]
The Organ Balcony is up from The Front of the Church. "You're on a thin platform above the pulpit. There's a large organ to the east, and a railing which overlooks the pulpit and congregation to the west."

The railing is scenery in The Organ Balcony. "It's a low wooden railing, presumably to stop the organist from accidentally toppling into the congregation."
The pipe organ is scenery in The Organ Balcony. "It's an impressive instrument. Pipes reach to the ceiling and there are numerous keyboards and pedals."

Instead of playing the pipe organ:
	say "You knock out a passable Toccata and Fugue in D-Minor before one of your fingers falls off and makes playing too difficult."
	
Instead of jumping from the railing when the player is in The Organ Balcony:
	say "You toss yourself over the railing and shortly find yourself on the church floor, bouncing off the pulpit on the way down. Luckily you missed the pointy wings or it could have been nasty... You've still bent your leg in a very weird way, but it doesn't hurt.";
	now the player is in The Front of the Church.
[Chapel Street]
Chapel Street is south of The Cemetery. "The street is eerily quiet. The drizzle and the wind rattle the leaves on the trees, but apart from that you can't hear a thing. There's a yellow car on the road outside of the church gates. The road goes west, out of town, but you have no particular desire to wander off that way, particularly in this weather. To the east, up a fairly steep slope, is the rest of the town."

The churchyard trees are scenery in Chapel Street. "Tall and green."
The church road is scenery in Chapel Street. "It's an ordinary tarmac road, in need of some care by the local authorities, but not in terrible condition. It's quite level here at the church, but slopes up steeply towards the rest of the town."

The yellow car is in Chapel Street. The yellow car is undescribed. The yellow car is fixed. The description of the yellow car is "It's a repulsive shade of canary yellow. Rather carelessly, the owner has left the window wound down. Inside, you can see a radio, a handbrake, and a steering wheel. [If the yellow car is broken]There's quite a lot of damage to the side of the car from the collision."

The radio is part of the yellow car. The radio is a device. The radio is switched off.
After switching on the radio for the first time:
	say "Between screeches of static, you can hear a news broadcast, 'ksskkshhsks-some king of infectious dis-ksssshhssskkss-hundreds of-ksssk-killing indiscriminately and consuming human flesh-ssshhshksrshkkrssh-trapped here in studio six with a crowd of these monsters outside the door-kssksrshhkshkh-the DEATH TOLL must be in the-rrkshs-What!?No!Keep away! Aargh-ksrkshsshk-aaaarghegheugh-ksh-AAARGH!' The broadcast alternates between screaming and static for about a minute... then just static."
Instead of listening to the radio when the radio is switched on:
	Say "Just static now."

The handbrake is part of the yellow car. The handbrake is a device. The handbrake is switched on. Understand "brake" as the handbrake.
Instead of pushing or pulling the handbrake:
	If the handbrake is switched on:
		say "You release the handbrake.";
		now the handbrake is switched off.;
	Otherwise:
		say "You put the handbrake on.";
		now the handbrake is switched on.
Instead of examining the handbrake:
	If the handbrake is switched off:
		say "The handbrake is off.";
	Otherwise:
		say "The handbrake is on."

The steering wheel is part of the yellow car.  The description of the steering wheel is "The steering wheel is round."

The yellow car can be parked or blocking. The yellow car is parked.
Instead of pushing the yellow car when the handbrake is switched on:
	say "It's not moving anywhere at the moment. The handbrake is on."
Instead of pushing the yellow car when the handbrake is switched off and the yellow car is parked:
	say "You push the car into the middle of the road. That's going to cause some inconvenience.";
	now the yellow car is blocking.
Instead of pushing the yellow car when the handbrake is switched off and the yellow car is blocking:
	say " You push the car back to the side of the road, out of everybody's way.";
	now the yellow car is parked.

Instead of pushing the blue car when the blue car is in Chapel Street:
	say "The collision has twisted the rear wheels, so it's not easy to move any more."

[Upper Chapel Street]
Upper Chapel Street is east of Chapel Street. "You are at the top of the street, with the hill sloping down to the churchyard to the west. The town begins to get a little more built up here, although there's little sign of activity. Occasionally, you think you see movement from further along the road.[If the blue car is in Upper Chapel Street] There's a blue car, stopped right in the middle of the road."

The blue car is in Upper Chapel Street. The blue car is undescribed. The description of the blue car is "[If the blue car is in Upper Chapel Street]You circle the car, looking for a way in, but it's securely locked. To be honest, there isn't much of interest inside. If you're really still, you think can hear something though.[End if][If the blue car is broken]The boot has been smashed open, but it's not too bad apart from that.[End If][If the blue car is fixed and the blue car is in Chapel Street]The boot is open now, and empty, but everything else is still locked up.[End if]".

Instead of listening to the blue car:
	say "Yes. There's definitely a noise. It sounds like there's a whimpering coming from the boot!"

The boot is part of the blue car. The boot is lockable container. The boot is locked. The description of the boot is "It's a storage space at the back of the car, a bit like a trunk but British."
Instead of listening to the boot:
	Say "Somebody in the boot seems to be crying."

Instead of unlocking or opening the boot when the boot is locked:
	say "You have no way of unlocking it. As you fiddle with it, the whimpering inside gets louder. You hear a bit of sobbing as well. Sounds like whoever is inside is having a bad day."

Instead of pushing the blue car when the blue car is in Upper Chapel Street:
	say "You give the car a little nudge, and it starts to roll backwards down hill. It picks up speed as it rolls, but somehow stays in the centre of the road.";
	if the yellow car is blocking:
		say "After a few seconds, the car reaches the church gate, where it collides violently with the car you pushed into the road. The boot pops open and a man flies out. He is tossed against the side of the other car, flies over the roof, and skids along the road for a few metres. That must have really hurt. He's not moving.";
		now the driver is dead.;
		now the driver is in Chapel Street.;
		now the blue car is in Chapel Street.;
		now the yellow car is broken.;
		now the blue car is broken.;
		now the boot is open.;
		now the boot is unlocked.;
	if the yellow car is parked:
		say "After a few seconds, the car reaches the church gate. It just keeps on rolling, but gradually slows down as it gets further away. When the car stops, the boot immediately pops open and a man leaps out. He takes a brief look around him and then sprints off down the road.";
		now the driver is escaped.;
		remove the driver from play.;
		now the blue car is in Chapel Street.;
		now the boot is open.;
		now the boot is unlocked.;
		
	[Character - the driver]
The driver is a man in the boot. The driver is alive.
Instead of examining the driver:
	say "Ouch. He looks like he's been in quite a nasty car accident. He's still quite fresh, so you take the opportunity to have a snack."
Instead of taking the driver when the driver is dead:
	say "Quite a lot of him is broken, which makes him a bit unwieldy to carry around."
[***END OF CHAPEL STREET***]

[The Market Square]

The Market Square is east of Upper Chapel Street. "The square is no longer the centre of the town, like it was 100 years ago. Nevertheless, on market days it's still bustling with activity as shoppers browse the stalls and traders holler out the deals of the day. Today is not one of those days. The plastic walls of the empty stands flap in the wind. From somewhere in the market you can here squelching and groaning.[line break][line break]The town fire station is north. To the south is an old fashioned hardware store. The road continues east towards the shopping centre."

The empty market is scenery in The Market Square. Understand "stalls" as the market. Understand "stands" as the market. The description of the empty market is "You amble among the stalls until you find the source of the noise. A pack of creatures are crouched over something. Whatever it is, they're eating it."

The lone creatures are scenery in The Market Square. Understand "zombies" as the lone creatures. The description of the lone creatures is "There are five of them. As you approach, you can see they are actually people. All are on their knees and gorging on something bloody. The one nearest you turns to look over her shoulder at you. Her face and hands are covered in blood. Her eyes are yellow, and her skin is pale like yours. She seems uninterested in you, and turns back to her meal."
Instead of attacking or chasing the creatures:
	say "Since they're ignoring you, it might be best not to provoke them."

The Fire Station is north of The Market Square. "The wide rolling door at the front of the station is open, and there's no obvious way of closing it. [If the new fire engine is in The Fire Station]Most of the ground floor is taken up by two fire engines - a shiny new one, and a slightly decrepit old one.[Otherwise]There's only one fire engine down here now - the rather used one.[End if] At the back of the room are a row of lockers. There is a flight of stairs going up to the first floor and a brass pole attached to the ground which disappears through a hole in the ceiling. [If the engine keys are in The Fire Station]There are a set of keys on the floor.[End if]".

The new fire engine is in The Fire Station. The new fire engine is undescribed. The description of the new fire engine is "It's shiny and red like a fire engine should be. It looks quite hi-tech, with buttons, nozzles and panels all over the sides. On top of the engine is a shiny ladder, and on the side is a coiled up hose."
The shiny ladder is part of the new fire engine. "It comes in a number of extending sections and looks like it might be controlled from inside the engine somewhere."
Instead of pulling the shiny ladder:
	say "It won't move at all."  
The hose is part of the new fire engine. The hose can be coiled or uncoiled. The hose is coiled. The description of the hose is "It's a tube that squirts water. [If the hose is coiled]At the moment it's wound around wheel on the side of the engine. [Otherwise]It has been left in an untidy pile on the floor next to the engine. That's definitely a health and safety risk."
Instead of pulling the hose when the hose is coiled:
	say "You completely uncoil the hose, and leave it piled untidily on the floor next to the fire engine.";
	now the hose is uncoiled.
Instead of pulling the hose when the hose is uncoiled:
	say "It's already uncoiled."


The old fire engine is in The Fire Station. The old fire engine is undescribed. The description of the old fire engine is "It's obviously been well used. The red paintwork is scratched and singed in places. The ladder on top looks quite rusty, and on the side of the vehicle, where there should be a hose, there is just an empty wheel."
The rusty ladder is part of the old fire engine. The rusty ladder can be extended or unextended. The rusty ladder is unextended. The description of the rusty ladder is "You wouldn't feel safe climbing it if it were upright. It doesn't seem to be held in place by anything apart from a small hook catch."
Instead of pulling the rusty ladder when the rusty ladder is unextended:
	Say "You tug the ladder and it rapidly extends out from the front of the engine. It's long enough to go all the way out of the fire station door!";
	Now the rusty ladder is extended.
Instead of pushing the rusty ladder when the rusty ladder is extended:
	Say "You puch the ladder back into its unextended position.";
	Now the rusty ladder is unextended.

The lockers are an openable container in The Fire Station. The lockers are closed. The lockers are undescribed. The description of the lockers is "A row of grey metal lockers, each about six feet tall and three feet wide.[If Eddie the fireman is in the lockers]You here someone try to stifle a sneeze inside one of the lockers.[End if]".
Understand "locker" as the lockers.
Instead of opening the lockers:
	say "You open the lockers one by one. [If Eddie the fireman is in the lockers]About halfway along the row, you open one to find a man inside. He makes an 'eep' noise as you stare into his eyes. He quickly darts under your arms and out into the room.";
	now Eddie the fireman is in The Fire Station.;
	now the lockers are open.;

The bottom of the pole is scenery in The Fire Station. "It's a smooth brass pole. Presumably the firemen come sliding down it when there's an emergency."

Eddie the fireman is in the lockers. Eddie the fireman is a man. Eddie the fireman is alive. Eddie the fireman can be tangled or untangled. Eddie the fireman is untangled. The description of Eddie the fireman is "He looks a bit lightweight to be a fireman. Also, he appears to have been caught somewhat by surprise by his current predicament as all he's wearing are a pair of Fireman Sam boxer shorts and a large fireman's helmet with 'EDDIE' written on it in permanent marker."

Every turn while the player is in The Fire Station and Eddie the fireman is in The Fire Station and Eddie the fireman is untangled:
	If the engine keys are in The Fire Station:
		Say "Eddie searches desperately for his lost keys. Suddenly he notices them lying on the floor. He grabs them and quickly unlocks the shiny new fire engine and jumps into the cabin. You narrowly avoid being run over as he tears out of the station and off down the road.";
		Remove the new fire engine from play.;
		Remove Eddie the fireman from play.;
		Remove the engine keys from play.;
		Now Eddie the fireman is escaped.;
	Otherwise:
		Say "[One of]Eddie frantically pats his chest and thighs as though he had pockets; 'Where'd I put the damn keys?!'.[or]While you're at a safe distance, Eddie throws open a locker; 'Keys Keys Keys!?', he says.[or]While you're at a safe distance, Eddie drops to his hands and knees and looks under a fire engine; 'Stupid keys! Where are they!?'[at random]"

Instead of chasing around Eddie the fireman:
	If Eddie the fireman is untangled:
		If the hose is coiled:
			Say "You chase him around the fire engines. He's quicker than you, so you can't get close.";
		If the hose is uncoiled:
			Say "Eddie runs around the fire engines to get away from you. Unfortunately, a large pile of hose gets in his way and he tumbles to the ground and immediately becomes horribly tangled in its coils.";
			Now Eddie the fireman is tangled.;
			Eddie the fireman untangles in two turns from now.;
	Otherwise:
		Say "There's no sport in chasing a man around when he's tangled in hose."

At the time when Eddie the fireman untangles:
	If Eddie the fireman is alive:
		Say "Eddie frees himself from the clumsy embrace of the fire hose.";
		Now Eddie the fireman is untangled.

Instead of chasing Eddie the fireman:
	Say "It doesn't seem like he wants to leave the relative safety of the fire station's ground floor. He's either worried about being eaten, or he's too embarrassed to go anywhere in just his underwear."

Instead of attacking Eddie the fireman when Eddie the fireman is untangled:
	Say "He's a little nimbler than you are, and avoids your shambling attack."
Instead of attacking Eddie the fireman when Eddie the fireman is tangled:
	Say "Oh the humanity! Caught up in the hose, there's no escape for poor, half-naked Eddie. As he gasps his last, you split his chest open and feast on his heart.";
	Now Eddie the fireman is dead.;
Instead of examining Eddie the fireman when Eddie the fireman is dead:
	Say "Poor Eddie. He was probably a hero in life, but in death he's just a bloke tangled in a hose with a hole in his chest."

Eddie the fireman is wearing Fireman Sam boxer shorts. The description of Fireman Sam boxer shorts is "It's rude to stare at a man's Fireman Sam boxer shorts."

Eddie the fireman is wearing a fireman's helmet. The description of the fireman's helmet is "It looks very sturdy. You're sure Eddie's head would be well protected from any unpleasant nastiness. It's a shame (for him) that the rest of his pasty body is about as exposed as it's possible to be."

[The Control Room]
The Control Room is up from The Fire Station. "The control room takes up the entire first floor of the fire station. It juxtaposes the high-tech requirements of an efficient and successful fire service with the low-tech requirement of a team of firemen. A large window, overlooking the market square, takes up most of the south wall. Elsewhere in the room are a rack of firemen's suits, a kitchen area, a control panel with a big screen attached, a large fuse box, a big map of the town, a photograph of some firemen, and a pole which disappears through a hole in the floor. [If the engine keys are in the Control Room]A set of keys lie on the floor next to the hole.[End If] [If unvisited]There's a fireman here, sitting at the table holding a spade. When he sees you, he stares at you with intent and rises from his chair, 'I'll kill you, you monster.'[End if][line break][line break]You are standing next to the [c_location]."

The giant window is scenery in The Control Room. The giant window is fixed. "It's huge, letting in lots of light[If the window is broken] but it's been smashed, so it's also letting in the weather[End if]. Through the window, you can see the market square.[If the rusty ladder is extended] Through the window, you can also see the extended ladder from the old fire engine poking out from the station doors."

The rack of suits is scenery in The Control Room. "A dozen or so firemen's outfits are hanging here."
The firemen's suits are scenery in The Control Room. "Heavy duty trousers and jackets." 
Instead of taking the firemen's suits:
	say "You already have a perfectly good suit."
The kitchen area is scenery in The Control Room. "There's a counter for preparing food. On it you can see a microwave oven and a kettle. There's also a plastic table with six chairs."
The microwave oven is scenery in The Control Room. The microwave oven is fixed. The description of the microwave oven is "It has a door and buttons, like most microwave ovens.[If the microwave oven is broken] The glass door has been smashed in with a spade."
The kettle is scenery in The Control Room. "A chrome kettle."
The large fuse box is scenery in The Control Room. The large fuse box is fixed. The description of the large fuse box is "It looks like all the electrics are controlled for the fire station are controlled from here.[If the large fuse box is fixed] The door is locked shut.[End if][If the fuse box is damaged] The door has been smashed open with a spade. All the fuses and dozens of wires are exposed. It doesn't look too safe.[End if]".
The screen is scenery in The Control Room.  The screen is fixed. The description of the screen is "[If the screen is fixed]The screen shows multiple surveillance camera views of important locations in the town. The shopping centre looks like it's busy - the crowd are mostly shambling monsters, but occasionally a normal person runs across the image. You can also see the front of the labs. Now you remember that you work there![End if][If the screen is broken] There's no image on the screen because it has been smashed in with a spade.[End if]".
The control panel is scenery in The Control Room. The control panel is fixed. "Lots of buttons, dials and knobs. There are also some blinking red lights. You have no idea what any of it does or what any of it means."
The big map of the town is scenery in The Control Room. The big map of the town is fixed. The description of the big map of the town is "It shows the entire town, with various emergency routes marked in red. It also shows where fire hydrants and electricity points are.[If the big map of the town is fixed] The map is framed and behind a large sheet of glass.[End if][If the big map of the town is broken] The map is framed, but its glass covering has been smashed all over the floor.[End if]".
The plastic table is scenery in The Control Room. "Four legs with a flat bit on top.[If the engine keys are on the table] There are a set of keys on the table.[End If]".
The engine keys are on the plastic table. The engine keys are plural-named. The engine keys are undescribed. The description of the engine keys is "Jangly."
Instead of taking the engine keys:
	Say "Your co-ordination is so poor at the moment that you're having trouble picking them up off the table and actually holding on to them."
Instead of pushing the engine keys when the engine keys are on the plastic table:
	Say "You sweep the keys off the table and onto the floor. They come to rest next to the hole.";
	Now the engine keys are in the Control Room.
Instead of kicking the engine keys when the engine keys are in the Control Room:
	Say "You give them a kick and they fall down the hole.";
	Now the engine keys are in The Fire Station.
The round hole is scenery in The Control Room. "It leads to the ground floor."
The top of the pole is scenery in The Control Room. "It's a smooth brass pole. Presumably the firemen go sliding down it when there's an emergency."
The photograph is scenery in The Control Room. The photograph is fixed. The description of the photograph is "At the top of the stairs, it's a large framed photograph of a group of firemen posing in front of a shiny fire engine.[If the photograph is broken] The photograph has a large gash in it.[End if]".

The c_location is a thing that varies.
Instead of going to The Control Room:
	now the c_location is the photograph.;
	now Jack the fireman is ready.;
	continue the action.
Standing next to is an action applying to one thing. Understand "stand next to [something]" as standing next to. Understand "stand near [something]" as standing next to. Understand "stand near to [something]" as standing next to. Understand "stand close to [something]" as standing next to.
Carry out standing next to:
	If the noun is the engine keys:
		now the c_location is the plastic table.;
		say "You shuffle over to the plastic table.";
	Otherwise:
		now the c_location is the noun.;
		say "You shuffle over to the [noun].".
		
Jack the fireman is in The Control Room. Jack the fireman is a man. Jack the fireman is alive. Jack the fireman can be ready, poised, unpoised or striking. Jack the fireman is unpoised. The description of Jack the fireman is "[If Jack the fireman is alive]He's a brawny, stubbled man, who looks like he means business. He is hold a large spade.[Otherwise]Well, he's significantly toastier than he was when he was alive.[End if]".
Instead of chasing Jack the fireman when Jack the fireman is alive:
	Say "Chase him? He's chasing you!"
Instead of chasing around Jack the fireman when Jack the fireman is alive:
	Say "Chase him? He's chasing you!"
Every turn while the player is in The Control Room and Jack the fireman is alive:
	If Jack the fireman is ready:
		Now Jack the fireman is unpoised.;
	Otherwise if Jack the fireman is unpoised:
		Say "'I'll kill you!', says Jack. He raises the spade to strike.";
		Now Jack the fireman is poised.;
	Otherwise if Jack the fireman is poised:
		Say "Jack swings the spade at your face.";
		Now Jack the fireman is striking.;
	Otherwise if Jack the fireman is striking:
		Say "Jack hits you hard in the face with the spade. Teeth fall out. 'Take that you monster!'";
		Now Jack the fireman is ready.
Instead of dodging when the player is in the Control Room and Jack the fireman is striking:
	Say "You duck out of the way of Jack's attack. [no line break]".;
	If the c_location is the photograph:
		Say "He strikes the photograph behind you instead, and damages it quite badly.";
		Now the photograph is broken.;
	If the c_location is the microwave oven:
		Say "He swings over your head and smashes the front of the microwave.";
		Now the microwave is broken.;
	If the c_location is the control panel:
		Say "He swings over your head and strikes the control panel instead. It's made of something remarkably tough as the spade just bounces off!";
	If the c_location is the screen:
		Say "He stabs the spade over your head and strikes the centre of the screen. There's a shower of glass and sparks.";
		Now the screen is broken.;
	If the c_location is the big map of the town:
		Say "He completely misses you and smashes the glass covering the map into thousands of dangerous shards.";
		Now the big map of the town is broken.;
	If the c_location is the fuse box and the fuse box is damaged:
		Say "He swings the spade into the open fuse box. The spade cuts into the wires and there's a loud crackling noise. Jack the fireman, holding onto the metal handle of the spade, quivers as thousands of volts of electricity course through his body. After about 30 seconds, smoke starts to rise from his ears and he topples to the floor.";
		Now the fuse box is broken.;
		Now Jack the fireman is dead.;
	If the c_location is the fuse box and the fuse box is fixed:
		Say "He swings the spade into the fuse box with tremendous force. The door springs open exposing the fuses and wires inside.";
		Now the fuse box is damaged.;
	If the c_location is the giant window and the giant window is fixed:
		Say "The spade crashes into the window smashes the entire thing into shards which rain down into the market square. The control room is open to the elements.";
		Now the giant window is broken.;
	If the c_location is the rack of suits:
		Say "He stabs the spade into the rack of firemen's suits. There are all sorts of belts, braces and ripcords in there, and the spade becomes tangled. [no line break]";
		If the giant window is fixed:
			Say "Believing his only weapon has been lost, he looks around frantically for an escape route. When he sees nothing sensible, he continues to pull on the spade until it comes free.";
		If the giant window is broken and the rusty ladder is unextended:
			Say "Believing his only weapon has been lost, he rushes over to the broken window, and looks out to see if there is an escape route. When he sees that the drop is too far he comes back to the rack and yanks the spade free.";
		If the giant window is broken and the rusty ladder is extended:
			Say "Believing his only weapon has been lost, he rushes over to the broken window, and looks out to see if there is an escape route. When he sees the rusty ladder poking out of the fire station door he realises it is his only chance at survival. He leaps through the window onto the ladder, and then drops to the ground. As he rushes off, a few of the monsters notice him and amble in pursuit. He looks fit enough to keep well ahead of them though.";
			Now Jack the fireman is escaped.;
			Remove Jack the fireman from play.;		
	Now Jack the fireman is ready.

[Hardware Store]
The Hardware Store is south of The Market Square. "It smells of wood and metal and the 1950s in here. To your right is a shelf full of tools. To your left, there's a rack with all sorts of bit and bobs on it. From the ceiling hang some hooks with loops of strong cord and chains hanging from them. Elsewhere, you can see all manner of other DIY paraphernalia. At the far end of the shop, to the south, there's a counter with an old-fashioned till on top. Next to the counter is a battered-looking tablesaw. [If unvisited]A little old shopkeeper is standing behind the counter. He's holding a nailgun. He speaks, 'I've been here 65 years boy. You'll have to burn this place down before I'll abandon it to the likes of you.' He ducks down behind the counter.'[End if][If the counter is aflame] In case you hadn't noticed, the shop is on fire, so it's probably best not to hang around too long.[End if]".

The tool rack is a supporter in The Hardware Store. The tool rack is undescribed. The description of the tool rack is "The rack holds dozens of tubs, each containing useful DIY stuff. You can see nails, matchboxes, tins of oil, and ball-bearings, amongst other less interesting items."

The nails are on the the tool rack. The description of the nails is "Three inches long and quite pointy.". The nails are plural-named.
The tin of grease is on the tool rack. The description of the tin of grease is "Exactly what it says on the tin. Slippery and flammable."
The matchbox is on the tool rack. The description of the matchbox is "They don't appear to be safety matches.". Understand "matches" as the matchbox. Understand "match" as the matchbox.
The ball bearings are on the tool rack. The description of the ball bearings is "Spherical and made of metal.". The ball bearings are plural-named.

The shelf is a supporter in The Hardware Store. The shelf is undescribed. The description of the shelf is "The shelf carries a variety of tools. Nearest to you is a circular saw. Also with reach are a set of gardening tools, including a fine-looking rake. Further down the shelves, you can see a chainsaw. You're not sure why, but the sight of it sends a cold shiver down your spine."
Instead of pulling or pushing the shelf:
	Say "It's heavy, but with a bit of effort you manage to move the shelf a bit. Behind it, you find an electrical socket.";
	Now the electrical socket is in The Hardware Store.
There is an electrical socket. The electrical socket is scenery. The description of the electrical socket is "It's a socket for a single plug. [If the orange wire is plugged]The orange wire is plugged into the socket.[Else If the blue cable is plugged]The blue cable is plugged into the socket.[Else If the yellow lead is plugged]The yellow lead is plugged into the socket.[Otherwise]Nothing is plugged into the socket at the moment.[End if] "

The circular saw is on the shelf. The circular saw is a device. The circular saw is switched off. The description of the circular saw is "It rests on its back with the large circular blade pointing up in the air. A blue cable is attached."
Instead of taking the circular saw:
	Say "It's too heavy for you to manipulate easily in your current state. You might chop something off."
Instead of switching on the circular saw:
	If the blue cable is unplugged:
		Say "It's not plugged in.";
	Otherwise:
		Say "You switch it on and the blade begins to whir noisily. You wouldn't want to drop anything on it when it was spinning that fast. It could be really dangerous.";
		Now the circular saw is switched on.

Instead of putting the nails on the circular saw:
	If the circular saw is switched off:
		Say "You drop the nails on the circular saw. Slightly pointless since it's turned off.";
		Continue the action.;
	Otherwise:
		Say "WOAH! The nails hit the spinning blade and shoot sideways at dangerous speed. They hit the glass front of the counter, shattering the glass.";
		Now the counter is broken.; 

The chainsaw is on the shelf. "It gives you the fear. Odd, because in the past you've always enjoyed a bit of amateur tree surgeonry."
Instead of taking the chainsaw:
	Say "That would just be asking for trouble."
The rake is on the shelf. The description of the rake is "The most amusing of all the garden implements."

The hooks are scenery in The Hardware Store. The description of the hooks is "They look like a pirate's hand."
The strong cord is scenery in The Hardware Store. Understand "chains" as the strong cord. Understand "chain" as the strong cord. Understand "cords" as the strong cord. The strong cord can be greased or ungreased. The strong cord is ungreased. The description of the strong cord is "Loops of washing line cord, rope, string, and chains hang from from the hooks on the ceiling."
Instead of putting the tin of grease on the strong cord:
	Say "You rub grease into all the chains and bits of cord.";
	Now the strong cord is greased.

The old-fashioned till is scenery in The Hardware Store. "It's tarnished, grimy, and definitely not digital. Looks heavy too."

The tablesaw is scenery in The Hardware Store. The tablesaw is a device. The tablesaw is switched off. The description of the tablesaw is "It's a big wooden table, with a slot in the middle. An angry looking circular blade sticks up halfway out of the slot. You imagine that it's for cutting timber to size, but you would be unsurprised if someone tried to tie a international secret-agent to it instead. A yellow lead is attached to the side of the saw."
Instead of switching on the tablesaw:
	If the yellow lead is unplugged:
		Say "It's not plugged in.";
	Otherwise:
		Say "You switch it on and the blade begins to whir noisily. Wow, it would hurt if someone fell on that.";
		Now the tablesaw is switched on.

The hideyhole is a closed container in The Hardware Store. The hideyhole is undescribed.
The geriatric shopkeeper is a man in the hideyhole. The geriatric shopkeeper is alive. The description of the geriatric shopkeeper is "He's the owner of the shop. The word 'wizened' was coined just to describe this man. [If the geriatric shopkeeper is alive]You'd be surprised if he was a day younger than 90, but he has a glint in his eye which suggests that he might not be ready for the great hardware store in the sky just yet. He's holding a large nailgun.[Otherwise]He's in two pieces, which can't be good for his health.[End if]".
The geriatric shopkeeper carries the nailgun. The nailgun is a device. The nailgun is switched on. The description of the nailgun is "It's a NailMaster3000, the most powerful nailgun in the world. It can take your head clean off. You can see an orange wire coming out of the handle."
Instead of chasing around the geriatric shopkeeper when the geriatric shopkeeper is alive:
	Say "He's well able to defend himself from your advances."
Instead of chasing the geriatric shopkeeper when the geriatric shopkeeper is alive:
	Say "He's well able to defend himself from your advances."
Instead of taking the geriatric shopkeeper when the geriatric shopkeeper is dead:
	Say "If he was in one piece you might manage it... but he's not, so you don't."

The counter is scenery in The Hardware Store. The counter is fixed. The counter can be aflame or nonaflame. The counter is nonaflame. The description of the counter is "It takes up most of the width of the shop. Behind a glass front, you can see numerous boxes of fireworks. [If the counter is broken]Now the glass has been shattered, the fireworks are exposed. [End if]On top of the counter is the till."
The fireworks are scenery in The Hardware Store. The fireworks can be greased or ungreased. The fireworks are ungreased. The description of the fireworks is "Rockets and bangers and other things with gunpowder and chemicals in."
Instead of putting grease on the counter:
	Try throwing grease at the fireworks.
Instead of throwing grease at the counter:
	Try throwing grease at the fireworks.
Instead of putting grease on the fireworks:
	Try throwing grease at the fireworks.
Instead of throwing grease at the fireworks:
	If the counter is broken:
		Say "You throw wads of grease at the fireworks. They're quite well covered now.";
		Now the fireworks are greased.;
	Otherwise:
		Say "You throw wads of grease at the fireworks, bit they're behind glass, so the excercise is slightly pointless."

There is a lit matchstick.
Understand "match" as the lit matchstick.
Instead of burning the lit matchstick:
	Try burning the matchbox instead.
Instead of burning the matchbox:
	If the player is not carrying the matchbox:
		Say "You're not carrying any matches.";
	Otherwise:
		If the player is carrying the lit matchstick:
			Say "You already have a lit matchstick. You don't need another.";
		Otherwise:
			Say "You light a match.";
			Now the player carries the lit matchstick.
Instead of dropping the lit matchstick:
	Say "You drop it on the floor and it goes out.";
	Remove the lit matchstick from play.

Instead of throwing the lit matchstick at the fireworks:
	Try throwing the lit matchstick at the counter instead.
Instead of throwing the lit matchstick at the counter:
	If the counter is fixed:
		Say "The lit match arcs towards the counter, bounces off the glass and goes out.";
		Remove the lit matchstick from play.;
	Otherwise:
		If the fireworks are ungreased:
			Say "The lit match arcs towards the counter, and lands among the boxes of fireworks. It burns for a few seconds, but goes out before causing any damage.".;
			Remove the lit matchstick from play.;
		Otherwise:
			Say "The lit match arcs towards the counter, and lands among the boxes of fireworks. It lands in the grease, which instantly catches light. Within 30 seconds the boxes of fireworks catch light, and soon all hell breaks loose. There are rockets zooming all over the place, and sparkling things spraying over every surface. In minutes, the shop is alight and the smoke begins to build.";
			Remove the lit matchstick from play.;
			Now the counter is aflame.;
			If the geriatric shopkeeper is alive:
				Say "[line break]The shopkeeper begins to cough and curse. 'Damn you! You burned my shop!' He runs past you, giving you a jab with his gardening shears on the way. Agile for his age, he's quickly out of the shop and long gone.";
				Now the geriatric shopkeeper is escaped.;
				Remove the geriatric shopkeeper from play.;
			

The orange wire is scenery in The Hardware Store. "Hmmm, not only is there an orange wire coming out of the nailgun, but there's a very similar looking orange wire coming back over the counter, along the right-hand wall, and behind the tool shelf."
The yellow lead is scenery in The Hardware Store. "It comes out of the tablesaw and ends in an electrical plug."
The blue cable is scenery in The Hardware Store. "It comes out of the circular saw and ends in an electrical plug."
The orange wire is pluggable. The orange wire is plugged.
The yellow lead is pluggable. The yellow lead is unplugged.
The blue cable is pluggable. The blue cable is unplugged.
	
Instead of plugging in the orange wire:
	If the electrical socket is not in The Hardware Store:
		Say "You can't see anywhere to plug it in.";
	Otherwise:
		Say "You make sure nothing else is plugged into the socket, and then plug the orange wire in.";
		Now the orange wire is plugged.;
		Now the nailgun is switched on.;
		Now the yellow lead is unplugged.; 
		Now the tablesaw is switched off.;	
		Now the blue cable is unplugged.;
		Now the circular saw is switched off.
Instead of plugging in the yellow lead:
	If the electrical socket is not in The Hardware Store:
		Say "You can't see anywhere to plug it in.";
	Otherwise:
		Say "You make sure nothing else is plugged into the socket, and then plug the yellow lead in.";
		Now the orange wire is unplugged.;
		Now the nailgun is switched off.;
		Now the yellow lead is plugged.;
		Now the blue cable is unplugged.;
		Now the circular saw is switched off.
Instead of plugging in the blue cable:
	If the electrical socket is not in The Hardware Store:
		Say "You can't see anywhere to plug it in.";
	Otherwise:
		Say "You make sure nothing else is plugged into the socket, and then plug the blue cable in.";
		Now the orange wire is unplugged.;
		Now the nailgun is switched off.;
		Now the yellow lead is unplugged.;
		Now the tablesaw is switched off.;
		Now the blue cable is plugged.

Instead of unplugging the orange wire when the electrical socket is in The Hardware Store:
	If the orange wire is plugged:
		Say "You unplug it.";
		Now the orange wire is unplugged.;
		Now the nailgun is switched off.;
	Otherwise:
		Say "It's already unplugged."
Instead of unplugging the yellow lead when the electrical socket is in The Hardware Store:
	If the yellow lead is plugged:
		Say "You unplug it.";
		Now the yellow lead is unplugged.;
		Now the tablesaw is switched off.;
	Otherwise:
		Say "It's already unplugged."
Instead of unplugging the blue cable when the electrical socket is in The Hardware Store:
	If the blue cable is plugged:
		Say "You unplug it.";
		Now the blue cable is unplugged.;
		Now the circular saw is switched off.;
	Otherwise:
		Say "It's already unplugged."

Instead of going south in The Hardware Store when the geriatric shopkeeper is alive:
	Say "You approach the counter, but as you do so, a little old man pops up from behind the counter. 'Get out of my shop!', he roars and he proceeds to [If the nailgun is switched on]open fire on you with a nail gun, driving you back towards the shop front.[Otherwise]throw nails at you with his bare hands. Still effective.";
	Now the geriatric shopkeeper is in The Hardware Store.;
	The geriatric shopkeeper hides in two turns from now.
At the time when the geriatric shopkeeper hides:
	Say "The old shopkeeper disappears back behind the counter again.";
	Now the geriatric shopkeeper is in the hideyhole.
	
Instead of going north in The Hardware Store when the player is carrying something:
	If the geriatric shopkeeper is not alive:
		Say "You may be a foul wraith, but you're not a thief. How about putting all the stuff back before you leave?";
	If the geriatric shopkeeper is alive and the nailgun is switched on:
		Say "You try to walk out of the shop but the shopkeeper has other ideas. His balding pate pops up over the top of the counter and he lets rip with a volley of nailgun fire. 'Put my stock back you thieving freak!' You're forced to hide rather than leave the shop.";
	If the geriatric shopkeeper is alive and the nailgun is switched off:
		Say "The little old man has been robbed of his nailgun, but he's not about to let you steal his stock. He runs out from behind the counter, armed with a pair of gardening shears...";
		If the rake is not in The Hardware Store:
			Say "He jabs at you a few times, preventing you from leaving the shop, and then dashes back to safety behind the counter.";
		Otherwise:
			Say "Unfortunately, in a moment of pure slapstick, he stands on the end of the rake and handle flies up smashing him in the face. He stumbles backwards...";
			If the ball bearings are not in The Hardware Store:
				Say "But regains his balance, and runs back to the safety of the counter.";
			Otherwise:
				Say "And steps on the ball bearings. His arms and legs are desperately swinging, trying to regain his balance, but he begins to fall backwards towards the tablesaw...";
				If the strong cord is ungreased:
					Say "At the last second he is able to grap onto one of the cords hanging from the ceiling. He rights himself and leaps back behing the counter.";
				Otherwise:
					Say "He desperately grasps at the cords hanging from the ceiling, but the grease stops him from getting a grip! He falls backwards onto the tablesaw...";
					If the tablesaw is switched off:
						Say "Fortunately, the tablesaw is off. He lands on the table and rolls about a bit, but is quickly back on his feet and behind the counter.";
					Otherwise:
						Say "Oh my! He falls onto the spinning tablesaw and is sawn cleanly in half. Blood is sprayed over the entire hardware store, a redecoration that the shopkeeper is unable to appreciate sadly.";
						Now the geriatric shopkeeper is dead.;
						Now the geriatric shopkeeper is in The Hardware Store.
				
[St. George's Square]
The Town Square is east of The Market Square. The description of The Town Square is "This is St. George's Square, a new development in the heart of town. It was only built a few years ago, as an elegant pedestrian forecourt to the massive new shopping centre to the east, and the classy restaurants to the south. Now it looks like a warzone.[line break][line break]Dozens of half-human creatures are ambling around the square. Most seem to be concentrating their attention on the north side. Here, a couple of dozen cars and vans have been parked as a barricade. Behind them are the labs where you work (used to work?). [If unvisited]Protecting the barricade, a mixed group of policemen and people in civilian dress are throwing homemade explosives into the crowd of monsters, and occasionally taking a potshot with a rifle or shotgun. More of the creatures mill around the square, gnawing at the bodies. Occasionally, a normal person makes a dash from somewhere towards the barricade, but most are taken down in gruesome style by the horde. [End if]There's no doubt that you're one of them, but they seem mindless, while you seem to have retained a sense of self. Strange. You wonder if the answer lies in your lab work.[If unvisited][Line break][Line break]A civilian climbs onto the top of the tallest van, and speaks through a loudhailer, 'People! People! If you can hear me, do NOT attempt to cross the square. The monsters will kill you. Please try to call the police station and let someone know where you are. We will send a team to rescue you. We have a helicopter, ready for escape, but we will not leave any living man, woman or child behind!' It doesn't look like this group is going anywhere until all the townsfolk are rescued or dead. [End if][If the chef is in the Town Square and the chef is alive]The chef has made it to the south side of the square, but a large number of the monsters have noticed him. He's going to be killed in seconds.[End if]"

The barricade is scenery in The Town Square. The barricade can be manned or unmanned. The barricade is manned. The description of the barricade is "It's formed of a three-vehicle thick line of cars, vans and trucks, with the taller vehicles at the front. [If the barricade is manned]Scores of the mindless killers paw and thump at the barricade, not caring if they trample one another in their desire to get to the people behind. Every so often, someone will shoot one of the more energetic creatures, before it can clamber up the barricade. The others are either left to their moaning, or taken out with a molotov cocktaill. On the far left of the barricade, you can see a policeman speaking on a walkie-talkie."

The policeman is a man in The Town Square. The policeman is undescribed. The policeman is notcounted. The description of the policeman is "He stands apart from the folk defending the barricade, and he's talking into a walkie-talkie. It looks like he might be co-ordinating the rescue. If you want to listen to him, you can probably approach safely, as the shooters and bombers are concentrating on the crowd in the middle of the barricade."

Instead of chasing the policeman:
	Say "He's on top of the barricade."
Instead of chasing around the policeman:
	Say "He's on top of the barricade."

Instead of listening to the policeman:
Say "You creep up to the edge of the barricade and hear him talking to someone on his walkie-talkie, '[One of][If the priest is alive]We think Father Jameson is still alive in the churchyard[End if][If the priest is dead]We've heard that one of them killed Father Johnson. It attacked him at its own funeral. Sheesh[End if][If the priest is escaped]Father Johnson got away from the churchyard. He's here with us. He says the creature had a chance to kill him, but didn't[End if][or][If the verger is alive]The verger has called us to say she's still OK. She's hiding in the church[End if][If the verger is dead]Someone went to the church and found the verger. No good I'm afraid. She's gone[End if][If the verger is escaped]Yeah... the verger escaped from the church. Says the creature nearly got her[End if][or][If the geriatric shopkeeper is alive]Frank Bosley is still holding out in the hardware store in the market. He says he's fending them off with nailgun[End if][If the geriatric shopkeeper is dead]Someone's seen one of them kill old Frank Bosley in his hardware store. Sheesh, I've known him since I was a baby[End if][If the geriatric shopkeeper is escaped]Frank Bosley managed to escape the hardware store. He says he only left because it caught fire! He's lucky to be alive[End if][or][If the driver is alive]There's some guy hiding in his boot at the top of Chapel Street. Can we get someone out there?[End if][If the driver is dead]We've found a body at the bottom of Chapel Street. Looks like some poor guys brakes failed at the top of the hill while he was hiding in the boot[End if][If the driver is escaped]Yeah... there's nobody on Chapel Street. We heard there was some guy hiding up there, but he's gone now[End if][or][If Eddie the fireman is alive]There's at least one still alive in the fire station. Can we get to them?[End if][If Eddie the fireman is dead]Someone went through the market and saw Eddie. He's gone I'm afraid..[End if][If Eddie the fireman is escaped]Eddie's with us now. He got out of the station and drove an engine round the back. Yeah he's safe[End if][or][If Jack the fireman is alive]There's at least one still alive in the fire station. Can we get to them?[End if][If Jack the fireman is dead]Jack's been talking to us from the fire station for a few hours... but now there's nothing. I think they got him[End if][If Jack the fireman is escaped]Jack's with us now. He says he managed to jump out of a window and then dodge all the monsters in the market. Lucky guy![End if][or][If the chef is alive]The pizza chef has locked himself in the restaurant. Says he's safe for now, but we need to get to him[End if][If the chef is dead]The pizza guy has gone. Nasty way to go[End if][If the chef is escaped]We've got the pizza guy here. Amazing thing... it looked like one of the creatures actually helped him escape. Crazy[End if][at random].'"

Every turn when the chef is in the Town Square and the player is in the Town Square:
	Say "The creatures surround the chef. He's in deep trouble.";
	
At the time when the chef dies:
	If the chef is alive:
		If the player is in the Town Square:
			Say "The horde of zombies rip the chef limb from limb while the barricade crowd look on in horror.";
		Otherwise:
			Say "From St. George's Square you hear a terrible scream. You can only imagine it's the zombies killing the chef.";
		Now the chef is dead.;
		Remove the chef from play.

Instead of attacking the chef when the chef is in the Town Square:
	Say "You give the rest of the monsters a helping hand. A score of you descend on the poor chef, and pretty soon there's nothing left but scattered bones.";
	Now the chef is dead.;
	Remove the chef from play.

Instead of attacking the townie creatures when the chef is in the Town Square:
	Say "You launch an unexpected and frankly unbelievable attack on the monsters. The chef seems astounded that one of the killers has come to his rescue and he nearly forgets to take advantage of the situation. He realises that you have rammed an opening through the surrounding circle of monsters and he dashes through it. He zig-zags through the remaining zombies until he reaches the barricade and the people pull him to safety. Nobody quite seems sure what just happened.";
	Now the chef is escaped.;
	Remove the chef from play.
		
Instead of going north in the Town Square when the barricade is manned:
	Say "If you walk up to the barricade you are likely to be trampled or set on fire."
Instead of going north in The Town Square when the barricade is unmanned:
	Say "Using wing mirrors and plenty of determination, you scale the abandoned barricade and make your way down the other side.";
	Continue the action.
	
Instead of going east in the Town Square:
	Say "A zombie in a shopping centre? Who ever heard of such a thing!? (maybe in the sequel)"

The townie creatures are scenery in The Town Square. Understand "zombies" as the townie creatures. Understand "monsters" as the townie creatures. Understand "crowd" as the townie creatures. The description of the townie creatures is "There's no getting away from it. These are zombies in the best Romero tradition. What's frightening is that you seem to be one of them, by appearance at least. Is it possible that you've kept your mind while they have lost theirs?" 

The labs are scenery in The Town Square. Understand "lab" as the labs. The description of the labs is "This is where you work. You're doing research into immunisation against infectious disease, work that you're proud to say is saving lives all over the world. You know that there are some top secret projects running deep in the labs - rumours in the canteen say it's biological weaponry, but you've never believed it."
[The Restaurant Courtyard]
The Restaurant Courtyard is south of The Town Square. "An elegant stone arch leads from St. George's Square to the north into a pretty courtyard. Small trees and other semi-tropical plants grown in giant terracotta pots. Interspersed among these are umbrella-covered tables carrying half-finish meals. There are a number of pleasant looking restaurants, but most are dark and empty. One, an upmarket pizza place to the south, has a light on.[If the chef is not in the Restaurant Courtyard] A lone woman, obviously infected by the same disease as the crowd in the square, paws pointlessly at the door clearly not understanding the concept of a handle.[End if][If the chef is in the Restaurant Courtyard] The chef is here, and he's in trouble. He seems to have lost his cleaver somewhere, and the zombie woman is taking advantage. He's trying to wrestle her away, but he's losing the fight.[End if][line break][line break]In the southeast corner of the courtyard, you can see an alley. There's quite a lot of noise coming from down there."

The lone woman is an animal in The Restaurant Courtyard. The lone woman can be intheway or outtheway. The lone woman is intheway. The lone woman is undead. The printed name of the lone woman is "woman". The description of the lone woman is "[If the chef is not in the Restaurant Courtyard]She looks very pale and she's groaning a lot. She doesn't react to you at all.[Otherwise]She's eagerly trying to kill the chef.[End if]"

Instead of going south in the The Restaurant Courtyard:
	If the lone woman is intheway:
		Say "You can't get in because the woman creature is in the way.";
	Otherwise:
		The chef hangs up in three turns from now.;
		Continue the action.
		
At the time when the chef hangs up:
	Now the chef is offthephone.
	
Instead of pushing the lone woman when the chef is not in the Restaurant Courtyard:
	Say "You give her a shove and she stumbles across the courtyard with a groan. She starts to amble back towards the door.";
	Now the lone woman is outtheway.;
	The lone woman reblocks in two turns from now.
At the time when the lone woman reblocks:
	If the player is in the Restaurant Courtyard:
		If the chef is not in the Restaurant Courtyard:
			Say "The woman resumes her futile attempts to enter the pizza restaurant.";
			Now the lone woman is intheway.
	
Instead of attacking the chef when the chef is in the Restaurant Courtyard:
	Say "Between you and killer woman, the poor chef doesn't stand a chance. While he wrestles with her, you approach from behind and bite out his jugular. He drops to the floor and you and your companion feast on his flesh.";
	Now the chef is dead.;
	Now the description of the chef is "He looks fairly well eaten.";
	Now the printed name of the chef is "dead chef".
	
Instead of attacking the lone woman when the chef is in the Restaurant Courtyard:
	Say "You attack the woman and free the chef from her clutches. He stumbles away from her and dashes off north towards St. George's Square. Once he's gone, the woman calms down and starts trying to get back into the pizza restaurant";
	Now the chef is in the Town Square.;
	The chef dies in three turns from now.
	
The courtyard trees are scenery in The Restaurant Courtyard. The printed name of the courtyard trees is "trees". The description of the courtyard trees is "Typical chic courtyard flora. They're a little too tropical for their temperate location."

The courtyard restaurants are scenery in The Restaurant Courtyard. The printed name of the courtyard restaurants is "restaurants". The description of the courtyard restaurants is "All abandoned except the pizza place to the south."


[Alley]
The Alley is southeast of The Restaurant Courtyard. "Wow! There is a seriously large crowd of zombies here. They're all gathered around a metal security door, obviously desperate to get in. If you push your way through, you can probably reach the door, but there's so many of them that there is little chance of getting any further down the alley."

The crowd of zombies are scenery in The Alley. The description of the crowd of zombies is "They're not interested in each other, or in you... only in what's behind that door."

The security door is a door. It is west of the The Alley and east of The Pizza Kitchen. The security door is locked and closed. The description of the security door is "[If the security door is closed]The door is closed.[Otherwise]The door is open.[End if] Next to the door is a keypad."
The keypad is scenery in The Alley. "It's an electronic keypad with alphanumeric keys. Above it there are some instructions. They read 'TYPE entrycode below'."

Instead of typing  "PIzz4" when the player is in The Alley:
	Say "There is a pleasant beep and a green light flashes on the keypad. You hear the door unlock.";
	Now the security door is unlocked.	
Instead of typing text when the player is in The Alley:
	Say "There is an angry buzz and a red light flashes on the keypad."


[The Pizza Palace]
The Pizza Palace is south of The Restaurant Courtyard. "[If the hiding place of the player is not the nothidden]You are hiding behind [the hiding place of the player]. [End if]The restaurant is quite upmarket for a pizza place. It even has real tablecloths. There are tables all around, and a kitchen to the south. You can also see a coat rack, a salad bar, and a dessert trolley, all of which stand next to the walkway from the front door to the kitchen doors. [If unvisited] Off to one side, you can see a man in chef's uniform. He has his back to you and is holding a conversation on a mobile phone. In his other hand, he carries a large meat cleaver. 'You gotta get me out of here... Yeah... In the Pizza Palace. There's only one out the front, but the guys on the barricade told me the square is full of them so I'm not going to run for it unless I have to. I can hear a whole crowd of them outside the back door, but they can't get in so I'm safe in here for now I think... Yeah... Yeah... OK. Just get someone here quick!'" 

Instead of going north from The Pizza Palace:
	If the lone woman is intheway:
		Say "You barge the woman outside out of the way as you leave.";
	Now the lone woman is outtheway.;
	The lone woman reblocks in two turns from now.;
	Now the hiding place of the player is the nothidden.;
	Continue the action.

The coat rack is scenery in The Pizza Palace. The description of the coat rack is "It's just inside the entrance to the restaurant. Quite a few people seem to have left their coats here."
The salad bar is scenery in The Pizza Palace. The description of the salad bar is "It's between the the walkway to the kitchen and the main restaurant space a little further into the restaurant than the coat rack. It holds quite a lot of wilted salad."
The dessert trolley is scenery in The Pizza Palace. The description of the dessert trolley is "It's full of cakes and puddings. It has been left next to the walkway to the kitchen, about halfway between the salad bar and the swingy kitchen doors they always have in restaurants."

The chef is a man in The Pizza Palace. The chef is alive. The chef can be facing or turnedaway. The chef is turnedaway. The chef can be onthephone or offthephone. The chef is onthephone. The description of the chef is "[If the chef is in the Pizza Palace]He's a big fellow and he carries a mobile phone in one hand and a meat cleaver in the other.[Otherwise]He looks terrified. He seems to have lost both his mobile phone and his weapon.[End if]".
Instead of chasing the chef when the chef is in the Pizza Palace:
	Say "He's got a meat cleaver. If anyone's going to be doing any chasing it's him."
Instead of chasing around the chef when the chef is in the Pizza Palace:
	Say "He's got a meat cleaver. If anyone's going to be doing any chasing it's him."
Instead of attacking the chef when the chef is in the Pizza Palace:
	Say "He's holding a massive meat cleaver. Who do you think will come out best in a fight?"

Every turn when the player is in The Pizza Palace and the chef is in the Pizza Palace and the chef is offthephone and a random chance of 1 in 3 succeeds:
	If the chef is turnedaway:
		Say "The chef turns to face the walkway.";
		Now the chef is facing.;		
	Otherwise:
		Say "The chef turns away from the walkway and fiddles with his phone.";
		Now the chef is turnedaway.

Every turn when the player is in The Pizza Palace and the chef is in The Pizza Palace:
	If the security door is open:
		Say "Zombies swarm into the restaurant. The chef, turns with a look of horror on his face, 'Who let THEM in!?' He realises he is so outnumbered that his cleaver isn't going to protect him, and he dashes out of the front door. What with the woman in the courtyard, and the crowd in the square, you don't give him much hope of surviving.";
		Now the chef is in The Restaurant Courtyard.;
		Now the lone woman is outtheway.;
	Otherwise if the chef is facing and the hiding place of the player is the nothidden and The Pizza Palace is visited:
		Say "The chef sees you lurking and lets out a high-pitched shriek of fright. However he soon composes himself and comes charging at you with his cleaver. You are forced to retreat from the restaurant. He might not see you if you HIDE BEHIND something.";
		Now the player is in The Restaurant Courtyard.;
		Now the lone woman is outtheway.;
		The lone woman reblocks in two turns from now.;
		Now the chef is turnedaway.
	
Instead of hiding behind when the player is in The Pizza Palace and the chef is not in The Pizza Palace:
	Say "Is there any point in hiding now? There's nobody to hide from."
Instead of hiding behind the coat rack:
	Say "You hide behind the coat rack before the chef sees you.";
	Now the hiding place of the player is the coat rack.
Instead of hiding behind the salad bar:
	If the hiding place of the player is not the coat rack:
		Say "You try to sneak all the way to the salad bar, but you can't quite make it before the chef turns round and spots you. He comes charging at you with his cleaver and you are forced to retreat from the restaurant.";
		Now the player is in The Restaurant Courtyard.;
		Now the hiding place of the player is the nothidden.;
		Now the lone woman is outtheway.;
		The lone woman reblocks in two turns from now.;
		Now the chef is turnedaway.;
	Otherwise if the chef is facing:
		Say "You try to sneak to the salad bar, but the chef is looking in your direction and sees you. That was a bit stupid. He comes charging at you with his cleaver and you are forced to retreat from the restaurant.";
		Now the player is in The Restaurant Courtyard.;
		Now the hiding place of the player is the nothidden.;
		Now the lone woman is outtheway.;
		The lone woman reblocks in two turns from now.;
		Now the chef is turnedaway.;
	Otherwise:
		Say "You quietly sneak from the coat rack to the salad bar while the chef isn't looking.";
		Now the hiding place of the player is the salad bar.
Instead of hiding behind the dessert trolley:
	If the hiding place of the player is not the salad:
		Say "You try to sneak all the way to the dessert trolley, but you can't quite make it before the chef turns round and spots you. He comes charging at you with his cleaver and you are forced to retreat from the restaurant.";
		Now the player is in The Restaurant Courtyard.;
		Now the hiding place of the player is the nothidden.;
		Now the lone woman is outtheway.;
		The lone woman reblocks in two turns from now.;
		Now the chef is turnedaway.;
	Otherwise if the chef is facing:
		Say "You try to sneak to the dessert trolley, but the chef is looking in your direction and sees you. That was a bit stupid. He comes charging at you with his cleaver and you are forced to retreat from the restaurant.";
		Now the player is in The Restaurant Courtyard.;
		Now the hiding place of the player is the nothidden.;
		Now the lone woman is outtheway.;
		The lone woman reblocks in two turns from now.;
		Now the chef is turnedaway.;
	Otherwise:
		Say "You quietly sneak from the salad bar to the dessert trolley while the chef isn't looking.";
		Now the hiding place of the player is the dessert trolley.
Instead of going south when the player is in The Pizza Palace and the chef is in The Pizza Palace:
	If the hiding place of the player is not the dessert trolley:
		Say "The distance to the swingy doors is just too far, and the chef spots you before you can make it the whole way. He comes charging at you with his cleaver and you are forced to retreat from the restaurant.";
		Now the player is in The Restaurant Courtyard.;
		Now the hiding place of the player is the nothidden.;
		Now the lone woman is outtheway.;
		The lone woman reblocks in two turns from now.;
		Now the chef is turnedaway.;
	Otherwise if the chef is facing:
		Say "So near, yet so far. You make a final leap for the door, but the chef was looking this way. He comes charging at you with his cleaver and you are forced to retreat from the restaurant.";
		Now the player is in The Restaurant Courtyard.;
		Now the hiding place of the player is the nothidden.;
		Now the lone woman is outtheway.;
		The lone woman reblocks in two turns from now.;
		Now the chef is turnedaway.;
	Otherwise:
		Say "You make the final move from behind the dessert trolley and into the kitchen. The chef has no idea!";
		Now the hiding place of the player is the nothidden.;
		Continue the action.

[The Pizza Kitchen]
The Pizza Kitchen is south of The Pizza Palace. "The kitchen is a bit of a mess, with pizza ingredients scattered over every surface, including the floor. There are the expected cookers and ovens, and racks and racks of cooking utensils. On the east wall is a metal door. Next to the door is an electric keypad.[If the security door is open] Zombies flood in from the alley, in search of food - probably not pizza.[End if]".

The electric keypad is scenery in The Pizza Kitchen. The description of the electric keypad is "It has a note stuck to it with a bit of tape. It reads 'BROKEN! Get someone outside to open it - P1zz4.'"

The ovens are scenery in The Pizza Kitchen. Understand "cookers" as the ovens. Understand "oven" as the ovens. The description of the ovens is "Warm, but no longer hot enough to cook with."

The utensils are scenery in The Pizza Kitchen. The description of the utensils is "Knives, spoons, whisks, spatulas, pans, corkscrews and other such kitchenalia. You don't think any of it will be much use for anything."

Instead of opening the security door when the security door is unlocked and the player is in the Pizza Kitchen:
	Say "You open the door and a crowd of zombies immediately pours into the kitchen. They ignore you, and make for the restaurant. There are so many of them, you are swept along with them, into the restaurant.";
	Now the player is in The Pizza Palace.;
	Now the security door is open.
Instead of opening the security door when the security door is unlocked and the player is in the Alley:
	Say "You open the door and the crowd of zombies immediately begins to amble through. There are so many of them trying to squeeze through the door that you are swept along with them, straight through the kitchen, and into the restaurant.";
	Now the player is in The Pizza Palace.;
	Now the security door is open.
Instead of closing the security door when the security door is open:
	Say "There are too many zombies in the way. You can't get it closed now."

[The Lab Entrance]
The Lab Entrance is north of The Town Square. "This is where you used to work before all this nonsense began. It's a new building, with modern architecture. A pair of large automatic doors slide open invitingly. While security is low at the entrance here, you're well aware that it is much more difficult to move around inside with the right authorization. Behind you, the barricade prevents the creatures from approaching any closer."

The automatic doors are scenery in The Lab Entrance. The description of the automatic doors is "Slidy."

The back of the barricade is scenery in The Lab Entrance. The description of the back of the barricade is "A slope of vehicles. From this side, it is easy to climb, but from the other side it's quite difficult, as you've recently experienced."

The building is scenery in The Lab Entrance. The description of the building is "Lots of modern lines and textures. An architect was probably paid millions. Above the automatic doors is a logo which is utterly meaningless - it's probably supposed to represent some abstract concept like scientific progress."

[The Lab Foyer]
The Lab Foyer is north of The Lab Entrance. "The foyer is where members of the public can come in to be shown to a seat until somebody with security clearance comes to collect them. At the moment it's a bit of a mess, mainly because there's a headless body in the middle of the floor. It looks like it was probably one of the monsters, rather than a normal person, and it looks like the head was taken off with something explosive. There's an unmanned reception desk here, and because it's unmanned there's nothing to stop you from visiting the labs. The lifts to get to them are north."

The reception desk is scenery in The Lab Foyer. The description of the reception desk is "A long and stylish desk with a dark marble top. It's has blood on it."

The body is in the The Lab Foyer. The body is undescribed. The description of the body is "It looks like it was a scientist. It still has a white labcoat on."
Instead of taking the body:
	Say "He looks heavy."
The labcoat is in the Lab Foyer. The labcoat is a container.  The labcoat is undescribed. The description of the labcoat is "It's white with a lot of red stains.[If the security card is enclosed by the labcoat] There's a security card in the pocket. How useful![End if]".
Instead of taking the labcoat:
	Say "You already have one of your own, and it's cleaner."
The security card is in the labcoat. "It has a picture of the owner on it. At least you know what his head looks like now."
After printing the name of the labcoat:
	omit contents in listing.

[The Ground Floor Lifts]
The Ground Floor Lifts are north of the Lab Foyer. "Lifts here can take you up to where your lab is, and also the admin focused departments. Down is where the more secret labs are located. They require a special security card."

[The Basement Lifts]
The Basement Lifts are down from the Ground Floor Lifts. "Lifts here can take you back up to the foyer. A short corridor, heading east, ends in a serious looking door. Next to the door is a device for swiping a security card."

The Biolab door is a door. It is east of the Basement Lifts and west of the Biolabs. The Biolab door is closed and locked. The description of the door is "It looks like it was designed to keep people like you out."

Instead of swiping the security card when the player is in the Basement Lifts:
	Try unlocking the Biolab door with the security card.
Instead of unlocking the Biolab door with the security card when the Biolab door is locked:
	Say "You swipe the card over the device. There's a ping and the door slides open.";
	Now the Biolab door is unlocked.;
	Now the Biolab door is open.
Instead of unlocking the Biolab door with the security card when the Biolab door is open:
	Say "The device pings. The door stays open."
Instead of closing the Biolab door:
	Say "It doesn't have handles. It just slid open, and now it won't shut again."
	
[The Biolabs]
The description of the Biolabs is "You've never been here before. It's quiet. You're in a long corridor with the words 'WARNING BIOHAZARD' written on the right hand wall in large red letters. The left wall is built entirely of glass, looking into a numerous different laboratories. It's carnage in there. Every single room contains either dead bodies, or more of these foul creatures. The ones down here seem to have been affected far worse than the ones above ground... or you. Most are hideously deformed, with bulging limbs and torn skin. All are groaning, and you can only hope they aren't in pain.[line break][line break]There's no way they can get out of the labs, and there's no way you can get in. Somebody has activated a lock down. There's nothing for you down here."

The glass is scenery in the Biolabs. "It's stopping them from getting out, and you from getting in. That's probably a good thing."
The hideous creatures are scenery in the Biolabs. Understand "zombies" as the hideous creatures. Understand "monsters" as the hideous creatures. The description of the hideous creatures is "You almost feel sorry for them. There is little humanity left in them and it looks like they are in pain. It seems like a reasonable hypothesis that whatever has caused this disaster started here."

The laboratories are scenery in the Biolabs. Understand "labs" as the laboratories. The description of the laboratories is "They are filled with all sort of amazing experiments... and quite a lot of zombies now as well."

[The first floor lifts]
The First Floor Lifts is up  from the Ground Floor Lifts. "This is a pleasant foyer, allowing access to the less secret laboratories. All sorts of interesting work goes on up here. Your lab is to the north. The lifts here can take you back down to the foyer."

[Your Lab]
Your Lab is north of The First Floor Lifts. "Home sweet home. All your experiments and notes are neatly laid out on your desk. You've been making real progress recently."

The notes are scenery in Your Lab. "You've been working on a general anti-viral agent made from the leaves of a recently discovered South American plant. It's not high profile for the company, but you've made some amazing breakthroughs which you were beginning to write up."
	
The experiments are scenery in Your Lab. "There are dozens of bottles and vials containing green and yellow liquids. Vial X is your latest concoction. It shows all the signs of being a superb anti-viral agent. You wonder if it has anything to do with your current state of half-death. Could it be the answer to this nightmare?"
Understand "desk" as the experiments.

Vial X is in your lab. Vial X is edible. Vial X is undescribed. The description of Vial X is "A green liquid in a bottle."

Instead of drinking Vial X:
	Say "You gulp down the contents of the bottle in the hope that it may cure you. Your head spins and crash to the floor...";
	If the number of people who are escaped is 7:
		Say "You wake up (who knows how many hours later, in incredible pain). It's the first pain you've felt since you escaped from the coffin. That's a good thing, right? Throughout this nightmare, you managed to maintain your humanity, and not a single person died by your hand. Now you have the cure which could save humanity... all you have to do is survive.";
		End the story saying "The end... for now.";
	Otherwise if the number of people who are dead is 7:
		Say "You wake up enraged. You clearly have more of your humanity left than the other creatures out there, but you still chose to go on a murderous killing spree. Well done for killing everybody... you're clearly a psychopath, undead or not.";
		End the story saying "The end... not just for you... for everybody.";
	Otherwise:
		Say "You never wake up... at least not consciously. The blood lust was in you, and not even your miracle cure could fend off the inevitable descent into mindless mania. You killed [if the number of people who are dead is 1]a person[Otherwise][the number of people who are dead] people. You may well kill many more, now you're one of them...";
		End the story saying "The end... You are one of the undead now, and humanity's last hope died with you."