Room serial by merricart

Room serial

Played 5,497 times
View game source (spoilers!)
Download the .z8 file
Source Code

The story title is "Room serial".
The story author is "merricart".
The story headline is "An escape game".
The release number is 2.
The story description is "An interactive fiction where you escape from a series of rooms by learning what happened to you."

Use American dialect and the serial comma. Use no scoring.

Chapter 1-definitions

Powerlevel is number variable. Powerlevel is usually 1.
Powerlist is a list of texts that varies.
Journal date is a number variable. Journal date is usually 0602.

Chapter 2- parser Rules

To say as the parser: do nothing. To say as normal: do nothing.
Rule for printing the name of a room:
	stop the action.
After reading a command:
	if the player's command includes "restore", reject the player's command.

Chapter 3-property Rules

A door is a scenery.
A door can be unlocked or locked. A door can be open or closed. 
A door can be movable or unmovable. A door is usually unmovable.
A thing is usually a scenery. A thing can be explored or unexplored. A thing can be seen or unseen. A thing is usually seen.
A thing can be on or off. 
A thing can be memorable or unmemorable. A thing is usually unmemorable. A thing can be remembered or unremembered.
A thing can be movable or unmovable. A thing is usually unmovable. A thing is usually fixed in place.
A container can be openable or unopenable. A container can be open or closed. A container is usually unopenable. 
A container can be locked or unlocked.
A room can be explored or unexplored. A room is usually unexplored.


Chapter 4-specific instead rules

Instead of examining the background, try looking.
Instead of listening, try listening to by point background.
Instead of searching a thing:
	if the noun is an open container or the noun is the background:
		try examining the noun;
	otherwise if the noun is a closed container:
		say "Open [noun] first.";
	otherwise if the noun is not a container:
		try informing powerless.

Instead of entering a closed door:
	say "Open the door first."
Instead of closing a door:
	say "I don't want to close it, just in case I get locked in again."

Instead of examining, touching, or moving with effort an unseen thing:
	say "You look everywhere, but the [noun] is nowhere in sight."

Instead of remembering an unmemorable thing:
	say "You remember nothing special about it."
Instead of moving with effort or taking an unmovable thing, say "You try hard to move [noun], but it doesn't budge at all."

Instead of going south while the player is in the first room, say "It's a hard decision, but you have to choose a door to enter."
Instead of going east while the player is in the first room, say "It's a hard decision, but you have to choose a door to enter."

Instead of opening the safe:
	if the safe is locked:
		say "It requires a four letter passcode to open.[line break][line break]To enter passcode, type use passcode (passcode) .";
	otherwise:
		continue the action.

Instead of moving with effort the cabinet:
	if the cabinet is unexplored:
		say "The cabinet looks heavy. You don't want to move it if you have no reason to.";
	otherwise:
		continue the action.	
Instead of opening the cabinet:
	if the cabinet is locked:
		say "It requires a five letter passcode to open.[line break][line break]To enter passcode, type use passcode (passcode) .";
	otherwise:
		continue the action.
Instead of opening the purple door:
	if the purple door is locked:
		say "You must remember who you are before you can proceed.";
	otherwise:
		continue the action.

Instead of opening the black door:
	if the black door is locked:
		say "Hah, I knew you weren't ready. You still don't have your voice yet."
Instead of entering the black door while the black door is open:
	if the chair is not carried by the player:
		say "You need something to fight with, grab the chair now!";
	otherwise:
		continue the action.	

Chapter 4-specific before rules

Before doing anything other than getting hint, cheating, looking, searching, examining, listing, or informing powerless:
	if powerlevel < 2, try informing powerless instead.

Before doing anything other than getting hint, cheating, going, going to by point, wandering, entering, looking, searching, examining, listing, or informing powerless:
	if powerlevel < 3, try informing powerless instead.

Before doing anything other than getting hint, cheating, touching, going, going to by point, wandering, entering, looking, searching, examining, listing, or informing powerless:
	if the powerlevel < 4, try informing powerless instead.

Before doing anything other than getting hint, cheating, using passcode, opening, closing, touching, going, going to by point, wandering, entering, looking, searching, examining, listing, or informing powerless:
	if the powerlevel < 5, try informing powerless instead.

Before doing anything other than getting hint, cheating, using passcode, listening, listening to by point, opening, closing, clocksetting, touching, going, going to by point, wandering, entering, looking, searching, examining, listing, or informing powerless:
	if the powerlevel < 6, try informing powerless instead.

