By The Wyrrm by Felix Lo

By The Wyrrm

Played 22 times
View game source (spoilers!)
Download the .z8 file
Source Code

When play begins:
    say "You awaken within the great pit where you've been exiled. Ash and stone surround you and as you look up, you fail to see the light any longer. Your memories of arriving to this place are blurry, only remembering being thrown down by a being too bright to comprehend. Death and decay infest the room with corpses littering the floor, devoid of all life. You suppose many were thrown down alongside you."

[ROOMS]
A room can be either white or black. A room is usually black.

To say darknesswarning: say "The path ahead is too dark to pass, best if you find a source of light before traversing through the dark."

Instead of going to a black room when the player does not carry the Silver Lantern: say "[darknesswarning]".

The King's Descent is a white room. "You see a great many rooms in this barren land, encased in hollow shells of stone. This room is illuminated by a radiant light shining down from the entrance."

Instead of going north from the King's Descent when the player does not carry the Silver Lantern and the player does not carry the Pale Flower:
    say "The path ahead is too dark to pass, haunted by ghosts and vengeful shades. Perhaps a certain light will allow you to pass.";

Instead of going north from the King's Descent when the player carries the Silver Lantern and the player does not carry the Pale Flower:
    say "The path has been illuminated, but it is still too dangerous to pass, haunted with ghosts and vengeful shades. Perhaps a different light will allow you to pass.";

The Pilgrim's Path is a white room. The Pilgrim's Path is east of the King's Descent. "The beginning of every journey, a humble encampment surrounds the area, filled with life where death resides. Pilgrims, wanderers, adventurers, forgotten and lost to the pit where they've all been exiled. Lanterns containing a silver light hang from iron posts."

Smithshaven is north of the Pilgrim's Path. "A dimly lit room illuminated by a faint fire and sparks of metal. The sounds of hammers swinging and smashing down upon an anvil deafen your ears." 

The Royal Chambers are a white room. The Royal Chambers are west of the King's Descent. "The grand resting place for the Pale Queen. You see an elegant bed full of wilted flowers in front of you."

The Archives are north of the Royal Chambers. "The royal archives for preserving the memory of our Pale Rulers. This room houses the knowledge and records of the Pale Kingdom. Strange tablets and murals encircle around you, displaying this place's history and memories. 
[Paragraph break]
You see three books on a shelf titled 'Doctrine of the Pale Wyrrm, Book of Lamentations, and Tome of Impurity.'"

The Ivory Monument is a room. It is north of Smithshaven. Inside of Ivory Monument is nowhere. "A statue of ivory stone lies ahead, depicting the greatness of the Pale King with subjects bowing down to serve. What was once a shining beacon of this land, now a fallen monument, cracked and chipped with no shine or radiance. [Paragraph break] You see a rugged etching on the statue."

The Abandoned Storerooms is a room. "A deserted room filled with shelves and chests that have been emptied long ago. A pile of impassable boulders blocks a passage to the west."

The Pale Shrine is south of the Royal Chambers. "Within the darkness shines a single light, white and radiant. A shrine lies here, depicting a woman of grace and elegance."

The Queen's Spire is north of the Archives. "A lone isolated tower, chiseled and designed with the grace of the Queen. Stairs circle around a central pillar filled with depictions of the Rulers."

The Putrid Caverns are south of the Pilgrim's Path.  "A cavern filled with vapours that release a putrid scent, this place has been poisoned by waste the Kingdom above has thrown down. Metal pipes stick out of the stone walls oozing out a toxic substance."

To say exit list:
	let place be location;
	repeat with way running through directions:
		let place be the room way from the location;
		if place is a room, say " [way]".
After looking:
	say "Exits: [exit list][line break]";

[LORE TABLETS/ENGRAVINGS]
The queen tablet is a fixed in place object in the Queen's Spire. The initial appearance is "A glowing tablet can be seen next to the spire." The description is "On the tablet, these words appear: [Paragraph break] 'Whence does the Hallowed One find mercy? Not of the Wyrrm, not of the Ivor.'
[Paragraph break] 
'As she falls, so will the Pale Kingdom.'";
Understand "lore tablet" or "tablet" as queen tablet. 
Instead of taking queen tablet: say "What would you do with this in your inventory? List ten reasons."
Instead of smelling queen tablet: say “Ahh. The smell of knowledge floods your nostrils.”

