Little Harmonic Labyrinth: Part 1 by Allison

Little Harmonic Labyrinth: Part 1

Played 9,023 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Little Harmonic Labyrinth: Part 1" by Allison

[V1 Hello, it's me! I'm the one who, about a year ago, wrote those games that basically amount to BBC Sherlock and Doctor Who fanfiction--which is odd, because I've never actually written fanfiction before. But now I've decided to do something original--or mainly original, as I didn't realize until I finished this section how heavily I've drawn from a very certain game series and a very certain book. Oh well; such is creativity. I've been making this up as I go along, so don't expect storytelling brilliance! But DO expect musical puns and the occasional reference to the game I accidentally ripped off!

For those playing this game for the first time: almost everything has a description, and because I'm bad at this, occasionally examining something is the only way to make something important happen. Also, this is just a partial draft, so you're only going to get to the entrance of the second dungeon. The field area isn't completely done yet, so there are areas you can't access. 

I've yet to figure out how to set up the levelling system elegantly, so your level caps at 7 and I have a giant brick of code describing each individual level instead of doing it with an equation or something. Also, the shop only carries 10 of each potion because that's all Playfic can handle. I think.

The monster difficulty vs the player levelling is something I'm still struggling with, so buy a lot of potions and try not to die (unless I've made it too easy--in that case, have fun one-shotting everything)--you end up with way too much money and nothing to buy anyway. I'm considering implementing a cap on the number of arcos you can have at one time so that you don't end up with 20000 arcos and nothing to spend it on.

Plants, pots, and monsters don't respawn, and characters will say different things depending on where you are in the story.

Tip: type "take all" to avoid having to take things individually, and maybe draw a map on paper as you're playing to avoid getting lost.
If the chord puzzle stumps you, Google "D major first inversion chord," and make sure to type the key names exactly as shown (i.e. with the hyphens: "a-key"; "f sharp-key").
Have fun!]


Part 1-Where is my Freaking Violin?

Chapter 1-Framework and Various Other Things

Use no scoring.

[this name thing was basically taken straight from the Recipe Book, because I was not creative enough to figure it out myself.]

The forename is an indexed text that varies. The full name is an indexed text that varies.
When play begins:
	now the command prompt is "What is your name? > ".
To decide whether collecting names: 
	if the command prompt is "What is your name? > ", yes;
	no.
After reading a command when collecting names:
	if the number of words in the player's command is greater than 4:
		say "[paragraph break]I can't remember a name that long! Do you have a nickname, perhaps?";
		reject the player's command;
	now the full name is "[the player's command in title case]";
	now the forename is word number 1 in the full name;
	now the command prompt is ">";
	say "Why hello, [full name]; welcome to this strange little harmonic labyrinth. I hope you like puzzles.[paragraph break]";
	say "[banner text]";
	move the player to the location;
	reject the player's command.

Instead of looking when collecting names: do nothing.
Rule for printing the banner text when collecting names: do nothing.
Rule for constructing the status line when collecting names: do nothing.

When play begins:
now right hand status line is "[price of arcos] ";
now the left hand status line is "HP:[health]/[maxhealth] MP:[magic]/[maxmp]".

Understand "pour [something] into [any container]" as inserting it into.

Playability is a kind of value. The playabilities are playable and nonplayable. A thing has a playability. A thing is usually nonplayable.

Price is a kind of value. 500 arcos specifies a price. A thing has a price. The price of something is usually 0 arcos.
Definition: a thing is free if its price is 0 arcos.

Stealability is a kind of value. A thing has stealability. The stealabilities are stealable and nonstealable. A thing is usually stealable.

Definition: a thing is for sale if it is nonstealable.

Check going:
	If the player is in a room (called the current space):
		if an enemy is in the current space:
			say "But you haven't defeated all of the enemies in the area yet!" instead.



Money is a kind of thing. A coin is a kind of money. The printed name of a coin is "arco". Understand "arco" as a coin. Understand "arcos" as coins. Rule for printing the plural name of a coin: say "arcos". The description of a coin is "Arco coin: a little brass (or perhaps copper?) piece of currency."

Instead of taking a coin: 
	if the player is carrying the wallet:
		say "You found an arco![paragraph break]";
		increase the price of arcos by 1 arcos;
		remove the noun from play;
	otherwise:
		say "You're not carrying your wallet!".

	
Understand "equip [something]" as wearing.

In the closet are 3 coin.

The plural of potion is potions. A potion is a kind of thing. An elixir is a kind of potion. The printed name of an elixir is "elixir". Rule for printing the plural name of an elixir: say "elixirs". The description of an elixir is "A revitalizing elixir. It might help you in dangerous situations." 
A Tonic is a kind of potion. The plural of Tonic is Tonics. The description of a Tonic is "A very powerful potion--it brings everything back to where it was meant to be. Restores all HP and MP."
A Subtonic is a kind of potion. The plural of Subtonic is Subtonics. The description of a Subtonic is "A powerful potion--it seems to almost, but not quite, fix everything up. Increases HP and MP by 1/2 of the maximum."

Understand the command "drink" as something new. Understand "drink [something]" as sipping. Sipping is an action applying to one carried object.
Check sipping:
	if the noun is not a potion:
		say "We should probably stick to potions." instead;
	if the noun is an elixir:
		say "It's a refreshing taste. You feel just a bit stronger.";
		increase Health by 25;
		increase Magic by 25;
		remove the noun from play;
	if the noun is a Tonic:
		say "You feel relaxed, as though everything is all right in the world. Your HP and MP are at maximum.";
		increase Health by MaxHealth minus Health;
		increase Magic by MaxMP minus Magic;
		remove the noun from play;
	if the noun is a Subtonic:
		say "You feel as though you're almost all healed up. Your HP and MP have been partially restored.";
		increase Health by MaxHealth divided by 2;
		increase Magic by MaxMP divided by 2;
		remove the noun from play.

A weapon is a kind of thing. The plural of weapon is weapons. The rusted sword is a weapon. A weapon has a number called Atknum.

Attackability is a kind of value. A thing has attackability. The attackabilities are attackable and nonattackable. A thing is usually nonattackable.

A pot is a kind of thing. The plural of pot is pots. A pot is attackable. A pot is fixed in place. The description of a pot is "A large earthenware pot. For some reason, you really want to break it to see what's inside."
A plant is a kind of thing. The plural of plant is plants. A plant is attackable. A plant is fixed in place. The description of a plant is "A small, leafy plant. You have a sudden urge to cut it with a weapon, just to see what would happen. It might have something hidden inside." 

Understand the command "attack" as something new. Understand "attack [something attackable] with [any weapon]" as attacking it with. Understand "a [something attackable] with [any weapon]" as attacking it with. Understand the commands "break" and "cut" and "hit" and "smash" and "destroy" and "fight" and "kill" as something new. Understand "break [something attackable] with [any weapon]" and "cut [something attackable] with [any weapon]" and "hit [something attackable] with [any weapon]" and "smash [something attackable] with [any weapon]" and "destroy [something attackable] with [any weapon]" and "fight [something attackable] with [any weapon]" and "kill [something attackable] with [any weapon]" as attacking it with. Attacking it with is an action applying to one thing and one carried thing.
Carry out attacking it with:
	if the noun is a pot:
		say "You [one of]lash out[or]strike[or]slash[or]swing[or]stab[or]execute a graceful combo[at random] with your [second noun], [one of]dashing the pot to bits[or]utterly destroying the pot[or]smashing up the pot[at random]!";
		if the player is carrying the wallet:
			let randnum be a random price from 1 arcos to 25 arcos;
			say "You found [randnum]!";
			increase the price of arcos by randnum;
		remove the noun from play;
	if the noun is a plant:
		say "You [one of]lash out[or]strike[or]slash[or]swing[or]stab[or]execute a graceful combo[at random] with your [second noun], [one of]tearing up the plant[or]demolishing the plant[or]ripping up the plant in a flurry of leaves[or]destroying the plant[or]cutting down the plant[at random]!";
		let randhealth be a random number from 5 to 25;
		say "You found some fruit! You eat it, increasing your health by [randhealth] points.";
		increase Health by randhealth;
	remove the noun from play.
	



