EuroOlympics! by Akis B

EuroOlympics!

Played 137 times
View game source (spoilers!)
Download the .z8 file
Source Code

"EurOlympics" by Akis

Story creation year is 2025.
The story description is "Can you tour through the EU countries, touching each once.".
The story genre is "Puzzle".
The story headline is "Be a Geography Whiz!".

A country is a kind of thing.
A country can be visited or unvisited. A country is usually unvisited.

Current-country is a country that varies.
Init-country is a country that varies.

Bordering relates various countries to each other.
The verb to border (he borders, they border, it is bordered) implies the bordering relation.

Geography Class is a room. "You're in EU Geography Class. Try visiting each country exactly once, moving only across borders."

[ --- Countries --- ]
Portugal, Spain, France, Belgium, Luxembourg, Germany, Switzerland, Italy,
Holland, Denmark, Poland, Czechia, Austria, Sweden, Norway, Finland,
Russia, Estonia, Lithuania, Latvia, Belarus, Ukraine, Moldova, Romania,
Hungary, Slovakia, Slovenia, Croatia, Serbia, Bosnia, Bulgaria,
North Macedonia, Kosovo, Montenegro, Albania, Greece are countries.

[ --- Borders --- ]
Portugal borders Spain.

Spain borders France.
France borders Belgium. France borders Luxembourg. France borders Germany.
France borders Switzerland. France borders Italy.
Belgium borders Luxembourg. Belgium borders Germany. Belgium borders Holland.
Germany borders Holland. Germany borders Luxembourg. Germany borders Switzerland.
Germany borders Denmark. Germany borders Poland. Germany borders Czechia. Germany borders Austria.

Sweden borders Denmark. Sweden borders Norway. Sweden borders Finland.
Norway borders Finland.

Russia borders Norway. Russia borders Finland. Russia borders Estonia.
Russia borders Lithuania. Russia borders Latvia. Russia borders Poland.
Russia borders Belarus. Russia borders Ukraine.

Estonia borders Latvia.
Lithuania borders Latvia.

Lithuania borders Belarus. Latvia borders Belarus. Ukraine borders Belarus. Poland borders Belarus.
Poland borders Lithuania. Poland borders Ukraine. Poland borders Slovakia. Poland borders Czechia. Poland borders Germany.

Ukraine borders Moldova. Ukraine borders Romania. Ukraine borders Hungary. Ukraine borders Slovakia.
Romania borders Moldova. Romania borders Hungary. Romania borders Serbia. Romania borders Bulgaria.

Austria borders Switzerland. Austria borders Italy. Austria borders Slovenia.
Austria borders Hungary. Austria borders Slovakia. Austria borders Czechia.
Italy borders Switzerland. Italy borders Slovenia.

Hungary borders Slovakia. Hungary borders Slovenia. Hungary borders Croatia. Hungary borders Serbia.
Croatia borders Slovenia. Croatia borders Serbia. Croatia borders Bosnia.
Serbia borders Bosnia. Serbia borders Montenegro. Serbia borders Kosovo. Serbia borders North Macedonia. Serbia borders Bulgaria.

Albania borders Kosovo. Albania borders Montenegro. Albania borders North Macedonia. Albania borders Greece.
Montenegro borders Bosnia. Montenegro borders Kosovo.
Kosovo borders North Macedonia.
Greece borders North Macedonia. Greece borders Bulgaria.
Bulgaria borders North Macedonia.

[ --- Actions --- ]
Visiting is an action applying to one visible thing.
Understand "visit [any thing]" as visiting.
Understand "[any country]" as visiting.

Carry out visiting:
    if the noun is not a country begin;
        say "That’s not a country on our map!" instead;
    end if;
    if noun is visited begin;
        say "You already visited [noun]." instead;
    end if;
    if current-country borders noun begin;
        now current-country is noun;
        now noun is visited;
        say "You travel to [noun].";
        if noun is Italy begin;
            say "[paragraph break]Attenzione Pickpocket! Make sure you have not had anything stolen by saying INVENTORY. You maybe want to EXAMINE your items as well...";
        end if;
        try statusing;
    otherwise;
        say "You cannot travel directly from [current-country] to [noun].";
    end if.

[ --- Lose condition check --- ]
To decide whether no-moves-left:
    repeat with place running through countries begin;
        if current-country borders place and place is unvisited begin;
            decide no;
        end if;
    end repeat;
    decide yes.

Statusing is an action applying to nothing.
Understand "status" as statusing.

Carry out statusing:
    say "You are in [current-country].";
    let count be the number of unvisited countries;
    say "You have [count] countries left to visit.";
    if count is 0 begin;
        say "[paragraph break]Congratulations! You visited every country in the EU tour!";
        end the story saying "You win!";
    end if;
    if no-moves-left begin;
        say "[paragraph break]Oh no! You’re stuck with no more moves. You lost!";
        end the story saying "Game over — you can type RESTART to try again.";
    otherwise;
        say "[paragraph break]From here, you can travel to:";
        repeat with place running through countries begin;
            if current-country borders place and place is unvisited begin;
                say " [place]";
            end if;
        end repeat;
        say ".";
    end if.

[ --- Player inventory --- ]
The player carries a fanny pack. The fanny pack is a container. 
The description of the fanny pack is "A stylish retro fanny pack — perfect for a clueless tourist."

The dollars are in the fanny pack.

The description of the dollars is "A wad of American bills you use to tip European workers, not very useful outside the USA, but you try anyway."

When play begins:
    now current-country is Switzerland;
    now Switzerland is visited;
    say "Hello American! Welcome to your EurOlympics, your goal this summer is to visit all of the countries of mainland Europe (No UK/Ireland) without crossing over a country twice. 
    You may visit a country by simply saying the country's name or by saying VISIT (country). 
    I am going to be helping you a bit by telling you what countries you are bordering. 
    Now, get ready! You just landed in Switzerland!";
    try statusing.