Before doing anything other than getting hint, cheating, using passcode, moving with effort, pushing, listening, listening to by point, opening, closing, clocksetting, touching, going, going to by point, wandering, entering, looking, searching, examining, listing, or informing powerless:
	if the powerlevel < 7, try informing powerless instead.

Before doing anything other than getting hint, cheating,using passcode, remembering, moving with effort, pushing, listening, listening to by point, opening, closing, clocksetting, touching, going, going to by point, wandering, entering, looking, searching, examining, listing, or informing powerless:
	if the powerlevel < 8, try informing powerless instead.

Before doing anything other than getting hint, cheating, using passcode, answering, announcing, taking, remembering, moving with effort, pushing,  listening, listening to by point, opening, closing, clocksetting, touching, going, going to by point, wandering, entering, looking, searching, examining, listing, or informing powerless:
	if the powerlevel < 9, try informing powerless instead.

Before doing anything other than using passcode, announcing or remembering to a personname, say "That's not going to work." instead.

Chapter 5-specific after rules

After listening to by point the background:
	if the player is in the third room:
		if the clock is set:
			say "The clock is chiming with an unsettling power.";
		otherwise:
			say "The room is humming quietly.";
	otherwise if the player is in the second room:
		if the television is unseen:
			say "You hear voices. Freaky!";
		otherwise:
			say "The TV news is going on and on.";
	otherwise:
		say "The room is humming quietly.".

After touching [something], say "You touch [noun], hoping that it would be the key to your dilemma."

After opening a container:
	say "You open [noun] with great expectations.";
	try examining the noun.

After examining the eye:
	if powerlevel < 2:
		now the powerlevel is 2;
		add {"go to", "go s/n", "enter"} to the powerlist.

After going to by point the foot print:
	if the vase is intact:
		if the shelf is unexplored and desk is unexplored:
			now the foot print is explored;
			say "You feel a rumbling underneath.";
		otherwise:
			now the desk is unexplored;
			now the shelf is unexplored;
			say "You drag your tired legs to the foot print, but nothing happened."
After going to by point the desk:
	if the vase is intact:
		if the foot print is explored and desk is unexplored:
			now the desk is explored;
			say "You feel a rumbling underneath.";
		otherwise:
			now the shelf is unexplored;
			now the foot print is unexplored;
			say "You drag your tired legs to the desk, but nothing happened."
After going to by point the shelf:
	if the vase is intact:
		if the foot print is explored and the desk is explored:
			now the shelf is explored;
			say "You feel a rumbling underneath.[line break]The shelf comes off one hinge. The vase crashes to the ground, splashing you with water.[line break]You feel your hands tremble. Maybe now you can touch things.";
			if powerlevel < 3:
				add {"touch"} to the powerlist;
				now powerlevel is 3;
			now the vase is broken;
		otherwise:
			now the desk is unexplored;
			now the foot print is unexplored;
			say "You drag your tired legs to the shelf, but nothing happened."
After touching the blue door:
	say "The power of your touch opens the door!";
	now the blue door is open.

After touching the hidden alcove:
	say "The power of your touch makes a candle rise into the alcove.";
	now the candle is seen.
After touching the green lamp:
	if the green lamp is on:
		now the green lamp is off;
		say "The green lamp goes off.";
	otherwise:
		now the green lamp is on;
		say "The lamp cast lights and shadows on the room";
		if the blue lamp is on:
			now the blue lamp is off;
			say "[line break]The blue lamp goes off.";
		if the yellow lamp is on:
			now the yellow lamp is off;
			say "[line break]The yellow lamp goes off.";
		if the red lamp is on:
			now the red lamp is off;
			say "[line break]The red lamp goes off.".
After touching the blue lamp:
	if the blue lamp is on:
		now the blue lamp is off;
		say "The blue lamp goes dark.";
	otherwise:
		now the blue lamp is on;
		say "The lamp cast lights and shadows on the room";
		if the red lamp is on:
			now the red lamp is off;
			say "[line break]The red lamp goes dark.";
		if the yellow lamp is on:
			now the yellow lamp is off;
			say "[line break]The yellow lamp goes dark."
After touching the red lamp:
	if the red lamp is on:
		now the red lamp is off;
		say "The red lamp sputters off.";
	otherwise:
		now the red lamp is on;
		say "The lamp cast lights and shadows on the room";
		if the yellow lamp is on:
			now the yellow lamp is off;
			say "[line break]The yellow lamp sputters off."