The wallet contains arcos. The wallet is closed. The price of the arcos is 0 arcos.
The description of the wallet is "[if the price of the arcos is 0 arcos]You're broke. Nothing to see here.[otherwise]Mmm, jingly money in a bag. Contains [price of arcos], which are little brassy coins.[end if]".
Instead of dropping coins, say "Let's just keep those in your wallet until you need them. You might lose them if you're not careful!"
Instead of taking something nonstealable:
	say "Just what do you think you're doing? Just because you're a down-on-your-luck composer doesn't mean you get anything for free."


Health is a number that varies. Health is 50.
Agility is a number that varies. Agility is 0.
Defense is a number that varies. Defense is 1.
Attack is a number that varies. Attack is 0.
Experience is a number that varies. Experience is 0.
Magic is a number that varies. Magic is 0.
Levnum is a number that varies. Levnum is 1.

MaxHealth is a number that varies. MaxHealth is 50.
Every turn:
	if Health is greater than MaxHealth:
		decrease Health by Health minus MaxHealth;
		say "...but you're already at maximum health.".

MaxMP is a number that varies. MaxMP is 25.
Every turn:
	if Magic is greater than MaxMP:
		decrease Magic by Magic minus MaxMP;
		say "...but you're already at maximum MP.".

The player has a number called Level. The Level of the player is 1.

Understand "help" as helping. Helping is an action applying to nothing. Understand "help me" and "h" as helping.
Carry out helping: say "HELP:[paragraph break]Type 'stat' or 'st' to see your stats.[paragraph break]Type 'inventory' or 'i' to see the items you're carrying.[paragraph break]Examine everything.[paragraph break]Pick up useful items.[paragraph break]Certain items affect your stats. You can wear clothing. Just carrying weapons automatically equips them.[paragraph break]Visit the item shop! Some monsters are tricky and you're going to need that Tonic. [paragraph break]Useful commands: EXAMINE, TAKE, PLAY (SONG) ON (INSTRUMENT), OPEN, CLOSE, UNLOCK, PRESS, UNPRESS, PUT, ATTACK, TALK TO (SOMEONE), NORTH, EAST, SOUTH, WEST, UP, DOWN, DRINK (POTION), EQUIP, BUY, LOOK, and many more.[paragraph break]Shortcuts: instead of 'play (song) on violin,' you can do 'p (song initials) v'. NORTH/SOUTH/EAST/WEST can be replaced with n/s/e/w, and UP/DOWN with u/d. Type 'a' for ATTACK and 'x' for EXAMINE.".

Understand "stat" as stating. Stating is an action applying to nothing. Understand "stats" and "statistics" and "st" as stating.
Carry out stating: say "STATS:[paragraph break]MAXHP:[MaxHealth][paragraph break]MAXMP:[MaxMP][paragraph break]AGL: [Agility][paragraph break]DEF:[Defense][paragraph break]ATK:[Attack][paragraph break]EXP:[Experience][paragraph break]LVL:[Levnum][paragraph break]".


A song is a kind of thing. The plural of song is songs. Minuet in G major is a song. Fur elise is a song.

Understand "dm" as Danse Macabre.

Playing it with is an action applying to one thing and one visible thing. Understand "play [any song] on the [something]" and "play [any song] on [something]" and "p [any song] [something]" as playing it with.
Check playing something with the harpsichord:
	if the player is not in the Bedroom,
		say "Do you see a harpsichord? I don't see a harpsichord."
Check playing something with something:
	if the second noun is nonplayable:
		say "That would just be silly. Let's stick to real instruments." instead;
	if the noun is playable:
		say "You need a song to play on that first!" instead;
	if the noun is not a song:
		say "Though metaphorical language is fun, you'll have to play an actual song.".
Carry out playing fur elise with the harpsichord:
		say "You play an elegant rendition of Beethoven's work, but nothing happens. You have a strange feeling that something will happen if you play a certain song.";
Carry out playing minuet in g major with the harpsichord:
	if the player is not carrying the brass key:		
		say "[first time]You hear a rattle and a click, and you look underneath the harpsichord. To your astonishment, a brass key has just fallen out of the instrument, probably shaken out by the Bach piece you just played! You have no idea how it got there, but you pick up the key anyway.[only]It was a lovely piece of music.";
		now the player is carrying the brass key.
Check playing minuet in g major with the harpsichord:
	if the player is carrying the brass key:
		say "A pretty piece to be heard again! But you have better things to do." instead.
		
Carry out unlocking the trunk with the brass key:
	remove the brass key from play.
	


The description of the player is "[one of]You're as attractive as ever.[or]Weary, but managing.[or] A devilishly handsome and remarkably clever person.[or]You haven't slept in days, but you maintain your blindingly good looks.[at random]".

The Storage Room is a room. 
Some dolce berries are in the Storage Room. The description of the dolce berries is "A bunch of sweet-smelling, inedible, deep purple berries. Useful for making inks, paints and dyes."


Violin Hunt is a scene. Violin Hunt begins when play begins. Violin Hunt ends when the player is in the Final Cave Room for the second turn. Missing Marcato is a scene. Missing Marcato begins when Violin Hunt ends. Missing Marcato ends when the player is in the Northeastern Field for the second turn. The Rock Temple is a scene. The Rock Temple begins when Missing Marcato ends.
When The Rock Temple begins:
	now Plotnum is 3;
	now Ottava is carrying the empty bottle;
	move Ottava to the Plaza;
	move the dolce berries to the Southwestern Field.
	
The player is in the Bedroom.
	
	

Chapter 2- Your House


Fur elise is in the bedroom. Fur elise is scenery. Fur elise is fixed in place.

The closet is in the Bedroom. The closet is fixed in place. The closet is scenery. The closet is a closed and openable container. In the closet are a simple tunic, a pair of leather boots, and a pair of wrist-length gloves. The description of the closet is "A neat-looking, finely-carved affair of honey-colored wood. It's likely there to hold clothing, as closets are generally used for such things. You can probably open it."

The wallet is a container.

The trunk is in the bedroom. The trunk is fixed in place. The trunk is scenery. The trunk is a closed and openable container. The trunk is locked. In the trunk is a rusted sword and a wallet. The description of the trunk is "A reddish trunk with brass finishings. It looks impressive, as though something fairly important might be inside.[if the trunk is locked]It appears to have a keyhole.[otherwise]It's unlocked, so you can open it up![end if]".

The brass key unlocks the trunk.

The harpsichord is in the bedroom. The harpsichord is playable. The harpsichord is scenery. The harpsichord is fixed in place. The description of the harpsichord is "A rickety-looking instrument, the harpsichord is one of your favorite items in the house. Touching the keys elicits a nice, sharp, concise sound from the strings hidden away in the instrument body. Perhaps you should play it; it's been a while. (Type 'play (song) on harpsichord' to start playing--for example, 'play fur elise on harpsichord')" 


The desk is in the bedroom. The desk is fixed in place. The description of the desk is "It's cluttered with musical things and ink-splattered pages. There's a wide drawer in the middle of the desk." The desk is scenery. The drawer is part of the desk. The drawer is a closed and openable container. In the drawer is Minuet in G Major. The description of Minuet in G major is "Sheet music for a  rather pretty Bach (or at least popularly attributed to Bach) minuet, which sounds very nice on the harpsichord, though in modern times people tend to play it on the piano."

An armor is a kind of thing. The plural of armor is armors. An armor is wearable. An armor has a number called Defnum.

The description of the simple tunic is "A simply-cut garment--it's a bit scratchy around the edges, but it wears nicely and provides minor protection from the elements." The simple tunic is an armor. The Defnum of the simple tunic is 2.

Check wearing an armor:
	if the player is wearing the noun:
		say "You're already wearing it!" instead;
	otherwise:
		increase Defense by Defnum.
Check taking off an armor:
	if the player is not wearing the noun:
		say "You're already not wearing it!" instead;
	otherwise:
		decrease Defense by Defnum.

A footwear is a kind of thing. The plural of footwear is footwear. A footwear is wearable. A footwear has a number called Aglnum.

The description of the leather boots is "A pair of scuffed, dull-colored boots worn out from years of adventuring. They make you just a little bit faster." The leather boots are a footwear. The Aglnum of the leather boots is 3.

