Sexy Space Adventure 3000 by EJ

Sexy Space Adventure 3000

by EJ
Played 4,928 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Sexy Space Opera 3000" by "E. Joyce"

Include Player Experience Upgrade by Aaron Reed.

Include Plurality by Emily Short.

Include Quip-Based Conversation by Michael Martin.

Use no scoring.

Chapter - The PC

The description of the player is "You are [the player's full name], a good-looking space commander [if the player is masculine]dude[otherwise if the player is feminine]lady[otherwise]of indeterminate gender[end if] wearing spiffy space armor. You are [if the player is nice]a pretty swell guy.[otherwise if the player is mean]kind of an asshole.[otherwise]neither particularly nice nor particularly douchey.[end if]"

The player carries no-tea. The printed name of no-tea is "no tea". Understand "no tea" as no-tea. The description of no-tea is "A profound and distressing lack of tea.". Instead of doing anything other than examining when the noun is the no-tea, say "You can't, wise guy. It's all conceptual and stuff.".

The cup of tea is a thing. The description of the cup of tea is "A cup of tea that you got from Nolan. It smells delicious." The cup of tea can be drunk. 

Instead of drinking the cup of tea:
	say "You gulp down the tea.";
	remove the cup of tea from play;
	now the player carries the no-tea;
	rule succeeds.

Chapter - When Play Begins

When play begins: 
    say "{Please note: this is not by any means a real finished game. This is a practice/proof-of-concept for a bigger project that I am working on. I put it here to show to some specific people, and if you are not them, you probably don't want to play this.} Welcome to the starship Placeholder, Space Marine! Before we begin, we need to know a few things about you.".
    
To decide whether choosing gender:
	if the player is in Choose Your Gender, yes;
	no.

Rule for printing the banner text when choosing gender: do nothing.

Gender is a kind of value. The genders are masculine, feminine, other, and mysterious. Understand "M" as masculine. Understand "F" as feminine.  Understand "P" as other.

A person has a gender. The gender of the player is mysterious. 

There is a room called Choose Your Gender. "Type the initial letter of your choice:[paragraph break][bold type]{F}[roman type]emale[line break][bold type]{M}[roman type]ale[line break][bold type]{P}[roman type]lease, binary concepts of gender are so 21st century."

After reading a command when the gender of the player is mysterious: 
	if the player's command includes "[gender]": 
		now the gender of the player is the gender understood; 
		if the gender of the player is masculine, now the player is male; 
		if the gender of the player is feminine, now the player is female;
		if the gender of the player is other, now the player is neuter;
		say "[line break]All right then, moving on..."; 
		move the player to Choose Your Name; 
		reject the player's command;
	otherwise:
		say "Come on, just play along here, won't you? Type F, M, or P.";
		reject the player's command. 

Rule for constructing the status line when choosing gender: do nothing. 

There is a room called Choose Your Name. "Type in a first and last name."

The player's forename is an indexed text that varies. The player's full name is an indexed text that varies.  The player's surname is an indexed text that varies.

To decide whether collecting names: 
	if the player is in Choose Your Name, yes;
	no.

After reading a command when collecting names: 
	if the number of words in the player's command is greater than 2: 
		say "[line break]You're a Space Marine. You keep it simple. You only need two names."; 
		reject the player's command;
	if the number of words in the player's command is 1:
		say "[line break]You're a Space Marine, not a pop star. Two names, soldier: first and last.";
		reject the player's command;
	now the player's full name is "[the player's command in title case]"; 
	now the player's forename is word number 1 in the player's full name; 
	now the player's surname is word number 2 in the player's full name;
	say "Welcome aboard, Commander [player's surname]!";
	say "[banner text]"; 
	move the player to Lower Deck Corridor;
	reject the player's command. 

Rule for printing the banner text when collecting names: do nothing. 

Rule for constructing the status line when collecting names: do nothing. 

Chapter - Layout

The Lower Deck Corridor is a room. "This is a hallway on the lower deck of the ship. You can go south to the engine room, north to the sleeping quarters, east to the Diplomacy Chamber, or west to the cargo bay from here."

South of the Lower Deck Corridor is the Engine Room. The description of the engine room is "This is a room full of machines which are not really necessary for running a sleek modern spaceship such as the one you command, but are impressive-looking nonetheless, with lots of blinky lights and unlabelled buttons and readout panels.[paragraph break]The door back to the corridor is to the north."

West of the Lower Deck Corridor is the Cargo Bay. The description of the Cargo Bay is "This room is full of boxes. You're not really sure what's in them, since this isn't a transport vessel anyway.[paragraph break]The door back to the corridor is to the east."

The boxes are plural-named scenery in the Cargo Bay. The description of the boxes is "Very mysterious."

North of the Lower Deck Corridor is the Sleeping Quarters. The description of the sleeping quarters is "The walls of this room are lined with futuristic space bunkbeds. You can tell they're futuristic space bunkbeds and not the regular kind because they're all white and blue and silver and shiny and don't have sharp corners.[paragraph break]The door back to the corridor is to the south."