After touching the yellow lamp:
	if the yellow lamp is on:
		now the yellow lamp is off;
		say "The yellow lamp goes off.";
	otherwise:
		now the yellow lamp is on;
		say "The lamp cast lights and shadows on the room";
		if the green lamp is on:
			if the red lamp is on and the blue lamp is on:
				say "[line break]All four lamps are on!";
				if the candle is unseen:
					say "[line break]Oddly, nothing grand came out of it, and the yellow lamp went off again. Maybe you missed something. Better check the room again.";
					now the yellow lamp is off;
				otherwise:
					say "[line break]The candle flares up, catching your eye.";
					now the candle is lit.

After touching the candle while the candle is lit:
	if powerlevel < 4:
		say "You hesitate at first, but you manage to overcome your trepidation. You touch the flame, and the searing pain tears through you.[line break]when the pain fades, you feel more strength in your hands. Maybe now you can interact with objects.";
		now the powerlevel is 4;
		add {"open","close"} to powerlist.

After examining the diary entry:
	if the journal date is 0618:
		if the grandfather clock is set:
			now the journal date is 0619;
		otherwise:
			now the journal date is 0602;
	otherwise if the journal date is 0602:
		now the journal date is 0618;
	otherwise if the journal date is 0619:
		if the calendar is remembered:
			now the journal date is 0609;
		otherwise:
			now the journal date is 0602;
			say "[line break][line break]The chilling account you just read restores strength to you. Now you can move objects.";
			if powerlevel < 6:
				now the powerlevel is 6;
				add {"move"} to powerlist;
	otherwise if the journal date is 0609:
		say "So that's my name, Paula[line break][line break]The knowledge of your identity empowers you, you have regained the final powers: to speak, and to take any useful object with you.";
		now myself is identified;
		if powerlevel < 8:
			now the powerlevel is 8;
			add {"speak", "take"} to powerlist;
	now the journal is explored.

After reading a command while the player is in the fourth room:
	if the player's command includes "use passcode":
		if the player's command includes "bert":
			now the safe is unlocked;
			say "Passcode accepted.";
		otherwise:
			say "Wrong passcode.";
		stop the action.
After reading a command while the player is in the second room:
	if the player's command includes "use passcode":
		if the player's command includes "sally":
			now the cabinet is unlocked;
			say "Pass code accepted";
		otherwise:
			say "Wrong passcode.";
		stop the action.
	
After touching the gun:
	if powerlevel < 5:
		say "Adrenaline rushes through you with the sense of imminent danger. You feel like your life is hanging by a thread--[line break][line break]bang bang bang[line break][line break]You flinch with the sound of shots fired. What is that?[line break]In you panic, you almost didn't notice that your ability to listen has returned.";
		now the powerlevel is 5;
		add {"listen", "listen to"} to powerlist.

After listening to by point the yellow door for the first time:
	say "click click click[line break][line break]You hear a series of clicks from the door. It seems to stop and start again. You realize there could be a pattern."
After listening to by point the yellow door for the second time:
	say "click click click[line break][line break]You are sure of the pattern now. When the clicking stops, you quickly try the door, unlocking it successfully.";
	now the yellow door is unlocked.

After listening to by point the grandfather clock:
	if the clock is set:
		say "You may be imagining it, but the chime of the clock sounds like words-hurry, hurry, hurry!";
	otherwise:
		say "The clock is silent as still water."
After touching the pendulum:
	say "As you touch the pendulum, you notice the clock hands start moving rapidly. They stop moving when you release the pendulum.[line break]You realize you can set the clock this way.[line break][line break]To set the clock, type set clock (hour)h(minute)m[line break]i.e. typing set clock 11h10m sets it to 11:10";
	now the pendulum is explored.
After reading a command while the player is in the third room:
	if the player's command includes "set":
		if the pendulum is explored:
			if the player's command includes "12h50":
				now the clock is set;
				say "You set the time to 12:50[line break]The clock chimes loudly, like rolling thunder.";
				now the date0619 is marked;
			otherwise:
				say "You set a random time, but nothing happened.";
		otherwise:
			say "You haven't found the mechanism to set it";
		stop the action.
After moving with effort the orange door:
	if the orange door is closed:
		say "With your new found strength, you push the door open!";
		now the orange door is unlocked;
		now the orange door is open;
		now the orange door is unmovable.

