The Jewel of Alithia by Celia

The Jewel of Alithia

Played 2,764 times
View game source (spoilers!)
Download the .z8 file
Source Code

"The Jewel of Alithia" by Celia Abernathy

Part 1 - Set Up

Section 1 - Modes

Mode is a kind of value. The modes are normal, ghost, and flying. A person has a mode. A person is usually normal.

Normaling is an action applying to nothing.
Understand the command "normal" as something new. Understand "normal" and "become normal" as normaling.
Check normaling:
	if the player is normal:
		say "You're as normal as you're going to get." instead.
Carry out normaling:
	now the player is normal;
	now every party member who is in the party is normal.
Report normaling: say "You go back to your normal form."

Ghosting is an action applying to nothing.
Understand "invisible" and "become invisible" as ghosting.
Check ghosting:
	if Daniel is not in the party:
		say "You don't know how to make yourself invisible." instead;
	if the player is ghost:
		say "'We're already invisible,' says Daniel." instead;
Carry out ghosting:
	now the player is ghost;
	now every party member who is in the party is ghost.
Report ghosting: say "You feel cold all over as you become invisible."
Instead of examining a person who is ghost:
	say "You try to look at [noun], but you can't see anything."
Instead of taking inventory when the player is ghost:
	say "You can't see your satchel right now."
Before examining something when the player is ghost:
	if the noun is carried by the player:
		say "It turned invisible with you." instead.

Section 2 - Talking

Understand the commands "ask" and "tell" and "say" and "answer" as something new.
Understand "ask [text]" or "tell [text]" or "answer [text]" or "say [text]" as a mistake ("[talk to instead]").
Instead of answering someone that something: say "[talk to instead][paragraph break]".
To say talk to instead: say "(To communicate in [story title], TALK TO a character. To ask someone to do something, use their name: BOB, SING.) ".
Understand "talk to [someone]" as talking to. Understand "talk to [something]" as talking to. Talking to is an action applying to one visible thing.

Report talking to something that is not a person:
	say "There's no response, unsurprisingly."
	
Section 3 - Persuasion

A persuasion rule for asking people to try doing something: persuasion succeeds.

Instead of asking someone for something: try asking the noun to try giving the second noun to the player.

The block giving rule is not listed in the check giving it to rules.

Section 4 - The Party

A party member is a kind of person. A party member can be either in the party or out of the party. A party member is usually out of the party.

Carry out going:
	repeat with mover running through party members who are in the party:
		move mover to the location of the player.

To say list party members:
	if Daniel is in the party:
		say "Daniel is floating near you.";
	else if Lina is in the party:
		say "Daniel, Lina and Scrap are here with you."


Section 5 - Party Talk

An every turn rule:
	if a random chance of 5 in 100 succeeds:
		if Lina is in the party:
			choose a random row from the Table of DL talk;
			say "[talk entry][pb]".
		
Table of DL talk
talk
"Suddenly, Scrap springs out of Lina's arms to pounce on a mote of dust. Unfortunately, Daniel is in his way. The cat passes through Daniel and lands hissing, with his fur sticking straight up.[pb]Daniel shudders and frowns at Lina. 'Please keep your pet under control,' he says.[pb]'Scrap's not my pet, he's my familiar!' says Lina petulantly, turning away from Daniel to comfort the wide-eyed cat."
"Lina turns to Daniel. 'You know, I've met a ghost before.'[pb]'Really?' asks Daniel, insubstantial eyebrows raised.[pb]'Yeah,' replies Lina. 'Granny had him over for dinner once. But he didn't even eat anything! He was SO old and boring!'[pb]Daniel looks displeased until Lina assures him, 'But you're nothing like him!'"
"Lina looks at you. 'So why are you looking for the jewel of Alish- Ilith -'[pb]'Alithia.' Daniel cuts in, eyes shining silver. Lina nods. 'Yeah, that.'[pb]'Just trying to make a living as a treasure hunter,' you tell her. [pb]And that is the reason. It has nothing to do with your curiosity about this place..."
"Daniel quietly clears his throat. When you and Lina both look at him, he says, 'I'm sorry, but I have a question, Lina. Do you know any magic that has to do with... death?'[pb]Lina shakes her head, eyes wide. 'No! That's necromancy! You'd need incredibly power to even try to learn necromancy.'[pb]Daniel nods, looking thoughtful.'"
		

Section 6 - Animals

Friend is an animal that varies.

The frighten rule is listed after the report stage rule in the specific action-processing rules.
This is the frighten rule: follow the animal scare rules.
The animal scare rules is a rulebook.

An animal scare rule for doing anything other than going, looking, examining, ghosting, taking inventory, or waiting in the presence of a friend:
	if the player is not ghost:
		if the friend is the goose:
			say "The goose hisses at you.";
		else:
			now the friend is off-stage;
			say "You scare off [the friend]."

Carry out going:
	if there is a buddy corresponding to a place of the location of the player in the Table of Animal Friends:
		choose the row with place of the location of the player in the Table of Animal Friends;
		now friend is the buddy entry;
		now friend is in location.