The path tablet is a fixed in place object in the Pilgrim's Path. The initial appearance is "Near the encampment, you see a glowing tablet." The description is "On the tablet, these words appear: 'Come willingly and you shall see; the fate realized by those who try; leave not by pale decree.'";
Understand "lore tablet" or "tablet" as path tablet.
Instead of taking path tablet: say "What would you do with this in your inventory? List ten reasons."
Instead of smelling path tablet: say “Ahh. The smell of knowledge floods your nostrils.”

The shrine etching is a fixed in place object in the Pale Shrine. The initial appearance is "You see an etching on the wall near the shrine—it seems the pilgrims were careful not to deface the statue." The description is "The etching is messy, but you can make out the words 'Oh Great One, those who seek shall find, those who forsake shall fall. With humble offerings we come, free us from our solitude!'";
Understand "lore etching" or "etching" or "wall" as shrine etching.
Instead of taking shrine etching: say "You grab the missing space out of the wall-Nah just kidding."
Instead of smelling shrine etching: say “Ahh. The smell of knowledge floods your nostrils.”

The statue of the king is scenery in ivory monument. The description is "A statue built in the honor of the Pale King, now a crumbling relic of a bygone era. The base of the statue has a message crudely chipped into it: 'Oh great leader, why have you forsaken me? For the crime of irreverence, I have been exiled indefinitely?'." Understand "statue of ivory stone" or "statue" or "ivory statue" or "stone statue" or "etching" as statue of the king.
Instead of taking statue: say "That would be blasphemy."
Instead of smelling statue: say “Smells like wealth.”

[ITEMS]

The Silver Lantern is a thing in the Royal Chambers. The initial appearance of Silver Lantern is "To the right of the bed, you see a lantern which illuminates the entire room." The description is "Brightens the area for pilgrims to adventure."; 
Understand "lantern" as Silver Lantern.
Instead of dropping Silver Lantern: say "You don't want to let go of your only source of light in the darkness."
Instead of eating silver lantern: say "This looks likes its been touched by many unwashed hands, it would be unsanitary to eat it."
Instead of drinking silver lantern: say “Unfortunately you don’t have a cup to drink the lantern with, otherwise you’d definitely be able to drink it.”
Instead of smelling silver lantern: say “Honestly don’t know what you were expecting, it’s a lantern.”

The Pale Flower is a thing. The description is "A pale white flower that glows brightly in the dark."; 
Understand "flower" as Pale Flower.
After opening Ornate Box: say "Inside the box, a flower glows softly."; stop the action.
Instead of eating pale flower: end the story saying "You swallow the Pale Flower and you die instantly."
Instead of drinking pale flower: say “You pick up a Pale Flower and attempt to drink it… nothing happens.”
Instead of smelling pale flower: say “A powerful scent radiates from the Pale Flower."

The elegant key is a thing. The description is "Object crafted with an ornate design. Bears the emblem of the kingdom above. Looks like it can open an elegant lock." Understand "key" as elegant key.
After opening suspicious compartment: say "Inside the small compartment you find a key, pristine despite the conditions of its housing."; stop the action.
Instead of eating elegant key: end the story saying "You take a bite into the elegant key and chip your tooth and die instantly. Well done."
Instead of drinking elegant key: say "The key does not appear to be drinkable, much to your surprise."
Instead of smelling elegant key: say "The elegant key gives off a prestigious scent."

The suspicious key is a thing in the Putrid Caverns.
The suspicious key can be repaired or unrepaired.  
The suspicious key is unrepaired.  
The initial appearance is "Lying on the ground is a strange looking object which seems to resemble a key."
The description is "Old looking object in the shape of a simple key. Looks like it needs repairs before it can be used."
Understand "key" or "sus key" as suspicious key.
Instead of eating suspicious key: end the story saying "You take a bite into the suspicious looking key and chip your tooth and die instantly. Well done."
Instead of drinking suspicious key: say "As you try to drink the very solid metal key, a mysterious liquid appears in front of y- just kidding, nothing happens."
Instead of smelling suspicious key: say "The suspicious key smells of rancid waste and filth."

The simple key is a thing. The description is "Commonly manufactured object with a simple design. Looks like it can open a simple lock." Understand "key" as simple key.
Instead of eating simple key: end the story saying "You take a bite into the simple key and chip your tooth and die instantly. Well done."
Instead of drinking simple key: say "The key does not appear to be drinkable, much to your surprise."
Instead of smelling simple key: say "The smell of metal fills your lungs, what a welcome scent."