Check wearing a footwear:
	if the player is wearing the noun:
		say "You're already wearing them!" instead;
	otherwise:
		increase Agility by Aglnum.
Check taking off a footwear:
	if the player is not wearing the noun:
		say "You're already not wearing them!" instead;
	otherwise:
		decrease Agility by Aglnum.


The description of the rusted sword is "It may be a clumsy instrument, but the burnished old weapon still has a rather sharp blade." The rusted sword is a weapon. The Atknum of the rusted sword is 3.

Check taking a weapon:
	if the player is carrying the noun:
		say "You already have that!" instead;
	otherwise:
		increase Attack by Atknum.
Check dropping a weapon:
	if the player is not carrying the noun:
		say "You're not carrying that right now, so you can't get rid of it!" instead;
	otherwise:
		decrease Attack by Atknum.


The description of the pair of wrist-length gloves is "Little black gloves that cover the wrists. Legend has it that wearing black gloves makes everything you do look much cooler." The pair of wrist-length gloves is an armor. The Defnum of the pair of wrist-length gloves is 1.

The table is in the Kitchen. The table is scenery. The table is fixed in place. The description of the table is "It's just a table, meant for whatever tables are usually meant for."

On the table is 1 elixir.


The oven is in the Kitchen. The oven is scenery. The oven is fixed in place. The description of the oven is "A cast-iron wood-burning oven, with a hinged grate that opens to allow for the exchange of food and firewood. A musty wood smell wafts from the interior." The grate is part of the oven. The grate is a closed and openable container. In the grate are 7 coins.

In the bedroom is a pot.

In the Den is a sign. The sign is scenery. The sign is fixed in place. The description of the sign is "It reads: [paragraph break]'A NOTE ON COMBAT.[paragraph break]You may come upon certain creatures during your time adventuring. The first of these that you will encounter is a Trill--a weak creature, but dangerous nonetheless. [paragraph break]To fight, you must have a weapon. (If not, you'll probably die.) Once you have a weapon, simply type 'attack' to start fighting the first monster in the area. Type 'attack' again until the monster is defeated. Once you enter an area with monsters, you cannot leave until they are all defeated. But do not fear! You may use items at any time during the battle. You may drink elixirs to replenish health and magic points.[paragraph break]Clothing does nothing unless worn! Wearing protective clothing, such as boots, tunics, and gloves, will improve your chances of survival. Merely picking up a weapon will equip it automatically, but clothing must be worn.[paragraph break]Once you learn new magical skills, those may be used in battle along with your normal attack.'"

Chapter 3- Fermata Village

There are four plants in Fermata Village.

There is a wooden sign in Fermata Village. The wooden sign is fixed in place. The description of the wooden sign is "The sign reads: 'If you cannot figure out how to successfully converse with other human beings, try typing 'talk to (person).' (So, for example, 'talk to Quaver.')[paragraph break]--this message brought to you by the Fermata Village Council for Assisting Socially Challenged Musicians'".
		
Chapter 4- Ottava's House 

In Ottava's House are three pots.

Chapter 5- Item Shop

The shelf is in the Fermata Item Shop. The shelf is scenery. 
In the shelf are 10 Tonics. In the shelf are 10 Subtonics.

A Tonic is nonstealable. A Subtonic is nonstealable.

The sharp sword is in the shelf. The sharp sword is nonstealable. The description of the sharp sword is "A sharper weapon than the rusted sword, this two-edged blade looks deadly. A stylized musical 'sharp' symbol has been worked into the hilt." The sharp sword is a weapon. The Atknum of the sharp sword is 8.

The sturdy tunic is in the shelf. The sturdy tunic is an armor. The description of the sturdy tunic is "A more reinforced version of the simple tunic." The Defnum of the sturdy tunic is 4. The sturdy tunic is nonstealable. The price of the sturdy tunic is 700 arcos.


A large sign is in the Fermata Item Shop. The large sign is fixed in place. The description of the large sign is "The sign reads: 'FERMATA ITEM SHOP.[paragraph break]We carry the finest Tonics and Subtonics.[paragraph break]Price of a Tonic: 100 arcos[paragraph break]Price of a Subtonic: 50 arcos[paragraph break]Price of the Sharp Sword: 500 arcos[paragraph break]Price of the Sturdy Tunic: 700 arcos[paragraph break]To buy something, type 'buy (something)'--for example, 'buy Subtonic'. Our inventory is very limited--eventually we might run out of stock.'"

Chapter 6- The Broken Fountain

The Fountain is in the Garden. The Fountain can be broken or unbroken. The Fountain is broken. The description of the Fountain is "[if the fountain is broken]A run-down old fountain, stained with old water residue and rusting from disuse[end if][if the fountain is unbroken]Water shoots from the spout and arcs back down into the pool. It works like new.[end if]". 


Chapter 7- Combat

[also just modified from the recipe book, because I am bad at this.]

An enemy is a kind of animal. The plural of enemy is enemies. 
An enemy is attackable. An enemy has a number called maximum hit points. An enemy has a number called current hit points. An enemy has a number called Max Damage. An enemy has a number called Min Damage. An enemy has a number called Min Gift. An enemy has a number called Max Gift. An enemy has a price called Min Lootnum. An enemy has a price called Max Lootnum.


A Trill is a kind of enemy. The description of the Trill is "A knobby-kneed little troll-creature with a batlike nose and a pot belly. It's a somewhat weak creature known for wielding crude clubs. Its name comes from its ululating call." The plural of Trill is Trills.

The maximum hit points of a Trill is 20. The current hit points of a Trill is 20.
The Min Gift of a Trill is 50.
The Max Gift of a Trill is 150.
The Max Damage of a Trill is 25. The Min Damage of a Trill is 15.
The Min Lootnum of a Trill is 10 arcos. The Max Lootnum of a Trill is 30 arcos.

A Tremolo is a kind of enemy. The description of a Tremolo is "A great, slavering, wolf-like creature with fearsome claws. It is known for stealing livestock and terrorizing lone travellers. Its blue-grey fur bristles and its hackles raise as it glares at you with steely eyes, its growl sounding a low tremolo." The plural of Tremolo is Tremolos.

The maximum hit points of a Tremolo is 40. The current hit points of a Tremolo is 40.
The Min Gift of a Tremolo is 150. The Max Gift of a Tremolo is 200. The Max Damage of a Tremolo is 70. The Min Damage of a Tremolo is 50. The Min Lootnum of a Tremolo is 30 arcos. The Max Lootnum of a Tremolo is 100 arcos.

A Mordent is a kind of enemy. The description of a Mordent is "Ghastly, eyeless, skeletal, and just generally your average living (or dead?) nightmare. It trails shreds of old cloth and decaying skin from its pallid bones. Its skeleton does not resemble a human's--rather, the body looks almost reptilian, though the grinning skull is human enough. Crooked horns and spines jut out from the curved vertebrae." The plural of Mordent is Mordents.

The maximum hit points of a Mordent is 60. The current hit points of a Mordent is 60. The Min Gift of a Mordent is 300. The Max Gift of a Mordent is 400. The Max Damage of a Mordent is 200. The Min Damage of a Mordent is 120. The Min Lootnum of a Mordent is 100 arcos. The Max Lootnum of a Mordent is 300 arcos.

A Caesura is a kind of enemy. The description of a Caesura is "Your breath pauses in your throat as you behold the great creature. It hovers silently on ungainly, owlish wings, and its spiked, whiplike tail trails threateningly behind enormous, hooked talons. Unlike an owl, however, it has no eyes--but it seems perfectly able to sense you anyway. Its head turns to follow your every move." The plural of Caesura is Caesuras.

The maximum hit points of a Caesura is 150. The current hit points of a Caesura is 150. The Min Gift of a Caesura is 300. The Max Gift of a Caesura is 400. The Max Damage of a Caesura is 300. The Min Damage of a Caesura is 200. The Min Lootnum of a Caesura is 100 arcos. The Max Lootnum of a Caesura is 350 arcos.

An Appoggiatura is a kind of enemy. The description of an Appoggiatura is "Looming above you, the scaly Appoggiatura flicks its forked tongue in your direction, poisonous saliva dripping from its snaggle-toothed maw. It's a dragonish creature about the size of a horse, known for its poisonous bite." The plural of Appoggiatura is Appoggiaturas.

