Wizards of New Coldain: Apprentice's Challenge v1.3 by Quincy West

Wizards of New Coldain: Apprentice's Challenge v1.3

Played 2,261 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Apprentice's Challenge" by Quincy West

Include Exit Lister by Eric Eve.

A room can be holy ground.

A wand is a kind of thing.

Definition: A thing is present if it is in the location.

The maximum score is 101.

Use undo prevention.

When play begins:
	say "You are an apprentice of the New Coldain Enclave of Magicians, Sorcerers, Wizards, and Warlocks. Your Final Examination approaches, and you have been sent to the Crucible of Challenge, a dungeon beneath the Enclave used to test wizard-candidates such as yourself. Completing this challenge will confirm your status as a full Wizard of the Conclave, but beware! The Crucible is full of deadly traps and foul beasts who have claimed the lives of many the would-be wizard. [paragraph break]You have knowledge of a few spells to assist you in your quest. Examine your Grimoire of Spells to see your list of spells and tips for how to use them."

Mouth of the Crucible is a room.  The description of Mouth of the Crucible is "[if unvisited]You appear in a flash of mystic power. [end if]The room is small and confining, always seeming to be closing in on you. At the top and bottom of the room are stalactics and stalagmites, stone teeth seemingly ready to bite." South of Mouth of the Crucible is The First Trial. The Second Trial is south of the First Trial.

The player is wearing apprentice robes. The  player carries a wand called a rowan wand. The player carries a Grimoire of Spells. The player carries a pack of smores.

The description of the smores is "A delicious treat you smuggled away just before your Trials."

Instead of embersparking the smores:
	say "A wonderful start to this adventure - a campfire classic.";
	award 1 point;
	remove the smores from play.

The description of the apprentice robes is "Long gray robes with two golden stripes, signifying your right to undergo the Final Examination as a wizard-candidate."

The description of the rowan wand is "An old wand made of rowan wood. Unlike many apprentices, this is the only wand you've ever had - you haven't broken it during your studies, which is a credit to your care and control. The wand is a focus for your magic - the precursor to a full Wizard's Staff - and you will find that you cannot work magic without it."

The description of the Grimoire is "Your book of spells, containing all the spells you know how to cast. Though you don't need the book to cast them anymore, reading the magical formulae contained within can refresh your memory on how they work. (Type I to see your inventory, then EXAMINE each spell. For example, EXAMINE FAR HAND will tell you about your Far Hand spell.)"

The Grimoire is a container. Far Hand Formula, Summon-Goblin Formula, and Emberspark Formula are scenery in the Grimoire. 

The description of Far Hand Formula is "The Far Hand spell is one of the most useful in the Wizard's repertoire. It can be used to push or pull things from far away. (Do so by using FARPUSH (object) or FARPULL (object). ) As an apprentice, you can only exert as much force as you can normally lift, so you won't be lifting gates until you pass your trials. You must be able to see something to grasp it with your Far Hand."

The description of Summon-Goblin Formula is "Goblins, minor demons from the Far Realms, are stupid, stinking creatures, but make useful servants.  They can carry things and, while vicious, don't stand up well in a fight alone, but will often buy a summoner some time. (Use SUMMON GOBLIN to call one forth and command it by using GOBLIN, (command). The goblin is too stupid to cast magic. The arch-warlock Quasie uses SUMMON GOBBO to call up his goblin servants.)"

The description of Emberspark Formula is "Raw, magical energy gathered in a spark of flame. While it is not the mighty doomsday blast that a master is capable of, it can be destructive with the right application. (Use EMBERSPARK (object) to cast an Emberspark at something. Not all things are flammable.)"

Chapter 1 - The First Trial

The description of the First Trial is "A large, open room, whose ceiling is obscured in darkness. Guarding the south door is a large ogre wielding a club and looking for trouble. The room is dimly lit by torches which line the walls. A rope is tied to a hinge in the wall near the ogre, extending up into the darkness."

