Barroom Brawl by Mathbrush

Barroom Brawl

Played 2,705 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Barroom Brawl" by One-Eye Jack.

The story genre is "Western". The story headline is "Punch for your life". The story description is "To be continued." The story creation year is 2016.

Use no scoring.

Section 1 - Initial Setup

Abouting is an action out of world. Understand "about" as abouting.

Carry out abouting:
	say "Barroom Brawl can be played as either a fighting game with PUNCH or KICK as the main actions, and 'smash' actions available in various compass directions. Or it can be played as a one-move game with most other commands.

Barroom brawls are messy and unfair. If you choose to fight, just get in there and hope for the best.

This game is inspired in part by Super Smash Brothers.";

A person has a number called health. Health is usually 10. A person has a number called rage. Rage is usually 1. A person has a person called the target. The target is usually Hank. A person has a thing called remains. A person can be prone or not prone.

A foe is a kind of person. A foe can be male or female.

Barroom is a room. The description of Barroom is "This seedy old watering hole is in total chaos. Tables are overturned, glasses are broken, chairs are missing[first time] and a brawl is brewing!

Sally lowers into a fighting stance.

Hank backflips and breaks a table!

Frank cracks his knuckles and looks about.

Belle spits loudly.

[bracket]First time players can type ABOUT.[close bracket]
[only]". Hank is a male foe. Hank is in barroom. Belle is a female foe. Belle is in Barroom. Frank is a male foe. Frank is in barroom. Sally is a female foe. Sally is in barroom. 

Before listing nondescript items: 
	repeat with currentperson running through people: 
		now currentperson is not marked for listing; 

A corpse is a kind of thing.

Instead of examining a corpse:
	say "You look over at [noun]; they're snoring away peacefully with lumps and bruises all over.";

HankCorpse is a corpse. HankCorpse is in HoldingCell. The printed name of HankCorpse is "Hank's body". The remains of Hank is HankCorpse. Understand "Hank" or "body" as HankCorpse.

BelleCorpse is a corpse. BelleCorpse is in HoldingCell. The printed name of BelleCorpse is "Belle's body". The remains of Belle is BelleCorpse. Understand "Belle" or "body" as BelleCorpse.

FrankCorpse is a corpse. FrankCorpse is in HoldingCell. The printed name of FrankCorpse is "Frank's body". The remains of Frank is FrankCorpse. Understand "Frank" or "body" as FrankCorpse.

SallyCorpse is a corpse. SallyCorpse is in HoldingCell. The printed name of SallyCorpse is "Sally's body". The remains of Sally is SallyCorpse. Understand "Sally" or "body" as SallyCorpse.

DiabloCorpse is a corpse. DiabloCorpse is in Holding Cell. The printed name of DiabloCorpse is "El Pollo Diablo's body". Understand "El Pooloo Diablo" or "body" as DiabloCorpse.

Remains of player is SallyCorpse.

Fighter is a person that varies. Fighter is usually Hank.

Section 2 - Fighting and sky jumping

Smashing is an action out of world. Understand "smash" as smashing.

Carry out smashing:
	say "To smash, just type a direction.";

When play begins:
 say "Well, it's just a typical night at the local watering hole. Hank got drunk and tripped over Sally, Sally punched Frank in the face, Belle slapped Sally, and Frank turned and punched you in the eye! Looks like it's another:

";
 now Fighter is player;

Kicking is an action applying to one thing. Understand "kick [someone]" as kicking.

Carry out kicking someone:
	if Fighter is player:
		say "You [one of]flex your knee and snaps your foot at [noun][or]cartwheel and slams your feet into [noun][or]dive low and sweep your feet at [noun][at random].";
	otherwise if noun is player:
		say "[Fighter] [one of]flexes their knee and snaps their foot at you[or]cartwheels and slams their feet into you[or]dives low and sweeps their feet at you[at random].";
	otherwise:
		say "[Fighter] [one of]flexes their knee and snaps their foot at [noun][or]cartwheels and slams their feet into [noun][or]dives low and sweeps their feet at [noun][at random].";
	now health of noun is health of noun minus 2;
	if health of noun is less than 1:
		now rage of fighter is rage of fighter plus 2;
		if noun is not player:
			say "[line break][noun] just got knocked out!";
			now noun is in HoldingCell;
			now remains of noun is in Barroom;
		otherwise:
			say "[line break]You got knocked out!";

