A Modest Proposal by Tully Hansen

A Modest Proposal

Played 6,450 times
View game source (spoilers!)
Download the .z8 file
Source Code

"A MODEST PROPOSAL" by Tully Hansen

Use no scoring.

When play begins:
	say "[italic type]Dear Craig,

I'm really looking forward to catching up. It'll be[line break]a good chance for you to [bold type]>ask about[roman type][italic type]â€¦ well, any-[line break]thing you like, really, as well as have a [bold type]>look at[roman type][italic type][line break]what I've been reading, working on, and thinking[line break]about. You'll find my address overleaf â€“ when you[line break]get there, just [bold type]>knock[roman type][italic type]. See you soon!

Tully.[roman type][line break]";
	move the index card to the player;
    now left hand status line is "Stuck?"; 
    now right hand status line is "[bold type]>knock[roman type]".

[Is there a way to test for a property within a 'say' statement?]

When play ends:
	if the player has the blue coffee cup:
		say "He takes the cup from your hands and sets it down on the desk.[run paragraph on]";
	say "[paragraph break]'Sorry, I'm beat. What's say we call it a day?'[paragraph break]You agree, and Tully shows you back down the hall to the front door, but before you can slip away he grabs your hand once more.[paragraph break]'Thanks again for coming round,' he says, pumping your arm up and down. 'It's really helped clarify a few things. I hope it's given you a better idea of how the project will work.'[paragraph break]You nod, extricate yourself from his grip, and set off, waving goodbye as you walk down the street.".

Section 1 - The Front Garden

[Could distinguish the two as separate scenes instead.]

The Front Garden is a room. "You're standing by the front door of a slightly shabby weatherboard house, the purple paint of its facade gone flaky in places. The lawn is similarly neglected, growing wild with mint and tall, spiky weeds.[first time] You double-check the address on the back of the card you were given â€“ yep, definitely the right place.[paragraph break]Even from here, the music blasting from inside is almost deafening.[only]".

The front door is east of the Front Garden. It is a locked door and scenery. Some weeds, the house, the lawn and the mint are scenery in the Front Garden.

The description of the house is "It's a narrow weatherboard, somewhere out in the western suburbs of Melbourne. A couple of boards near ground level are showing signs of rot." Understand "board/weatherboard/boards/rotten/rot/rotting" as the house.

The description of the weeds is "There are clumps of them all over, long, slender stalks topped with weird three-bladed blooms. Their shape reminds you of wind turbines.". Understand "weed/weeds/spiky/wind/turbines" as the weeds. 

The description of the mint is "What the weeds have missed, the mint has colonised completely, sprawling all over what might once have been a front lawn. It smells pretty good, though."

The description of the lawn is "There may have been grass growing in this patch of earth once upon a time, but there certainly not now â€“ the mint and the weeds have seen to that.". Understand "garden/yard" as the lawn.

The description of the front door is "The front door is closed. At some point someone decided to paint it a fetching maroon, which clashes mightily with the pale purple of the house itself."

Instead of taking the weeds, say "You're not here to do the gardening."
Instead of taking the mint, say "You break off a leaf and roll it in your fingertips, releasing the scent more strongly. Mmmm, minty!"

Before smelling:
	if the player is in the front garden:
		say "The air is heavy with the smell of mint.";
		stop the action.

Every turn:
	if the front door is unknocked:
		say "[one of]The music from inside continues to play.[or]Music continues to blare from inside the house.[or]Sounds like whoever's home [italic type]really[roman type] likes They Might Be Giants.[then at random]";

Before listening:
	if the front door is unknocked:
		say "The lyrics seem to be something about[one of] a doctor worm.[or]â€¦ Constantinople?[or] spines.[sticky random]";
		stop the action;
	else if the study contains the player:
		say "You hear the soft tick of the clock on the wall.";
		stop the action.

A door can be knocked or unknocked. A door is usually unknocked.