Table of Animal Friends
place	buddy		talk
Entrance to the Courtyard	bunny		"'Don't go near the lake! My friend slipped in once and he never came out.'"
Hedge Path	goose		"'[if the small brass key is in the hedges]Cat, do you see that shiny thing in the hedge? I wish there weren't so many thorns, so I could get closer to it.'[else]I'm warning you - stay away from my nest!'"
Around the Gazebo	squirrel		"'Hey, do you ever wish you could be something else? Something like... a phoenix?'"
Study	moth		"'Staelgiest ne waes wihte thy gleawra the he tham wordum swealg.'[pb]You give Lina a confused look, but she just shrugs."
Dining Hall	crow		"'Do you have anything shiny? I love shiny things! If I find anything really great I'm going to take it back to my nest in the gazebo.'"

Section 10 - Miscellaneous

Use American dialect, the serial comma, and no scoring. To say pb: say "[paragraph break]".

Doors are usually scenery. A staircase is a kind of door. A staircase is usually open.
Instead of climbing a staircase: 
    try entering the noun.

Definition: a direction (called thataway) is viable if the room thataway from the location is a room.
Instead of going nowhere: 
    let count of exits be the number of viable directions; 
    if the count of exits is 0, say "You appear to be trapped in here." instead; 
    if the count of exits is 1, say "From here, the only way out is [list of viable directions]."; 
    otherwise say "From here, the viable exits are [list of viable directions]."

Definition: a thing is interesting if it is not dull.
Definition: a person is dull:
	no.
Definition: a thing is dull:
	if it is handled, no;
	yes.	
For printing a locale paragraph about a dull thing (called item):
    now the item is mentioned.

When play begins:
	 say "UNFINISHED[pb]Sometimes it's hard being a treasure hunter. Sure, it sounds glamorous, but when you get down to it, it's a lot of work with little pay-off.[paragraph break]Not this time, though. This time you're after the Jewel of Alithia, an artifact rumored to have magical powers. You've tracked it to this weird old castle, and now it's time to do your job.[paragraph break]You don't know it yet, but it will take far more than just ordinary skill to find this particular jewel...";
	now the right hand status line is "[if player is ghost]Invisible[else]Normal".

Part 2 - Characters

Chapter 1 - Player

The description of the player is "You glance down at yourself. You're pretty average as far as treasure-hunters go: fit, not too tall, dressed in dark, utilitarian clothing. You carry a satchel[if the player is carrying nothing].[else] with various things, including [a list of things carried by the player].[end if][if Daniel is in the party][pb][list party members]".

The player carries a map. The description of the map is "It's the map that led you here. Now that you're here, you don't really need it anymore."

The satchel is a backdrop. The satchel is everywhere. "It's a sturdy satchel. At the moment it[if the player is carrying nothing]'s empty.[else] holds [a list of things carried by the player]."

After taking inventory: say "[list party members]".

Chapter 2 - Daniel

Section 1 - Description

Daniel is a male party member. Daniel is scenery. Daniel is not proper-named. Daniel has carrying capacity 1. Understand "ghost", "man", "Daniel Veret", or "Veret" as Daniel.

Instead of examining Daniel when Daniel is out of the party:
	if Daniel is not proper-named:
		say "The figure by the bookcase is transparent and insubstantial. It's the ghost of a tall, dark-haired man in old-fashioned clothes. His gray face is thin and serious.";
	else:
		say "Daniel is tall. He's colorless and insubstantial, but you can tell he once had dark hair and he seems to be wearing old-fashioned clothes. His gray face is thin and serious. He's watching you closely."

The description of Daniel is "Daniel is tall. He's colorless and insubstantial, but you can tell he once had dark hair and he seems to be wearing old-fashioned clothes. His gray face is thin and serious. As you look at him, he catches your eye and gives you a small smile.[if Daniel is carrying something][pb]He's doing his best to hold [a list of things carried by Daniel]."

To say Daniel is present:
	if Daniel is not proper-named:
		say "There's a ghost floating by the table.";
	else:
		say "Daniel is floating here."

Daniel is in the Library.

Instead of going from the Library when Daniel is out of the party:
	if Daniel is not proper-named:
		say "As you start to open the door, the ghost seems to notice you for the first time. 'Oh!' he says. You turn around.";
	else:
		say "As you start to open the door, Daniel calls out to you. 'Wait a moment. I haven't had someone to talk to for a while.' You turn around.";
	try talking to Daniel.

Section 2 - Talking

Drownum is a number that varies. Drownum is 1.

Instead of talking to Daniel when Daniel is out of the party:
	if Daniel is not proper-named:
		say "'Hello?' you say awkwardly.[paragraph break]The ghost gives you a sad smile. 'Hello,' he says. 'It's nice to see a new face around here. I'm Daniel Veret.'[paragraph break]You introduce yourself and make a move to shake his hand, then stop awkwardly - can ghosts shake hands? - and put your hand back in your pocket. He pretends he didn't notice.[paragraph break]'So what are you doing here?' he asks.[paragraph break]You shrug. 'I'm looking for something. It's a long story.'[paragraph break]Daniel smiles. 'Well, you're talking to the king of long stories. I'm also looking for ...something.'";
		now Daniel is proper-named;
	else:	
		choose row Drownum from the Table of Daniel OoP talk;
		say "[talk entry][pb]";
		increase Drownum by 1;
		if Drownum is 4:
			now Drownum is 0;
			now Daniel is in the party;
			silently try ghosting.