The maximum hit points of an Appoggiatura is 100. The current hit points of an Appoggiatura is 100. The Min Gift of an Appoggiatura is 300. The Max Gift of an Appoggiatura is 400. The Max Damage of an Appoggiatura is 350. The Min Damage of an Appoggiatura is 300. The Min Lootnum of an Appoggiatura is 100 arcos. The Max Lootnum of an Appoggiatura is 360 arcos.

Turnnum is a number that varies. Turnnum is 0.

[this next bit is REALLY EMBARRASSING PLEASE IGNORE]

Instead of attacking an enemy with a weapon:
	let the damage be a random number between Attack - 3 and Attack + 5;
	say "You [one of]slash[or]stab[or]execute a graceful combo[or]thrust[or]swing[at random] with your [second noun] at [the noun], causing [damage] points of damage!";
	decrease the current hit points of the noun by the damage;
	if the current hit points of the noun is less than 0:
		say "[line break][The noun], defeated, vanishes in a puff of smoke!";
		let Dropnum be a random price between Min Lootnum and Max Lootnum;
		say "The [noun] dropped [dropnum]!";
		increase the price of arcos by Dropnum;
		let Elixnum be a random number from 1 to 5;
		if Elixnum is 1:
			say "The [noun] also left behind a small potion, which you drink to heal your wounds!";
			Increase Health by MaxHealth divided by 5;
			increase Magic by MaxMP divided by 5;
		let Expnum be a random number between Min Gift and Max Gift;
		increase Experience by Expnum;
		say "You earned [expnum] experience!";
		if the Level of the player is 1:
			if Experience is greater than 100:
				now the level of the player is 2;
				increase Levnum by 1;
				say "You've levelled up to level [levnum]!";
				increase Attack by 2;
				increase Defense by 2;
				increase Agility by 1;
				increase MaxHealth by 10;
				increase MaxMP by 5;
		if the Level of the player is 2:
			if Experience is greater than 500:
				now the level of the player is 3;
				increase levnum by 1;
				say "You've levelled up to level [levnum]!";
				increase Attack by 3;
				increase Defense by 2;
				increase Agility by 2;
				increase MaxHealth by 10;
				increase MaxMP by 5;
		if the Level of the player is 3:
			if Experience is greater than 2500:
				now the level of the player is 4;
				increase levnum by 1;
				say "You've levelled up to level [levnum]!";
				increase Attack by 4;
				increase Defense by 5;
				increase Agility by 4;
				increase MaxHealth by 15;
				increase MaxMP by 10;
		if the Level of the player is 4:
			if Experience is greater than 5000:
				now the level of the player is 5;
				increase levnum by 1;
				say "You've levelled up to level [levnum]!";
				increase Attack by 5;
				increase Defense by 5;
				increase Agility by 6;
				increase MaxHealth by 20;
				increase MaxMP by 15;
		if the Level of the player is 5:
			if Experience is greater than 15000:
				now the level of the player is 6;
				increase levnum by 1;
				say "You've levelled up to level [levnum]!";
				increase Attack by 7;
				increase Defense by 6;
				increase Agility by 6;
				increase MaxHealth by 25;
				increase MaxMP by 20;
		if the Level of the player is 6:
			if Experience is greater than 30000:
				now the level of the player is 7;
				increase levnum by 1;
				say "You've levelled up to level [levnum]!";
				increase Attack by 7;
				increase Defense by 8;
				increase Agility by 8;
				increase MaxHealth by 30;
				increase MaxMP by 25;
		remove the noun from play;
		stop the action;
	let Dodgenum be a random number from 1 to 100 minus Agility;
	if Dodgenum is 1:
		say "[The noun] attacks, but you quickly dodge!";
		stop the action;
	let the counterattack be a random number between Max Damage divided by Defense and Min Damage divided by Defense;
	say "[line break][The noun] attacks you, causing [counterattack] points of damage!";
	decrease the Health by the counterattack;
	if the noun is an Appoggiatura:
		let Poisonnum be a random number between 1 and 4;
		if Poisonnum is 1:
			decrease Health by MaxHealth divided by 20;
			say "The Appoggiatura sinks its poisonous fangs into your shoulder! You've been poisoned!";
			now Turnnum is 1;
	if Health is less than 0:
		say "[line break]You've died!"; 
		end the story.

Every turn:
	if Turnnum is 1:
		decrease Health by MaxHealth divided by 10;
		say "You're poisoned! You lost some HP!";
	if Health is less than 0:
		say "[line break]You've died!";
		end the story.

Carry out sipping a potion: now Turnnum is 0.
Carry out playing Danse Macabre with the violin: now Turnnum is 0.






Chapter 8- People


Quaver is a man in Fermata Village. The description of Quaver is "An irresponsible-looking man, a few years your senior, dressed in earth-toned hunting gear with a quiver and bow slung over his back. He's your neighbor and a longtime friend of yours."

Understand "talk to [someone]" as talking to. Talking to is an action applying to one thing.

Plotnum is a number that varies. Plotnum is 1.

Carry out talking to Quaver:
	if Plotnum is 1:
		say "[first time]'Hey, [forename]! About time you climbed out of your cave. I suppose you needed to see the sun after your tumultuous storm of creative processes--speaking of which, how's the fugue coming along?'[paragraph break]You mention that you cannot find your violin.[paragraph break]'Really? Where could it have gone? I'd try asking around the village. It can't have gone far!'[paragraph break][only]'By the way, there are a LOT of new monsters showing up just outside the village. Must be breeding season or something...just watch out for Trills, okay?'";
	if Plotnum is 2:
		say "'[forename]! Hurry! I haven't seen Marcato anywhere--you WHAT? A Mordent?!? Why was one of those hiding beneath the garden? I've never even seen a Mordent before! Was it terrifying?'[paragraph break]'--but I'm getting ahead of myself! I don't know what to do! He may have wandered off into the Field! I hope he hasn't gone too far east--there's a broken bridge out in the East-Southeastern Field. It spans an enormous gorge! Please, [forename], if you could go look for him, I'd do anything in return. I'd go search, too, but I'm not really Mordent-fighting material, and I have to stay here with Minim and Volta. Please find him!'";
	if Plotnum is 3:
		say "'An obelisk? I've heard of some ancient structures up in the Northeastern Drylands. Legend has it that there's a whole city up there, hidden in the cliffs! Marcato used to talk about it all the time. Maybe he's gone looking for it! Please find him, [forename]; it's dangerous to go alone out there!'"

Every turn when the player can see Quaver:
	If Plotnum is 2:
		say "Quaver watches you worriedly, pacing.";
	If Plotnum is 3:
		say "Quaver is restringing his bow. He still looks extremely nervous about his son.";
	If Plotnum is 1:
		say "[one of]Quaver sits quietly on a bench, restringing his elegant bow.[or]Quaver mills absently back and forth, watching the clouds.[or]Quaver inspects the fletching on one of his arrows.[or]Quaver begins whistling a lilting tune. You recognize it as one of your own compositions.[or]Quaver shoots an arrow into the sky.[or]Quaver reaches out and catches an arrow that has just apparently fallen from the sky, a silly grin on his face.[or]Quaver is counting the arrows in his quiver.[at random]".
 
		
Ottava is a woman. Ottava is in Ottava's House. The description of Ottava is "A young woman wearing spectacles that seem too large for her face. Her extremely curly red hair is swept aside from her face into a messy bun, and she's so coated with mutlicolored splashes that she looks as though she's been painting herself as much as the canvas."

Instead of giving the dolce berries to Ottava:
	try talking to Ottava instead.