The Ore is a thing. The initial appearance is "A dull piece of ore lays in the miner's hand." The description is "A chunk of raw ore waiting to be smelted."
Instead of eating ore: end the story saying "In your great wisdom, you decide to bite into the ore emanating toxic fumes. Your teeth make contact with the ore, releasing toxic fumes straight into your mouth. You die instantly."
Instead of drinking ore: end the story saying "Because of your vast judgement and critical thinking skills, you decide to drink the very very toxic waste oozing from the very poisonous ore. The liquid reaches your mouth and you die instantly."
Instead of smelling ore: end the story saying "Rancid and vile fumes fill your lungs as you breathe in. You die instantly."

The craft metal is a thing. The description is "Rare, glittering object found in the darkest reaches of the kingdom. Can be used by a skilled smith to repair tools."

Paper strip is a thing. The description is “An old strip of paper. You can just barely make out the letters ‘pay’.”
Instead of eating paper strip: say "As you attempt to eat the strip of paper, the smith appears behind you with a look of pure confusion on his face, then vanishes."
Instead of drinking paper strip: say “Why?”
Instead of smelling paper strip: say “Nothing but old paper.”

Paper scrap is a thing. The description is "An old scrap of paper. You can just barely make out the letters 'wrl'."
Instead of eating paper scrap: say "You take a bite into the paper and get a tase of nothing but musty paper. Congratulations, a new taste has been added to your collection."
Instead of drinking paper scrap: say “Perhaps if you try another 1000000 times the paper will magically liquify for you.”
Instead of smelling paper scrap: say “Nothing but old paper.”

Paper piece is a thing. The description is "An old piece of paper. You can just barely make out the letters ‘erm’." The initial appearance is "A single piece of paper lays in the hand of a dead pilgrim."
Instead of eating paper piece: say "This looks likes its been touched by many unwashed hands, it would be unsanitary to eat it."
Instead of drinking paper piece: say “Please state three reasons why you typed this and provide MLA citations.”
Instead of smelling paper piece: say “Nothing but old paper.”

Understand "strip" as paper strip.
Understand "scrap" as paper scrap.
Understand "piece" as paper piece.

After examining paper strip: if the player carries paper scrap and the player carries paper piece begin; say "Pay... You realize this is part of a code. As you hold the scraps together, the torn edges align perfectly."; continue the action; end if;

After examining paper scrap: if the player carries paper strip and the player carries paper piece begin; say "Wrl... You realize this is part of a code. As you hold the scraps together, the torn edges align perfectly."; continue the action; end if;

After examining paper piece: if the player carries paper strip and the player carries paper scrap begin; say "erm... You realize this is part of a code. As you hold the scraps together, the torn edges align perfectly."; continue the action; end if;

[OBJECTS OF IMPORTANCE]

The Ornate Box is a fixed in place closed openable locked container. Inside the Ornate Box is a Pale Flower. The elegant key unlocks the Ornate Box. The initial appearance of Ornate Box is "A pristine lockbox is stuck within the walls of the chambers." The description of the Ornate Box is "An ivory box with an elegant keyhole and various engravings of the beings in this land."; 
Understand "box" or "lockbox" or "ivory box" as Ornate Box. 

The wall is a fixed in place object in the Royal Chambers. The initial appearance is "Amidst the ruin, you see a faint white glow coming from the wall adjacent the bed." The description is "You clear the dust from the walls to find a shining box with an elegant keyhole."; 
Understand "glow" as wall.

After examining the wall: 
    remove the wall from play; 
    now the Ornate Box is in the Royal Chambers; 
    continue the action. 

The wooden drawer is a closed openable container in Smithshaven. The wooden drawer is fixed in place. The description is "A simple wooden drawer containing various smithing tools."
The initial appearance is "You see a wooden drawer placed next to where the Smith stands. Perhaps you can find something inside."
The wooden drawer contains paper strip and smithing tools;
Understand "drawer" as wooden drawer.

After opening the wooden drawer for the first time:
    say "You find various smithing tools, as well as a single strip of paper."; stop the action.

The dead pilgrims are a fixed in place object in the Pale Shrine. The initial appearance is "Pilgrims robed in white surround the shrine, collapsed from years of praying. It seems that pilgrims often bear offerings in their palms." The description is "After careful examination, you find that the pilgrims are no longer alive. A single piece of paper hangs from a pilgrim's grasp.";
Understand "pilgrim" or "fallen pilgrims" as dead pilgrims.