After knocking:
	now the front door is knocked;
	now right hand status line is "[bold type]>wait[roman type]";
	Tully arrives in 3 turns from now;

Every turn when the front door is knocked and the player is in the garden and Tully is not in the garden:
	say "[one of]It seems to do the trick: the music cuts out abruptly.[or]From inside the house you can make out the sound of footsteps approaching.[or]You hear a jangling of keys on the other side of the door.[or]The front door opens. Standing in the doorway is a young man, clean-shaven, wearing [a list of things worn by Tully]. You'd say he was in his early twenties, but you'd be off by about four years.[stopping]"

At the time when Tully arrives:
	say "'Craig, hi!' says Tully, grabbing your hand and shaking it enthusiastically. 'Sorry, have you been out here long?'[paragraph break]Without waiting for an answer, he ushers you inside, down a dim corridor lined with shoes, bags and boxes.";
	now the player is in the study;
	now right hand status line is "[bold type]>look at stuff[roman type]";
	Tully gets coffee in 5 turns from now;
	now the blue coffee cup is not gotted.

Section 2 - The Study

Study is a room. "[one of]You're shown into a study [or]The study is [stopping]crammed full of books and papers piled up all over the place. Up against one wall is a desk, where a laptop lies half-hidden beneath more mounds of paper. The wall itself is almost completely covered in yellow Post-It notes, haphazardly arranged around a piece of paper on which the word IDEAS is written in permanent marker. There is a white plastic clock on the opposite wall.[first time][paragraph break]Tully sweeps a stack of manila folders from a small plastic stool and motions for you to sit. 'Wait here a tic, I'll grab us some coffee. Feel free to look around.'[paragraph break]He bustles back out the door and disappears into the house.[only]"

The stool, the books, the clock, the desk, the wall and the manila folders are scenery in the study. The laptop and the piles of paper are scenery on the desk. The stool is an enterable supporter.

The description of the wall is "The cheery yellow Post-Its radiate outwards from the paper that says IDEAS. Turns out that each Post-It has writing on it, some whole sentences, most just a word or two. They're so scribbled and overlapped it's hard to make sense of more than a handful: library, Borges, Portugal, RMIT, Babel, IF, Violet, Zarfâ€¦ a motley vocabulary.". Understand "wall/postit/postits/post-it/post-its/ideas/piece/note/notes/sticky/yellow" as the wall.

The description of the manila folders is "These oversize cream-coloured oblongs are familiar from offices the world over. A quick flick through reveals nothing of interest.". Understand "folder/folders/manila" as the manila folders.

The description of the clock is "You regard the clock on the wall. The clock ticks back at you softly.[first time] You catch yourself wondering, how would I market this as a product?[only]"

The description of the desk is "The finest writing surface money can buyâ€¦ from IKEA.". Understand "table/ikea" as the desk.

The description of the stool is "The stool is made of metal and black plastic[first time], and strikes you as a little rickety. Still, you'd probably get away with sitting on it[only].". Understand "chair/plastic" as the stool.

The description of the laptop is "The logo in the lid tells you it's a Mac of some description, but as it's currently closed you're not game to go poking around on it.". Understand "laptop/computer/mac/macbook" as the laptop.

The description of the books is "There are books everywhere, stacked in small piles or splayed open face-down on any available surface. There are novels, poetry anthologies, essay collections, weighty academic tomesâ€¦ judging by the barcode stickers and Dewey decimal numbers, many of these are from the library.[first time] You wonder if Tully has read them all, or is planning to.[only]". Understand "book/library/novels/anthologies/poetry/essay/collections/tomes" as the books.

The description of the piles of paper is "Great swathes of paper - photocopies and printouts, mostly - lie drifted about the study like snow: on the floor, the desk, everywhere.[first time] The paperless office this ain't.[only]". Understand "pile/piles/paper/papers/drifts" as the piles of paper. 