Carry out talking to Ottava:
	if Plotnum is 1:
		say "[first time]You clear your voice softly, and Ottava looks up with the expression of someone who has just found spiders in her oatmeal. You note that the subject of her painting is a frolicking red fox.[paragraph break]'Hi, [forename]. Sorry, I'm just working really hard on this painting. The fox represents my desire for free expression in a repressive society. What do you want?'[paragraph break]You tell her about your violin.[paragraph break]'Oh, I actually heard old Mr. Crotchet muttering about that! You can probably find him in the garden, searching for fairies in the fountain or something.'[paragraph break][only]'Hey, have you finished that fugue yet? I really want to hear it. I'm working on some music, too, but it's in a much different style. You've probably never heard of it. Conventional music is so mainsteam!'";
	if Plotnum is 2:
		say "'You found it? I'm glad. Hey, did you hear that Marcato is missing? You should talk to Minim across the way!'";
	if Plotnum is 3:
		if the player is not carrying the dolce berries:
			say "'Hey, [forename]! I'll give you this cool vintage bottle I have if you could go find me some dolce berries out in the southwestern forest for my ink. I'm working on a new painting!'".;
		if the player is carrying the dolce berries:
			say "'I see you found them! Thanks for getting them to me. Here's the bottle I promised.'";
			now the player is carrying the empty bottle;
			now Ottava is carrying the dolce berries.


The cat is an animal. The cat is in Quaver's House. The description of the cat is "A small, rotund silver tabby cat with wide green eyes. He mewls at you and paws at your leg. The tag on his collar reads 'Purrkofiev.'"

Carry out talking to the cat:
	say "Purrkofiev looks at you blankly, then mews plaintively again, begging for food."

Minim is a woman. Minim is in Quaver's House. The description of Minim is "Minim is a rather pretty woman with an open, intelligent face. You've known her for years, and she's quickly become another very good friend of yours."

Carry out talking to Minim:
	if Plotnum is 2:
		say "[first time]You catch Minim just as she's about to head out the door. She looks distraught.[paragraph break]'[forename]! Thank goodness you're here! Marc went out to get something from the shops, but I haven't seen him in hours! If he was abducted by monsters, I am going to kick their furry/scaly/skeletal/whatever little behinds!'[paragraph break][only]'But I have to stay here with Volta. Can you go look for him?'";
		stop the action;
	if Plotnum is 3:
		say "'Please, can you find Marcato? I hope he's not out looking for that 'ancient city hidden in the cliff face of the Northeastern Drylands' he always used to talk about--there are so many monsters out there!'";
		stop the action;
	Otherwise:
		say "[first time]'Your violin? Heck, I don't know--FOR THE LAST TIME, MARCATO, STOP PUTTING THE CAT ON THE PIANO. HE DOESN'T LIKE IT AND NEITHER DOES ANYONE ELSE.--sorry, Marc is being a bit...you know how developing musicians can be. Here I thought we'd raise a proper prodigy, like you--'[paragraph break]You open your mouth to protest, but Minim cuts you off.[paragraph break]'No. I'm not hearing the 'but I'm so untalented!' thing again. You're a genius; deal with it. Anyway, I thought he'd take music a bit more...seriously...but, as you can probably hear, his latest work--'Allegro in D Major for Cat and Keyboard'--is about as good as it gets. Anyway, have you tried asking Ottava about it? She's a strange character; she may know.'[paragraph break][only][one of]'Did I tell you about the time Quaver was so scared of a spider in his bedroom that he had me shoot an arrow at it for him? Don't be fooled by his bravado, [forename]. That man is a sissy and we all know it. Gotta love him, though.'[or]Minim shows you her heavy kitchen knife. 'This baby's taken out three Tremolos and a Trill. Back when Quaver and I went camping, it was the only weapon I had. If you look carefully, you can still see the claw-marks.'[or]'My twins are doing fine. Marcato is progressing well in his piano studies, and his sister Volta is starting the oboe.'[paragraph break]Resounding through the house you hear the shrill, nasal voice of an oboe played by a beginner.[or]'I don't know why some people think cooking is boring or domestic. It's AWESOME. It's knives and fire and dead things!'[at random]".
	


The shopkeeper is a man. The shopkeeper is in the Fermata Item Shop. The description of the shopkeeper is "A young man who appears strangely overdressed for his line of work. You're pretty sure his name is Segno." Understand "segno" as the shopkeeper.
Carry out talking to the shopkeeper:
	say "'Hello again, [forename]! What can I get for you today?'".
	
Old Man Crotchet is a man. Old Man Crotchet is in the Garden. The description of Old Man Crotchet is "A crotchety old man wearing a good deal of tweed and a quarter-note pin on his lapel."

Carry out talking to Old Man Crotchet:
	if Plotnum is 1:
		say "'[forename], my boy! I just saw your violin get carried off by a pair of Trills! They took it down the stairwell behind the fountain!'";
	if Plotnum is 2:
		say "'You found your violin--good, maybe that will help. We think Marcato might be lost out in the Field! Go talk to Quaver!'";
	if Plotnum is 3:
		say "'Have you found him yet? He always talked about exploring the Northeastern Drylands, but it's so dangerous up there! Perhaps that's where he's gone?'"


Chapter 9- Buying Things

[also heavy Recipe Book usage here]

Understand the command "buy" as something new. Understand "buy [something not carried]" as purchasing. Purchasing is an action applying to one thing.

Before purchasing something for sale when the price of arcos is 0 arcos:
	say "You have no money. Good luck buying anything." instead.

Before purchasing something when the price of arcos is less than the price of the noun:
	say "I'm afraid you don't have enough money to afford [the noun]." instead.
	
Before purchasing something when the price of the noun is 0 arcos:
	say "You can't buy that!" instead.

Instead of purchasing something:
	decrease the price of arcos by the price of the noun;
	say "You bought [the noun] for [the price of the noun].";
	now the player is carrying the noun;
	now the noun is stealable.

The price of the sharp sword is 500 arcos.

Instead of purchasing the sharp sword:
	if the price of arcos is greater than 499 arcos:
		decrease the price of arcos by 500 arcos;
		now the player is carrying the sharp sword;
		remove the rusted sword from play;
		say "You have the sharp sword! You give the rusted sword to the shopkeeper, because you won't be needing it anymore.";
		decrease Attack by 3;
		increase Attack by 8;
		now the sharp sword is stealable;
		now the price of the sharp sword is 0 arcos;
	otherwise:
		say "You can't afford it!".

Instead of purchasing the sturdy tunic:
	if the price of arcos is greater than 699 arcos:
		decrease the price of arcos by 700 arcos;
		now the player is carrying the sturdy tunic;
		remove the simple tunic from play;
		say "You have the sturdy tunic! You give the simple tunic to the shopkeeper, because you won't be needing it anymore.";
		decrease Defense by 2;
		now the sturdy tunic is stealable;
		now the price of the sturdy tunic is 0 arcos;
	otherwise:
		say "You can't afford it!".
		

The counter is in the Fermata Item Shop. The counter is scenery.

Instead of dropping something nonstealable:
	say "Why would you do that? It's best to keep that safe in your inventory."

The price of a Tonic is 100 arcos.
The price of a Subtonic is 50 arcos.

Chapter 10- Rooms

The Bedroom is a room. "[first time]You wake up to the sound of a half-finished melody winding its way through your groggy mind.[only] Your bedroom is a simple one: light streams in gently through a narrow window on the right, and over the walnut-colored floor are scattered several discarded pages of a fugue you've been working on. Various obscure musical paraphernalia lies strewn about the space--metronomes, mouthpieces, rosin for violin bow-hairs, pitch pipes, reams of paper lined with blank staves, and even a harpsichord in the corner.[paragraph break][first time]You ready yourself for another day of working on your magnum opus, but you immediately realize that your violin, your first and most loved instrument, is missing! You should probably go find that violin.[paragraph break] Type 'help' to get started.[paragraph break][only]There's an elegant closet standing on the far side of the room. There's also a sturdy trunk waiting at the foot of the bed, a desk on the near side, and a harpsichord in the corner. To the east and west are other rooms."

The Kitchen is a room. The Kitchen is east of the Bedroom. "It's a fairly standard kitchen. A low oak table sits in the center of the room, and there's a wood-burning oven against one wall. To the west is your bedroom."

The Den is a room. The Den is west of the Bedroom. "A sparsely-decorated den with a few chairs. A single sign hangs on the west wall. There's a front door on the northern wall that leads outside. Your bedroom is to the east."