After examining the dead pilgrims for the first time:
    now paper piece is in the Pale Shrine;

The untouched chest is a fixed in place closed openable container. The initial appearance is "One chest on top of a shelf catches your eye." The description is "The only chest within the storerooms that is in working condition." The untouched chest contains paper scrap. Understand "chest" as untouched chest.
After opening untouched chest: say "In the chest, you find nothing but a ragged scrap of paper."; stop the action.

The stone door is a door. It is west of the Ivory Monument and east of the Abandoned Storerooms.
The stone door is closed and lockable. The stone door is locked.
The description is "A heavy slab of stone fitted with a simple lock, old and weathered but still functional."

Rule for writing a paragraph about the stone door when the player is in Ivory Monument and stone door is closed:
    say "A large stone door blocks passage to the west."
Rule for writing a paragraph about the stone door when the player is in Ivory Monument and stone door is open:
    say "The stone door is open, allowing passage to the west."
Rule for writing a paragraph about the stone door when the player is in Abandoned Storerooms and stone door is closed:
    say "A large stone door blocks passage to the east."
Rule for writing a paragraph about the stone door when the player is in Abandoned Storerooms and stone door is open:
    say "The stone door is open, allowing passage to the east."

The suspicious compartment is a fixed in place locked closed openable container in the Queen's Spire. The description is "A small opening in the wall, blocked by a small metal plate. Doesn't look like it could fit much." The initial appearance is "You see a suspicious compartment in one of the walls, sealed by an old lock." The suspicious key unlocks the suspicious compartment. Inside the suspicious compartment is an elegant key. Understand "compartment" or "box" or "chest" as suspicious compartment.

Instead of unlocking the suspicious compartment with the suspicious key: if the suspicious key is unrepaired begin; say "You try to use the key, but it’s too worn and fragile to turn the lock safely."; stop the action; otherwise; now the suspicious compartment is unlocked; say "The key fits perfectly, turning smoothly to unlock the compartment."; end if;

The chests are scenery in the Abandoned Storerooms. The description is "Many chests have been ransacked long ago, though one remains untouched."

After examining chests: now the untouched chest is in the Abandoned Storerooms; continue the action. 
Understand "chest" as chests.

[MISC OBJECTS]

Corpse is a fixed in place object in King's Descent. The initial appearance is "Beside you lies the remains of a poor pilgrim that suffered the same fate of exile as you did." The description is "This one didn't survive the fall."

Stones are scenery in King's Descent. The description is "You see a various range of stones scattered among the bodies."
Instead of taking stones: say "You pick up a stone and it starts to dissolve in your hands."
Instead of smelling stones: say "These stones are odorless."
Understand "stone" or "rocks" or "rock" or "boulders" or "boulder" as stones.

Understand "pilgrim" or "remains" or "body" or "poor pilgrim" or "pilgrims" as corpse. 
Instead of taking corpse: say "You try to drag a corpse but it seems that all the bones have seperated from a single form."
Instead of smelling corpse: say “This corpse is so rotten not even a smell remains.”

The smithing tools are scenery. The description is "Tools used to shape metal into anything from jewelry to weapons." 
Instead of taking smithing tools: say "The smith glares at you as you try to take his tools. Best leave them be." Understand "tools" as smithing tools.
Instead of smelling smithing tools: say "These tools smell metallic and warm."

The encampment is scenery in The Pilgrim's Path. The description is "Faint red tents are set up around the encampment. They appear to be inhabited by pilgrims."
Understand "camp" or "tent" as encampment.
Instead of taking encampment: say "Attempting to take the tents alert the pilgrims attention, best if you leave it be."
Instead of smelling encampment: say “Your fellow pilgrims gawk at you as you attempt to smell their encampment.”

The iron posts are scenery in The Pilgrim's Path. The description is "Strong iron posts firmly planted in the ground. They appear to be fairly recently constructed."
Understand "iron post" or "post" or "posts" as iron posts.
Instead of taking iron posts: say "The iron post is firmly planted in the ground."
Instead of smelling iron posts: say “You don’t smell anything particularly interesting, but you do look ridiculous to the surrounding pilgrims who stare at you as you sniff it.”

The lanterns are scenery in The Pilgrim's Path. The description is "Hanging lanterns fixed to posts." Understand "lantern" as lanterns.
Instead of taking lanterns: say "The lanterns are firmly attached to the posts."
Instead of smelling lanterns: say “Mmmmm. The smell of fire. Delicious.”

