Intro to Gamification by Dan Mount

Intro to Gamification

Played 2,070 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Intro to Gamification" by "Dan"

Include Plurality by Emily Short.

Include Quip-Based Conversation by Michael Martin.

Include  Hidden Items by Krister Fundin.

use no scoring.

Chapter 1 Layout

The Office is a room. "You are in your office. To the EAST is a Trophy Room, to the WEST is a Conference Room, to the NORTH is a Classroom, and to the SOUTH is a Presentation Hall."

The Classroom is north of office. "You are in the Classroom. In the Classroom there is a professor.  You can TALK TO the professor." 

The Trophy Room is east of office. "You are in the Trophy Room.  In the Trophy Room there is a display case. There are a lot of things to EXAMINE in here."

The Presentation Hall is south of office. "You are in the Presentation Hall. In the Presentation Hall there is a podium.  You can EXAMINE the podium."

The Conference Room is west of office. "You are in the Conference Room. In the Conference Room there is a Guru. You can TALK TO the Guru."

Chapter 2 Objects

An idea is a kind of thing.

Section 1 Podium

A podium is in the Presentation Hall. The description of the podium is "On the podium are some notecards. You can EXAMINE the notecards.".

A notecard is a kind of thing. The plural of notecard is notecards. A notecard can be complete. A notecard is usually not complete.

Before taking a notecard:
	say "I think it is fine where it is." instead.

after examining a notecard:
if notecard is not complete begin;
	say "The notecard is incomplete. You can COMPLETE a notecard with an item you are carrying.[paragraph break]";
end if.

Understand "complete [something] with [something]" as completing. Completing is an action applying to one visible thing and one carried thing.

check an actor completing:
	if the noun is not a notecard:
		say "Only notecards can be completed[paragraph break]" instead;
		stop the action;
	if the second noun is not an idea:
		say "You can only complete [the noun] with an idea. Try looking for ideas in other rooms." instead;
		stop the action.

after completing a notecard:
	say "[the noun] is now complete.";
	hide the second noun;
	change the noun to complete.
	
A notecard called Notecard 1 is on the podium. 
The description of Notecard 1 is  "On Notecard 1 is written, [quotation mark]_____ can be gamified. Gamification is a _____ rather than a set of _____. [quotation mark]".

A notecard called Notecard 2 is on the podium.
The description of notecard 2 is "On Notecard 2 is written, [quotation mark]A few examples of Gamification are, _____ that gives an item for completing, a _____ with points, levels, and free items, or a _____ with post counts, badges, and contribution levels.[quotation mark]".

A notecard called Notecard 3 is on the podium. 
the description of Notecard 3 is "On Notecard 3 is written, [quotation mark]Gamers are composed of four personality types: ______, ______, ______, and _______. In addition, one of the personality types will be more prominent than the others.[quotation mark]".

A notecard called Notecard 4 is on the podium.
The description of Notecard 4 is "On Notecard 4 is written, [quotation mark]Gabe Zichermann provides the acronym SAPS to describe rewards people prefer.  SAPS stands for _____, _____, _____, and ______.  Zichermann also found that people valued ______ over _____.[quotation mark]".

check completing notecard 1:
	if the second noun is not how-to:
		say "That doesn't sound right, maybe it is a different idea." instead;
	otherwise: 
		now the description of Notecard 1 is "On Notecard 1 is written, [quotation mark]Anything can be gamified. Gamification is a concept rather than a set of guidelines. [quotation mark]".
		
check completing notecard 3:
	if the second noun is not gamer personality:
		say "That doesn't sound right, maybe it is a different idea." instead;
	otherwise: 
		now the description of Notecard 3 is "On Notecard 3 is written, [quotation mark]Gamers are composed of four personality types: Killers, Achievers, Explorers, and Socializers. In addition, one of the personality types will be more prominent than the others.[quotation mark]".
	
check completing notecard 4:
	if the second noun is not rewards:
		say "That doesn't sound right, maybe it is a different idea." instead;
	otherwise: 
		now the description of Notecard 4 is "On Notecard 4 is written, [quotation mark]Gabe Zichermann provides the acronym SAPS to describe rewards people prefer.  SAPS stands for Status, Access, Power, and Stuff.  Zichermann also found that people valued Status over Stuff.[quotation mark]".