There is an ogre in First Trial. The ogre is a person. The description of the ogre is "Large, ugly, ornery, and smelly. He wears a ragged loincloth and carries a huge tree-trunk for a club.  [if the ogre is angry]He looks like he wants to smash something.[end if]"

The ogre can be angry or calm. The ogre is calm.

to say ogre death:
	say "Crunch, crunch, crunch go the little apprentice's bones while the ogre smashes you to a pulp...."

To incite the ogre:
	if the ogre can see the goblin:
		say "The ogre lifts its club and smashes your goblin servant to bits. Fortunately, you can just call another one, but the ogre is still angry, and you're the only thing to smash!";
		if the ogre is not angry, now the ogre is angry;
		remove the goblin from play;
	otherwise:
		say ogre death;
		end the game in death.

Ogre-defeated is a truth state that varies.

Instead of embersparking the ogre while ogre-defeated is false:
	say "You manage to light the ogre's loincloth on fire. After rolling about on the ground a bit, the ogre puts it out, stands up, and ROARS!";
	incite the ogre.

Instead of going south in First Trial while ogre-defeated is false:
	say "The ogre blocks your path, swinging its club at you and roaring! You dodge out of the way as the club dents the stone floor where you stood just moments before.";
	if the ogre is not angry, now the ogre is angry.

Ogre Rage is a scene. Ogre Rage begins when the ogre is angry. Ogre Rage ends when the ogre is dealt with.

When Ogre Rage begins:
	award -5 points.

Every turn during Ogre Rage:
	if Ogre Rage has been happening for exactly 1 turn:
		say "The ogre snorts and roars at you, 'SMASH LITTLE HUMAN!' as it slams its club into the floor.";
	otherwise if Ogre Rage has been happening for exactly 2 turns:
		say "The ogre bashes the walls near the door, swinging at you wildly, forcing you to dive out of the way.";
	otherwise if Ogre Rage has been happening for 3 turns:
		incite the ogre.

To decide whether the ogre is dealt with:
	if ogre-defeated is true, yes;
	decide no.

There is a sconce in First Trial. The sconce is an open, transparent container. The sconce is fixed in place. The description of the sconce is "A metal bracket, used to hold torches."

In the sconce is a  torch. The description of the torch is "A lengthy bit of oak, covered in oils, hanging just below the rope." The torch is unlit.

Instead of farpushing the torch: 
	if ogre-defeated is false:
		say "You try striking the ogre with the torch. The torch harmlessly bounces off the ogre's head and clatters to the floor. It takes a moment to think about what happened, then roars in anger!";
		now the ogre is angry;
		now the torch is in the location;
	otherwise:
		say "You push the torch out of the sconce.";
		now the torch is in the location.

Instead of embersparking the torch:
	say "You light the torch.";
	if the location is First Trial and the torch is in the sconce:
		say "With a quick incantation and gesture of your wand, you light the torch. The flames from the torch burn through the rotting rope, and with a great crash, a chandelier hidden high in the darkness above comes down on the ogre's head, felling the monster!";
		now the ogre is calm;
		now ogre-defeated is true;
		award 10 points;
	now the torch is lit.

Chapter 2 - The Second Trial

The description of the Second Trial is "A much smaller room. There are two levers on the wall on either side of the iron portcullis that blocks the southern exit. In the northwest corner is a bookshelf. (Use PULL LEFT or PULL RIGHT to pull the levers, should you wish to.)" 

South of Second Trial is an iron portcullis. The portcullis is a locked door.

A lever is a kind of device. A lever is usually fixed in place. The description of a lever is usually "A rusty, iron lever with a huge handle, ripe for pulling."

Before an actor pulling a lever:
	try the actor switching on the noun instead.

There is a lever called a left lever in the Second Trial. Understand "left" as the left lever. 

There is a lever called a right lever in the Second Trial. Understand "right" as the right lever. The description of the right lever is "A rusty, iron lever with a huge handle, ripe for pulling. Beneath the lever is a dark, sooty stain."

Summon Puzzle is a scene. Summon Puzzle begins when the Second Trial is visited for the first time. Summon Puzzle ends when the puzzle is solved.