Instead of attacking someone:
 try punching the noun;

Understand "punch" as something new.

Punching is an action applying to one thing. Understand "punch [someone]" as punching.

Carry out punching someone:
	if Fighter is player:
		say "You [one of]swing a wild haymaker at [noun][or]duck left, jab, jab again, and uppercut [noun][or]slap [noun] with all your force[at random]!";
	otherwise if noun is player:
		say "[Fighter] [one of]swings a wild haymaker at you[or]ducks left, jabs, jabs again, and uppercuts you[or]slaps you with all their force[at random]!";
	otherwise:
		say "[Fighter] [one of]swings a wild haymaker at [noun][or]ducks left, jabs, jabs, and uppercuts [noun][or]slaps [noun] with all their force[at random]!";
	now health of noun is health of noun minus rage of fighter;
	if health of noun is less than 1:
		now rage of fighter is rage of fighter plus 2;
		if noun is not player:
			say "[line break][noun] just got knocked out!";
			now noun is in HoldingCell;
			now remains of noun is in Barroom;
		otherwise:
			say "[line break]You got knocked out!";

Instead of examining a foe:
 Say "You are not one to reduce living, breathing human beings to  bare numbers and calculations, but if you were to do so, you would say that [noun] has health [health of noun] and rage [rage of noun]."

Instead of examining the player:
	say "You glance at the tattoo over your heart. Just what you remember: a heart that says 'Mom', a tombstone with the phrase 'Your current health is [health of player]', and a thermometer labeled 'Rage!' that is currently set to [rage of player] degrees."

Instead of examining El Pollo Diablo:
 say "El Pollo Diablo cannot be examined. He is a mystery."

Sky High is up from Barroom. "You swing your arms and flex your knees, and then spring upwards at a breakneck pace, smashing through the roof and soaring into, then through the clouds. You reach your apex and pause ever so slightly before your descent."

TimeUpHigh is a number that varies. TimeUpHigh is usually 0.

Every turn when in Sky High:
 	 If TimeUpHigh is one:
		now target of player is a random person in Barroom;
		now health of target of player is health of target of player minus 2;
		say "You rocket downward, head first, plummeting to the earth. As air heats up and begins to burn about you, you scream out wildly. Smashing back into the barroom, you attack [target of player].";
		now the player is in Barroom;
		now TimeUpHigh is 0;
	otherwise:
		 now TimeUpHigh is TimeUpHigh plus one;

Every turn when in Barroom:
	repeat with currentperson running through foes in Barroom:
		if player is not in Barroom:
			end the story saying "You got brawled!";
		if currentperson is not prone:
			now fighter is currentperson;
			if JustFroze is 1:
				now target of fighter is player;
			otherwise if HiddenGuy is 1:
				now target of fighter is a random foe in the barroom;
			otherwise:
				now fighter is in WaitingPlace;
				now target of fighter is a random person that is in barroom;
				now fighter is in Barroom;
			if a random chance of 1 in 2 succeeds:
				 try punching target of fighter;
			otherwise:
				 try kicking target of fighter;
		otherwise:
			say "[currentperson] [one of]stumbles to their feet[or]jumps up with a shout[or]backflips off the floor[or]slowly climbs up a table to stand again[at random].";
			now currentperson is not prone;
	if health of player is less than 1:
		end the story saying "You got brawled!";
	otherwise if health of player is less than 3:
		say "[italic type][one of]I wonder sometimes what it's like in other towns.[or]At least I'm doing better than last time.[or]How long am I going to be doing this?[or]I miss Mom sometimes.[at random][roman type]";
	now  JustFroze is 0;
	if El Pollo Diablo is in WaitingPlace:
		now  HiddenGuy is 0;
	now fighter is player;

Section 3 - Directional moves that are not sky jumping 

