Footprints by Joey Jones

Footprints

Played 3,006 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Footprints" by Joey Jones

The story headline is "A mucky romp"

Use no scoring.

Chapter Exit Listing

[This bit is code pinched from Example 337: Guided Tour.]

When play begins:
	now left hand status line is "Nearby: [if a room is adjacent][the list of adjacent rooms][end if][if a room is adjacent and a door is visible] and [end if][if a door is visible][the list of visible doors][end if]";
	now right hand status line is "".

Rule for printing the name of an unvisited room (called the target) while constructing the status line:
	let aim be the best route from the location to the target;
	say "something [aim]".

After printing the name of a visited room (called the target) while constructing the status line:
	let aim be the best route from the location to the target;
	say " ([aim])".

Rule for printing the name of a direction (called the aim) while constructing the status line:
	choose row with a heading of the aim in the Table of Abbreviation;
	say "[shortcut entry]".

Table of Abbreviation
heading	shortcut
north	"N"
northeast	"NE"
northwest	"NW"
east	"E"
southeast	"SE"
south	"S"
southwest	"SW"
west	"W"
up	"U"
down	"D"
inside	"in"
outside	"out"

Chapter Everything Else

When play begins:
say "You have to get to the tower, past the the wintery path somewhat to the east. Make sure you don't tread prints into its nice carpet!"

The Courtyard is a room. The Kitchen is south of the courtyard. The Gladiatorial Arena is a west of the courtyard. The Winter Path is east of the Courtyard. The Winding Tower is east of the Winter Path. Yourself is in the kitchen.

Ichor is a kind of value. The ichors are bloody, floury, snowy, muddy and clean.
A room has an ichor called cleanliness. The cleanliness of a room is usually clean.
A thing has an ichor called staining. The staining of a thing is usually clean.


The cleanliness of the gladiatorial arena is bloody.
The cleanliness of the Winter Path is snowy.
The cleanliness of the Courtyard is muddy.


The description of yourself is "You are nice and [staining of the player]."

Every turn:
	if the cleanliness of the location of the player is snowy:
		if the staining of the player is bloody:
			now the cleanliness of the location of the player is clean;
			now the staining of the player is clean;
			say "Though the snow washes the blood from your boots, the heat from the blood soon melts a clear path through the snow.";
	if the cleanliness of the location of the player is floury:
		if the staining of the player is bloody:
			now the cleanliness of the location of the player is clean;
			now the staining of the player is clean;
			say "The heat from the blood bakes the flour, cleansing the [printed name of the location of the player in lower case], as well as your own feet.";
	if the cleanliness of the location of the player is clean and the staining of the player is not clean:
		now the cleanliness of the location is the staining of the player;
		say "You spread [staining of the player] prints everywhere.";
	if the cleanliness of the location of the player is not the staining of the player:
		now the staining of the player is the cleanliness of the location of the player;
		say "You're beginning to get [the staining of the player].".
		
Understand the command "shake", "empty" and "pour" as attack.
		
The description of a room is "[one of]You stand in[or]This is[or]Here you are in[at random] the [printed name of the location in lower case][corny stand-up][if the cleanliness of the location is not clean] The ground is [one of]very[or]particularly[or]unreasonably[or]excessively[or]almost irrevocably[or]unhygienically[at random] [cleanliness of the location].[end if][if the cleanliness of the location is bloody] The blood here is from the fire beast of Th'all and is piping hot.[end if]"

The bag of flour is in the kitchen.

To say corny stand-up:
	if the table of remarks is not empty:
		choose a random row in the table of remarks;
		say ". [remark entry]";
		blank out the whole row;
	otherwise:
		say ". ".
			
Stains is a backdrop. Stains is everywhere. The description of the stains is "It's pretty [cleanliness of the location of the player] round here."


Understand "blood", "snow" and "mud" as the stains.

Table of remarks
Remark
"Its a small place but the rent is cheap."
"You once met a man from Nantucket here. He had no sense of humour."
"It needs a bit of a sweep but eh, what can you do?"
"What's worse than a room with no scenery? A messy room with no scenery!"
"You look around for exits, and quickly populate the status bar with your assessment."
"You'll be glad to know, there are no tea making puzzles in this game."
"You dimly wonder what it would be like to live in a fully implemented environment."
"You sense that today's puzzling may have something to do with walking through rooms in a certain order after doing something."
"You briefly admire yourself in an unimplemented reflective surface: still nice and [staining of the player]."
"[if the flour is not held by the player]You sure wish you were carrying around your trusty bag of flour right now[otherwise]This flour is great, only it tends to get everywhere at the slightest provocation[end if]."
"Why if you had a muffin for every generic fantasy castle you got stuck in... you'd have several muffins."
"Come to think of it, you're not too sure why you have to get to the tower. It's not as if there's even a macguffin there."

Instead of doing anything other than taking to the bag of flour:
say "No sooner do you even look at it and flour puffs out the top of the bag.";
now the cleanliness of the location of the player is floury.

Every turn in the winding tower:
	if the staining of the player is not clean:
		end the story saying "Uh oh! You messed up the tower!";
	if the staining of the player is clean:
		end the story finally saying "Congratulations! You didn't muck up the floor!"