The bunkbeds are plural-named scenery in the Cargo Bay. The description of the bunkbeds is "They look very comfortable. Futuristic space comfortable."

East of the Lower Deck Corridor is the Diplomacy Chamber. The description of the Diplomacy Chamber is "This room, in contrast to the shiny slick metal-and-plastic aesthetic of the rest of the ship, is rather... plushy. The deep red carpet is so thick that small animals could probably get lost in it, and the walls are covered by richly-embroidered wine-colored draperies. A large bed dominates the middle of the room.[paragraph break]The door back to the corridor is to the west."

The bed is scenery in the Diplomacy Chamber. The description of the bed is "It's big enough for about ten people to sleep in at once and adorned with more pillows than even those ten people could possibly need. It has the kind of mattress that you could sink into and never get up again."

Chapter - People

Section - Anneli

Anneli is a woman in the Engine Room. "Anneli is here, [one of]humming to herself as she pushes buttons and turns dials in an important-looking manner[or]cheerfully tinkering with the innards of some machine[or]drumming her talons absently on the table as she frowns at some technical diagrams, deep in thought.[at random]".

The description of Anneli is "Anneli, the ship's engineer, is a small, energetic woman who never seems to quite stand still. Her greenish-brown scales are smudged with dirt, as is the old blue jumpsuit which hangs loosely on her slender form, but her slit-pupilled orange eyes gleam excitedly."

The litany of Anneli is the Table of Anneli Comments.

The greeting of Anneli is a-hello.

Before going north from the Engine Room:
	if the affection of Anneli is greater than two:
		say "Anneli waves cheerily. 'Come back soon!'";
	otherwise:
		say "'Goodbye,' Anneli says, turning back to her machines.".

Table of Quip Texts (continued)
quip			quiptext
a-work			"'Yeah, everything's great! I'm just working on some upgrades.' She gestures towards some machinery with the spanner she's holding, as if by way of an explanation.'"
a-self			"'Oh, I'm fine! Keeping myself occupied by doing some upgrades on the ship.'"
a-upgrades		"'Well, either they'll make the ship run faster and more fuel-efficiently, or they'll make the engine explode and then we'll all die horribly in the vacuum of space,' she says, her cheerful tone never faltering. Seeing the look on your face, she hastily adds, 'Kidding! I'm kidding.'"
a-no-upgrade	"'As you wish, Commander,' she says, voice level. 'It is your ship, after all.' She turns and stalks off to the other side of the engine room to inspect some gauges very, very carefully."
a-no-upgrade2	"'As you wish, Commander. It is your ship, after all.' She turns and stalks off to the other side of the engine room to inspect some gauges very, very carefully."
a-yay-you		"'Oh, good! I'm so glad you approve, Commander.'"
a-well-yes		"Her crest droops a bit sheepishly. 'Well... yes. But it's so much nicer when I can do things in a legitimate and officially-approved manner! It saves all the arguments, the recriminations, the completely accidental explosions, the having to find another job...'"
a-no-regret		"'You really mean it? Oh, you won't regret this, Commander!' She grabs her toolbox and gets back to work with renewed vigor."
a-carry-on		"She gives you a jaunty salute. 'I will, Commander!'"
a-goodbye		"'Talk to you later, Commander!'"
a-hello			"'Hey, how's it goin[']?' Anneli grins widely, in a way that makes you sort of worried."

Table of Anneli Comments
prompt															response		enabled
"Everything running smoothly?"									a-work			1
"How are you doing?"												a-self			1
"Upgrades? What do they do?"										a-upgrades		0
"Hey, quit messing with my ship. If it ain't broke, don't fix it."			a-no-upgrade	0
"Sounds good to me!"												a-yay-you		0
"Uh... maybe we had better not, then."								a-no-upgrade2	0
"You'd do it even if I didn't, wouldn't you?"							a-well-yes		0
"You know way more about this than I do, so just do your thing, man."	a-no-regret		0
"... I see. Well, uh, carry on!"										a-carry-on		0
"I'm done with this conversation."									a-goodbye		1

After quipping when the current quip is a-work:
	disable the a-self quip;
	disable the a-work quip;
	enable the a-upgrades quip;
	enable the a-no-upgrade quip.
	
After quipping when the current quip is a-self:
	increase the affection of Anneli by one;
	increase the niceness of the player by one;
	disable the a-self quip;
	disable the a-work quip;
	enable the a-upgrades quip;
	enable the a-no-upgrade quip.

After quipping when the current quip is a-upgrades:
	increase the affection of Anneli by one;
	increase the niceness of the player by one;
	disable the a-upgrades quip;
	disable the a-no-upgrade quip;
	enable the a-yay-you quip;
	enable the a-no-upgrade2 quip.
	
After quipping when the current quip is a-no-upgrade:
	decrease the affection of Anneli by 1;
	decrease the niceness of the player by 1;
	now Anneli is conversed;
	terminate the conversation.