Barroom is south of barroom.
Instead of going south from Barroom:
	if El Pollo Diablo is in Barroom:
		now target of player is El Pollo Diablo;
	otherwise:
		now target of player is a random foe in barroom;
	say "You kick [target of player] below the belt. [if target of player is female]She laughs at you.[otherwise]They double over in pain.[end if]";
	now health of target of player is health of target of player minus 2.

Barroom is down from barroom.

Instead of going down from barroom:
	if El Pollo Diablo is in WaitingPlace:
		now target of player is a random foe that is not player;
 		say "You crouch low and sweep out a foot, tripping [target of player].";
		now target of player is prone;
	otherwise:
		say "You try to trip El Pollo Diablo, but he avoids you!";

JustFroze is a number that varies. JustFroze is usually 0;

Instead of going north from barroom:
	say "You pause for a moment, and imagine a place far away. In your mind, you gather the frozen breath of the Boreal winds. 

Snowflakes dance about your closed lashes and frost rhimes your every inch of skin. You exhale ever so gently, and streams of mist flow out before violently expanding into a frozen mist. 

Everyone shouts in fear and pain as the mist stings them, before turning to you with angry stares.";
	now JustFroze is 1;

Barroom is west of barroom.

ShooterCounter is a number that varies. ShooterCounter is six.

Instead of going west from barroom:
	say "You can't fight it any more. You pull out your six-shooter and fire it in the air. The room goes still as you pant breathlessly.

'I'm sorry, I just...' You shake your head. 'Come on! Let's do this!'
";
	now ShooterCounter is ShooterCounter minus one;
	if ShooterCounter is 0:
		say "You reach down and grab some ammunition from a knocked-out buckaroo and reload your gun in one fluid motion before tucking it back into your waist.";
		now ShooterCounter is six;
 	otherwise:
		say "You tuck your gun back in before reentering the fray."; 
 	now rage of player is rage of player plus one.

HiddenGuy is a number that varies. HiddenGuy is usually 0.

Instead of going east from barroom:
 say "Wishing you were somewhere else, you recall the teachings of a small pamphlet left by a traveling Buddhist...

Thoughts wash away, and you find yourself in a peaceful realm of spirit. As you realize that you are nothing, you become nothing.

You fade from the notice of the others, and lose all of your aggression and rage.[if El Pollo Diablo is in Barroom][otherwise if the number of people in HoldingCell is at least 3]

Your foe looks about in confusion.[otherwise]

They look about in confusion.[end if]";
 now rage of player is 1;
 now HiddenGuy is 1.

Instead of going northwest:
 say "This bickering is futile; you did not come here for this. These backwards hayseeds will never help you find the northwest passage.

You shoulder your pack and go, traveling northwest into Oregon territory. You venture into Alaska, but find yourself too poor to buy the requisite materials.

You become a fur trader, trapping beavers with primitive log traps. You develop a network of friends, trappers you see once or twice a year as you cross into each other's territory.

You earn enough money for your trip to Alaska within a year, but you never get around to leaving.";
 end the story finally;

Instead of going northeast:
 say "Surveying the room with bloodshot eyes, you loudly declare, 'I!! Am Getting! An Education!'

Everyone stops and stares at you, some picking themselves off the floor. The men place their hats over their hats, and all sing a rousing rendition of 'God Be With You Till We Meet Again'.

A local fund is started, and you head off northeast to Harvard. It is cold and friendless there, but you think of home, and push on.

You are the first in your state to obtain a doctor of philosophy, and a statue is erected in your honor. You organize a committee and petition the government to form a land-grant university in the state which, when built, contains a building named in your honor.";
 end the story finally;

Instead of going southwest:
 say "'Now y'all wait... now y'all wait just a minute here. Why'we doing this? Why'we...Why'we fighting each other?'

You gaze about the room, pleading with them earnestly with your eyes. 'I'm not gonna be like this any more. I'm going in a new direction; I'm going...southwest!'

You start a rival grub house in town serving enchiladas and chiles rellenos. Instead of slinging punchew, you're slinging hash at the Annual Southwestern Cooking Expedition year after year. 

Looking back at your collection of trophies it's safe to say that ...";
 end the story finally saying "You have won";

Instead of going southeast:
	say "You are blown off your feet by a sudden gust of wind. You smash through the wall of the bar and are tumbled down the street.