Table of Daniel OoP talk
talk
"'What are you looking for?' you ask with a tinge of suspicion. Ghost or not, you don't want Daniel to get in your way.[pb]Daniel gives you a long, sad look. 'I'm looking for a person. A girl. Her name is Alithia.'[pb]You stare at him. 'Alithia? I thought she was dead! Or - I mean -' You remember you're already talking to a dead person and stop, but once again Daniel looks unruffled.[pb]'Alithia is - was - someone... very important to me,' he tells you calmly. 'I wish to be reunited with her, and I think the key is somewhere in this castle.[pb]'Judging by your reaction, it seems you've heard of her.' You notice a gleam in his semi-transparent eyes as he looks at you. 'Tell me what you know, and I'll help you with whatever you're searching for.'"
"You explain everything to Daniel: about why you're searching for the jewel of Alithia and that you know it's somewhere in this castle. He nods. 'She wore a purple diadem that they say had been passed down through her family for generations. They say it had magical powers.' He shakes his head, a tender look on his face. 'She never thought it had magic. But then, she was always a skeptic. Think if she could see me now.' He chuckles as he looks down at his insubstantial body. 'I've been dead for years, and I'm still chasing after her.'[pb]'Anyway,' he says, looking back at you, 'I don't see why we shouldn't join forces. I may seem like little help, but you'd be surprised at the tricks I've figured out over the years.'"
"'What do you mean, tricks?' you ask.[pb]Daniel smiles. 'For one, I'm mostly insubstantial and can walk through walls and locked doors. But I can still touch things - somewhat.' He demonstrates by ruffling the pages of the book that lies open on the table.[pb]'Also, I can do this -' He reaches over and slips his hand into yours. His hand feels strange and cold. Then the claminess starts to spread up your arm and throughout your body. Shivering, you look at Daniel accusingly - but you can't see him.[pb]'We're invisible,' he tells you. You hold up your other hand and, with a shock, realize he's right. Your body is completely invisible.[pb](From now on, just type BECOME INVISIBLE or INVISIBLE to take advantage of Daniel's power. NORMAL will turn you back.)"

Report talking to Daniel:
	if player is normal:
		choose a random row from the Table of Daniel normal talk;
		say "[talk entry][pb]";
	if player is ghost:
		choose a random row from the Table of Daniel ghost talk;
		say "[talk entry][pb]";

Table of Daniel normal talk
talk
"'So, Daniel, what's your story?' you ask. 'Where are you from? How'd you end up here?'[pb]Daniel shakes his head with a little smile. 'That's too long a story for right now.'"
"'By the way, Daniel, do you know where the Jewel of Alithia might be?' you ask.[pb]Daniel sighs. 'No. I might have known when I was alive, but since then, my memories of this place have faded. I can only remember one thing, or should I say person, now...'"
"'Daniel, what are you thinking about?' you ask.[pb]'Just remembering something...' he says, and you can't get him to elaborate further."
"Looking at Daniel, you ask, 'So what's it like being a ghost?'[pb]His already serious expression grows grimmer. 'It's hard to describe,' he says, and you decide to drop it."
"You clear your throat. 'So, Daniel, about Alithia...'[pb]A complex, pained look passes over his face. 'Let's just find her - or the jewel - or something, okay?'"
"'You know, I've never met a ghost before,' you tell Daniel.[pb]'Well, most people haven't,' he says, sounding a little bored."
"'Daniel, do you have any... hobbies?' you ask.[pb]He smiles. 'Well, I used to read a lot. I still like to read, although it takes more work to turn the pages.'"
"You clear your throat to talk to Daniel, but he looks deep in thought, and you decide not to disturb him."
"You turn towards Daniel, but he has a contemplative expression. You don't want to interrupt his train of thought."

Table of Daniel ghost talk
talk
"You turn to where you think Daniel is. 'It's weird not being able to see you at all,' you say.[pb]'Actually, it's a little weird for me, seeing other people become invisible,' he answers from a totally different direction."
"'Daniel, do you ever spy on people?' you ask, grinning.[pb]Daniel's voice replies drily, 'When you've been a ghost as long as I have, that sort of thing loses its appeal.'"

Section 3 - Persuasion

Unsuccessful attempt by Daniel doing something:
	say "'I don't think I can do that,' says Daniel."

Instead of giving something to Daniel when Daniel is carrying something:
	say "Daniel shakes his head, holding up [the list of things carried by Daniel]. 'I can barely manage to hold this,' he says."

Instead of asking Daniel to try going nowhere:
	say "Daniel walks through the wall, but quickly returns. 'There's nothing there,' he says."