After quipping when the current quip is a-no-upgrade2:
	decrease the affection of Anneli by 1;
	decrease the niceness of the player by 1;
	now Anneli is conversed;
	terminate the conversation.

After quipping when the current quip is a-yay-you:
	increase the affection of Anneli by one;
	increase the niceness of the player by one;
	disable the a-yay-you quip;
	disable the a-no-upgrade2 quip;
	enable the a-well-yes quip;
	enable the a-no-regret quip.
	
After quipping when the current quip is a-well-yes:
	disable the a-well-yes quip;
	disable the a-no-regret quip;
	enable the a-carry-on quip.

After quipping when the current quip is a-no-regret:
	increase the affection of Anneli by one;
	increase the niceness of the player by one;
	now Anneli is conversed;
	terminate the conversation.
	
After quipping when the current quip is a-carry-on:
	now Anneli is conversed;
	terminate the conversation.
	
After quipping when the current quip is a-goodbye:
	terminate the conversation.
	
Section - Rodriguez

Rodriguez is a woman in the cargo bay. "Rodriguez is here, [one of]rifling idly through one of the boxes.[or]practicing her rakish grin on no one in particular.[or]cleaning her blaster gun.[at random]". The description of Rodriguez is "The tall, dark, and handsome Peaches Rodriguez is your ship's Official Space Pirate. Every crew has to have one now--it's regulations. She is dressed rather monochromatically in black slacks, a black vest, a black gun holster, and a white shirt (the top few buttons of which are unbuttoned in a carefully careless manner). Her glossy black hair falls in waves to her shoulders, and she sports a wicked devil-may-care grin."

Understand "Peaches" as Rodriguez.

The litany of Rodriguez is the Table of Rodriguez Comments.

The greeting of Rodriguez is r-hello.

Before going east from the cargo bay:
	if the affection of Rodriguez is greater than 2:
		say "'Nice talking to you, doll,' Rodriguez says, and leans against the wall to watch you go.";
	otherwise:
		say "'Goodbye, [italic type]Commander[roman type],' Rodriguez drawls.".

Table of Quip Texts (continued)
quip			quiptext
r-innocent		"'Oh, nothing,' says Rodriguez, with an airy wave of her hand. 'Just checking on the inventory and all.'"
r-mercenary		"'As long as you're paying me, sweetheart,' she says, 'I'm ready for anything.'"
r-stealing		"'All right, maybe I'm not,' she admits. 'But in this position, who wouldn't contemplate cutting and running with a nice share of the cargo?'"
r-gone			"Rodriguez raises an eyebrow. 'If you want me gone, Commander, just say the word. I don't stay where I'm not wanted.'"
r-prissy			"'With all due respect,' Rodriguez says, 'you're a prissy goody-two-shoes.'"
r-runaway		"'Why, Commander,' Rodriguez says, grinning wolfishly. 'Are you asking me to run away with you?'"
r-stuck			"'Well, then, I guess we're stuck with each other,' she says. 'And now if you'll excuse me, I have things to do. Important things.'"
r-sorry			"Rodriguez snorts. 'Not only are you a priss, you're a priss with no conviction. But thanks.'"
r-grudging		"'At least you own it,' she says. 'I can respect that.'"
r-haha			"'Oh, that is precious,' she laughs. 'Haven't you got some wrongs to be righting, then? You had better run along.'"
r-seeyou		"'My pleasure,' she says, sweeping a mocking bow. 'Now, haven't you got stick-in-the-mud things to be attending to? I'll talk to you later.'"
r-wastetime		"'In that case, we had better not waste any more of one another's time, hmm?' she says, and without waiting for a response, goes back to rifling through the boxes."
r-sowhat		"She raises her eyebrows. 'Why shouldn't it be?'"
r-hooray		"'Glad we're on the same page,' she says. 'You wouldn't believe how many people hire my services and then are shocked--shocked, I tell you!--that I don't care about their cause.'"
r-whatevs		"She shrugs. 'I'm sure someone else would save the galaxy if I didn't. I don't really want to argue about this.'"
r-money		"'Ah, a person after my own heart.' She grins. 'Shall we get back to our money-making endeavors, then?'"
r-rich			"'The love of money is the root of being rich,' she says. 'That's the important part, as far as I'm concerned. So you can take your moralizing and shove it.'"
r-later			"'My, so forward!' she says. 'Come by later and we'll see what we can do about that.'"
r-joking			"'Neither was I, sweetcheeks,' she says. 'Look, I'm busy right now. Can we talk another time?'"
r-goodbye		"Rodriguez shrugs. 'Suit yourself.'"
r-hello			"Rodriguez gives a casual wave. 'Hey, babe.'"