check completing notecard 2:
if the second noun is not frequent flyer card and the second noun is not survey and the second noun is not discussion board, say "That doesn't sound right, maybe it is a different idea." instead;
		
after completing notecard 2:
	hide the second noun;
	if survey is hidden and frequent flyer card is hidden and discussion board is hidden:
		now notecard 2 is complete;
		say "Notecard 2 is now complete.";
		now the description of notecard 2 is "On Notecard 2 is written, [quotation mark]A few examples of Gamification are, a survey that gives an item for completing, a frequent flyer program with points, levels, and free items, or a discussion board with post counts, badges, and contribution levels.[quotation mark]";
	otherwise: 
		say "[the second noun] was added to Notecard 2, but it needs more to be complete.";
	
every turn when in presentation hall:
if the notecard 1 is complete  and the notecard 2 is complete and the notecard 3 is complete and the notecard 4 is complete
begin;
   say "You are ready to give a great presentation.";
   try examining notecard 1;
   try examining notecard 2;
   try examining notecard 3;
   try examining notecard 4;
   end the game in victory;
end if.

Section 2 Display Case

A display case is in the Trophy Room.

A Frequent Flyer Card is an idea in the display case. 
The description of the Frequent Flyer Card is "Frequent Flyer programs are a classic example of Gamification.  The programs typically involve accumulating miles/points, they have different levels that can be reached, can offer access to airport clubs and faster lines, and provide free upgrades or tickets.".
After examining Frequent Flyer Card: 
if Frequent Flyer Card is in display case, 
	say "You now have the Frequent Flyer Card[paragraph break]";	
	move Frequent Flyer Card to the player.

A Survey is an idea in the display case. 
The description of the Survey is "If you have ever received a cookie or a trinket for completing a survey, you have experienced Gamification".
After examining Survey: 
if Survey is in display case, 
	say "You now have the Survey[paragraph break]";	
	move Survey to the player.
	
A Discussion Board is an idea in the display case.
The description of the Discussion Board is "Many discussion boards now include points, badges, and leader-boards which help motivate participation.".
After examining Discussion Board: 
if Discussion Board is in display case, 
	say "You now have the Discussion Board[paragraph break]";	
	move Discussion Board to the player.
	
Chapter 3 People

A person can be met. A person is usually not met.

The Professor is a man in the Classroom.
The professor carries an idea called Gamer Personality.
The professor carries an idea called Rewards.

The Guru is a woman in the Conference Room. The Guru carries an idea called How-To.

Chapter 4 Conversations

Section 1 The Professor

The litany of Professor is the Table of Professor Comments.

before talking to Professor:
if the Professor is not met
begin;
	say "Hello, I have some great research to share with you.";
	change the Professor to met;
otherwise;
	say "So we meet again.";
end if.

Table of Professor Comments
prompt	response	enabled
"What have you been researching?"	p-research	1
"Tell me about personality."	p-personality	0
"Tell me about rewards."	p-rewards	0
"Killers are more than a band?"	p-killers	0
"I've heard of overachievers, tell me about achievers."	p-achievers	0
"Socializers, are they like social butterflies?"	p-socializers	0
"Columbus was an explorer."	p-explorers	0
"Thanks for the information"	p-thanks	1

Table of Quip Texts (continued)
quip	quiptext
p-research	"I have been looking into both Rewards and Personality."
p-personality	"Well, gamers are composed of four personality types: Killers, Achievers, Explorers, and Socializers. In addition, one of the personality types will be more prominent than the others."
p-rewards	"Gabe Zichermann provides the acronym SAPS to describe rewards people prefer.  SAPS stands for Status, Access, Power, and Stuff.  Zichermann also found that people valued Status over Stuff."
p-thanks	"You're welcome, talk to you soon."
p-explorers	"Explorers enjoy discovering areas and hidden items; games with items to unlock or undocumented maps work well for explorers."
p-killers	"Killers prefer competition and to destroy competitors; first person shooters are attractive to these gamers as are leader-boards."
p-socializers	"Socializers prefer interacting with others, and working as a group; they are not usually drawn to single player games."
p-achievers	"Achievers prefer to gain rewards, points, levels; achievers enjoy games with a progression of levels with awards or trophies."

