Dare Not Speak by Jake Wallace

Dare Not Speak

Played 1,557 times
View game source (spoilers!)
Download the .z8 file
Source Code

"Dare Not Speak"

Use no scoring.

Part Prologue

The Clearing is a room. "You are in the middle of a clearing in a lush garden. Plants of all kinds spread out in dense, uneven rows."

Plants are scenery in the Clearing. The description is "There are plants of all kinds here."

A tree is here. "There is a large fruit tree here, with unusual fruit like you've never seen before.[if we have examined the snake] There is a snake perched in the branches of the tree."

A thing can be examined or unexamined. A thing is usually unexamined. After examining something: now the noun is examined; continue the action.

Understand "talk to [someone]" as a mistake ("To start a conversation, try to ASK [the noun] ABOUT something or TELL [the noun] ABOUT something.").

The snake is an animal in the tree. The description is "There is a large snake sunning in the branches of the tree. [if unexamined]The snake is looking at you languidly, as though he has something to say.[end if]"

Instead of asking snake about "Eve", say "The snake smiles, 'Honey, you've got the wrong garden.'"

Instead of asking snake about "garden", say "The snake sighs, 'Aren't you interested in the fruit?'"

Instead of asking snake about "tree/fruit":
	say "The snake hisses, 'The tree is a portal. Those who eat the fruit will possess knowledge. Only those over 18 should proceed. Do YOU want to proceed?'";
	if the player consents:
		say "The snake smiles and uncoils from the fruit, which you take gingerly.";
		move fruit to player;
	otherwise:
		say "The snake sighs, 'Run along now.'";
		end the story;

fruit is in the tree. The description is "The fruit is an intense red-orange, like a cross between a pomegranate and a blood orange."

Instead of taking fruit, say "The snake rears at you when you reach for the fruit."

Instead of eating fruit:
	say "You push your thumb into the fruit, breaking the nubby rind to reveal the blood-red fruit inside. You eat a segment tentatively. It has the slightly bitter, herbal taste of a chinotto orange mixed with the tannin sweetness of a pomegranate. You feel a slight head-rush and you begin scarfing down the fruit greedily while the world swirls around you...";
	move player to the Apartment, without printing a room description

Part 1 - Roommates

Instead of examining player:
	if the player is in the Clearing:
		say "You are naked, but don't feel embarassed. In fact, you think you look pretty good. You have an athletic build with defined abs that taper to a slim waist.";
	if the player is in the Apartment:
		say "You are wearing your favorite red flannel jammies, without a shirt. Your chest is covered in a sticky-sweet substance, like fruit juice.";

The Apartment is a room. "You are standing in the living room of your apartment. The sun is shining through the windows, and you blink and try to remember how you got here. You're wearing your red flannel pajamas, so you must have been sleep-walking again. Your bare chest is covered with a sticky, sweet substance. Sleep-eating? That's a new one."

The front door is east of the Apartment and west of the Front Yard. It is a door and scenery.

Every turn when the player is in the Apartment and the front door is closed:
	say "The doorbell is ringing."

Colin is a person. The description is "He's average height, with wide shoulders and an athletic build. In fact, his whole body is uniformly wide. He somehow manages to look [bold type]solid[roman type] without looking stocky. His neatly-kempt curly black hair contrasts with his shock-blue eyes."

Instead of opening the front door:
	now the front door is open;
	move Colin to Front Yard;
	say "You open the front door. A man is standing outside in the act of pushing the doorbell. He looks annoyed, but his annoyance quickly gives way to amusement as notices your shirtless, sticky chest.[line break]'Hi, I'm Colin. Here to see the apartment. It looks like I woke you...'"

Every turn when the front door is open and Colin is in the Front Yard:
	say "Colin eyes you,  [one of]amused. 'Is this a bad time?'[or]quizzically. 'Are you ok? Is the apartment still available?'[or]confused. 'I saw the ad online. Can I see the room now?'[or]annoyed. 'I can come back later if you need some time.'[as decreasingly likely outcomes]"

Instead of asking Colin about "apartment/coming in/room":
	say "'Oh, right. Come in.";
	move Colin to apartment;