Table of Rodriguez Comments
prompt																		response		enabled
"What are you doing in here?"													r-innocent		1
"Ready to kick some Space Douchebags in the teeth?"								r-mercenary		1
"Haha, sure you are."															r-stealing		0
"You're stealing, aren't you? I should never have allowed space pirates on my ship!"	r-gone			0
"I wouldn't! That would be wrong."												r-prissy			0
"Fair enough. Just don't go without me if you do, okay?"							r-runaway		0
"Maybe I am."																r-later			0
"I wasn't serious."																r-joking			0
"Sadly, I can't. Regulations, you know."											r-stuck			0
"Sorry, I guess I was out of line."												r-sorry			0
"That's Commander Goody-Two-Shoes to you."									r-grudging		0
"I am not! I just know right from wrong, unlike some people."						r-haha			0
"Thank you."																	r-seeyou		0
"I don't want [italic type]your[roman type] respect."								r-wastetime		0
"Is the money all you care about?"												r-sowhat		0
"That's what I like to hear."														r-hooray		0
"Isn't saving the entire galaxy a cause you should care about?"						r-whatevs		0
"I'm mostly in it for the money myself."											r-money		0
"They say the love of money is the root of evil, you know."							r-rich			0
"I'm done with this conversation."												r-goodbye		1

After quipping when the current quip is r-innocent:
	disable the r-innocent quip;
	disable the r-mercenary quip;
	enable the r-stealing quip;
	enable the r-gone quip.
	
After quipping when the current quip is r-mercenary:
	increase the affection of Rodriguez by 1;
	disable the r-innocent quip;
	disable the r-mercenary quip;
	enable the r-sowhat quip;
	enable the r-hooray quip.

After quipping when the current quip is r-stealing:
	increase the affection of Rodriguez by 1;
	disable the r-stealing quip;
	disable the r-gone quip;
	enable the r-prissy quip;
	enable the r-runaway quip;
	
After quipping when the current quip is r-gone:
	decrease the affection of Rodriguez by 1;
	decrease the niceness of the player by 1;
	disable the r-stealing quip;
	disable the r-gone quip;
	enable the r-stuck quip;
	enable the r-sorry quip.
	
After quipping when the current quip is r-prissy:
	decrease the affection of Rodriguez by 1;
	increase the niceness of the player by 1;
	disable the r-prissy quip;
	disable the r-runaway quip;
	enable the r-grudging quip;
	enable the r-haha quip.

After quipping when the current quip is r-runaway:
	increase the affection of Rodriguez by 1;
	decrease the niceness of the player by 1;
	disable the r-prissy quip;
	disable the r-runaway quip;
	enable the r-later quip;
	enable the r-joking quip.
	
After quipping when the current quip is r-stuck:
	decrease the affection of Rodriguez by 1;
	disable the r-stuck quip;
	disable the r-sorry quip;
	now Rodriguez is conversed;
	terminate the conversation.

After quipping when the current quip is r-sorry:
	increase the niceness of the player by 1;
	disable the r-stuck quip;
	disable the r-sorry quip;
	now Rodriguez is conversed;
	terminate the conversation.
	
After quipping when the current quip is r-grudging:
	increase the niceness of the player by 1;
	increase the affection of Rodriguez by 1;
	disable the r-grudging quip;
	disable the r-haha quip;
	enable the r-seeyou quip;
	enable the r-wastetime quip.
	
After quipping when the current quip is r-haha:
	increase the niceness of the player by 1;
	decrease the affection of Rodriguez by 1;
	disable the r-grudging quip;
	disable the r-haha quip;
	now Rodriguez is conversed;
	terminate the conversation.
	
After quipping when the current quip is r-seeyou:
	increase the affection of Rodriguez by 1;
	increase the niceness of the player by 1;
	disable the r-seeyou quip;
	disable the r-wastetime quip;
	now Rodriguez is conversed;
	terminate the conversation.

After quipping when the current quip is r-wastetime:
	decrease the niceness of the player by 1;
	decrease the affection of the player by 1;
	disable the r-seeyou quip;
	disable the r-wastetime quip;
	now Rodriguez is conversed;
	terminate the conversation.
	
After quipping when the current quip is r-sowhat:
	decrease the affection of Rodriguez by 1;
	increase the niceness of the player by 1;
	disable the r-sowhat quip;
	disable the r-hooray quip;
	enable the r-whatevs quip;
	enable the r-rich quip.
	
After quipping when the current quip is r-money:
	decrease the niceness of the player by 1;
	increase the affection of Rodriguez by 2;
	disable the r-whatevs quip;
	disable the r-money quip;
	now Rodriguez is conversed;
	terminate the conversation.

After quipping when the current quip is r-rich:
	decrease the niceness of the player by 1;
	decrease the affection of Rodriguez by 1;
	disable the r-whatevs quip;
	disable the r-rich quip;
	now Rodriguez is conversed;
	terminate the conversation.

After quipping when the current quip is r-later:
	increase the affection of Rodriguez by 1;
	disable the r-later quip;
	disable the r-joking quip;
	now Rodriguez is conversed;
	terminate the conversation.

After quipping when the current quip is r-joking:
	decrease the affection of Rodriguez by 1;
	disable the r-later quip;
	disable the r-joking quip;
	now Rodriguez is conversed;
	terminate the conversation.
	