Fermata Village is a room. "[first time]You step out into the near-blinding midday sun. You're in Fermata Village, your birthplace and home town. (This isn't surprising, as you've just walked out of the front door of your own home.)[paragraph break][only]A cobblestone path, embraced in lush and verdant grass, gently slopes ahead of you. To the east there is a Plaza; to the west, more houses like your own; to the north, the Garden. The path is lined with a few leafy shrublike plants. To the south is [forename]'s (your) house."  

The Residential Area is a room. The Residential Area is west of Fermata Village. "The houses are cute and orderly, built with white stucco and terra cotta roof tiles. To the south you see a house emblazoned with the symbol of an eighth note. To the north there is a house marked with an '8.' To the east is Fermata Village Main."

Ottava's House is a room. Ottava's house is north of the Residential Area. "As you walk in, you're partially blinded by the walls, which are plastered with moody, sepia-toned paintings of sunsets, autumn woods scenes, and--strangely enough--shoes. Piled about the house are colorful scarves, strange knit hats, and several oddly blocky pairs of thick-lensed spectacles. [if Plotnum is 1]Ottava sits at her studio table, sweeping a murky red-dipped brush over her most recent painting.[end if]". 


The front door is a closed door. The front door is north of the Den and south of Fermata Village. The front door is closed. The description of the front door is "A large, simply-designed door."
Instead of opening the front door:
	if Plotnum is 1:
		if the player is carrying the rusted sword:
			if the player is carrying the wallet:
				if the player is wearing the simple tunic:
					if the player is wearing the leather boots:
						if the player is wearing the pair of wrist-length gloves:
							say "[first time]This is the end of the prelude. Let's begin the next movement.[only]You open the door.";
							now the front door is open;
						otherwise: 
							say "Wait, [forename]! Did you make sure to equip all of your clothing items? If you do't have any more, go check the closet! You have to be prepared for the outdoors!";
					otherwise:
						say "Wait, [forename]! Did you make sure to equip all of your clothing items? If you're missing some, go check the closet! You have to be prepared for the outdoors!";
				otherwise:
					say "Wait, [forename]! Did you make sure to equip all of your clothing items? If you're missing some, go check the closet! You have to be prepared for the outdoors!";
			otherwise:
				say "Wait, [forename]! There are still things in the house that you need to find before you go out looking for your violin! Make sure you checked the closet and the trunk. If you're carrying clothing, make sure you put it on! You need to be prepared for the dangers of the outside world--make sure you have a weapon, too!";
		otherwise:
			say "Wait, [forename]! There are still things in the house that you need to find before you go out looking for your violin! Make sure you checked the closet and the trunk. If you're carrying clothing, make sure you put it on! You need to be prepared for the dangers of the outside world--make sure you have a weapon, too!".

Quaver's House is a room. Quaver's House is south of the Residential Area. "[if Plotnum is 1]This is your good friend Quaver's house. Minim, Quaver's wife, stands at the kitchen counter, slicing up ingredients for the night's dinner. You can hear the sounds of children playing in some other room of the house.[end if][if Plotnum is 2]Minim is wringing her hands, looking tremendously worried. She holds her hefty kitchen knife tightly in one hand, as though getting ready to go out and fight some monsters. The house seems mysteriously absent--and then you remember that Marcato is missing, so there are no cat-on-piano sounds like Marcato usually makes.[end if] The home of Quaver and Minim, and their children Marcato and Volta."

The Plaza is a room. The Plaza is east of Fermata Village. "A wide plaza stretches before you. Usually this area is filled with a throng of people, but it must not be a busy day today. To the north is an item shop. The road leads back west to the main part of the village." In the plaza are five plants. 

The Fermata Item Shop is a room. The Fermata Item Shop is north of the Plaza. "You're surrounded by shelves groaning under the weight of hundreds of bottles. The shopkeeper watches you patiently, waiting for you to make a selection. A big sign at the front of the shop lists the prices of the items." In the Fermata Item Shop are two pots.

The Garden is a room. The Garden is north of Fermata Village. "[if Plotnum is 2][first time]Old Man Crotchet is almost trembling with distress. When he sees you, he starts and says,[paragraph break]'[forename]! We need your help! Minim's son Marcato has been missing for hours! We don't want to assume anything, but...we think he may have been abducted by monsters!'[only][end if] [if the fountain is broken]A once-grand fountain stands in the center of the vibrant garden, but it's been broken for years.[end if][if the fountain is unbroken]The fountain is revived. It spews water up into the sky, filling the air with a fine mist.[end if] Vivid plant life surrounds you. Going farther north will take you out of the village and into the dangerous Field. (Don't go out there without a weapon!) There is a stairwell behind the fountain that leads into the darkness below. Going south will take you back to the main part of the village."



The Southern Field is a room. The Southern Field is north of the Garden. "A long, wide expanse of grass with sparse growths of trees is spread before you. This field is known to have monsters. South of here is Fermata Village. The field extends to the east and west of here."

There are three Trills in the Southern Field.

The South-Southeastern Field is a room. The South-Southeastern Field is east of the Southern Field. "A long, wide expanse of grass with a few trees. Watch out for monsters! You can go to the east and west of here."

There are two Trills in the South-Southeastern Field. There is one Tremolo in the South-Southeastern Field.

The Southeastern Field is a room. The Southeastern Field is east of the South-Southeastern Field. "A long, wide expanse of praire grassland. Monsters flourish here. To the east and west are further sections of prairie."

There are four Tremolos in the Southeastern Field. There is one plant in the Southeastern Field.

The East-Southeastern Field is a room. The East-Southeastern Field is east of the Southeastern Field. "A wide expanse of prairie grasses. A deep gorge lies directly north of here[if the wooden bridge is broken], but it's currently impassable because the bridge is broken.[end if][if the wooden bridge is unbroken], and it may be crossed via the bridge to the north.[end if]. To the west is more prairie."

The Eastern Field is a room. "The grass is beginning to fade as a rockier, harder surface begins to predominate. The soil is red and dusty. There is a bridge to the south, and to the north ahead you can see more dusty terrain."

There are two Mordents in the Eastern Field.

There are three Tremolos in the East-Southeastern Field. There is one Trill in the East-Southeastern Field.

The wooden bridge is an open and unopenable door. The wooden bridge is north of East-Southeastern Field and south of Eastern Field. The wooden bridge can be broken or unbroken. The wooden bridge is broken. The description of the wooden bridge is "[if the wooden bridge is broken]A few shards still hang on to the frame, but this bridge is not even remotely usable.[end if][if the wooden bridge is unbroken]A rickety, but passable, wooden bridge crosses a deep gorge."

Instead of going through the wooden bridge while the wooden bridge is broken:
	say "Not a good plan. That bridge looks just about to fall apart entirely, and below that bridge are about one hundred and fifty meters of gravitational acceleration. So, no. Don't cross the bridge.".
	



Chapter 11-Dungeon 1 and Danse Macabre

The Cave Under the Garden is a room. The Cave Under the Garden is below the Garden. "A damp, dark cave. In front of you, a giant bell stands behind a sign. The cave continues to the east, but it is sectioned off by a cave door."

The cave door is east of the Cave Under the Garden and west of Cave Room 1. The cave door is a door. The cave door is locked.
The bell sign is in the Cave Under the Garden. The bell sign is scenery. The description of the bell sign is "The sign reads: 'Sound will give you passage.'" 
The giant bell is in the Cave Under the Garden. The description of the giant bell is "An enormous golden bell. It probably makes a great deal of sound when struck." The giant bell is attackable. The giant bell is fixed in place.
Carry out attacking the giant bell with a weapon:
	say "The gargantuan instrument releases a low, reverberating clang, and you hear a door click open.";
	now the cave door is unlocked;
	now the cave door is open.
	
Cave Room 1 is a room. "A dark, damp section of cave. You can see another room farther to the east of here." In Cave Room 1 are four Trills. In Cave Room 1 are two elixirs. 

Cave Room 2 is a room. "A slightly damper, slightly darker section of cave. The Cave continues to the north." Cave Room 2 is east of Cave Room 1. In Cave Room 2 are four pots. In Cave Room 2 are two Tremolos. In Cave Room 2 are two plants.