After listening to by point the cabinet:
	say "You definitely hear voices from behind the cabinet. They unsettle you with their urgency.";
	now the cabinet is explored.
After moving with effort the cabinet:
	now the television is seen;
	now the cabinet is not movable;
	say "You use all your strength to push the cabinet aside. It was so heavy![line break][line break]You discover a television behind the cabinet."
After examining the television:
	say "So that's what happened [line break][line break] Regret and sadness grip you, though you aren't sure where they came from. The strong emotions overcome you like a tide, and they restore an important power to you: the power to remember.";
	if the powerlevel < 7:
		now the powerlevel is 7;
		add {"remember (rem)"} to powerlist.
After remembering the ski hat:
	say "That's right, this is the hat Sally wore when we went skiing together. We had such fun on that day. Yes, I remember I took a photo of us, and I've seen it around here.";
	now the photograph is remembered.

After remembering the photograph:
	say "You've remembered what you look like! Go open the door with this knowledge!";
	now Myself is remembered.

After remembering Myself:
	if Myself is unremembered:
		say "Sadly, you don't remember yet";
	otherwise:
		say "You remember now. You are Sally's friend, and you were in the house when Bert came to kill her.";
		if Myself is identified:
			say "[line break][line break]Your name is Paula!";
		if the player is in the second room:
			now the purple door is unlocked;
			say "By the power of your memories, you have unlocked the door!".
After remembering Sally:
	say "You remember now. Sally is a caring friend. You remember her bright smiles. Bert is the only shadow in her life, and he came to kill her!".
After remembering Bert:
	say "You still tremble with fear when you remember Bert with the gun."

After touching the chair:
	say "Like electric shock, the chair communicates a message to you--[line break][line break]Go back to the calendar and remember.";
	now the calendar is memorable;
	now the calendar is unremembered.

After remembering the calendar:
	say "Yes, you remember another significant date. Maybe you wrote it down in the journal.";
	now calendar is remembered;
	now the date0609 is marked.

After announcing Myself:
	say "You speak your name, loud and clear:[line break][line break]I am Paula![line break][line break]The power of your conviction opens the black door. Grab the chair and get out of here!";
	now the black door is unlocked;
	now the black door is open;
	now the chair is movable.

Chapter 7-understand object rules

Background is a backdrop. Understand "room", "seventh room", "sixth room", "fifth room", "fourth room", "second room", "first room" as background. Background is everywhere. 

Understand "exit", "sign", "gate" as door.
Understand "empty walls", "empty wall", "walls" as wall.

Understand "image", "photo", and "woman" as the photograph.
Understand "eyes" as the eye.

Understand "red paint", "paint", "June" as foot print. 
Understand "19th" as desk.
Understand "water" as vase. Understand "hinge" as shelf.
Instead of going to by point the note, try going to by point the desk.
Instead of going to by point the panels, try going to by point the desk.
Instead of going to by point the vase, try going to by point the shelf.

Understand "colored lamps", "colored lamp", "colors", "color" as colored lamps.
Instead of doing anything to the colored lamps, say "specify a color".
Understand "shadows" as shadow.
Understand "lights" as light.
Understand "flares", "flare", "candle flares", "candle flare", "flames", "fire", "fires", "candles" as candle.
Understand "page", "entries" as diary entry.

Understand "hands", "clock hands", "hand", "clock hand" as the grandfather clock.
Understand "hole", "bullet hole", "bullet holes" as holes.

Chapter 8-standard verbs

Understand "look around" as looking.
Understand "ex [something]" as examining.
Understand "touch", "feel" as touching.
Understand "unlock", "unlock [something]" as opening. Understand "lock", "lock [something]" as closing.
Understand "grab [something]" as taking.

Chapter 9-new verbs

Listing is an action applying to nothing. Understand "list", "list action", "powers", "list actions", and "list powers" as listing.
After listing:
	say "the following actions can be performed:[line break][powerlist].".

Informing powerless is an action applying to nothing.
After informing powerless:
	if powerlevel < 2:
		say "You are a shadow. You can't do that.";
	otherwise if powerlevel < 3:
		say "You are still ephemeral. You can't do that.";
	otherwise if powerlevel < 4:
		say "You are still not real enough. You can't do that.";
	otherwise if powerlevel < 8:
		say "You still don't have the power to do that.";
	say "To see what you can do, type powers."

Wandering is an action applying to nothing. Understand "escape", "wander", "walk around" as wandering.
After wandering:
	say "You can wander around, but better go somewhere or look at something.";