An object can be gotted. An object is usually not gotted.

An object can be empty or filled.

At the time when Tully gets coffee:
	say "Tully reappears at the door with two mugs, one of which he hands you. He perches on a second stool, hitherto hidden under a particularly dense pile. As you take a sip, you realise you weren't asked how you have your coffee, but somehow it's exactly right. When you bring this up, he looks sheepish.[paragraph break]'Sorry â€“Â not really sure how to program something like that yet, so I just guessed.' He brightens. 'I hope you got a good look aroundâ€¦ find anything you wanted to ask me about? Or did you just want to ask me about my ideas?'";
	now the blue coffee cup is gotted;
	now right hand status line is "[bold type]>ask aboutâ€¦[roman type]";
	now Tully is in the study;
	now Tully is holding the green coffee cup;
	now the player is holding the blue coffee cup;
	Tully gets antsy in 7 turns from now;
	Tully shows you out in 14 turns from now.

At the time when Tully gets antsy:
	now the green coffee cup is empty.
	
every turn when the green coffee cup is empty:
	say "[one of]Tully glances up at the clock on the wall.[or][run paragraph on][or]Tully drums his fingers against his thigh absentmindedly.[or][run paragraph on][or]Tully stifles a yawn, poorly.[or]All of a sudden Tully stands and walks towards you. [run paragraph on][stopping]".
	
At the time when Tully shows you out:
	end the story finally saying "Thanks for visiting!".
	
Instead of drinking the blue coffee cup, say "You take another sip of coffee. [first time][run paragraph on]It's delicious.[only][paragraph break]"

Instead of taking when the player is in the study, say "Better leave that alone."

Instead of drinking the blue coffee cup more than five times:
	say "[one of]You raise the cup to your lips, only to realise it is empty.[or]The empty blue cup fills you with melancholy.[stopping]";
	now the blue coffee cup is empty.

Every turn when the blue coffee cup is gotted and the green coffee cup is not empty:
	if a random chance of 1 in 3 succeeds:
		say "Tully takes a sip of his coffee.".
	
Every turn when the blue coffee cup is not gotted and the player is in the study:
	say "[one of]You can hear a tap running.[or][run paragraph on][or][run paragraph on][or]From the rear of the house comes the perky burble of a stovetop espresso maker.[or]You can smell fresh coffee.[or][run paragraph on][stopping]"

Tully is a man. Understand "man" and "boy" and "tul" and "t" as Tully. The description of Tully is "Tully is a young man with brown hair and glasses. He wears [a list of things worn by Tully][if Tully carries something] and is carrying [a list of things carried by Tully][end if].". The Nick Cave t-shirt is worn by Tully. Understand "tee" and "teeshirt" and "tshirt" and "tee-shirt" and "t-shirt" and "nick" and "cave" as the Nick Cave t-shirt. The description is "The black t-shirt has a line from Cave's [italic type]Ship Song[roman type] printed in ragged white letters. It's a bit big for him, really." The pair of glasses are worn by Tully. Understand "pair" and "glasses" and "specs" and "spectacles" as the pair of glasses. The description is "They're a pair of narrow tortoise-shell glasses. The plastic looks a little flimsy."

Section 3 - Conversation

After asking Tully about "ideas", say "'[first time]I've got a few loose ideas. They're kinda random. [only][one of]What if you played the conscience or consciousness of a lesser creature, and your commands were less instructions thanâ€¦ suggestions? The game could play out in the first personâ€¦'[or]It's funny, you know, whenever I think of mapping out a location, I imagine the main entrance as south, and in as north, or upâ€¦'[or]Did you check out my Post-it notes? I've kind of been using them to jot down themes or concepts as they occur.'[run paragraph on][or]Aw, man, I can't think of anything more cool to sayâ€¦'[or]I'm done.'[run paragraph on][stopping][run paragraph on] Tully says.[line break][line break]"