After quipping when the current quip is p-research:
	enable the p-personality quip;
	enable the p-rewards quip.
	
After quipping when the current quip is p-personality:
	enable the p-socializers quip;
	enable the p-explorers quip;
	enable the p-achievers quip;
	enable the p-killers quip.

After quipping when the current quip is p-killers :
if the Professor has Gamer Personality,
	say "The professor has given you the idea of gamer personality.  [paragraph break]";
	move the Gamer Personality to the player.

After quipping when the current quip is p-socializers :
if the Professor has Gamer Personality,
	say "The professor has given you the idea of gamer personality.  [paragraph break]";
	move the Gamer Personality to the player.

After quipping when the current quip is p-explorers :
if the Professor has Gamer Personality,
	say "The professor has given you the idea of gamer personality.  [paragraph break]";
	move the Gamer Personality to the player.
	
After quipping when the current quip is p-achievers :
if the Professor has Gamer Personality,
	say "The professor has given you the idea of gamer personality.  [paragraph break]";
	move the Gamer Personality to the player.
	
After quipping when the current quip is p-rewards:
	say "The professor has given you the idea of rewards.  [paragraph break]";
	move the Rewards to the player.
	
After quipping when the current quip is p-thanks:
		enable the p-thanks quip;
		terminate the conversation.
		
Section 2 The Guru

The litany of Guru is the Table of Guru Comments.

before talking to Guru:
if the Guru is not met
begin;
	say "I hear you are looking into Gamification.";
	change the Guru to met;
otherwise;
	say "Howdy.";
end if.

Table of Guru Comments
prompt	response	enabled
"Yes, what can you tell me?"	g-tellme	1
"What can be Gamified?"	g-what	0
"Isn't just adding points and badges to something?"	g-points	0
"So how do I gamify something?"	g-how	0
"Great info, thanks."	g-thanks	1

Table of Quip Texts (continued)
quip	quiptext
g-thanks	"Nice talking with you."
g-tellme	"At its core, Gamification is applying game mechanics to a topic."
g-what	"Anything can be gamified."
g-points	"Gamification can be more than just points and badges, those are just two of multiple available game components."
g-how	"Gamification is a concept rather than a set of guidelines. It can be used as a new way to solve a problem."

After quipping when the current quip is g-tellme:
		enable the g-what quip;
		enable the g-how quip;
		enable the g-points quip.
		
After quipping when the current quip is g-how:
	say "The guru has given you the idea of how to gamify.  [paragraph break]";
	move the How-To to the player.
	
After quipping when the current quip is g-thanks:
		enable the g-thanks quip;
		terminate the conversation.
	
Chapter 5 Help

understand "help" as help.
help is an action applying to nothing.
Carry out help:
	say "To move between rooms type the direction (i.e. North, South, East, West) [line break]";
	say "To talk to someone, type 'talk to <person>' [line break]";
	say "To examine something type 'examine <item>' [line break]";
	say "To complete something type 'complete <item> with <item>' [line break]";
	say "To see what you have type i (inventory) [paragraph break]".
	
Chapter 6 Test

test prof with "n / talk to professor / 1 / 2 / 1 / 1 / 1 / 1 / 1 / 1 / talk to professor / 1 / i / s".
test guru with "w / talk to guru / 1 / 1 / 1 / 1 / 1 / talk to guru / 1 / i / e".
test trophy with "e / examine display case / examine frequent flyer card / examine discussion board / examine survey / i / w".
test speech with "help / test prof / test guru / test trophy / s / examine podium / examine notecard 1 / complete notecard 2 with podium / complete notecard 1 with notecard 3 / complete podium with how-to / complete notecard 2 with how-to / complete notecard 1 with how-to / examine notecard 1 / complete notecard 2 with survey / complete notecard 2 with frequent flyer card / complete notecard 2 with discussion board / complete notecard 4 with rewards / complete notecard 3 with gamer personality".