Going to by point is an action applying to one thing.
Understand "go to [something]", "go over to [something]", "walk over to [something]" as going to by point.
After going to by point [something]:
	say "You drag your tired legs to [noun]."

Listening to by point is an action applying to one thing. Understand "listen [something]" , "listen to [something]" as listening to by point. 
After listening to by point [something]:
	say "you listen to [noun], hoping for a clue."
Instead of listening to a thing, try listening to by point the noun.

Clocksetting is an action applying to one thing. Understand "set clock to" or "set time to" as clocksetting.

Using passcode is an action applying to one thing. Understand "use passcode [something]" as using passcode.

Moving with effort is an action applying to one thing. Understand "move [something]", "push [something]" as moving with effort.
Instead of pushing a thing, try moving with effort the noun.

Remembering is an action applying to one thing. Understand "remember [something]", "rem [something]" as remembering.

Announcing is an action applying to one thing. Understand "say [something]", "speak [something]" as announcing.
After announcing a thing:
	if the noun is not a personname:
		say "You got to speak a name."


Cheating is an action applying to nothing. Understand "cheat" as cheating.
After cheating:
	now the powerlevel is 8;
	now myself is remembered;
	now myself is identified;
	move the player to the first room.

Getting hint is an action applying to nothing. Understand "hints", "hint", "get hint", "get hints", "walkthrough", "w" as getting hint. 
After getting hint:
	if the player is in the seventh room:
		say "To escape the seventh room: look at wall->look at words->look at photo->look at eye->go south.";
	otherwise if the player is in the sixth room:
		say "To escape the sixth room: look at desk->look at shelf->look at vase->look at foot print->go to foot print->go to desk->go to shelf->touch blue door->go south.";
	otherwise if the player is in the fifth room:
		say "To escape the fifth room: look at journal->touch green lamp->touch blue lamp->touch red lamp->look at shadows->look at hidden alcove->touch hidden alcove->touch yellow lamp->touch candle->open journal->read diary->read diary->go south.";
	otherwise if the player is in the fourth room:
		say "To escape the fourth room: look at calendar->open safe->use passcode bert->open safe->touch gun->listen->listen to yellow door->listen to yellow door->go south.";
	otherwise if the player is in the third room:
		say "To escape the third room:look at bullet holes->look at clock->touch pendulum->set time 12h50m->(go back to read the journal)go north->go north->open journal->read diary(repeat read diary until you have read the June 19th entry)->(go back to the third room)go south->go south->move orange door->go south.";
	otherwise if the player is in the second room:
		say "To escape the second room:look at mirror->listen->listen to cabinet->move cabinet->watch television->remember Sally->remember bert->open cabinet->use passcode Sally->open cabinet->remember ski hat->(go back to the seventh room)go north->go north->go north->go north->go north->look at photo->remember photo->(go back to second room)->go south->go south->go south->go south->go south->look at mirror->remember me->go south.";
	otherwise if the player is in the first room:
		say "To escape through the white door: enter white door->this will get you to ending 1.[line break][line break]To escape through the balck door: touch chair->(go back to the calendar)go north->go north->go north->remember calendar->look at calendar->(go back to the journal)go south->open journal->read diary(repeat read diary until you have read the June 9th entry)->(go back to the first room)go south->go south->go south->go south->say Paula->take chair->enter black door->this will get you to ending 2."

Chapter 10-rooms and doors

The seventh room is a room. "You are in  the 7th room.[line break]How do you know it's the 7th room? You just do.[line break][line break]The sign on the green door says: I took over for you own good.[line break][line break]You see empty walls, except for a photograph on the wall."

The green door is south of the seventh and north of the sixth room. It is an unlocked and open door. "The green door beckons you. It is open."

The sixth room is a room. "You are in the 6th room.[line break]You are getting closer.[line break][line break]The sign on the blue door reads: You are only safe in here.[line break][line break]You spot a desk and a shelf. And what's that foot print on the floor?" 

The blue door is south of the sixth room and north of the fifth room. It is an unlocked and closed door. "The blue door beckons you. It is [if the blue door is open]open[otherwise]closed[end if]."

The fifth room is a room. "You are in the 5th room.[line break]You are making progress.[line break][line break]The sign on the red door says: Don't go any further.[line break][line break]A blue lamp, a green lamp, a yellow lamp, and a red lamp blink at you. You didn't miss the journal on the floor either."