After quipping when the current quip is r-hooray:
	increase the affection of Rodriguez by 1;
	decrease the niceness of the player by 1;
	enable the r-whatevs quip;
	enable the r-money quip;
	disable the r-sowhat quip.
	
After quipping when the current quip is r-whatevs:
	disable the r-rich quip;
	disable the r-whatevs quip;
	now Rodriguez is conversed;
	terminate the conversation.

Section - Nolan

Nolan is a man in the Diplomacy Chamber. "Nolan is here, [one of]lounging on the bed.[or]lighting some incense.[or]plucking idly at some odd kind of musical instrument.[at random]". The description of Nolan is "Nolan Sagarin, your diplomatic officer, catches your gaze and gives you a warm smile. He is dressed in a deep-red robe with gold trim, which both matches the decor of the room and picks up the hints of red and gold in his curly brown hair. The robe is open just enough to afford you a glimpse of his well-muscled chest.[paragraph break]Your ship as a whole is more of an ass-kicking ship than a diplomacy-having ship, but you are still representatives of the Council, and as such there are some situations which require a more delicate touch. Nolan's job is to handle those situations. To put people at their ease in an intimate one-on-one environment (or one-on-several, if that's what floats their spaceship). To give people a hands-on demonstration of your commitment to galactic peace.[paragraph break]What we're saying here is that his job is to bone people. For politics."

The litany of Nolan is the Table of Nolan Comments.

The greeting of Nolan is n-hello.

Before going west from the Diplomacy Chamber:
	if the affection of Nolan is greater than three:
		say "'Be well,'  says Nolan, lightly touching your shoulder.";
	otherwise:
		say "'Goodbye,' Nolan says, in a perfectly calm and impassive tone".

Table of Quip Texts (continued)
quip			quiptext
n-hello			"Nolan looks up. 'Oh, hello, [the player's forename]. Would you like to talk?'"
n-feelings		"He smiles, amused. 'If that's what you'd like to discuss,' he says."
n-marine		"'If you say so.' He isn't quite laughing, but you get the feeling he'd like to. He glances over to the other side of the room, where a kettle is steaming on a brazier. 'Would you like some tea?'"
n-marine2		"'If you say so.' He isn't quite laughing, but you get the feeling he'd like to. He glances over to the other side of the room, where a kettle is steaming on a brazier. 'Would you like some tea?'"
n-notea			"Nolan raises an eyebrow. 'I see. Well, suit yourself; I for one am going to have some tea now.' He turns and begins busying himself with the tea kettle."
n-tea			"He pours you a cup and hands it to you. 'This is a special blend made by a friend of mine.'"
n-special		"'It's just tea,' he says mildly. 'Nothing that exciting, I'm afraid. But if you don't trust me, you don't have to drink it.' He takes the cup back from you."
n-sharing		"He smiles. 'I'm not much for keeping things all to myself. Please, enjoy it.'"
n-whatsup		"'Well enough.' He pours two cups of tea and hands you one. 'These long space journeys can drag somewhat, but I keep myself occupied.'"
n-seduction		"'Everyone? That would be quite an undertaking. I don't have [italic type]that[roman type] much time.'"
n-movesfast		"'Because I'm so terribly charming?' he says, smiling sweetly. 'Thank you, you're too kind.'"
n-job			"'Just because something is in your job description doesn't mean it's all you do in your free time. Although,' he adds with a grin, 'I do enjoy it.'"
n-skilled			"'I'd like to think so,' he says. 'Perhaps I'll show you sometime. But not just yet, I think.'"
n-enjoy			"'Precisely,' he says, with a small laugh."
n-hobbies		"'I read. I listen to music and dabble in making it. I meditate. That sort of thing.'"
n-boring		"'Well, to each their own. Although if you find me so dull, perhaps you would like to spend your own free time elsewhere.' He gives you a pointed look."
n-music			"'One thing I appreciate about all this travel is that it has given me the opportunity to discover a wide variety of music. I once attended a live performance of Kangra music on the planet Xaros, and...'"
n-busy			"'Of course,' he says smoothly, 'your duties must keep you very busy. Perhaps we will speak again later.'"
n-cool			"'You should try a live performance at least once, if you have the chance. Recordings just aren't the same. Ah, but I shouldn't waste your time babbling on,' he adds. 'I'm sure you have important things to attend to.'"
n-goodbye		"'It has been a pleasure talking to you,' Nolan says. You can't tell whether or not he's completely sincere."