After asking Tully about "library", say "'I had an idea to model the RMIT library, because it's a known physical space. But it's not super-interesting to me now. Though in brainstorming I did come up with the idea of a story or game with the player taking on library-consciousness, being the buildingâ€¦ that could still be a goer. What does a library want? How does a library [italic type]feel?[roman type]'[line break]".

After asking Tully about "Borges", say "'I've had his infinite library in my headâ€¦ the Library of Babel! I think. Anyway, something about modelling an unreal literary space through interactive fiction appeals to meâ€¦'[paragraph break]Tully blushes.[paragraph break]'I guess I'm a little weird that way.'".

After asking Tully about "Portugal", say "Tully regards you with curiousity. 'Portugal?'".

After asking Tully about "Zarf", say "'Zarf is Andrew Plotkin, who's something of an [italic type]Ã©minence grise[roman type] in the interactive fiction worldâ€¦ a legend. He used Kickstarter to fund development on his latest text adventure project. Besides, there's a game called [italic type]Being Andrew Plotkin[roman type], based off of [italic type]Being John Malkovich[roman type]. How cool is that?'[paragraph break]'He's a real advocate for awareness of the medium, too. You should google his interactive fiction postcard, which has everything the beginner needs to know.'".

After asking Tully about "Violet", say "'I'd been reading about interactive fiction for years, but I'd never really played any. Or read any. Which is the more appropriate verb, I wonder? But I started with Jeremy Freese's [italic type]Violet[roman type], which is about procrastinating on an academic assignment. Pretty sure I played it in order to procrastinate on an assignment. But it's brilliant, hilarious. Won the IF - that is, interactive fiction - competition the year it came out.'[paragraph break]A thought seems to strike him.[paragraph break]'It'd be great to put this project into the comp, maybe. The timing's right. Could be a good incentive?' In lieu of a beard, Tully strokes his clean-shaven chin.".

After asking Tully about "Babel", say "'That old biblical myth of the tower of all tonguesâ€¦ or was it further back than that? Sumerian? I don't know. I guess I picked up most of what little I know out of Neal Stephenson's [italic type]Snow Crash[roman type].'".

After asking Tully about "RMIT", say "Tully pauses for a moment.[paragraph break]'On the wholeâ€¦ it's been a good school, a good course. This major project's a great idea. I guess my worry comes from the scope of itâ€¦ how do I keep from trying to do too much with it?'[paragraph break]He laughs. 'I guess maybe I can't.'".

Instead of asking about "RMIT" more than once, say "[one of]Tully looks a little bored.'You already asked me that.'[or]'I kind of told you everything I had to say on that topic.'[or]Tully grins.[paragraph break]'Search me. Nothing more I can say about that.'[then at random]".

Instead of asking about "Portugal" more than once, say "Tully shakes his head.[paragraph break]'Again with the Portugal!'".

Instead of asking about "babel" more than once, say "[one of]Tully looks a little bored.'You already asked me that.'[or]'I kind of told you everything I had to say on that topic.'[or]Tully grins.[paragraph break]'Search me. Nothing more I can say about that.'[then at random]".

Instead of asking about "library" more than once, say "[one of]Tully looks a little bored.'You already asked me that.'[or]'I kind of told you everything I had to say on that topic.'[or]Tully grins.[paragraph break]'Search me. Nothing more I can say about that.'[then at random]".

Instead of asking about "Borges" more than once, say "[one of]Tully looks a little bored.'You already asked me that.'[or]'I kind of told you everything I had to say on that topic.'[or]Tully grins.[paragraph break]'Search me. Nothing more I can say about that.'[then at random]".

Instead of asking about "Zarf" more than once, say "[one of]Tully looks a little bored.'You already asked me that.'[or]'I kind of told you everything I had to say on that topic.'[or]Tully grins.[paragraph break]'Search me. Nothing more I can say about that.'[then at random]".