The red door is south of the fifth room and north of the fourth room. It is an unlocked and closed door."The red door beckons you. It is [if the red door is open]open[otherwise]closed[end if]."

The fourth room is a room. "You are in the 4th room.[line break]You are halfway there.[line break][line break]The sign on the yellow door reads: Don't go any further!!![line break][line break]You catch glimpses of a calendar and a safe box."

The yellow door is south of the fourth room and north of the third room. It is a locked and closed door. "The yellow door beckons you. It is [if the yellow door is open]open[otherwise]closed[end if]."

The third room is a room. "You are in the 3rd room.[line break][line break]You have come a long way.[line break][line break]The sign on the orange door says: Fool! I'm protecting you![line break][line break]What's here? A lonely grandfather clock. And what's with the bullet holes on the wall?".

The orange door is south of the third room and north of the second room. It is a locked and closed door. "The orange door beckons you. It is [if the orange door is open]open[otherwise]closed[end if]." The orange door is movable.

The second room is a room. "You are in the 2nd room.[line break]You are almost there.[line break][line break]The sign on the purple door reads: I'm warning you, stay back or you will die![line break][line break]You find a mirror and a cabinet."

The purple door is south of the second room and north of the first room. It is a locked and closed door. "The purple door beckons you. It is [if the purple door is open]open[otherwise]closed[end if]."

The first room is a room. "You are in the 1st room.[line break]This is it, you have to make the choice now.[line break][line break]A big shiny white door welcomes you. The sign on the door proclaims: This way! Take the easy way out![line break][line break]You briefly glances at a chair. But who cares about that? The exit is wide open in front of you! Oh yeah, there is also a small black door here".

The white door is south of the first room and north of the bad ending room. It is an open door. "The white door is wide open and you should go in there right now."

The black door is east of the first room and west of the good ending room. It is a closed and locked door. "The black door is tiny and gloomy. Listen to me, you shouldn't go there. It is [if the black door is open]open[otherwise]closed[end if]."

The bad ending is a room. 
The good ending is a room. 

Chapter 11-objects

A green wall is a scenery in the seventh room. "When you squint, you can make out words on the wall".
A green floor is a scenery in the seventh room.

A photograph is a thing on the green wall. The photograph is memorable and unremembered. "[if the photograph is unremembered]There is a woman in the photograph. She looks vaguely familiar, but you don't remember anything about her. For some reason, her eyes make you feel small.[otherwise]That's right, that's Sally in the photograph. And next to her is me. We were smiling so happily when we took this photograph at the ski resort.[end if]" 

The eye is part of the photograph. It is a thing. "[if we have examined the photograph]You look into the woman's eyes. They pierce into you, making you feel keenly aware of your immaterial self. You take a step back, and discover that you have regained the ability to walk.[otherwise]You look around, but fortunely there are no eyes spying at you.[end if]". 

The words is a thing on the green wall. "It says 'The eye is the window to the soul.'".

A blue wall is a scenery in the sixth room.
A blue floor is a scenery in the sixth room. "A foot print is on the floor."

A foot print is a thing on the blue floor. "Could be red paint, but you aren't so sure. The word 'June' is written on it." It is unexplored.

The desk is a supporter in the sixth room. "An old desk with loose panels. There is a note on the desk[line break][line break]When you look closer, you notice the phrase '19th' is scratched on the desk." It is unexplored.

The panels is part of the desk. "The panels are baredly held together."
The note is a thing on the desk. The description is "Reconstruct that day and that time by connecting the dots. Walk to the objects with a time stamp on them.'".

The shelf is a supporter in the sixth room. "[if the vase is intact]There is a vase on the shelf.[otherwise]The shelf hangs by one hinge, and the vase has fallen off." It is unexplored.

The vase is a thing on the shelf. The vase can be broken or intact. It is intact. "[if the vase is intact]The vase has water in it. The phrase '12:50' is barely visible on the vase.[otherwise]The vase lies broken on the floor, but the phrase 12:50 has remained intact.[end if]" 

The red floor is a scenery in the fifth room.
The red wall is a scenery in the fifth room. 

The journal is an openable container on the red floor. The journal is a thing. The journal is closed and unexplored. "[if the journal is closed]The cover says 'The pain will jolt you to action.'[otherwise]There is a diary entry on the page. Strangely, the diary changes as you read it.[end if]". 