Table of Nolan Comments
prompt																		response		enabled
"About what, my feelings?"													n-feelings		1
"No way, I'm a Space Marine. I don't have feelings!"								n-marine		0
"No, I only drink badass drinks, like diesel fuel with razor blades in it."				n-notea			0
"Sure, I'd love some."															n-tea			0
"'Special', huh? What's it spiked with?"											n-special		0
"Thanks for sharing it with me, then. You must have a limited supply."				n-sharing		0
"Well, I'm not feeling especially feelings-y right now, but maybe later."				n-marine2		0
"Sure. How are you doing?"													n-whatsup		1
"By seducing everyone on the entire ship, right?"									n-seduction		0
"Oh, I doubt it would take you that long."										n-movesfast		0
"Sorry, I just assumed... what with your job..."									n-job			0
"You must be very skilled at it."													n-skilled			0
"Yeah, I guess you'd have to or you'd have chosen a different career path, huh?"		n-enjoy			0
"What do you do?"															n-hobbies		0
"Those are pretty lame hobbies."												n-boring		0
"Sounds pretty cool. I like music."												n-music			0
"Yeah that's totally fascinating bro, but oh hey look at the time!"					n-busy			0
"That sounds like fun! I mostly just listen to stuff on the extranet myself."				n-cool			0
"I'm done with this conversation."												n-goodbye		1

After quipping when the current quip is n-feelings:
	disable the n-whatsup quip;
	disable the n-feelings quip;
	enable the n-marine quip;
	enable the n-marine2 quip.

After quipping when the current quip is n-marine:
	decrease the affection of Nolan by 1;
	disable the n-marine2 quip;
	disable the n-marine quip;
	enable the n-tea quip;
	enable the n-notea quip.
	
After quipping when the current quip is n-marine2:
	increase the affection of Nolan by 1;
	disable the n-marine2 quip;
	disable the n-marine quip;
	enable the n-tea quip;
	enable the n-notea quip.

After quipping when the current quip is n-tea:
	increase the affection of Nolan by 1;
	disable the n-tea quip;
	disable the n-notea quip;
	enable the n-special quip;
	enable the n-sharing quip.

After quipping when the current quip is n-notea:
	decrease the affection of Nolan by one;
	disable the n-tea quip;
	disable the n-notea quip;
	now Nolan is conversed;
	terminate the conversation.

After quipping when the current quip is n-special:
	decrease the affection of Nolan by 1;
	disable the n-special quip;
	disable the n-sharing quip;
	now Nolan is conversed;
	terminate the conversation.

After quipping when the current quip is n-sharing:
	increase the affection of Nolan by 1;
	disable the n-special quip;
	disable the n-sharing quip;
	remove the no-tea from play;
	now the player carries the cup of tea.

After quipping when the current quip is n-whatsup:
	increase the affection of Nolan by 1;
	disable the n-whatsup quip;
	disable the n-feelings quip;
	enable the n-seduction quip;
	enable the n-hobbies quip;
	remove the no-tea from play;
	now the player carries the cup of tea.

After quipping when the current quip is n-seduction:
	decrease the affection of Nolan by 1;
	disable the n-seduction quip;
	disable the n-hobbies quip;
	enable the n-movesfast quip;
	enable the n-job quip.

After quipping when the current quip is n-movesfast:
	decrease the affection of Nolan by 1;
	disable the n-movesfast quip;
	disable the n-job quip;
	now Nolan is conversed;
	terminate the conversation.

After quipping when the current quip is n-job:
	increase the affection of Nolan by 1;
	disable the n-movesfast quip;
	disable the n-job quip;
	enable the n-skilled quip;
	enable the n-enjoy quip.

After quipping when the current quip is n-skilled:
	increase the affection of Nolan by 1;
	disable the n-skilled quip;
	disable the n-enjoy quip;
	now Nolan is conversed;
	terminate the conversation.

After quipping when the current quip is n-enjoy:
	disable the n-skilled quip;
	disable the n-enjoy quip;
	now Nolan is conversed;
	terminate the conversation.

After quipping when the current quip is n-hobbies:
	increase the affection of Nolan by 1;
	disable the n-seduction quip;
	disable the n-hobbies quip;
	enable the n-boring quip;
	enable the n-music quip.

After quipping when the current quip is n-boring:
	decrease the affection of Nolan by 1;
	disable the n-boring quip;
	disable the n-music quip;
	now Nolan is conversed;
	terminate the conversation.

After quipping when the current quip is n-music:
	increase the affection of Nolan by 1;
	disable the n-boring quip;
	disable the n-music quip;
	enable the n-busy quip;
	enable the n-cool quip.

After quipping when the current quip is n-busy:
	decrease the affection of Nolan by 1;
	disable the n-busy quip;
	disable the n-cool quip;
	now Nolan is conversed;
	terminate the conversation.

After quipping when the current quip is n-cool:
	increase the affection of Nolan by 1;
	disable the n-busy quip;
	disable the n-cool quip;
	now Nolan is conversed;
	terminate the conversation.

After quipping when the current quip is n-goodbye:
	now Nolan is conversed;
	terminate the conversation.
	
After drinking the cup of tea:
	now the player is carrying the no-tea.
	
Section - Khar'ss