A person has a room called the destination.
After Daniel going:
	now the destination of Daniel is the location of Daniel;
	if the location of the player is in the Courtyard and the destination of Daniel is in the Courtyard:
		say "'I don't see any reason that we can't go together,' Daniel says.";
	else:
		say "Daniel passes eerily right through the door.[paragraph break]Eventually he returns. 'It looks like [the destination of Daniel]', he says. 'I didn't see anything too interesting.'";
	now Daniel is in the location of the player.
			
A procedural rule: if the actor is Daniel, ignore the can't go through closed doors rule.

Chapter 3 - Lina (and Scrap)

Section 1 - Description

Lina is a female party member. Lina is scenery. Lina is not proper-named. Understand "girl" and "witch" as Lina.

Instead of examining Lina when Lina is out of the party:
	say "She's curled on the bed, crying wholeheartedly. She has short black hair and wears a blue dress and a pointed blue hat. When she looks up at you, you see she has a round, cute face with big blue eyes."

The description of Lina is "Lina has a round, cute face with big blue eyes. Her black hair is cropped short, and she wears a blue dress and a pointed blue witch's hat. Scrap is by her side.[if Lina is carrying something][pb]She's carrying [a list of things carried by Lina]."

Scrap is a male party member. Scrap is scenery. Understand "cat", "kitty", and "Scrappy" as Scrap. The description of Scrap is "A small, fluffy black cat, Scrap wears a blue bow around his neck. He sticks close to Lina."

The wet cat is a thing. Understand "cat", "kitty", "Scrappy", and "Scrap" as the wet cat. The description of the wet cat is "The black cat is soaked and shivering, but otherwise seems unharmed."

To say Lina is present:
	if Lina is not proper-named:
		say "A girl is sitting on the bed, crying.";
	else:
		say "Lina is sitting on the bed, crying."

Lina is in the Master Bedroom.

Section 2 - Talking

Lrownum is a number that varies. Lrownum is 1.

Instead of talking to Lina when Lina is out of the party:
	if the player is ghost:
		say "The girl jumps and looks around. '... Is someone there?'";
	else:
		if the player does not carry the wet cat and Daniel does not carry the wet cat:
			say "[one of]'Are you all right?' you ask the girl.[paragraph break]'No!' she sobs, without lifting her head.[or]'What's wrong?'[paragraph break]The girl looks up, sniffling. 'It's - it's - Scrap! I crash-landed outside and Scrap -' She collapses into sobs again.[or]'What happened to, uh, Scrap?' you ask gently.[paragraph break]'He fell in the pond! That horrible pond!' she says, wiping her eyes desperately. 'Please, help me! Get Scrappy back!'[or]Crying, the girl looks at you. 'Save Scrap from the pond!' she says.[stopping]";
		else:
			say "[give cat]".

Instead of giving the wet cat to Lina:
	say "[give cat]".
Instead of trying taking the wet cat when the player is in the Master Bedroom:
	say "[give cat]".
			
To say give cat:
	say "The girl glances up as you hold out the cat. Suddenly her expression goes from distraught to overjoyed. 'Scrappy!' she cries, jumping to her feet. The cat leaps to her and they nuzzle happily.[paragraph break]Eventually the girl turns to you. 'Thank you so much!' She wipes the last of the tears from her face as she beams at you. 'I don't know what I would do if I lost Scrap. I'm a witch, so I need a familiar, you see. Oh! I'm Lina!' You introduce yourself, and Lina continues. 'Listen, I'm here by accident, but I'd be glad to help you if I can. Did you know that Scrap can talk to animals?'[pb]You can use SCRAP, TALK TO MOUSE to talk to animals (assuming you haven't scared the animal away.)";
	now Lina is in the party;
	now the wet cat is off-stage;
	now Scrap is in the Master Bedroom;
	now Scrap is in the party.


Report talking to Lina:
	if player is normal:
		choose a random row from the Table of Lina normal talk;
		say "[talk entry][pb]";
	if player is ghost:
		say "'Lina? Are you still here?' you call, unable to see her.[pb]'Lina and Scrap, reporting for invisible duty!' she replies with a giggle.".

Table of Lina normal talk
talk
"'Lina, you can really do magic?' you ask.[pb]Lina grins. 'Yep. Well, actually I'm still in training. But I have Scrap, my familiar. And I can fly on my broomstick - well - I could before it broke...'"
"'So what are you doing here, anyway?' you ask Lina.[pb]'Well, I was just practicing flying on my broom, when something happened and I crash-landed in this weird place! And then Scrappy fell into the lake...'A shadow passes over Lina's face.[pb]Scrap leaps into her arms and rubs his face against hers. Lina smiles again. 'But I'm so glad that, thanks to you two, he's fine.'"
"'Show me some magic!' you say to Lina.[pb]'I'd love to,' says Lina excitedly. 'But... Granny said never to use magic frivolously. Anyway, things tend to go a little wrong when I try to do magic. It's probably safer if I don't.'"
"Turning to Lina, you ask, 'Have you ever heard of the Jewel of Alithia? It's supposed to have magical powers.'[pb]'The Jewel of Alithia?' she says. 'Sorry, never heard of it. Studying's not really my strong suit.'"
"You notice Lina looks a little down. 'Lina, is everything okay?' you ask.[pb]'Yeah,' she says. 'I was just trying to think of what to do now that I broke my broomstick. I wish I had a way to fix it... Oh well, I'm sure we'll figure something out.' And just like that, the worry disappears from her expression."
"You look over at Lina. She's already engaged in conversation - with Scrap. Holding him in her arms, she mutters to him as he meows back."