The diary entry is a thing in the journal. "[if journal date is 0602]June 2nd,[line break]I went skiing with (omitted). I always won our downhill race, but today she won instead.[line break] (omitted) told me that her divorce to Bert has been finalized. She looks so relieved. 'It's twelve long years', she says. I've been single all my life and can't imagine living any other way, so I guess I can relate.[otherwise if journal date is 0618]June 18th,[line break]I went to (omitted)'s house to help her move. She's still worried about Bert because he still has the house key. As I was helping her move the couch, she keeps looking out the window. [line break]I asked her, 'Do you really think he's going to barge in here?'. And she replied, 'After what happened last time. I better be careful.'[line break]We moved the major stuff to the apartment today. There is still some things left in the house, so we have to make another trip tomorrow. Bert doesn't know where her new apartment is, so at least that's a good thing.[end if][if the journal date is 0619]June 19th,[line break][line break]I went to help Sally move again. We were packing the last of her stuff when I heard the front door slam. And then I heard Sally scream. I was in the bedroom closet packing some clothes. I looked out and saw Sally struggling with Bert. He has a gun! My heart jumps to my throat and the only thing I could think of is 'I'm going to die--'[end if][if journal date is 0609]I went to the farmer's market with Sally. She bought me a potted tomato plant, as a thank-you gift for promising to help her move.[line break]Then a scary thing happened: we ran into Bert! He saw us and came toward us. He was cursing at Sally and threatening her. We tried to get away, but he followed us around. Suddenly, he tried to put his hand around Sally's neck. I freaked and just rammed into him without thinking, and he was trying to hit me as well.[line break][line break]We finally got rid of Bert after someone called the police. Afterward Sally said to me, 'Paula, I think Bert's going to try to kill me one of these days.' I don't know, but the dangerous look Bert gave me really scared me.[end if]".

The colored lamps is a thing in the fifth room. "Specify a color".
The green lamp is a thing in the fifth room. "A green lamp. It doesn't have a switch, maybe it responds to touch.[line break]Lamp is [if green lamp is on]on.[otherwise]off.[end if]". It is off.
The blue lamp is a thing in the fifth room. "A blue lamp. It doesn't have a switch. Maybe it responds to touch.[line break]Lamp is [if blue lamp is on]on.[otherwise]off.[end if]". It is off.
The red lamp is a thing in the fifth room. "A red lamp. It doesn't have a switch. Maybe it responds to touch.[line break]Lamp is [if red lamp is on]on.[otherwise]off.[end if]". It is off.
The yellow lamp is a thing in the fifth room. "A yellow lamp. It doesn't have a switch. Maybe it responds to touch.[line break]Lamp is [if yellow lamp is on]on.[otherwise]off.[end if]". It is off.

The light is a thing in the fifth room. 
The shadow is a thing in the fifth room. "You discover a hidden alcove in the shadows."

A hidden alcove is an open container in the fifth room. The hidden alcove is a thing. "[if the candle is unseen] An alcove carved into the wall.[otherwise]There is a candle inside.[end if]"

The candle is a supporter in the hidden alcove. The candle is a thing. The candle can be lit or unlit. It is unlit. The candle is unseen. "[if the candle is unlit]An unlit candle.[otherwise]The candle burns brightly. The flame beckons you.[end if]"

The yellow wall is a scenery in the fourth room.
The yellow floor is a scenery in the fourth room.

The calendar is a thing on the yellow wall. "It says on the top, Did you read the journal yet?[line break]It shows the month of June.[line break][if journal is unexplored]None of the dates are marked.[end if][if date0602 is marked][line break]the June 2nd date is marked.[end if][if date0618 is marked][line break]the June 18th date is marked.[end if][if date0619 is marked][line break]The June 19th date is marked.[end if][if date0609 is marked][line break]the June 9th date is marked[end if]." The calendar is memorable and unremembered.

The date0602 is a thing on the calendar. The date0602 can be marked or unmarked. The date0602 is marked.
The date0618 is a thing on the calendar. The date0618 can be marked or unmarked. The date0618 is marked.
The date0619 is a thing on the calendar. The date0619 can be marked or unmarked. The date0619 is unmarked.
The date0609 is a thing on the calendar. The date0609 can be marked or unmarked. The date0609 is unmarked.

The safe box is an openable container in the fourth room. The safe box is closed and locked. "[if the safe box is closed]A safe box. You have a feeling nothing good awaits you inside.[otherwise][line break]You peek inside--Why is there a gun here?[end if]".