Cave Room 3 is a room. "Another cave section. An ornately-carved door blocks the way to the north. There appears to be a riddle or poem carved into the door, and some kind of informative sign on the wall facing it. You can see a set of large piano keys jutting out from one wall. You recognize them as belonging to a D-major scale." Cave Room 3 is north of Cave Room 2.
The examine devices rule is not listed in any rulebook.
Understand the command "press" as something new. Understand "press [something]" as switching on.
Understand "unpress [something]" as switching off.

In Cave Room 3 is a Chord book. The description of the Chord book is "It reads: 'CHORDS.[paragraph break]The most familiar type of chord is the triad, which consists of three notes. Major triads are formed of a major third and a fifth; minor triads of a minor third and a fifth. The 'root note' is the note from which these intervals are counted, and it decides the key of the chord.[paragraph break]For example, a G minor triad would be G-B flat-D, while a major triad would be G-B-D. An A-minor triad would be A-C-E, and an A-major is A-C sharp-E. A D-minor is D-F-A and a D major is D-F sharp-A. An F-minor is F-A flat-C and an F major is F-A-C.  E minor is E-G-B, and E major is E-G sharp-B.[paragraph break]A first inversion triad starts on the second note of the triad in root position. (So, an inverted G-major triad would be B-D-G, with the G above the B and D, and an inverted E-minor would be G-B-E, with the E above the G and the B.) Second inversions start on the third note. We'll get into diminished and augmented triads in the next chapter.'"

In Cave Room 3 is a Key-sign. Understand "sign" as Key-sign. The printed name of the Key-sign is "sign". The key-sign is fixed in place. The description of the key-sign is "The sign reads: 'A NOTE ON PRESSING AND UNPRESSING.[paragraph break]You will come upon devices in your travels. Sometimes these devices will have buttons or keys. To engage a device, say 'press (device)'--for example, 'press d-key'. To disengage a device, say 'unpress (device)'--for example, 'unpress d-key'."

In Cave Room 3 is the first D-key. The first D-key is fixed in place. The first D-key is a device. The first D-key is switched off.
The description of the first D-key is "A white key on the wall, as though it's been pulled from a piano and stuck there.[if the first D-key is switched on]It's currently pressed down.[end if][if the first D-key is switched off]It's currently not pressed down. It looks like you can press it." 

In Cave Room 3 is an E-key. The E-key is fixed in place. The E-key is a device. The E-key is switched off.
The description of the E-key is "A white key on the wall, as though it's been pulled from a piano and stuck there.[if the E-key is switched on]It's currently pressed down.[end if][if the E-key is switched off]It's currently not pressed down. It looks like you can press it." 

In Cave Room 3 is an F sharp-key. The F sharp-key is fixed in place. The F sharp-key is a device. The F sharp-key is switched off.
The description of the F sharp-key is "A black key on the wall, as though it's been pulled from a piano and stuck there.[if the F sharp-key is switched on]It's currently pressed down.[end if][if the F sharp-key is switched off]It's currently not pressed down. It looks like you can press it." 

In Cave Room 3 is a G-key. The G-key is fixed in place. The G-key is a device. The G-key is switched off.
The description of the G-key is "A white key on the wall, as though it's been pulled from a piano and stuck there.[if the G-key is switched on]It's currently pressed down.[end if][if the G-key is switched off]It's currently not pressed down. It looks like you can press it."

In Cave Room 3 is an A-key. The A-key is fixed in place. The A-key is a device. The A-key is switched off.
The description of the A-key is "A white key on the wall, as though it's been pulled from a piano and stuck there.[if the A-key is switched on]It's currently pressed down.[end if][if the A-key is switched off]It's currently not pressed down. It looks like you can press it." 

In Cave Room 3 is a B-key. The B-key is fixed in place. The B-key is a device. The B-key is switched off.
The description of the B-key is "A white key on the wall, as though it's been pulled from a piano and stuck there.[if the B-key is switched on]It's currently pressed down.[end if][if the B-key is switched off]It's currently not pressed down. It looks like you can press it." 

In Cave Room 3 is a C sharp-key. The C sharp-key is fixed in place. The C sharp-key is a device. The C sharp-key is switched off.
The description of the C sharp-key is "A black key on the wall, as though it's been pulled from a piano and stuck there.[if the C sharp-key is switched on]It's currently pressed down.[end if][if the C sharp-key is switched off]It's currently not pressed down. It looks like you can press it." 

In Cave Room 3 is a second D-key. The second D-key is fixed in place. The second D-key is a device. The second D-key is switched off.
The description of the second D-key is "A white key on the wall, as though it's been pulled from a piano and stuck there. [if the second D-key is switched on]It's currently pressed down.[end if][if the second D-key is switched off]It's currently not pressed down. It looks like you can press it." 
The ornate door is a door. The ornate door is locked. The ornate door is north of Cave Room 3 and south of the Cavern. The description of the ornate door is "A finely-decorated wooden door. A riddle is carved into the wood: 'I hate A major--it's too calm for my tastes.[paragraph break] G major is also too cheery for me.[paragraph break] I'm partial to the first inversions of chords--[paragraph break]but I will play nothing in a minor key. [paragraph break]Play nothing diminished and nothing augmented--[paragraph break]please play me a chord with which I'll be contented. [paragraph break](If you have been stumped by this so-simple rhyme, or if you are not of the musical kind, a quick reading will surely save you some time, if you have no answers in your troubled mind.)'"

Every turn while the player is in Cave Room 3:
	If the F sharp-key is switched on:
		if the A-key is switched on:
			if the second D-key is switched on:
				if the D-key is switched off:
					if the E-key is switched off:
						if the G-key is switched off:
							if the B-key is switched off:
								if the C sharp-key is switched off:
									now the ornate door is unlocked;
									if the ornate door is closed:
										say "The melodious D-major triad echoes pleasantly through the dampness of the cave. You hear the door to the north click open."
								

The Cavern is a room. "[first time]You walk into the great, mouthlike room with trepidation. You can barely see three feet in front of you--the darkness is so thick and claustrophobic that, even in such a great space, you feel trapped and uneasy. The rise and fall of ragged breathing seems to emanate from all around you. As a dark form drags itself forward from the pitch blackness, you suddenly seem to forget how to move--but once you regain your senses, you sprint back towards the door. It's too late, though; the door has locked itself again. You turn around to face the hideously ghastly face, eyeless and skeletal, of a Mordent.[only]There is another room to the north. The Cavern is very dark, but you can make your way around."

There are two elixirs and two plants in the Cavern. In the Cavern is a Mordent.

The Final Cave Room is a room. The Final Cave Room is north of the Cavern. "This room is much lighter than those before it. In front of you is a podium, on which sits a chest."

The chest is in the Final Cave Room. The chest is fixed in place. The chest is an openable and closed container. The description of the chest is "A run-of-the-mill treasure chest, like the ones you see spread far and wide in video games (which is odd, because they're all identical--you have to wonder if all of the dungeon bosses shop at the same treasure chest emporium.)"

In the chest is the violin. Understand "v" as violin. The description of the violin is "Your violin! A four-stringed wooden instrument with a sweet, pure sound. To play it, just type 'play (song) on violin'--for example, 'play Danse Macabre on violin'. You can also say 'play Danse Macabre on v' or even 'p dm v'." The violin is playable.

In the chest is Danse Macabre. The description of Danse Macabre is "The score for a beautiful, haunting symphonic work by composer Camille Saint-SaÃ«ns. You have the urge to play the violin solo from the beginning. According to the story, this is the song that Death plays to raise the dead. The way your violin is glowing--perhaps playing it will have a special effect?" Danse Macabre is a song.

In the Final Cave Room is a vase. The vase can be broken or unbroken. The vase is broken. The description of the vase is "[if the vase is broken]A pile of jagged shards. It appears to have been shattered.[end if][if the vase is unbroken]A pristine vase with a shining glaze and an intricate paint design.[end if]". The vase is fixed in place.



Carry out playing Danse Macabre with the violin:
	if Magic is less than 10:
		say "But you don't have enough magic!" instead;
		stop the action;
	if the player can see something broken:
		now every broken thing in the room is unbroken;
		say "The rousing tritones of the solo make you feel uneasy, as though you're playing to raise the dead! But everything broken responds, resurrecting and becoming like new!";
		decrease Magic by 10;
	otherwise:
		say "You resurrect yourself just a bit with the strange tune.";
		increase Health by MaxHealth divided by 10;
		decrease Magic by 10.
	
		