Section 3 - Persuasion

Unsuccessful attempt by Lina doing something:
	say "'No way, that's impossible!' says Lina."

A persuasion rule for asking Scrap to try doing something except talking to:
	say "Scrap ignores you." instead.
	
Instead of asking Scrap to try talking to a friend:
	choose the row with place of the location of the player in the Table of Animal Friends;
	say "Scrap goes over and talks to [the friend]. Lina repeats its words to you:[pb][talk entry][pb]";
	
Part 3 - Places

Chapter 1 - Courtyard

Section 1 - Outside the Doors

The player is in Outside the Doors.

Outside the Doors is a room. "You're right in front of the main door of the castle. To the south runs the road you took to come up here. [pb]The castle itself, a stone building with one large tower, looms north of where you stand. There's something a little unsettling about it."
The castle is scenery in Outside the Doors. "It's not too large, but it's still pretty imposing. You know the castle is empty, and the crumbling stonework and overgrown vines show it's been abandoned for a while; but as you look up at it, there's something strange about it.[pb]Is this the magic of the Jewel of Alithia...?"
The road is scenery in Outside the Doors. "You glance back at the road. Getting here wasn't so easy, but the hard part is still in front of you: searching the castle."
The front door is a door. It is north of Outside the Doors. "There are two wooden doors barred with strips of metal. They look large and heavy."
The Long Road is south of Outside the Doors. Instead of going south from Outside the Doors: say "You're not planning to leave until you have the jewel."

Section 2 - The Courtyard and Lake

The Courtyard is a region. The plants are a backdrop in the Courtyard. Understand "plant" as plants. "What were once carefully-tended plants now grow wild. Weeds intermix with bushes and flowers of all types." The pond is a backdrop in the Courtyard. "The water is murky with algae, and reeds have grown up around the edge. It's hard to tell just how deep it is." The old gazebo is a backdrop in the Courtyard. "You imagine it once stood elegantly apart from the rest of the courtyard, but now nature has reclaimed it, plants growing to cover it as its fine white finish flakes off. There are some unsteady-looking benches in it." The stone tower is a backdrop in the Courtyard. "The centerpiece of the castle, the gray tower reaches into the sky. Ivy clings to its weatherbeaten stone."

The Lake is north of the Entrance to the Courtyard, west of Around the Gazebo, south of the Flower Garden, and east of the Hedge Path. The Lake is in the Courtyard.
Instead of the player going to the Lake:
	say "If you go that way, you'll be going right into the pond. Do you want to keep going?";
	if the player consents:
		if Daniel is in the party and Lina is not in the party and the wet cat is not on-stage:
			say "[pb]'Are you sure you want to do that?' Daniel asks you. 'You still need to breathe, don't you?'[pb](You can ask your friends to do things: try DANIEL, GO [if the player is in the Entrance to the Courtyard]NORTH[else if the player is in Around the Gazebo]WEST[else if the player is in the Flower Garden]SOUTH[else]EAST[end if])";
		else:
			say "[pb]Bracing yourself, you step into the pond. The water is cold and full of thick, slimy plants. As you step forward, suddenly the ground drops out from under you. You sink under the cloudy water. You can't touch the bottom of the pond, and when you try to swim back to the surface, you find yourself tangled in underwater vines.[paragraph break]Struggle as you might, you can't escape. Eventually you succomb to the murky gloom.";
			end the story.

Instead of asking Daniel to try going to the Lake:
	say "Daniel nods and walks into the pond, passing through the tangled plants. The pond must be deeper than it looks, because he is soon completely underwater.";
	if Lina is not in the party and the wet cat is not on-stage:
		say "[pb]When he returns, he's gingerly carrying a small black shape. You look closer: it's a soaking wet cat. Amazingly, it stirs in Daniel's hands, shaking itself off.";
		now Daniel is carrying the wet cat;
	else:
		say "[pb]Eventually he returns, looking no different.".

Section 3 - The Entrance to the Courtyard

The Entrance to the Courtyard is north of the front door. The Entrance is in the Courtyard. "[if unvisited]You were expecting to step into some dark castle room, but instead, after passing through a short entryway, you find yourself outside again.[pb][end if]You're standing at the south end of a large, open courtyard. You can tell it was once a well-laid out garden with a pond as centerpiece. Now, though, the plants have grown wild, giving the courtyard a strange beauty. In the middle is the pond, thick with reeds and algae. The castle walls that circle the courtyard are interspersed with doors.[pb]To the northwest is an area with a row of hedges; to the northeast, a gazebo borders the pond. If you go north, you'll be walking right into the pond."
The bunny is an animal. Understand "rabbit" as bunny. The description is "The bunny is brown and fluffy, with a white cotton-ball tail."