The wind picks up, spinning you faster and faster, until you are aloft.  You soar south east, spiraling slowly across the globe, befriending migratory birds.

You feel no chill as you slowly, slowly settled down at the magnetic south pole. You will wait, until She is ready.";
	end the story finally.

Barroom is outside from Barroom.

Before going outside:
	try outing instead.

Outing is an action out of world. Understand "run" or "walk" or "out" or "get out" as outing.

OutCount is a number that varies. OutCount is usually 0.

Carry out outing:
	if OutCount is 1:
		say "You get out of there. Out of the bar, out of the town. You get out of your body. You get out of your fear, your sadness, but also your joy and friendship. You exist and do not exist.";
		end the story finally saying "";
	otherwise:
		now OutCount is OutCount plus one;
		say "Which direction do you want to go?";

Instead of going inside from Barroom:
	say "You look deep within. You see a faint, glowing spark within your heart. With gentle hands, you coax the spark out and into your hands.

With awe, the others crowd together to view your spark. With trembling hands, they bring forth their own sparks, which fill the room with light.

You begin to rise. All around you, on the ground, you see brilliant points of light form, as all of humanity rises to follow you. Towards the stars you go, faster and faster, and you shout with pure joy.";
	end the story finally saying "You have truly won."

Left is a direction. Right is a direction. The opposite of left is right. The opposite of right is left. Forward is a direction. Backward is a direction. The opposite of forward is backward. The opposite of backward is forward.

Understand "backwards" or "back" as backward. Understand "fore" as forward.

Instead of going left:
	say "Left. Sinister.

Time slows down as you hook with your left, followed by a jab. Your right arm shrivels and weakens, giving its power to your left. The sinister-side fist becomes a blur, and red rage fills your eyes.

You never stop fighting. You'll never leave this town.";
	end the story finally saying "You have given in to your sinister side."

Instead of going right:
	say "Right!";

Barroom is left of Barroom. Barroom is forward from Barroom. 

Section 4 - El Pollo Diablo

PolloTime is a scene. PolloTime begins when the number of people in HoldingCell is 4.

PolloTime ends when El Pollo Diablo is in HoldingCell.

WaitingPlace is a room.

El Pollo Diablo is a person. El Pollo Diablo is in WaitingPlace.

When PolloTime begins:
 Say "Everyone lies scattered on the floor. You stand still, breathing heavily. Behind you, you hear the saloon door swing and hear slow, heavy, footsteps.

Slowly, you turn around and see El Pollo Diablo, toughest son-of-a-gun in all the west. Six foot six, covered in rippling muscles and a leather jerkin, thick black hair pulled back with a hunk of twine. He cracks his knuckles.

You feel a surge of energy, and rise to the challenge!";
 now El Pollo Diablo is in Barroom;
 Now health of El Pollo Diablo is 20;
 now rage of El Pollo Diablo is 3;
 now health of player is 15;

Every turn during PolloTime:
	if El Pollo Diablo is prone:
		say "El Pollo Diablo [one of]stumbles to their feet[or]jumps up with a shout[or]backflips off the floor[or]slowly climbs up a table to stand again[at random].";
		now El Pollo Diablo is not prone;
	otherwise if HiddenGuy is 0:
		now fighter is El Pollo Diablo;
		if a random chance of 1 in 2 succeeds:
			 try punching player;
		otherwise:
			 try kicking player;
	otherwise:
		say "El Pollo Diablo pauses, searching the room, and, shaking off his confusion, waits patiently for you to reappear";
	if health of player is less than 1:
		end the story saying "You got brawled!";
	otherwise if health of player is less than 3:
		say "Maybe you should get out of here!";
	now  JustFroze is 0;
	now  HiddenGuy is 0;
	now fighter is player;

When PolloTime ends:
 end the story finally.

Section 5 - Scenery

Tables are scenery. Tables are in barroom. Understand "table" as tables. The description of tables is "By the official rules of bar fighting, tables are off limits in fights of four or more individuals.". Glasses are scenery. Glasses are in barroom. Understand "glass" as glasses. The description of glasses is "Yikes! Those shards of glass look pointy! I wouldn't grab that if I were you!"