The storage shelves are scenery in the Abandoned Storerooms. 
The description is "Cobwebs and dust blanket the surrounding shelves, covering scraps of metal, broken tools, and other forgotten junk. Nothing of worth or importance catches your eye."
Understand "shelves" or "shelf" as the storage shelves.
Instead of taking storage shelves: say "A higher being commands you to stop taking shelves."
Instead of smelling storage shelves: say “You smell the fragrent combination of rotting wood and dust.”

The boulders are scenery in the Abandoned Storerooms. The description is "Remnants of a tunnel remain here. Under a boulder lies an unfortunate soul, seemingly carrying an empty sac.";
Understand "pile" or "boulder" as boulders.
Instead of taking boulders: say "The boulders might be a bit too big for you to take, just a bit too big."
Instead of smelling storage shelves: say “The boulders themselves have no smell but the decaying corpse beneath them smells like a decaying corpse. Crazy I know.”

The dim fire is scenery in Smithshaven. The description is "A dim fire is flickering in the background providing a pleasant warmth." Understand "fire" as dim fire.
Instead of taking dim fire: say "In your infinite wisdom, you approach the fire to take it and burn yourself."
Instead of smelling dim fire: say “You take a whiff of the dim fire and smell nothing but burning wood.”

The anvil is scenery in Smithshaven. The description is "An old anvil dented and scratched by years of smithing."
Instead of taking anvil: say "The anvil is a bit too heavy for you to carry."
Instead of smelling anvil: end the story saying “As you lean in to smell the anvil, the smith swings down his hammer, turning your head hollow. At least you get to meet the Hallowed Queen in the afterlife.”

The bed of wilted flowers is scenery in royal chambers. The description is "A bed of wilted flowers, devoid of all life." Understand "flowers" or "flowerbed" or "wilted flowers" as bed of wilted flowers.
Instead of taking flowers: say "You attempt to take one of the flowers but it disintegrates at your very touch."
Instead of smelling flowers: say “A very faint smell ashes and bitterness.”

The golden telescope is a fixed in place object in queen's spire. The initial appearance is "A golden telescope with a crystal lens stands in the corner of the room." The description is "You peer into the telescope, only to find the lens has been shattered." Understand "telescope" as golden telescope.
Instead of taking telescope: say "The telescope is firmly planted in the ground, don’t think you can take it."
Instead of smelling telescope: say “Would the Queen want you to smell this?”

The metal pipes are scenery in Putrid Caverns. The description is "A viscous murky green substance is leaking out a rusting metal pipe." Understand "pipes" or "pipe" or "metal pipe" as metal pipes.
Instead of taking metal pipes: end the game saying "Armed with the cognitive capability of a shoe, you approach the extremely toxic substance to take it and you die instantly."
Instead of smelling metal pipes: end the game saying “In your divine intellect, you decide to smell the very very toxic fumes which result in you dying instantly."

[Archive Books]

The Doctrine of the Pale Wyrrm is scenery in the Archives.
The description is "Doctrine of the Pale Wyrrm, Chapter 1, Provenance. [Paragraph break] 
There stirred an endless void; and from that formless deep arose the Pale Wyrrm. With a will unbound, he consumes that which binds mortal beings; freeing them from their illusion. Yet as He consumes the darkness, so too does the darkness consume Him. As the field lay waste, the Pale Flower blooms; a Kingdom wrought in glory and light had been erected. 
[Paragraph break]
Now all who were once shrouded bow to the radiance. For those who turn away shall be cast unto the Abyss, where the void spreads its blight."

Understand "1st book" or "first book" or "book 1" or "pale wyrrm book" or "doctrine" as Doctrine of the Pale Wyrrm.
Instead of taking doctrine: say "You don't have a library card."
Instead of smelling doctrine: say “Just musty old books.”

The Book of Lamentations is scenery in the Archives. The description is "Book of Lamentations, Chapter 5, Abyssal horror. [Paragraph break]
1>>The supplicants from below beg for deliverance. They ask: why must the Holy Kingdom above shine as we rot below? 
[Paragraph break]
?>> Borne of the pale deity, the royal descent rule over with absolute benevolence. Those found in the abyss entered not by our hand, but by their own. 
[Paragraph break]
Remarks: Enter by your hand and exit by naught; an unwavering observer may be guiltier than not."