Section 4 - The Hedge Path

The Hedge Path is northwest of the Entrance to the Courtyard. The Hedge Path is in the Courtyard. "This was once an area of hedges that would make for a nice walk. Now the hedges are overgrown and spill into the path that leads from the courtyard entrance to a door into the castle proper.[pb]The edge of the pond is directly east of you. A door is to the west. Southeast and northeast will lead you to other areas of the courtyard.[if Lina is not in the party][pb]You hear what sounds like someone crying coming from the west."
The hedges are in the Hedge Path. The hedges are scenery. Understand "hedge" and "bush" as the hedges. "Once neatly groomed, these hedges have grown misshapen.[if the key is in the hedges]You notice something glinting under the branches."
The small brass key is in the hedges. Instead of taking the small brass key when the small brass key is in the hedges: say "You reach for the key, but quickly draw your hand back. The hedge that the key is in has many small thorns that make it impossible to reach inside.[if Daniel is in the party][pb]'Oh, would you like me to help with that?' Daniel says. (Ask him with DANIEL, TAKE KEY.)" Instead of asking Daniel to try taking the key: say "Daniel's hand passes right through the thorny branches. His hand closes around the key and he starts to pick it up, but then drops it with a pained expression. 'I don't think I can do it. I have to solidify my hand to carry something, and then the thorns get me...'" Instead of asking Scrap to try taking the key: say "Scrap yawns once, then lazily jumps from Lina's arms to the ground. Carefully, he winds his small body through the thorny branches of the hedge. He picks up the key in his mouth, comes out, and drops it at your feet, whereupon he starts to groom himself as if nothing had happened."; now the key is in the Hedge Path; now the key is handled.
Instead of listening when the location of the player is the Hedge Path: say "[if Lina is not in the party]The sound of a young girl crying is coming through the window in the wall next to you.[else]You hear nothing unexpected."
The west window is in the Hedge Path. The west window is scenery. "It's an open window. Unfortunately, it's too high on the wall for you to look through."
The goose is an animal. "A goose struts about near the door." The description of the goose is "Large and proud, the goose alternates between pacing and ducking its head into a bush to check something: you guess that it's guarding a nest."
Instead of going west from the Hedge Path:
	if the player is ghost:
		say "You slip past the goose without disturbing it.";
		continue the action;
	else:
		say "You start for the door, but on the way you get too close to the goose. Hissing, it jumps at you with a flurry of white wings and starts pecking at you ruthlessly.[paragraph break]You are forced to retreat."

Section 4 - Around the Gazebo

Around the Gazebo is northeast of the Entrance to the Courtyard. Around the Gazebo is in the Courtyard. "Grass thick with weeds surrounds a wooden gazebo. The gazebo's white paint is peeling off, and one side of its roof has collapsed entirely. The benches inside it seem distinctly unsafe.[pb]The west side of the gazebo looks over the pond. To the east, across a stretch of grassy lawn, you see a door into the castle. Other parts of the courtyard are to the southwest and northwest."
The benches are scenery in Around the Gazebo. Understand "bench" as benches. "The wooden benches have started rotting away in places. You don't think it would be a good idea to sit on them."
The squirrel is an animal. The description is "You're not sure you've ever seen a black squirrel before. It's scampering about, fluffy tail waving."
After examining the gazebo:
	If the player is in Around the Gazebo:
		say "You notice a bird's nest under the eaves of the gazebo."
The bird's nest is in Around the Gazebo. The description is "A round clump of sticks[if the bird's nest is dull] is stuck under the eaves of the gazebo. When the light falls on it just right, something inside glimmers[end if]."
Before doing something except examining to the bird's nest:
	If the bird's nest is dull:
		say "The bird's nest is out of your reach." instead.
The green jewel is a thing. The description is "About the size of a coin, this jewel shines pure green."
			

Section 5 - The Flower Garden

The Flower Garden is northwest of Around the Gazebo and northeast of the Hedge Path. It is in the Courtyard. "Here, tangled bushes bloom with vivid flowers. This is by far the prettiest part of the courtyard, filled with color and beauty. Rising directly in front of you is a tall stone tower.[pb]The pond is to your south. To the north, a large wooden door leads into the tower. Southeast and southwest will take you to other parts of the courtyard."
The flowers are scenery in the Flower Garden. Understand "flower" and "bushes" as flowers. "You guess that this was once a well-organized garden, but now all the plants have grown wild. Delicate flowers mix with colorful weeds and snaking vines."


Chapter 2 - East Wing

The East Wing is a region.

The eastern door is a door. It is east of Around the Gazebo. Eastern Hallway is east of the eastern door. The description of the Eastern Hallway is "You step into a dimly lit hallway. On the west end is the door to the courtyard; there are also doors north, south, and southeast." It is in the East Wing.

Section 1 - The Library