When Summon Puzzle ends:
	award 10 points;
	say "There is a horrid, wrenching sound as gears turn and pull up the iron portcullis.";
	now the iron portcullis is unlocked.

To decide whether the puzzle is solved:
	if the right lever is switched on and the left lever is switched on, yes;
	decide no.

After an actor switching on the right lever:
	if the actor is the player:
		say "A massive jolt of power courses through your body, reducing you - and everything you possess - to ash.";
		end the game in death;
	otherwise if the actor is the goblin:
		say "The goblin emits an unearthly scream as it pulls the lever before disappearing with a pop.";
		remove the goblin from play.

Instead of farpushing a lever in Second Trial:
	say "You pull [the noun] easily with your magic.";
	now the noun is switched on.

In Second Trial is a bookshelf. The bookshelf is fixed in place. The bookshelf is a supporter.The description of the bookshelf is "A surprisingly well-kept bookshelf. On the shelf is a single book."

The strange book is a closed, openable container. The strange book is on the bookshelf. The description of the book is "Similar in appearance to your Grimoire, this book is covered in strange sigils. It is lighter than it appears to be. Written within is a single phrase: 'Upon the sacred altar while the black flame burns, offer up violence. Destroy temptation, and salvation shall be yours.' "

In the strange book is a silver key. The description of the key is "Made of pure sterling silver."

Instead of embersparking the bookshelf:
	say "The bookshelf[if the book is on the bookshelf] - and the book upon it -[end if] are burnt to a crisp.";
	if the strange book is on the bookshelf:
		remove the strange book from play;
		remove the silver key from play;	
	remove the bookshelf from play;
	award -5 points.

Chapter 3 - The Third Trial

The Third Trial is south of the iron portcullis. The description of the Third Trial is "Another narrow room that stinks of ogres - ah, yes, the two sleeping in the corners; one blue-skinned and one black-skinned. Between you and the ogres - as well as the door - is a thick wall of sheer glass, in which a small hole has been cut. Above each ogre is a rope and a button, each colored the same as the ogre beneath it. Again, the things that the ropes are connected to are shrouded in darkness. You probably don't want to wake the ogres. These two are larger than the first one. Embedded in a pedestal near to the wall is a silver knife."

There is a glass wall in Third Trial. The description of the wall is "A wall of sheer glass with a small hole - too small for you to crawl through."

There is a blue ogre in Third Trial. The description of the blue ogre is "Bigger, nastier, and uglier than the one in the first room - but thankfully asleep. Its skin is the color of the sky.".

There is a black ogre in Third Trial. The description of the black ogre is "Bigger, nastier, and uglier than the one in the first room - but thankfully asleep. Its skin is the color of charcoal.".

The blue ogre can be caged. The blue ogre is not caged.

The black ogre can be caged. The black ogre is not caged.

Stealth Puzzle is a scene. Stealth Puzzle begins when Third Trial is visited for the first time. Stealth Puzzle ends when the ogres are trapped.

To decide whether the ogres are trapped:
	if the blue ogre is caged and the black ogre is caged, yes;
	decide no.

When Stealth Puzzle ends:
	say "The glass wall shatters, restoring sound to the room. The ogres remain peacefully sleeping in their cages.";
	remove the glass wall from play;
	now nothing is blocked;
	award 15 points.

There is a blue rope in Third Trial. The description of the blue rope is "A rope, dyed blue, attached to something in the darkness above." The blue rope is fixed in place.

Instead of embersparking the blue rope when Stealth Puzzle is happening:
	say "The rope burns away as you set it ablaze. From the ceiling, a steel cage crashes to the ground, trapping the blue ogre!";
	if all is quiet:
		say "The giant falling cage makes no noise.";
		remove the blue rope from play;
		now the blue ogre is caged;
	otherwise:
		say "Unfortunately, the sound wakes the black ogre, who roars, stands up, [if the goblin is present]beats the goblin to a pulp, [end if] smashes the glass wall down, and bends you into a pretzel.";
		end the game in death.

 There is a black rope in Third Trial. The description of the black rope is "A rope, dyed black, attached to something in the darkness above." The black rope is fixed in place.