Understand "2nd book" or "second book" or "book 2" or "lamentation book" as Book of Lamentations.
Instead of taking Book of Lamentations : say "You don't have a library card."
Instead of smelling Book of Lamentations : say “Just musty old books.”

The Tome of Impurity is scenery in the Archives. The description is "Tome of Impurity, Chapter 14, The Elegy of the False Queen.
[Paragraph Break]
Pale Queen of past, whose impurity beckons destruction by one’s own hand. Lament the masses for obedience and heed not as the Pale Wyrrm commands, and an answer must be found. 
[Paragraph Break]
....We have discovered your true nature; as you climb your final step, have you any words? [Paragraph break]
Remarks: The Hallowed Queen would accept her fate with diligence. One may wonder if the burdens of purity are more crushing than the void itself."

Understand "3rd book" or "third book" or "book 3" or "tome book" or "impurity book" or "tome" as Tome of Impurity.
Instead of taking tome: say "You don't have a library card."
Instead of smelling tome: say “Just musty old books.”

[NPCS]

Talking to is an action applying to one visible thing. 
Understand "talk to [someone]" or "converse with [someone]" or "speak to [someone]" or "speak with [someone]" as talking to.
Check talking to: say "[The noun] doesn't reply."

The Smith is a person in Smithshaven. The initial appearance is "You see a lone smith here shrouded in darkness, stout and strong." The description is "The only smith left in Smithshaven. He seems to have something to say to you."

The Smith can be talked-to or untalked-to. The Smith is untalked-to.
The Smith can be given-ore or not-given-ore. The Smith is not-given-ore.

Instead of talking to the Smith:
    if the Smith is untalked-to begin;
        say "Hey ol' pilgrim, I see you have tested the bounds of the nobelites. I have an object of which is no use to me, but perhaps it will serve you better. It's a simple key, so don't be tryin to stick it where it don't belong.";
        now the player carries the simple key;
        now the Smith is talked-to;
        now the simple key unlocks the stone door;
    otherwise if the player carries the Ore and the player carries the suspicious key and the Smith is not-given-ore;
        say "Heyo! I see you've found the ore—hope it wasn't off of a dead miner's body! Gimme a sec to smelt it.[paragraph break]Here you go, this suspicious key should be all fixed up!";
        now the suspicious key is repaired;
        remove the Ore from play;
        now the Smith is given-ore;
    otherwise if the player carries the Ore and the Smith is not-given-ore;
        say "Heyo! I see you've found the ore—hope it wasn't off of a dead miner's body! Gimme a sec to smelt it. Here it is, the craft metal. I'll keep this in case you bring me something that I could repair.";
        now the player carries the craft metal;
        remove the Ore from play;
        now the Smith is given-ore;
    otherwise if the player carries the suspicious key and the suspicious key is unrepaired;
        say "Wow, where'd you find this? I'm not very familiar with this type of key, but it looks like if you tried to use it in its current state, it would surely break at its hinge. If you gave me some ore, I could use the metal to repair this key.";
    otherwise if the Smith is talked-to and the Smith is given-ore and the suspicious key is repaired;
        say "You know son, I've always known the Pale Rulers to be tyrants. But when facing kin who masquerade as stewards yet act only for their own gain, I begin to question the meaning of the word 'tyrant.'";
    otherwise;
        say "There used to be a whole crew of people down here supplying valuable metals to the royal kingdom, but now I seem to be the only one left. If you can find me an ore, I can smelt it and give you the metal for old time's sake.";
    end if.

The Miner is a person in the Putrid Caverns. The initial appearance is "Amidst the poisonous fumes, you hear an occasional clang that echoes throughout the hollow cavern. In front of you is a slim and slouched miner, wearing a mask to protect his face from the rancid smell and carrying an iron pickaxe on his shoulder." The description is "The Miner looks weary and worn from years of labor in these toxic caverns."

The Miner can be conscious or collapsed. The Miner is conscious.

Instead of talking to the Miner:
    if the Miner is conscious begin;
        say "You tap the Miner on the shoulder. He turns to look at you and suddenly keels over, collapsing to the ground. An ore falls out of his pockets.";
        now the Miner is collapsed;
        now the Ore is in the Putrid Caverns; 
        now the initial appearance of Miner is "";
    otherwise;
        say "The Miner lies motionless on the ground.";
        end if;

