(WIP) A Game About You by Jane Doe

(WIP) A Game About You

Played 3,349 times
View game source (spoilers!)
Download the .z8 file
Source Code

"A Game About You"

Include Basic Screen Effects by Emily Short.

Table of radio messages
message
"Something breaks the silence. There's a voice coming from downstairs. You can't make out what it's saying."
"A muffled voice continues to come from downstairs."
"[magenta letters]'What you see is what will get you. Close your eyes, quickly, before they come to take you away. Welcome to Night Vale.'[default letters]"
"The radio plays a calming tune."
"[magenta letters]'Reports are coming in about a strange red ectoplasm oozing from the walls of every building in Night Vale. The employees in Big Ricoâ€™s Pizza are daring each other to touch the walls, andâ€¦ well, I suggest that you do not touch the walls. The walls of my booth are still ectoplasm-free, but nonetheless, I will be diligent about staying a safe distance away from them. Oh, another update. Definitely do not lick the walls either.'[default letters]"
"[magenta letters]'An update on the giraffe situation, listeners. As you know, Night Vale happens to be situated in the middle of a giraffe migration path, and a enormous herd was passing right through us. While the majesty of a giraffe migration is certainly a sight to behold, one should keep in mind that they are also fearsome predators with deadly venom and telekinesis. Thatâ€™s why I cautioned all of you to stay at home, lock your doors, and hide your keys in a secure place -  such as inside your electronics. Then you could safely appreciate nature from your windows. Anyways, the last giraffe is gone now, so you can exit your homes with only the usual amount of risk.'[default letters]"

House is a scene.
House begins when play begins. House ends when the player is in the streets.

When House ends:
	end the story finally saying "That's it for now. The end."
	
Understand "lick [something]" as licking.
Understand "lick" as a mistake ("You don't know what to lick, so you just kind of... lick the air.")

Licking is an action applying to one touchable thing.

Report licking:
	say "You lick [the noun]. Why did you do that?"
	
[//////////]
	
When play begins:
	now the time of day is 9:04 PM;
	First message happens in 0 turns from now.

Sound-heard is a truth state which varies. Sound-heard is false.
	
At the time when first message happens:
	say "[message in row 1 of the Table of radio messages]";
	Now Sound-heard is true.
	
Every turn when Sound-Heard is true and the living room is unvisited:
	say "[message in row 2 of the Table of radio messages]";
	
A wall is a kind of thing. A wall is scenery.
Understand "walls" as wall.

Your bedroom is a room. "[if unvisited]You have not left your bedroom for the past three days, busy as you were hiding from the sound of thundering hooves, the low mournful buzzing in the air, and the reggae rhythm emitting from the moon. [line break]You gradually realize that the various noises that tend to haunt Night Vale day and night have all subsided, even the chiming from your ceiling that you've learned to tolerate. The total silence is a bit unsettling. You cautiously crawl out from under your desk. [end if]The living room is downstairs."

In your bedroom is a wall.

In your bedroom is a bed. The bed is fixed in place. The bed is an enterable supporter. The description of the bed is "It's a bed. "

In your bedroom is a desk. The desk is a supporter. The desk can be pushed or unpushed. The desk is unpushed. The description of the desk is "It's a desk with a drawer."

Instead of taking the desk, say "There's no practical way of taking the desk with you."

There is a closed openable container called a drawer. The description of the drawer is "It's a drawer." The drawer is part of the desk.

On the desk is a screwdriver. The description of the screwdriver is "It's a screwdriver."

Instead of pushing the desk:
	if the desk is unpushed:
		Now the desk is pushed;
		Say "With some effort, you push the desk back to its usual spot.";
	otherwise:
		say "It should be safe outside now, so you see no reason to trap yourself in the room again."

In your bedroom is a clock. The clock is fixed in place. The description of the clock is "The clock on the wall reads [the time of day].[if we have not examined the clock for the first time] You've really been stuck in here for a while.[end if]"

The bedroom door is down of your bedroom and up of Your living room. The bedroom door is a door.

Instead of opening the bedroom door:
	if the desk is unpushed:
		say "The way down is blocked by a desk. You barricaded your bedroom door after hearing on the radio about the herd of migrating giraffes that were prowling the streets, but the hungry beasts have probably passed by Night Vale by now.";
	otherwise:
		now the bedroom door is open.

Your living room is a room. "[if unvisited][message in row 3 of the Table of radio messages][line break][end if]The living room. A window and a door lie to the east."

Before going to the living room for the first time:
	fourth message happens in 1 turn from now;
	fifth message happens in 2 turns from now;
	continue the action.
	
At the time when the fourth message happens:
	say "[if player can see radio and radio is switched on][message in row 4 of the Table of radio messages][end if]"
	
At the time when the fifth message happens:
	say "[if player can see radio and radio is switched on] [message in row 5 of the Table of radio messages][end if]"
	
In your living room is a living room wall. The description of the living room wall is "The wallpaper has a pattern of pale green tessellated enneagons, as always. Nothing seems out of order about it." Understand "walls" as living room wall.

Instead of touching the living room wall:
	say "You touch the wall. Nothing happens."
	
Instead of licking the living room wall:
	say "You lick the wall. Nothing happens."
	
The window is scenery in your living room. The description of the window is "Through the window you can see the streets outside. It is indeed night time."

Understand "look out [the window]" as examining.

The radio is a device in the living room. The radio is switched on. The description of the radio is "It's a radio. [if the radio is in the living room]You've never been able to pick it up or touch the dials without burning yourself, so it's been sitting there for as long as you've lived in this house.[end if][if player has radio] You notice a battery compartment on the bottom of it.[end if]"

Report taking the radio for the first time:
	say "You pick up the radio without incident." instead.

A locked openable container called the battery compartment is a part of the radio. The screwdriver unlocks the battery compartment.

The house key is inside the battery compartment.

Instead of unlocking the battery compartment with the screwdriver when the player is not carrying the radio:
    say "It would be easier to do that while holding the radio."

Instead of turning the battery compartment:
    say "(with the screwdriver)[command clarification break]";
    try unlocking the battery compartment with the screwdriver;
	try opening the battery compartment.
    
Instead of turning the battery compartment when the player is not carrying the screwdriver:
    say "You don't have a suitable tool."

Report opening the battery compartment for the first time:
	say "You open the battery compartment. Unsurprisingly, there are no batteries inside. There's a house key in it." instead.

The front door is east of your living room and west of the streets. The front door is a door. The door is locked. The house key unlocks the front door.


Before trying opening front door for the first time:
		sixth message happens in 2 turns from now;

At the time when sixth message happens:
	say "[if player can see radio and radio is switched on] [message in row 6 of the Table of radio messages][end if]"
	
Every turn:
	if player can touch radio and radio is switched on:
		say "The radio crackles and hisses.";

The streets is a room. "It's looking pretty descriptionless outside at the moment."