The library door is north of the Eastern Hallway. The library door is a door. There is a room called the Library. It is north of the library door. It is in the East Wing. "The ceiling is very high, leaving room for towering bookcases that line the wall. A tarnished golden ladder is set on a track, so you can wheel it around the room. There is a skylight, which is open: underneath it, the floor has started to rot away from rain.[if the old green book is on the round table] Near the center of the room is a table with a large green book sitting on it.[end if][pb]The door to the hall is to the south; there's also a smaller door that heads northeast. You might even be able to climb out the skylight.[if Daniel is not in the party][pb][Daniel is present]".
The bookcases are scenery in the library. "They cover the walls entirely. You can't even count the number of large, dusty books." Understand "bookcase", "shelf", and "shelves" as bookcases.
The books are scenery in the library. "There's a variety of books on the shelves, but they all look old, moldy, and boring. There's also a book on the table with a green cover."
The round table is a supporter in the library. The table is scenery. The old green book is on the round table. The description of the old green book is "The title is 'A Thorough Account of the Lives and Lineage of the Esteemed Family of Brintor.' It's thick and looks so boring that you can't bring yourself to read it.[if Daniel is in the party][pb]'By the way,' says Daniel, 'Let me know if there's anything I can do to help.[pb](You can ask your friends to do things: try DANIEL, READ BOOK.)" Instead of asking Daniel to try examining the old green book: say "'Daniel, were you looking at that book before?' you ask.[paragraph break]Daniel nods. 'It's very interesting. It's the lineage of Alithia's family, the Brintors. Did you know that her four grandparents were all descended from noble houses?' Peering at a page in the book, he reads, 'And when the son of Verdell the wise and Sapphire the true-hearted was united with the daughter of Rowan the brave and Celandine the kind, it was then that the family of Brintor reached new heights of nobleness and purity of character.'[paragraph break]Daniel looks up at you. 'And so forth. I've already checked the end - the record stops after Alithia's birth.'"
The skylight is scenery in the library. "If there was once glass on the skylight, it's not there now. It's wide open, leaving the library at the mercy of the elements."
The ladder is scenery in the library. "The ladder, which reaches nearly to the ceiling, is attached to a track. It has wheels on the bottom so you can move it along the track to reach different books." Instead of climbing the ladder: say "You gingerly ascend the ladder. This gives you access to the higher shelves; unfortunately, they look just as uninteresting as the bottom shelves. And even on the ladder, you still can't reach the skylight."
There is a thing called the library floor. It is in the library. It is scenery. "The floor is elegant hardwood, except where the skylight has let rain in: there the floor is rotting and revealing the rough stone underneath."

Section 2 - The Study

The study door is a door. It is northeast of the Library. It is locked. The small brass key unlocks the study door. There is a room called the Study. It is northeast of the study door. It is in the East Wing. "This is a small nook of a room, with just enough space for a desk and a few bookcases. A thick layer of dust covers everything, from the desk chair to the papers piled on the desk.[pb]The door to the southwest leads back to the library."
The moth is an animal. The description is "Small, soft, and brown, the moth flutters around the desk."

Section 3 - The Dining Hall

The dining hall door is a door. It is south of the Eastern Hallway. There is a room called the Dining Hall. It is south of the dining hall door. It is in the East Wing. "A large hall panelled with dark wood, this room must have once been grand, but now it's just gloomy. Abandoned plates and silverware are scattered across the long tables. Dusty red curtains still droop over the windows, except for one whose curtain is askew and whose glass is shattered.[pb]The door to the hall is to the north."
The dining tables are scenery in the Dining Hall. Understand "table" as the tables. The description is "These long tables could probably fit everyone from your hometown. Long benches sit on either side of each table." The dining benches are scenery in the Dining Hall. Understand "bench" as the benches. The description is "Long, heavy-looking wooden benches."
Some plates are in the Dining Hall. Understand "plate" as plates. The description is "These plates were once elegant, but they're a little chipped."
Some silverware is in the Dining Hall. Understand "knife", "fork",  and "spoon" as silverware. The description is "A handful of old, tarnished cutlery."
The curtains are scenery in the Dining Hall. The description is "These thick red velvet curtains are doing an impressive job keeping light out of the room, although a few are hanging crooked."
The windows are scenery in the Dining Hall. Understand "window" as windows. The description is "There are a number of windows on the southern wall. Most are covered by curtains. One is gaping open. A few plants from outside have pushed their way in and curl weakly in the small patch of light under the window." The plants are scenery in the Dining Hall.
The crow is an animal. Understand "bird" as crow. "A large black crow hops about near the open window." The description is "The bird is large, with shiny black feathers. It pecks interestedly at pieces of silverware."

Section 4 - The Kitchen