Instead of embersparking the black rope when Stealth Puzzle is happening:
	say "The rope burns away as you set it ablaze. From the ceiling a bucket of water descends, drenching the black ogre and waking the monster. He roars, which also wakes the blue ogre, and together they smash everything in the room - including yourself[if the goblin is present] and the goblin[end if].";
	end the game in death.

A button is a kind of device. A button is usually fixed in place.

There is a button called a blue button in Third Trial. The description of the blue button is "A bright blue button with strange markings. It's fairly low to the ground."

After an actor switching on the blue button:
	say "Silence suddenly fills the room - you can't hear yourself breathe. Good thing you don't need to speak to order your goblin around."

After an actor switching off the blue button while Stealth Puzzle is happening:
	say "In a sudden rush of noise, sound returns to the room. Unfortunately, it wakes the ogres, who smash everything in the room - including you[if the goblin is present] and your goblin servant[end if].";
	end the game in death.

To decide whether all is quiet:
	if the blue button is switched on, yes;
	decide no.

There is a button called a black button in Third Trial. The description of the black button is "A dark button with no other design. It's fairly low to the ground."

After an actor switching on the black button:
	say "From the ceiling, a cage suddenly drops on the black ogre.";
	if all is quiet:
		say "Though the cage is heavy, you don't hear a thing, and neither do the ogres.";
		now the black ogre is caged;
	otherwise:
		say "The cage crashes to the ground loudly, waking the blue ogre. Roaring angrily, he smashes[if the goblin is present] your goblin servant,[end if] the glass wall, and then your face.";
		end the game in death.

Instead of farpushing a button:
	say "Strange magic prevents your spells from working on the buttons."

Before an actor pushing a button:
	try the actor switching on the noun instead.

Before the goblin doing anything while in Third Trial:
	if the noun is the blue rope or the noun is the black rope, say "The rope is too high to reach for the little goblin." instead.

There is a pedestal in Third Trial. The pedestal is a supporter. The pedestal is fixed in place. The description of the pedestal is "Made of solid alabaster.[if the knife is on the pedestal] A silver knife is embedded within, much like a fabled sword of legend.[end if]"

There is a silver knife on the pedestal. The description of the silver knife is "A silver knife with an alabaster handle; this must be worth a fortune..."

Instead of the goblin taking the silver knife:
	say "Holy energy surges through the knife, banishing the goblin back to the lower realms.";
	remove the goblin from play.

Before taking the silver knife when the silver knife is on the pedestal:
	say "A surge of power emanates from the pedestal on which the knife sits, searing your hand and preventing you from taking the knife." instead.

Before farpulling the knife:
	now the knife is not blocked;
	continue the action.

A thing can be blocked or not blocked. The silver knife, the pedestal, the blue rope, the black rope, the black button, the blue button, the black ogre, and the blue ogre are blocked.

Before not spellcasting:
	if the current action is examining something:
		continue the action;
	otherwise if the current action is asking the goblin to try doing anything:
		continue the action;
	otherwise if the glass wall is not off-stage and the noun is blocked and the actor is not the goblin:
		say "The glass wall is in your way." instead;
	otherwise:
		continue the action.

Chapter 4 - The Fourth Trial

The Fourth Trial is south of the Third Trial. The description of the Fourth Trial is "A long, narrow hallway, with various crevices in the walls. Along the floor are fine white chips that, on closer examination appear to be bone - probably the remnants of previous apprentices like yourself! As you ponder this, you hear a grinding sound at the end of the hallway, the sound of granite scraping against itself. A stone panel blocks the entrance, and you see - and hear - a giant block of granite headed inexorably in your direction! Look around, and think fast - you don't have long before you, too, are pulverized!"

Granite Deathtrap is a scene. Granite Deathtrap begins when Fourth Trial is visited for the first time. Granite Deathtrap ends when the moving wall is stopped. Granite Deathtrap has a number called kill turn. Granite Deathtrap has a number called death timer.