Khar'ss is a man in the sleeping quarters. "Khar'ss is here, [one of]sharpening his claws on one of the beds.[or]grooming himself.[or]just sort of lazing around.[at random]". The description of Khar'ss is "Khar'ss Ff'thrar mrr Rheow is the most feared assassin this side of the Virgo Supercluster. Well, okay, that's not really true. Khar'ss [italic type]would[roman type] be the most feared assassin this side of the Virgo Supercluster if anyone actually knew who he was. However, since he's good at his job, no one does.[paragraph break]He may look cute with his slight build, wide greeny-gold eyes, and general fluffiness, but he is a ruthless and efficient killer. His sharp and pointy weapons are a part of his body, unlikely to raise suspicion, impossible to confiscate. He can move so silently that the most observant bodyguard would never know he was there. He can blend effortlessly into any situation, coming and going completely unnoticed. All things considered, you're glad he's on your side. You just wish he'd stop marking everything on the ship as his property by peeing on it."

The litany of Khar'ss is the Table of Khar'ss comments.

The greeting of Khar'ss is k-hello.

Before going south from the Sleeping Quarters:
	if the affection of Khar'ss is greater than 2:
		say "Khar'ss rubs his face against your shoulder affectionately. This is just one of those things that he does that you have to put up with.";
	otherwise:
		say "Khar'ss pretends not to notice you leaving.".

Table of Quip Texts (continued)
quip			quiptext
k-hello			"'Oh, hello, Commander [the player's surname],' Khar'ss says, looking at you hopefully. 'Have you got any fish?'"
k-nofish			"Khar'ss looks affronted; his stubby vestigial tail twitches in annoyance. 'Why [italic type]wouldn't[roman type] you be?'"
k-getfish		"'That's all right,' he says, 'it isn't urgent. But perhaps later...?'"
k-doitself		"'Of course I can get it myself,' he says. 'It's just... oh, never mind. [italic type]You[roman type] wouldn't understand.' He gets up and stalks over to the other side of the room. Evidently your conversation is over."
k-yayfish		"'Why, thank you,' he purrs. 'You're too kind. A bit of grilled salmon would do nicely.'"
k-butfish		"'But it's fish!' Khar'ss exclaims. 'How can you not need fish?'"
k-wellok			"Khar'ss sighs. 'Well, I [italic type]suppose[roman type] that's a good enough reason. But you could still get some for me, couldn't you?'"
k-wellok2		"Khar'ss sighs. 'Well, I [italic type]suppose[roman type] that's a good enough reason. But you could still get some for me, couldn't you?'"
k-ugh			"'How rude,' Khar'ss sniffs. 'Entirely uncalled-for, really.' He begins carefully grooming a paw, no longer paying attention to you."
k-thanks		"'That's all I ask,' Khar'ss says magnanimously. 'And now you had better be off, hadn't you?'"
k-what			"'Excuse me?' Khar'ss says, his ears back and his teeth bared. 'I don't insult the disgusting food that you humans eat, do I? Like textured soy protein, or-' he shudders delicately- '[italic type]vegetables[roman type].'"
k-whatever		"'That was different,' he says. 'Entirely different. And I am quite finished dealing with your rudeness.'"
k-fine			"Khar'ss tilts his head to one side and considers what you've said for a long moment. 'I suppose I can forgive you,' he says. 'But I'm still not going to talk to you for the rest of the day. That's your punishment.'"
k-goodbye		"'Oh, well, that's fine, then. So was I. In fact, I was done with it [italic type]first[roman type].'".

Table of Khar'ss Comments
prompt																		response		enabled
"No, obviously not. Why would I be carrying fish around with me?"					k-nofish			1
"Uh, I could go get some..."													k-getfish		1
"Come to think of it, why can't you get it yourself?"								k-doitself		0
"Okay, I'll stop by the galley later and see what they've got."						k-yayfish		0
"Why the fuck would I need fish for anything?"									k-butfish		0
"Because this space armor has no pockets."										k-wellok			0
"We've been in space for months, dumbass. All we've got is tinned sardines."			k-ugh			0
"I'll see what I can do, but I make no promises."									k-thanks		0
"I hate seafood, actually. It's so gross."											k-what			0
"I don't know, it just doesn't come up a lot, I guess."								k-wellok2		0
"You just did, didn't you?"														k-whatever		0
"I'm sorry, I shouldn't have said that."											k-fine			0
"I'm done with this conversation."												k-goodbye		1

After quipping when the current quip is k-nofish:
	decrease the niceness of the player by 1;
	decrease the affection of khar'ss by 1;
	disable the k-nofish quip;
	disable the k-getfish quip;
	enable the k-butfish quip;
	enable the k-wellok quip.

After quipping when the current quip is k-getfish:
	increase the niceness of the player by 1;
	increase the affection of khar'ss by 1;
	disable the k-nofish quip;
	disable the k-getfish quip;
	enable the k-doitself quip;
	enable the k-yayfish quip.
	
After quipping when the current quip is k-doitself:
	decrease the affection of khar'ss by 1;
	disable the k-doitself quip;
	disable the k-yayfish quip;
	now Khar'ss is conversed;
	terminate the conversation.