The kitchen staircase is a staircase. It is southeast of the Eastern Hallway. There is a room called the Kitchen. It is below the kitchen staircase. It is in the East Wing. "[if unvisited]You descend a small, dark staircase and find yourself in what looks like a kitchen. [end if]You're in a spacious stone room with a row of ash-filled ovens along the back wall. There's also a wide stone sink, some large, bare tables, and a pantry in the corner. Rusty pots and pans hang on the walls. The room feels damp and subterranean, but a few narrow windows let in sunlight.[pb]You can go up the stairs to get back to the hall."
The ovens are scenery in the Kitchen. Understand "oven" as ovens. The description is "There are several huge ovens, made of scorched, ashy stone. Looks like this kitchen could handle a lot of cooking in its day."
The kitchen tables are scenery in the Kitchen. Understand "table" as kitchen tables. The description is "These large, flat tables were probably kept pristine when the kitchen was in working operation. Now, a layer of grime covers them."
The pantry is a closed, opaque, openable container. It is scenery in the Kitchen. The description is "A tall pantry with a double door is in one corner." Some cooking implements are in the pantry. A few empty sacks of flour are in the pantry.
The pots are scenery in the kitchen. Understand "pot", "pan", and "pans" as the pots. The description is "There's a staggering array of different pots and pans, but they all look rusty and disused."
The kitchen windows are scenery in the kitchen.
The sink is a container. The sink is scenery in the Kitchen. The sink can be either dry or watery. The sink is dry. The description is "This is a wide, deep sink you could almost swim in.[if the sink is dry] If it weren't bone-dry and apparently the home of a fat brown spider.[else] If the brown water filling it didn't look so disgusting.[end if] A metal faucet is above it."
The faucet is scenery in the Kitchen. "A dented metal faucet is set above the sink. It has two knobs, which you might be able to turn." Understand "knob" and "knobs" as the faucet.
[Faucet-turning is an action applying to one visible thing. Understand "turn [something]" as faucet-turning.
Check faucet-turning:
	if the noun is not the faucet:
		say "Nothing obvious happens." instead.
Carry out faucet-turning:
	say "There's a horrible grinding sound, and brownish water starts to flow into the sink. You turn off the water [if the sink is wet] quickly, before the sink overflows.[else]when the sink is full. It doesn't seem to be going down the drain. Perhaps it's clogged?";
	now the sink is watery;
	if the red jewel is off-stage:
		now the red jewel is in the sink;
		say "[pb]You see something floating up through the murky water. It shines red.".]
The red jewel is a thing. The description is "Red light glints off this small jewel."


Chapter 3 - West Wing

The West Wing is a region.

The western door is a door. It is west of the Hedge Path. There is a room called the Western Hallway. It is in the West Wing. It is west of the western door. The description of the Western Hallway is "You step gingerly on the crumbling carpet that runs the length of the hallway. The exit is to the east. The building has partially collapsed here, blocking the west side of the hallway with pieces of rock. There are two doors on the east side of the hallway, one to the north and one to the south.[if Lina is not in the party][pb]The sound of crying is coming from the door to the north."
The rocks are in the Western Hallway. The description is "A pile of stone has fallen here. It looks like this part of the hallway just collapsed. Bent-up pieces of metal lie among the chunks of roof and wall that block your way." Understand "rock", "stone", and "debris" as the rocks.
Instead of listening when the location of the player is the Western Hallway: say "[if Lina is not in the party]The sound of a young girl crying is coming from the door to the north.[else]You hear nothing unexpected."

Section 1 - The Master Bedroom

The bedroom door is a door. It is north of the Western Hallway. There is a room called the Master Bedroom. It is in the the West Wing. It is north of the bedroom door. The description is "In the center of the room is a large four-poster bed. The covers and the canopy are covered in dust and the carpet has been nibbled on by something. There's a large wooden dresser here as well as a window onto the courtyard.[if the broken broom is in the Master Bedroom] Next to the bed lies a broomstick, broken into two pieces.[end if][pb]The door to the hallway is to the south.[if Lina is not in the party][pb][Lina is present]".
The red four-poster bed is in the Master Bedroom. It is scenery. It is a supporter. The description is "The bed is large, with a dark red canopy and bedspread. It would look comfortable if it weren't so moth-eaten."
There is a thing called the bedroom carpet. It is in the Master Bedroom. It is scenery. The description is "The carpet once had an elegant design, but by now it's faded and starting to fall apart."
The large wooden dresser is in the Master Bedroom. It is scenery. It is a closed, opaque, openable container. The description is "A large, chunky dresser made of dark wood." The dresser contains some old clothes and a stack of bedsheets.
The bedroom window is in the Master Bedroom. It is scenery.
The broken broom is in the Master Bedroom. Understand "broomstick" as broom. The description is "This broom, which has a blue bow on its handle, has snapped right in the middle.[if Lina is in the party] Lina sighs as she looks at it. 'My trusty broomstick... I wish I knew a spell to fix it.'"

Section 2 - Sitting Room

Section 3 - Second Bedroom

The broken door is a door that is open. "The door has been partially crushed and is mostly in splinters on the ground." It is west of the Western Hallway. There is a room called the Second Bedroom. It is in the West Wing. It is west of the broken door. "This is the bedroom with the entrance to the secret vault."
Instead of going west from the Western Hallway when the rocks are in the Western Hallway: say "A large pile of rock and debris blocks your way."

Section 4 - Secret Vault

Chapter 4 - Tower

The Round Tower is a region.

Section 1 - Round Hall

Section 2 - Underground Lab

Section 3 - Throne Room