Every turn during Granite Deathtrap:
	increment the death timer of Granite Deathtrap;
	if the death timer of Granite Deathtrap is the kill turn of Granite Deathtrap:
		say "You took too long - a solid block of granite wooshes down the hall, smashing you into so much paste and shattered bone.";
		end the game in death.

When Granite Deathtrap begins:
	now nowhere is mapped north of Fourth Trial;
	now the kill turn of Granite Deathtrap is 5;

When Granite Deathtrap ends:
	say "The sound of grinding granite stops, and by magic, you are whisked away!";
	let bonus be the kill turn of Granite Deathtrap minus the death timer of Granite Deathtrap;
	let total be 15 plus bonus;
	award total points;
	now the player is in End of the Journey;
	if the goblin is not off-stage, remove the goblin from play.
	
There is a button called a shimmering button in Fourth Trial. The description of the shimmering button is "This button is protected from magic by a shimmering blue field. You know that such fields cannot stop mundane objects. It sits high in one of the crevices." 

Before farpushing or farpulling or embersparking the shimmering button:
	say "The button is protected from magic." instead.

Before the goblin doing anything in Fourth Trial:
	if the noun is a button, say "It's too high for the goblin to reach." instead.
	
Instead of switching on a button in Fourth Trial:
	say "That's too high for you to reach."

There is an unlit black candle in Fourth Trial.  The description of the candle is "A three-pronged candle, [if the candle is unlit]currently unlit,[end if]made from black wax. It sits high on a stone shelf in one of the crevices."

Instead of embersparking the black candle:
	say "You light the black candle. A sweet scent fills the air.";
	now the black candle is lit.

Instead of farpushing something in Fourth Trial while the shimmering button is switched off:
	now the noun is in the location;
	now the command prompt is "Farpush it where? ";
	say "1. The shimmering button.";
	say "2. The crack in the wall above the candle."

To decide whether choosing a farpush target:
	if the command prompt matches the text "Farpush", yes;
	no.

After reading a command when choosing a farpush target:
	if the player's command matches "1":
		if the shimmering button is switched on: 
			say "You press the button again, and the grinding comes faster.";
			now the shimmering button is switched off;
			now the command prompt is ">";
			decrease the kill turn of Granite Deathtrap by 3;
		otherwise:
			say "Using your Far Hand spell, you send it flying into the shimmering button. You hear the grinding noise slow a bit.";
			now the shimmering button is switched on;
			now the command prompt is ">";
			increase the kill turn of Granite Deathtrap by 3;
	otherwise if the player's command matches "2":
		say "You send it flying toward the crack in the wall, but the object harmlessly bounces off.";
		now the command prompt is ">";
	otherwise:
		say "Please choose a target.";
	reject the player's command.

There is a lever called a gray lever in Fourth Trial. The description of the gray lever is "A simple gray lever."

After an actor switching on the gray lever:
	say "The grinding noise gets louder, and you[if the goblin is present] and your goblin servant[end if] are smashed against the back wall, becoming so much bloody paste.";
	end the game in death.

There is a lever called black lever in Fourth Trial.  The description of the black lever is "A simple black lever."

After an actor switching on the black lever:
	say "The grinding noise gets farther away, and you hear the sound of chains. Soon, an ogre comes into view! Unlike the others, though, it doesn't seem to be hostile. It looks confusedly at you and says, 'You free Kirak. Kirak thanks. How Kirak help?' (Command Kirak like you would your goblin servant - KIRAK, (command).";
	now Kirak is in the location.
	
There is a boulder in Fourth Trial. It is fixed in place. The description of the boulder is "A huge, heavy boulder."

Kirak is a person. The description of Kirak is "A foul-smelling, hulking, brutish ogre, much like the rest. He seems to lack the bloodlust of his fellows."

Persuasion rule for asking Kirak to try doing anything:
	if the noun is not the boulder: 
		say "Kirak looks at you confusedly.";
		stop the action;
	otherwise:
		rule succeeds.