The gun is a thing in the safe box. It is a scenery. The description is "A dangerous toy."

The orange wall is a scenery in the third room.
The orange floor is a scenery in the third room.

The grandfather clock is a thing in the third room. The grandfather clock can be set or unset. The grandfather clock is unset. "[if the clock is unset]A grandfather clock. The clock hands have stopped moving, and the pendulum hangs still [otherwise]The clock is ticking away[end if]."
The pendulum is part of the clock. The pendulum is an unexplored thing. The description is "[if the clock is unset]The pendulum hangs still[otherwise]The pendulum swings widely[end if]."

The holes is an unopenable, open container on the orange wall. "Three bullet holes stare at you, sending a chill down your spine. There is a note sticking out from the hole."
The orange note is a thing in the holes. "It says, 'Certain information is buried deep because you don't want to remember it. But if you really want to, check the journal again after you set the time.'".

The purple wall is a scenery in the second room.
The purple floor is a scenery in the second room.

The cabinet is an openable, lockable container in the second room. The cabinet is closed, locked, unexplored, and movable. "A sturdy cabinet. [if the cabinet is closed]It is closed[otherwise]Inside the cabinet is a ski hat[end if]".

The ski hat is a thing in the cabinet. The ski hat is memorable and unremembered.

The television is a thing in the second room. It is unseen. "The news is on. The same item is repeating again and again--[line break]Yesterday afternoon at around 1pm, a local woman was shot and killed in her residence. The woman, Sally McKinney, was recently divorced from her ex-husband, Bert, whom the police apprehended at the scene."
Instead of listening to by point the television, try examining the television.

The mirror is a thing in the second room. "[if Myself is unremembered]You don't see your reflection, as if you still don't exist![otherwise]You see your reflection. You look almost ready."

The white wall is a scenery in the first room.
The white floor is a scenery in the first room.

The chair is an undescribed thing in the first room. The chair is not a scenery, not fixed in place, and movable. "[if we have examined the chair]A sturdy looking chair.[end if]"


Chapter 12-persons

Personname  is a kind of backdrop. A personname can be identified or unidentified.
Myself is a memorable personname. Understand "Paula", "me", "myself", "my name" as myself. Myself is unidentified and unremembered. Myself is everywhere.
Sally is a memorable personname. Understand "Sally", "McKinney", "Sally McKinney" as Sally. Sally is everywhere.
Bert is a memorable personname. Understand "Bert" as Bert.  Bert is everywhere.


Chapter 13-beginning and endings

When play begins:
	say "Someone has taken over your life , leaving you a shadow. They also left you locked in a room. If you can find your way out, maybe you can learn what happened. You actions may be limited, being a shadow and all.";
	say "[line break]Common commands include look (l), examine (ex), and go north/south (go n/s).[line break]To see your available actions at any time, type powers.[line break]To see the walkthrough in any room, type walkthrough or w.[line break][line break]";
	add {"look (l)", "examine (ex)"} to the powerlist.

Before entering an open door:
	if powerlevel > 1:
		if the noun is the white door:
			say "You decide to take the advice and enter the white door. Light envelopes you.";
		otherwise if the noun is the black door:
			say "Ignoring the advice from your scared self, you run out wielding the chair."

Bad ending scene is a scene. Bad ending scene begins when the player is in the bad ending. Bad ending scene ends when the player is in the first room.
When bad ending scene begins:
	say "You find yourself walking out of the closet. You have been hiding in there all this time, shaking in fear while Bert killed Sally. You only came out after the police discovered you. [line break][line break]Well, this is it. You are safe now because your fear protected you well. Your friend is dead, but at least you are unhurt.";
	end the game in victory.

Good ending scene is a scene. Good ending scene begins when the player is in the good ending. Good ending scene ends when the player is in the first room.
When good ending scene begins:
	say "You emerge from the closet, where you had been hiding all this time. Bert and Sally are still struggling in the bed room. You run to them, shouting 'leave her alone!'[line break][line break]Bert turns his gun toward you, but you smash him on the head with the chair. The gun goes off, and the two of you both collapse.[line break][line break]You thought you had died, but you wake up after a few days. You are in the hospital room, and Sally is by your bedside.[line break][line break]You learned that Bert was arrested and will be tried for attempted murder. But it's okay now, Sally tells you, all thanks to you. Your bravery has saved both of you.";
	end the game in victory.
Log in

Room serial

Source Code