Check playing a song with the violin:
	if Magic is 0:
		say "But you have no magic points!" instead.
	
		
Carry out taking the violin:
	now Plotnum is 2;
	say "DA-DA-DA-DAAAAAAAAA! Oh, sorry, it just felt natural to have some music at this point. You know, you've defeated the boss, you've gotten the special item...can you tell how unoriginal the game writer is yet? Anyway, you've gotten your beloved instrument back! But it seems different now, as though it's glowing slightly. Perhaps it has special abilities now!".
Instead of dropping the violin:
	say "Goodness, no! You're not losing that instrument again. Let's keep that violin safe in your inventory."
	
Part 2-Where is Freaking Marcato?

Chapter 12- Here there be Harder Monsters

The South-Southwestern Field is a room. The South-Southwestern Field is west of the Southern Field. "The plain begins to blend into a savannah, and then into a forest, as trees begin to appear all around you. You have the feeling that more dangerous creatures will appear here. Perhaps you should turn back and go East instead. To the west, a dark forest looms." 
There is one elixir in the South-Southwestern Field. There are four Tremolos in the South-Southwestern Field.

The Southwestern Field is a room. The Southwestern Field is west of the South-Southwestern Field. "You're certainly in a forest now. Trees swathed in mosses and suspicious-looking fungi surround you. The air practically smells of danger. Going east will take you out of the forest and towards the prairie, while going west will lead you even deeper into the trees."

There are two Mordents in the Southwestern Field. There are two Tremolos in the Southwestern Field.

The West-Southwestern Field is a room. The West-Southwestern Field is west of the Southwestern Field. "It's beginning to get darker as the tree canopy allows less and less sunlight to diffuse through. A soft, eerie hooting sound surrounds you. The forest thins out towards the east and continues to thicken towards the west (but I haven't written that part yet!)"

There is one Caesura in the West-Southwestern Field. There is one Mordent in the West-Southwestern Field.

The East-Northeastern Field is a room. The East-Northeastern Field is north of the Eastern Field. "A red, dusty, canyon-type area. Though there is less vegetation, there are still plenty of monsters around. These dry lands extend to the north and south of here."

There is one Appoggiatura in the East-Northeastern Field. There are two elixirs in the East-Northeastern Field. There is a poison sign in the East-Northeastern Field. The printed name of the poison sign is "sign". Understand "sign" as the poison sign. The description of the poison sign is "It reads:[paragraph break]'POISON.[paragraph break]Warning. Poisonous monsters have been spotted in this area. If you are poisoned, you will continue to deteriorate until you find some way of healing yourself. All potions, including elixirs and both kinds of Tonics, serve as antidotes. Be careful!'[paragraph break](Danse Macabre will work as an antidote, too.)" The poison sign is fixed in place.

The Northeastern Field is a room. The Northeastern Field is north of the East-Northeastern Field. "The land is cracked and whatever plants survive are tough and thorny. You can clearly see bands of sediment in a variety of colors wrapping themselves around towering rock formations. An enormous stone monument of some sort stands before you, and your way is blocked to the north by cliff walls and rocks. Going south will eventually take you back to the prairie."

Chapter 13- Getting Into the Rock Temple

The obelisk is in the Northeastern Field. The obelisk is fixed in place. The description of the obelisk is "A towering, tapering structure made of the same dusty stone as the surrounding land--it looks as though it was carved out of one of the rock formations. [paragraph break] You notice a deep bowl jutting out from one face of the monument. There appears to be a small inscription above it."

The inscription is in the Northeastern Field. The inscription is scenery. The description of the inscription is "It reads:[paragraph break]'FILL ME WITH WHAT THE LAND LACKS.'[first time][paragraph break] You look around at the dusty terrain. 'What the land lacks?' What a simple riddle, you think. The answer, of course, is obvious.[only]"


Instead of inserting something into the bottle:
	say "Its narrow neck will not allow anything other than liquids to enter.".

The empty bottle is in the Storage Room. The empty bottle is a container. The carrying capacity of the empty bottle is 1.  The description of the bottle is "A cool bottle you got from Ottava. It's currently empty."

The bowl is in the Northeastern Field. The bowl is scenery. The bowl is a container. The carrying capacity of the bowl is 1. The description of the bowl is "A deep bowl-like depression jutting out from one side of the obelisk."

The Rock Wall is a door. The Rock Wall is north of the Northeastern Field and south of the Rock Temple Entrance. The Rock Wall is locked. The Rock Wall is scenery.

The Rock Temple Entrance is a room. "A vast building, likely painstakingly carved over generations into the cliff face, looms over you to the north. Its many columns and triangular roofs bring to mind the great architecture of Petra." In the Rock Temple Entrance are six plants. In the Rock Temple Entrance are four pots.

Instead of opening the Rock Wall:
	if the Rock Wall is locked:
		say "You pound on the pile of boulders, but it does not give, probably because you are a tiny human and it is a thousand-year-old pile of two-ton boulders made of some of the harder rocks and minerals known to geology.";
		stop the action;
	if the Rock Wall is unlocked:
		now the Rock Wall is open.
	

Carry out inserting something into the bowl:
	if the noun is the bottle of water:
		say "You hear a grinding noise, and a boulder to the north slides aside, revealing a hidden entrance.  The water in the bowl disappears!";
		now the Rock Wall is unlocked;
		now the Rock Wall is open;
		remove the noun from play;
	otherwise:
		say "Nothing happened."
		
Instead of inserting something into the Fountain:
	say "That would be silly."

The Fountain is a container. The Fountain is scenery.

In the Storage Room is the bottle of water. Understand "water" as the bottle of water. The description of the bottle of water is "The bottle Ottava gave you. It's full of water from the fountain."

[the "Storage Room" is how I cheat.]

Carry out examining the Fountain:
	if the Fountain is unbroken:
		if the player is carrying the empty bottle:
			say "You decide it would be a good plan to have some water with you. You fill up the bottle you got from Ottava with water from the fountain.";
			now the player is carrying the bottle of water;
			remove the empty bottle from play.

Chapter 14- The Rock Temple

The Rock Temple Door is a door. The description of the Rock Temple Door is "An imposing door that brings to mind the awesome power of the earth. It looks as though it were crushed into shape by the staggering weight of the crust of the earth itself, thousands of meters below the surface." The Rock Temple Door is north of the Rock Temple Entrance and south of the Rock Temple Room 1. The Rock Temple Door is closed.

The Rock Temple Room 1 is a room. "[first time]Your boots click softly on the floor as they transition from the soft, silty earth of the Drylands to the rough-hewn and time-smoothed floor of the temple. Silence borders your every breath. You've entered a sacred place of the earth.[only][paragraph break]Carved by hundreds, if not thousands, of ancient artisan hands, the temple flows around you in a distinctly un-rock-like manner, culminating in a grand set of steps leading to a curiously humble altar. Going south will take you out of the temple."

The altar is in the Rock Temple Room 1. The description of the altar is "For all the masterful sculpture in this place, the altar seems strangely simple. It looks just like a natural boulder from the Drylands, but with the top sliced off to make a smooth, flat surface." The altar is fixed in place.

On the altar is a note. The description of the note is "You recognize the paper as coming from Ottava's stationery shop in Fermata Village. The note reads, in the handwriting of a six- or perhaps eight-year-old child:[paragraph break]'TO WHO IT MIGHT CONCERN.[paragraph break]Ive watched enough plays to know were this is going. I wanted to explore the ruins of the tempel, but I think I will probably be in danger soon. If you are reading this and you are a freind, then I am in the bottom floor in the furthest room, and you should come find me so I dont get hurt. If you are reading this and you are a monster, then dont read this and I am not here. If you are reading this and you are Mommy, then I'm sorry for using youre good paper for this note but I really wanted to find the ruins Ive been reading about in books and maybe if I find something cool than I can get better at music.[paragraph break]--Marcato Assai'"

After examining the note:
	say "[paragraph break]And that's all I have for now! I will write the Rock Temple soon. Check back for updates!";
	end the story.