Before Kirak doing anything:
	if the noun is the boulder: 
		say " 'Okay! Kirak smash!' Eagerly, the ogre smashes the boulder to tiny bits, revealing a switch, which you eagerly press.";
		remove the boulder from play;
		rule succeeds.

To decide whether the moving wall is stopped:
	if the shimmering button is switched on and the black lever is switched on and the boulder is off-stage: 
		yes;
	no.

Chapter 5 - End of the Journey

End of the Journey is a room.

There is a wand called a Wizard's Staff in End of the Journey.  The description of the Wizard's Staff is "Made of mahogany wood, this is the traditional staff of a Wizard of the Enclave. It is a mightier focus than your apprentice wand."

South of End of the Journey is a locked, lockable door called a silver door. The description of the silver door is "Made of an alloy of steel and silver, this door has a peculiar keyhole." The silver door is unlocked by the silver key.

After taking the Wizard's Staff:
	say "You've completed your journey! You have achieved the rank of full Wizard. Yet, one door remains unlocked. If you have the means, you can open this door and take on what lies beyond it. You know that your magic has grown more powerful; you practically glow with your newfound might.";
	award 16 points;
	say "Continue beyond the door? (Y/N) ";
	if the player consents:
		say "Very well, Wizard. See what you can find there! Good luck!";
	otherwise:
		say "Come, then - join your peers in the Enclave, Wizard, for you have completed your trials!";
		end the game in victory.
		
Chapter 6 - Bonus Room

Sacred Vault is south of the silver door. The description of Sacred Vault is "A sacred sanctuary. There is an altar in the center of the room, covered with a white cloth. There is a bowl upon the altar as well. In the south wall there is a gate, and behind it, you catch a glimpse of what appears to be another Wizard's Staff." The Vault is holy ground. The Vault is dark.

In the Vault is a sacred altar. The description of the altar is "Sacrifices to the gods are made here.[if the bowl is on the altar] An offering-bowl sits upon it.[end if]".  The altar is fixed in place. The altar is a supporter.
	
There is a wand called a Warlock's Staff in Sacred Vault. The description of the Warlock's Staff is "A staff made of black ash. It radiates a tempting aura of power."

Instead of embersparking the altar when the Warlock's Staff is carried:
	award -5 points;
	say "In an explosion of dark magic, you destroy the altar. The ground rumbles and shakes, and the ground erupts into molten lava and dark flame. You fall deep into darkness, hitting the ground hard. Somehow, though, you are unharmed, though your robes are singed.  Before you stands the seven-headed demon Xiras, holding a burning scourge in one hand and a hell-blade in the other that is longer than you are tall.[paragraph break]'You have broken the seal and summoned me, warlock. Am I now to do your bidding?'[paragraph break]Bind Xiras, Lieutenant of the Dark Realms to your service? (Y/N) ";
	if the player consents:
		say "You have become a Warlock, a binder of dark powers. With your new demon servant, you become the headmaster of the Enclave, slaying the former with your fell power. The land is shrouded in the darkness of your rule...";
	otherwise:
		say "Xiras roars at you, 'If not to bind me, then surely you have called me forth to destroy me! But you have made a grave mistake, warlock. In summoning me, you have left a gate open to the mortal realms! Now, I shall destroy you and your world, and bring my hell to earth!'[paragraph break]The battle is short and bitter. Despite your magical might, the demon brings you low, enslaving you forever to the powers of the Dark Realms. Through the gate you opened, Xiras does indeed bring hell on earth.";
	end the story.

There is an iron gate in Sacred Vault. The description of the gate is "Made of solid iron."

Before doing anything when the iron gate is in the location:
	if the noun is the Warlock's Staff, say "The gate is in your way." instead.

Instead of embersparking the iron gate when Wizard's Staff is carried:
	say "Your newfound might manifests as a blast of pure elemental flame, melting the gate.";
	remove the iron gate from play.
	
Instead of farpushing or farpulling the iron gate:
	say "With your new power, you easily lift the iron gate and lock it in place.";
	remove the iron gate from play.