After quipping when the current quip is k-yayfish:
	increase the niceness of the player by 1;
	increase the affection of khar'ss by 1;
	disable the k-doitself quip;
	disable the k-yayfish quip;
	enable the k-ugh quip;
	enable the k-thanks quip.

After quipping when the current quip is k-butfish:
	decrease the niceness of the player by 1;
	decrease the affection of khar'ss by 1;
	disable the k-butfish quip;
	disable the k-wellok quip;
	enable the k-what quip;
	enable the k-wellok2 quip.
	
After quipping when the current quip is k-wellok:
	disable the k-butfish quip;
	disable the k-wellok quip;
	enable the k-doitself quip;
	enable the k-yayfish quip.
	
After quipping when the current quip is k-wellok2:
	disable the k-what quip;
	disable the k-wellok2 quip;
	enable the k-doitself quip;
	enable the k-yayfish quip.

After quipping when the current quip is k-ugh:
	decrease the niceness of the player by 1;
	decrease the affection of khar'ss by 1;
	disable the k-ugh quip;
	disable the k-thanks quip;
	now Khar'ss is conversed;
	terminate the conversation.

After quipping when the current quip is k-thanks:
	increase the niceness of the player by 1;
	increase the affection of khar'ss by 1;
	disable the k-ugh quip;
	disable the k-thanks quip;
	now Khar'ss is conversed;
	terminate the conversation.
	
After quipping when the current quip is k-what:
	decrease the niceness of the player by 1;
	decrease the affection of khar'ss by 1;
	disable the k-what quip;
	disable the k-wellok2 quip;
	enable the k-whatever quip;
	enable the k-fine quip.

After quipping when the current quip is k-whatever:
	decrease the niceness of the player by 1;
	decrease the affection of khar'ss by 1;
	disable the k-whatever quip;
	disable the k-fine quip;
	now Khar'ss is conversed;
	terminate the conversation.

After quipping when the current quip is k-fine:
	increase the niceness of the player by 1;
	increase the affection of khar'ss by 1;
	disable the k-whatever quip;
	disable the k-fine quip;
	now Khar'ss is conversed;
	terminate the conversation.
	
Chapter - Stats

A person has a number called affection. The affection of a person is usually 0.

A person has a number called niceness.

Definition: a person (called the PC) is nice if the niceness of the PC is greater than 0.

Definition: a person (called the PC) is mean if the niceness of the PC is less than 0.

Definition: a person (called the PC) is neutral if the niceness of the PC is 0.

Chapter - Other Stuff

A person can be conversed or unconversed. A person is usually unconversed.

To say a-status of player: 
	if the affection of Anneli is greater than 2:
		say "Anneli thinks you are awesome.";
	otherwise if the affection of Anneli is less than 3 and the affection of Anneli is greater than 0:
		say "Anneli thinks you are kind of okay.";
	otherwise:
		say "Anneli thinks you are a no-fun killjoy.".
		
To say r-status of player:
	if the affection of Rodriguez is greater than 2:
		say "Rodriguez thinks you're pretty OK, actually.";
	otherwise if the affection of Rodriguez is less than 3 and the affection of Rodriguez is greater than 0:
		say "Rodriguez finds you tolerable.";
	otherwise:
		say "Rodriguez thinks you're a moralistic stick-in-the-mud.".

To say k-status of player:
	if the affection of Khar'ss is greater than 2:
		say "Khar'ss will love you as long as you bring him that fish.";
	otherwise if the affection of Khar'ss is less than 3 and the affection of Khar'ss is greater than 0:
		say "Khar'ss doesn't like you that much, but he [italic type]might[roman type] reconsider if you feed him.";
	otherwise:
		say "Khar'ss thinks you are a fish-hating jerk.".

To say n-status of player:
	if the affection of Nolan is greater than 2:
		say "Nolan would have tea with you anytime.";
	otherwise if the affection of Nolan is less than 3 and the affection of Nolan is greater than 0:
		say "Nolan is shaking his head at you just a little bit.";
	otherwise:
		say "Nolan is probably secretly laughing at you right now.".
		
To say m-status of player:
	if the niceness of the player is greater than 0:
		say "On balance, you acted like a pretty good person.";
	otherwise if the niceness of the player is less than 0:
		say "You were kind of selfish and needlessly mean.";
	otherwise:
		say "You have subverted our binary morality system by being nice and douchey in roughly equal measure. You paragade, you."
	

Chapter - Ending the Game

Final is a scene. Final begins when Anneli is conversed and Nolan is conversed and Khar'ss is conversed and Rodriguez is conversed.

When Final begins:
	say "If this were something remotely resembling a finished game, this would be where an event would happen that would advance the plot or something. Instead you have reached the end of the content that the programmer has bothered to put in at this stage. Congratulations! Here's how things shook out:[paragraph break][m-status of player][paragraph break][a-status of player][paragraph break][r-status of player][paragraph break][n-status of player][paragraph break][k-status of player]";
	end the story finally saying "FIN".