The Spire Pilgrim is a person in the Queen's Spire. The printed name is "pilgrim". The initial appearance is "A devoted pilgrim stands here, gazing up the spiraling staircase." The description is "A pilgrim who seems to be waiting for something... or someone.";
Understand "pilgrim" as Spire Pilgrim.

Instead of talking to the Spire Pilgrim:
    say "She walked up this path right here, right up those stairs there, and I've been waiting nearly my whole life to see her walk back down these steps, I swear— Our Queen will save us from the wrath of her Pale Husband. She must walk down the steps…"

The Path Pilgrim is a person in the Pilgrim's Path. The printed name is "devoted pilgrim". The initial appearance is "A devoted pilgrim preaches loudly about the Pale Kingdom." The description is "A fervent supporter of the Pale King.";
Understand "pilgrim" or "pilgrims" or "devoted pilgrim" as Path Pilgrim. 

Instead of talking to the Path Pilgrim:
    say "Those blasted nobelites from above reprieve themselves and yet share no interest in preserving the Pale King's grand plan! I cannot stand within scum any longer; I have ventured down to escape their rule. All hail the Pale Kingdom!"

[WIN CONDITION]

The Gate Room is a white room. It is north of the King's Descent.
The Ending Hall is a white room. 

The Grand Gate is a door. It is north of the Gate Room and south of the Ending Hall.
Understand "gate" or "grand gate" as the Grand Gate.

The description of the Gate Room is "The towering silver gate gleams with divine radiance. Its engraved figures seem to shift in the light, as if beckoning you forward."

Instead of opening the Grand Gate when the player does not carry the paper strip
	and the player does not carry the paper scrap
	and the player does not carry the paper piece:
	say "The gate denies entry to all. An inscription on the wall says 'Only those who recognize our Rulers shall exit.'";

Instead of going through the Grand Gate:
	if the player does not carry the paper strip
		or the player does not carry the paper scrap
		or the player does not carry the paper piece:
		say "The gate denies entry to all. An inscription on the wall says 'Only those who recognize our Rulers shall exit.'";
	else:
		say "You take out the slips of paper and place them in front of the Grand Gate. The letters on the paper begin to glow and realign themselves, revealing the true code 'Pale Wyrrm.'[paragraph break]
The code fades from the paper and the seal upon the gate glows. Absolute radiance consumes you as you ascend to the Pale Kingdom.[paragraph break]
Blinding light begins to shine upon the Abyss. The dead foliage dissolve, the rocks crumble, and corpses vanish into dust. Will the raging eclipse finally be halted?";
		end the story saying "You squint at the sight of two tall figures—much taller than you. As you lift your gaze, you see both Pale Rulers standing before you.[paragraph break]
The light grows stronger…[paragraph break]
Slowly but surely, the Pale King’s form starts to dissolve. You see what has truly come of the Hallowed One.[paragraph break]
'A will unbound falters to none.'";


[secret room]
The Flower Seal is a fixed in place object. The initial appearance is "You notice a strange glowing symbol on the back of the statue." Understand "symbol" or "strange glowing symbol" or "back of the statue" or "glow" as flower seal.

Instead of examining Flower Seal: say "As you approach the back of the statue, you hear a rumbling sound. At the source of the sound, the ground opens, revealing a secret passageway."; now the secret passageway is in ivory monument; remove the flower seal from play.

After taking pale flower: now the flower seal is in ivory monument; continue the action.

The secret passageway is a fixed in place object. The initial appearance is "Behind the statue is an opening in the floor, revealing a secret passageway." Understand "passage" or "secret passage" or "passageway" as secret passageway. Instead of entering secret passageway: move the player to throne room.

The Throne Room is a room. Outside of Throne Room is Ivory Monument. The description is "A dark hall designed with the likeness of the Pale King. At the end of it, a lone beam of pale light illuminating a large structure in the darkness. A throne, a single seat of power to rule over two lost kingdoms, lies empty at the center. [paragraph break]Hollow paladins bearing pale armour stand throughout the darkened halls, molded into stone, endlessly protecting the King." 

The Hollow Paladins are scenery in the Throne Room. The description is "Strong figures standing at attention, although bearing no soul or mind."

The iron throne is scenery in the throne room. The description is "An intricately crafted iron throne radiating a powerful aura." Understand "throne" as iron throne.
Instead of taking throne: say "The Pale Throne does not accept you."
Instead of smelling throne: end the game saying “You die instantly."