Instead of embersparking the Warlock's Staff:
	say "The staff bursts into flame, leaving behind an acrid smell and some black ash.";
	remove the Warlock's Staff from play.

There is a bowl on the altar. The description of the bowl is "An offering bowl to receive offerings to the gods." The bowl is a container.

Final Puzzle is a scene. Final Puzzle begins when Sacred Vault is visited for the first time. Final Puzzle ends when the demon is sealed away.

When Final Puzzle ends:
	say "You have sealed away the demon lurking beneath the Crucible. You have, through your actions, prevented a great evil from arising. As you are teleported out of the Crucible, a single word is whispered into your mind: 'Falwyn.' Congratulations, Wizard!";
	award 30 points;
	end the game in victory.
	
To decide if the demon is sealed away:
	if the Warlock's Staff is off-stage and the silver knife is in the bowl and the black candle is lit and the black candle is on the altar, yes;
	decide no.

Chapter S -  Spellcasting

There is a goblin. The goblin is a person. The description of the goblin is "A minor demon from the lower realms. It is bound to you, so it will follow you where you go and obey your commands to the best of its meager ability. (Command it with GOBLIN, (command))." Understand "gobbo" as the goblin.

Persuasion rule for asking the goblin to try doing anything:
	rule succeeds.

Goblin-summoning is an action applying to nothing. Understand "summon goblin" as goblin-summoning. Understand "summon gobbo" as goblin-summoning.

Check goblin-summoning (this is the only one goblin rule):
	if the goblin is not off-stage:
		say "You can only command one goblin at a time.";
		stop the action.

Check goblin-summoning (this is the can't summon on holy ground rule):
	if the location is holy ground:
		say "You can't summon such a creature on holy ground.";
		stop the action.

Carry out goblin-summoning:
	move the goblin to the location.

Report goblin-summoning:
	say "You call forth a goblin from the lower realms. It is eager to serve."

Every turn (this is the goblin follows master rule):
	if the goblin is not in the location and the goblin is not off-stage:
		let pth be the best route from the location of the goblin to the location;
		try the goblin going pth.

Every turn (this is the goblin can't stand in holy ground rule):
	if the location is holy ground and the goblin is in the location:
		say "The goblin can't enter holy ground; it disappears from view.";
		remove the goblin from play.

Farpushing is an action applying to one thing. Understand "farpush [something]" as farpushing.

Check farpushing (this is the can't farpush things you can't move rule):
	if the noun is scenery or the noun is fixed in place:
		say "You are not mighty enough to move that.";
		stop the action.
		
Check farpushing (this is the you can't disrobe with farpushing rule):
	if the noun is worn by the player:
		say "How crass! Blasting off your own clothes?";
		stop the action.
	
Report farpushing:
	say "You push [the noun] away from you.[if the noun is the goblin] It smacks into the wall with a crunch and a squeak.[end if]"

After farpushing:
	if the noun is a wand which is not the Wizard's Staff:
		say "[The noun] breaks.";
		remove the noun from play.

Farpulling is an action applying to one thing. Understand "farpull [something]" as farpulling.

Check farpulling (this is the can't farpull things you can't move rule): 
	if the noun is scenery or the noun is fixed in place:
		say "You are not mighty enough to move that.";
		stop the action.

Carry out farpulling: 
	if the noun is the goblin:
		say "You yank the goblin back to you, like a dog on a leash.";
	otherwise:
		move the noun to the player.

Report farpulling: 
	if the noun is not the goblin:
		say "Using your Far Hand, you pull [the noun] into your grasp."

Instead of farpulling or farpushing a person who is not the goblin:
	say "You are not mighty enough to do that."

Embersparking is an action applying to one thing. Understand "emberspark [something]" as embersparking.

Carry out embersparking:
	say "Why would you commit wanton acts of destruction?".

Goblin-summoning is spellcasting.
Farpulling something is spellcasting.
Farpushing something is spellcasting.
Embersparking something is spellcasting.

Before spellcasting:
	if the player is not carrying a wand:
		say "You cannot cast magic without a wand.";
		stop the action.