Instead of asking about "Violet" more than once, say "[one of]Tully looks a little bored.'You already asked me that.'[or]'I kind of told you everything I had to say on that topic.'[or]Tully grins.[paragraph break]'Search me. Nothing more I can say about that.'[then at random]".

Section 4 - Random Objects

The green coffee cup and the blue coffee cup are objects. Understand "blue" and "coffee" and "cup" and "cuppa" and "mug" as the blue coffee cup. The blue coffee cup is filled. The green coffee cup is filled.
The description of the blue coffee cup is "It's a cup designed for the retention of coffee in a pleasant blue hue.".
The description of the green coffee cup is "It's a cup designed for the retention of coffee in a keen and mean green hue.".

The index card is an object. The description of the card is "On one side of a 3x5 index card someone has hand-written an address in red pen; on the other is the following message:[line break][line break][italic type]Dear Craig,

I'm really looking forward to catching up. It'll be[line break]a good chance for you to [bold type]>ask about[roman type][italic type]â€¦ well, any-[line break]thing you like, really, as well as have a [bold type]>look at[roman type][italic type][line break]what I've been reading, working on, and thinking[line break]about. You'll find my address overleaf â€“ when you[line break]get there, just [bold type]>knock[roman type][italic type]. See you soon!

Tully.[roman type]"

Section 4 - Additional Rules

Understand "look at stuff" as a mistake ("There's plenty of stuff to look at. You might try being a little more specific.").

Understand "look around" as a mistake ("What in particular did you want to look at? Or did you just want to look?").

Understand "ask about stuff" as a mistake ("'How's stuff? Stuff is great.' Tully laughs. 'Would you care to be a little more specific?'").

Understand "ask about" as a mistake ("Tully looks at you expectantly. 'Yes? What did you want to ask about?'").

Knocking on is an action applying to one visible object. Understand "knock [something]" or "knock on [something]" as knocking on.
Check knocking on:
	if the noun is not the front door, say "Not really something you're inclined to knock on." instead;
	try knocking instead;

Knocking is an action applying to nothing. Understand "knock" as knocking. 
Check knocking:
	if the player is in the study, say "There's nothing you'd want to knock on." instead;
	if the front door is knocked, say "You knock on the door again, just to get your point across." instead.
Carry out knocking: 
    say "You rap your knuckles hard against the front door, hoping to be heard above the din."

[Version 2 of Assumed Conversers by Michael Martin begins here. A minimal extension that makes the NPC optional in ASK NPC ABOUT TOPIC and TELL NPC ABOUT TOPIC commands.]

Use authorial modesty.

The default converser is a person that varies. The default converser is yourself.
Asking generically is an action applying to one topic. Understand "ask about [text]" or "a [text]" as asking generically.
Telling generically is an action with past participle told, applying to one topic. Understand "tell about [text]" and "t [text]" as telling generically. 

Check asking generically (This is the check for only one sensible converser rule):
change the default converser to the player;
if the number of persons enclosed by the location is two begin;
repeat with candidate running through the persons enclosed by the location begin;
if the candidate is not the player, change the default converser to the candidate;
end repeat;
end if.

Check asking generically (This is the check for sensible converser rule):
if the default converser is player, say "[bracket]I can't figure out who you want to talk to.[close bracket][paragraph break]" instead;
if the default converser is not visible, say "There's nobody here to talk to." instead.

Check asking generically (This is the convert to asking it about rule):
    try asking the default converser about instead.

The check for only one sensible converser rule is listed in the check telling generically rules.
The check for sensible converser rule is listed in the check telling generically rules.
Check telling generically (this is the convert to telling it about rule):
    try telling the default converser about instead.

The convert to asking it about rule is listed last in the check asking generically rules.
The convert to telling it about rule is listed last in the check telling generically rules.

Before asking or telling or answering (this is the log latest converser rule):
change the default converser to the noun.

[Assumed Conversers ends here.]